SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any);
   7
   8 use SL::Helper::Csv;
   9 use SL::DB::Order;
  10 use SL::DB::OrderItem;
  11 use SL::DB::Part;
  12 use SL::DB::PaymentTerm;
  13 use SL::DB::Contact;
  14 use SL::DB::Department;
  15 use SL::DB::Project;
  16 use SL::DB::Shipto;
  17 use SL::TransNumber;
  18
  19 use parent qw(SL::Controller::CsvImport::BaseMulti);
  20
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24  'scalar --get_set_init' => [ qw(settings languages_by all_parts parts_by all_contacts contacts_by all_departments departments_by all_projects projects_by all_ct_shiptos ct_shiptos_by) ],
  25 );
  26
  27
  28 sub init_class {
  29   my ($self) = @_;
  30   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  31 }
  32
  33
  34 sub init_settings {
  35   my ($self) = @_;
  36
  37   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column) };
  38 }
  39
  40
  41 sub init_profile {
  42   my ($self) = @_;
  43
  44   my $profile = $self->SUPER::init_profile;
  45
  46   foreach my $p (@{ $profile }) {
  47     my $prof = $p->{profile};
  48     if ($p->{row_ident} eq 'Order') {
  49       # no need to handle
  50       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  51       # handable, but not handled by now
  52     }
  53     if ($p->{row_ident} eq 'OrderItem') {
  54       delete @{$prof}{qw(trans_id)};
  55     }
  56   }
  57
  58   return $profile;
  59 }
  60
  61
  62 sub setup_displayable_columns {
  63   my ($self) = @_;
  64
  65   $self->SUPER::setup_displayable_columns;
  66
  67   $self->add_displayable_columns('Order',
  68                                  { name => 'datatype',         description => $::locale->text('Zeilenkennung')                  },
  69                                  { name => 'verify_amount',    description => $::locale->text('Amount (for verification)')      },
  70                                  { name => 'verify_netamount', description => $::locale->text('Net amount (for verification)')  },
  71                                  { name => 'taxincluded',      description => $::locale->text('Tax Included')                   },
  72                                  { name => 'customer',         description => $::locale->text('Customer (name)')                },
  73                                  { name => 'customernumber',   description => $::locale->text('Customer Number')                },
  74                                  { name => 'customer_id',      description => $::locale->text('Customer (database ID)')         },
  75                                  { name => 'vendor',           description => $::locale->text('Vendor (name)')                  },
  76                                  { name => 'vendornumber',     description => $::locale->text('Vendor Number')                  },
  77                                  { name => 'vendor_id',        description => $::locale->text('Vendor (database ID)')           },
  78                                  { name => 'language_id',      description => $::locale->text('Language (database ID)')         },
  79                                  { name => 'language',         description => $::locale->text('Language (name)')                },
  80                                  { name => 'payment_id',       description => $::locale->text('Payment terms (database ID)')    },
  81                                  { name => 'payment',          description => $::locale->text('Payment terms (name)')           },
  82                                  { name => 'taxzone_id',       description => $::locale->text('Steuersatz')                     },
  83                                  { name => 'cp_id',            description => $::locale->text('Contact Person (database ID)')   },
  84                                  { name => 'contact',          description => $::locale->text('Contact Person (name)')          },
  85                                  { name => 'department_id',    description => $::locale->text('Department (database ID)')       },
  86                                  { name => 'department',       description => $::locale->text('Department (description)')       },
  87                                  { name => 'globalproject_id', description => $::locale->text('Document Project (database ID)') },
  88                                  { name => 'globalprojectnumber', description => $::locale->text('Document Project (number)')   },
  89                                  { name => 'globalproject',    description => $::locale->text('Document Project (description)') },
  90                                  { name => 'shipto_id',        description => $::locale->text('Ship to (database ID)')          },
  91                                 );
  92
  93   $self->add_displayable_columns('OrderItem',
  94                                  { name => 'parts_id',       description => $::locale->text('Part (database ID)')          },
  95                                  { name => 'partnumber',     description => $::locale->text('Part Number')                 },
  96                                 );
  97 }
  98
  99
 100 sub init_languages_by {
 101   my ($self) = @_;
 102
 103   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 104 }
 105
 106 sub init_all_parts {
 107   my ($self) = @_;
 108
 109   return SL::DB::Manager::Part->get_all;
 110 }
 111
 112 sub init_parts_by {
 113   my ($self) = @_;
 114
 115   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_parts } } ) } qw(id partnumber ean description) };
 116 }
 117
 118 sub init_all_contacts {
 119   my ($self) = @_;
 120
 121   return SL::DB::Manager::Contact->get_all;
 122 }
 123
 124 sub init_contacts_by {
 125   my ($self) = @_;
 126
 127   my $cby = { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_contacts } } ) } qw(cp_id cp_name) };
 128
 129   # by customer/vendor id  _and_  contact person id
 130   $cby->{'cp_cv_id+cp_id'} = { map { ( $_->cp_cv_id . '+' . $_->cp_id => $_ ) } @{ $self->all_contacts } };
 131
 132   return $cby;
 133 }
 134
 135 sub init_all_departments {
 136   my ($self) = @_;
 137
 138   return SL::DB::Manager::Department->get_all;
 139 }
 140
 141 sub init_departments_by {
 142   my ($self) = @_;
 143
 144   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_departments } } ) } qw(id description) };
 145 }
 146
 147 sub init_all_projects {
 148   my ($self) = @_;
 149
 150   return SL::DB::Manager::Project->get_all;
 151 }
 152
 153 sub init_projects_by {
 154   my ($self) = @_;
 155
 156   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_projects } } ) } qw(id projectnumber description) };
 157 }
 158
 159 sub init_all_ct_shiptos {
 160   my ($self) = @_;
 161
 162   return SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 163 }
 164
 165 sub init_ct_shiptos_by {
 166   my ($self) = @_;
 167
 168   my $sby = { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_ct_shiptos } } ) } qw(shipto_id) };
 169
 170   # by trans_id  _and_  shipto_id
 171   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $self->all_ct_shiptos } };
 172
 173   return $sby;
 174 }
 175
 176 sub check_objects {
 177   my ($self) = @_;
 178
 179   $self->controller->track_progress(phase => 'building data', progress => 0);
 180
 181   my $i;
 182   my $num_data = scalar @{ $self->controller->data };
 183   foreach my $entry (@{ $self->controller->data }) {
 184     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 185
 186     if ($entry->{raw_data}->{datatype} eq $self->settings->{'order_column'}) {
 187
 188       my $vc_obj;
 189       if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_id)) {
 190         $self->check_vc($entry, 'customer_id');
 191         $vc_obj = SL::DB::Customer->new(id => $entry->{object}->customer_id)->load if $entry->{object}->customer_id;
 192       } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_id)) {
 193         $self->check_vc($entry, 'vendor_id');
 194         $vc_obj = SL::DB::Vendor->new(id => $entry->{object}->vendor_id)->load if $entry->{object}->vendor_id;
 195       } else {
 196         push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 197       }
 198
 199       $self->check_contact($entry);
 200       $self->check_language($entry);
 201       $self->check_payment($entry);
 202       $self->check_department($entry);
 203       $self->check_project($entry, global => 1);
 204       $self->check_ct_shipto($entry);
 205
 206       if ($vc_obj) {
 207         # copy from customer if not given
 208         foreach (qw(payment_id language_id taxzone_id)) {
 209           $entry->{object}->$_($vc_obj->$_) unless $entry->{object}->$_;
 210         }
 211       }
 212
 213       # ToDo: salesman and emloyee by name
 214       # salesman from customer or login if not given
 215       if (!$entry->{object}->salesman) {
 216         if ($vc_obj && $vc_obj->salesman_id) {
 217           $entry->{object}->salesman(SL::DB::Manager::Employee->find_by(id => $vc_obj->salesman_id));
 218         } else {
 219           $entry->{object}->salesman(SL::DB::Manager::Employee->find_by(login => $::myconfig{login}));
 220         }
 221       }
 222
 223       # employee from login if not given
 224       if (!$entry->{object}->employee_id) {
 225         $entry->{object}->employee_id(SL::DB::Manager::Employee->find_by(login => $::myconfig{login})->id);
 226       }
 227
 228     }
 229   }
 230
 231   $self->add_info_columns($self->settings->{'order_column'},
 232                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 233   $self->add_columns($self->settings->{'order_column'},
 234                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment language department globalproject));
 235   $self->add_columns($self->settings->{'order_column'}, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 236
 237   foreach my $entry (@{ $self->controller->data }) {
 238     if ($entry->{raw_data}->{datatype} eq $self->settings->{'item_column'} && $entry->{object}->can('part')) {
 239
 240       next if !$self->check_part($entry);
 241
 242       my $part_obj = SL::DB::Part->new(id => $entry->{object}->parts_id)->load;
 243
 244       # copy from part if not given
 245       $entry->{object}->description($part_obj->description) unless $entry->{object}->description;
 246       $entry->{object}->longdescription($part_obj->notes)   unless $entry->{object}->longdescription;
 247       $entry->{object}->unit($part_obj->unit)               unless $entry->{object}->unit;
 248
 249       # set to 0 if not given
 250       $entry->{object}->discount(0)      unless $entry->{object}->discount;
 251       $entry->{object}->ship(0)          unless $entry->{object}->ship;
 252     }
 253   }
 254
 255   $self->add_info_columns($self->settings->{'item_column'},
 256                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 257
 258   # add orderitems to order
 259   my $order_entry;
 260   my @orderitems;
 261   foreach my $entry (@{ $self->controller->data }) {
 262     # search first Order
 263     if ($entry->{raw_data}->{datatype} eq $self->settings->{'order_column'}) {
 264
 265       # new order entry: add collected orderitems to the last one
 266       if (defined $order_entry) {
 267         $order_entry->{object}->orderitems(@orderitems);
 268         @orderitems = ();
 269       }
 270
 271       $order_entry = $entry;
 272
 273     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->settings->{'item_column'} ) {
 274       # collect orderitems to add to order (if they have no errors)
 275       # ( add_orderitems does not work here if we want to call
 276       #   calculate_prices_and_taxes afterwards ...
 277       #   so collect orderitems and add them at once)
 278       if (scalar @{ $entry->{errors} } == 0) {
 279         push @orderitems, $entry->{object};
 280       }
 281     }
 282   }
 283   # add last collected orderitems to last order
 284   if ($order_entry) {
 285     $order_entry->{object}->orderitems(@orderitems);
 286   }
 287
 288   # calculate prices and taxes
 289   foreach my $entry (@{ $self->controller->data }) {
 290     next if @{ $entry->{errors} };
 291
 292     if ($entry->{raw_data}->{datatype} eq $self->settings->{'order_column'}) {
 293
 294       $entry->{object}->calculate_prices_and_taxes;
 295
 296       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 297       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 298     }
 299   }
 300
 301   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 302   # And throw an error if the differences are too big.
 303   my $max_diff = 0.02;
 304   my @to_verify = ( { column      => 'amount',
 305                       raw_column  => 'verify_amount',
 306                       info_header => 'Calc. Amount',
 307                       info_method => 'calc_amount',
 308                       err_msg     => 'Amounts differ too much',
 309                     },
 310                     { column      => 'netamount',
 311                       raw_column  => 'verify_netamount',
 312                       info_header => 'Calc. Net amount',
 313                       info_method => 'calc_netamount',
 314                       err_msg     => 'Net amounts differ too much',
 315                     } );
 316
 317   foreach my $tv (@to_verify) {
 318     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 319       $self->add_raw_data_columns($self->settings->{'order_column'}, $tv->{raw_column});
 320       $self->add_info_columns($self->settings->{'order_column'},
 321                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 322     }
 323
 324     # check differences
 325     foreach my $entry (@{ $self->controller->data }) {
 326       next if @{ $entry->{errors} };
 327       if ($entry->{raw_data}->{datatype} eq $self->settings->{'order_column'}) {
 328         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 329         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 330         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $max_diff) {
 331           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 332         }
 333       }
 334     }
 335   }
 336
 337   # If order has errors set error for orderitems as well
 338   my $order_entry;
 339   foreach my $entry (@{ $self->controller->data }) {
 340     # Search first order
 341     if ($entry->{raw_data}->{datatype} eq $self->settings->{'order_column'}) {
 342       $order_entry = $entry;
 343     } elsif ( defined $order_entry
 344               && $entry->{raw_data}->{datatype} eq $self->settings->{'item_column'}
 345               && scalar @{ $order_entry->{errors} } > 0 ) {
 346       push @{ $entry->{errors} }, $::locale->text('order not valid for this orderitem!');
 347     }
 348   }
 349
 350 }
 351
 352
 353 sub check_language {
 354   my ($self, $entry) = @_;
 355
 356   my $object = $entry->{object};
 357
 358   # Check whether or not language ID is valid.
 359   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 360     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 361     return 0;
 362   }
 363
 364   # Map name to ID if given.
 365   if (!$object->language_id && $entry->{raw_data}->{language}) {
 366     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 367                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 368
 369     if (!$language) {
 370       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 371       return 0;
 372     }
 373
 374     $object->language_id($language->id);
 375   }
 376
 377   if ($object->language_id) {
 378     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 379   }
 380
 381   return 1;
 382 }
 383
 384 sub check_part {
 385   my ($self, $entry) = @_;
 386
 387   my $object = $entry->{object};
 388
 389   # Check wether or non part ID is valid.
 390   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 391     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 392     return 0;
 393   }
 394
 395   # Map number to ID if given.
 396   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 397     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 398     if (!$part) {
 399       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 400       return 0;
 401     }
 402
 403     $object->parts_id($part->id);
 404   }
 405
 406   if ($object->parts_id) {
 407     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 408   } else {
 409     push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 410     return 0;
 411   }
 412
 413   return 1;
 414 }
 415
 416 sub check_contact {
 417   my ($self, $entry) = @_;
 418
 419   my $object = $entry->{object};
 420
 421   # Check wether or not contact ID is valid.
 422   if ($object->cp_id && !$self->contacts_by->{cp_id}->{ $object->cp_id }) {
 423     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 424     return 0;
 425   }
 426
 427   # Map name to ID if given.
 428   # Todo: names have not to be unique ... search all and check for matching customer/vendor?
 429   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 430     my $cp = $self->contacts_by->{cp_name}->{ $entry->{raw_data}->{contact} };
 431     if (!$cp) {
 432       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 433       return 0;
 434     }
 435
 436     $object->cp_id($cp->cp_id);
 437   }
 438
 439   # Check if the contact belongs to this customer/vendor.
 440   my $trans_id = $object->customer_id || $object->vendor_id;
 441   if ($object->cp_id && $trans_id
 442       && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $trans_id . '+' . $object->cp_id }) {
 443     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact this customer/vendor');
 444     return 0;
 445   }
 446
 447   if ($object->cp_id) {
 448     $entry->{info_data}->{contact} = $self->contacts_by->{cp_id}->{ $object->cp_id }->cp_name;
 449   }
 450
 451   return 1;
 452 }
 453
 454 sub check_department {
 455   my ($self, $entry) = @_;
 456
 457   my $object = $entry->{object};
 458
 459   # Check wether or not department ID is valid.
 460   if ($object->department_id && !$self->departments_by->{id}->{ $object->department_id }) {
 461     push @{ $entry->{errors} }, $::locale->text('Error: Invalid department');
 462     return 0;
 463   }
 464
 465   # Map description to ID if given.
 466   if (!$object->department_id && $entry->{raw_data}->{department}) {
 467     my $dep = $self->departments_by->{description}->{ $entry->{raw_data}->{department} };
 468     if (!$dep) {
 469       push @{ $entry->{errors} }, $::locale->text('Error: Invalid department');
 470       return 0;
 471     }
 472
 473     $object->department_id($dep->id);
 474   }
 475
 476   return 1;
 477 }
 478
 479 sub check_project {
 480   my ($self, $entry, %params) = @_;
 481
 482   my $id_column          = ($params{global} ? 'global' : '') . 'project_id';
 483   my $number_column      = ($params{global} ? 'global' : '') . 'projectnumber';
 484   my $description_column = ($params{global} ? 'global' : '') . 'project';
 485
 486   my $object = $entry->{object};
 487
 488   # Check wether or not projetc ID is valid.
 489   if ($object->$id_column && !$self->projects_by->{id}->{ $object->$id_column }) {
 490     push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 491     return 0;
 492   }
 493
 494   # Map number to ID if given.
 495   if (!$object->$id_column && $entry->{raw_data}->{$number_column}) {
 496     my $proj = $self->projects_by->{projectnumber}->{ $entry->{raw_data}->{$number_column} };
 497     if (!$proj) {
 498       push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 499       return 0;
 500     }
 501
 502     $object->$id_column($proj->id);
 503   }
 504
 505   # Map description to ID if given.
 506   if (!$object->$id_column && $entry->{raw_data}->{$description_column}) {
 507     my $proj = $self->projects_by->{description}->{ $entry->{raw_data}->{$description_column} };
 508     if (!$proj) {
 509       push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 510       return 0;
 511     }
 512
 513     $object->$id_column($proj->id);
 514   }
 515
 516   return 1;
 517 }
 518
 519 sub check_ct_shipto {
 520   my ($self, $entry) = @_;
 521
 522   my $object = $entry->{object};
 523
 524   # Check wether or not shipto ID is valid.
 525   if ($object->shipto_id && !$self->ct_shiptos_by->{shipto_id}->{ $object->shipto_id }) {
 526     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 527     return 0;
 528   }
 529
 530   # Check if the shipto belongs to this customer/vendor.
 531   my $trans_id = $object->customer_id || $object->vendor_id;
 532   if ($object->shipto_id && $trans_id
 533       && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id } ) {
 534     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto for this customer/vendor');
 535     return 0;
 536   }
 537
 538   return 1;
 539 }
 540
 541
 542
 543 sub save_objects {
 544   my ($self, %params) = @_;
 545
 546   # set order number and collect to save
 547   my $objects_to_save;
 548   foreach my $entry (@{ $self->controller->data }) {
 549     next if @{ $entry->{errors} };
 550
 551     if ($entry->{raw_data}->{datatype} eq $self->settings->{'order_column'} && !$entry->{object}->ordnumber) {
 552       my $number = SL::TransNumber->new(type        => 'sales_order',
 553                                         save        => 1);
 554       $entry->{object}->ordnumber($number->create_unique());
 555     }
 556
 557     push @{ $objects_to_save }, $entry;
 558   }
 559
 560   $self->SUPER::save_objects(data => $objects_to_save);
 561 }
 562
 563
 564 1;