SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any none);
   7
   8 use SL::Helper::Csv;
   9 use SL::Controller::CsvImport::Helper::Consistency;
  10 use SL::DB::Order;
  11 use SL::DB::OrderItem;
  12 use SL::DB::Part;
  13 use SL::DB::PaymentTerm;
  14 use SL::DB::Contact;
  15 use SL::DB::Department;
  16 use SL::DB::PriceFactor;
  17 use SL::DB::Pricegroup;
  18 use SL::DB::Project;
  19 use SL::DB::Shipto;
  20 use SL::DB::TaxZone;
  21 use SL::DB::Unit;
  22 use SL::TransNumber;
  23
  24 use parent qw(SL::Controller::CsvImport::BaseMulti);
  25
  26
  27 use Rose::Object::MakeMethods::Generic
  28 (
  29  'scalar --get_set_init' => [ qw(settings languages_by all_parts parts_by part_counts_by contacts_by ct_shiptos_by price_factors_by pricegroups_by units_by) ],
  30 );
  31
  32
  33 sub init_class {
  34   my ($self) = @_;
  35   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  36 }
  37
  38 sub set_profile_defaults {
  39   my ($self) = @_;
  40
  41   $self->controller->profile->_set_defaults(
  42                        order_column    => $::locale->text('Order'),
  43                        item_column     => $::locale->text('OrderItem'),
  44                        max_amount_diff => 0.02,
  45                       );
  46 };
  47
  48
  49 sub init_settings {
  50   my ($self) = @_;
  51
  52   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  53 }
  54
  55
  56 sub init_cvar_configs_by {
  57   my ($self) = @_;
  58
  59   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  60   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  61
  62   my $ccb;
  63   $ccb->{class}->{'SL::DB::Order'}          = [];
  64   $ccb->{class}->{'SL::DB::OrderItem'}      = $item_cvar_configs;
  65   $ccb->{row_ident}->{$self->_order_column} = [];
  66   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  67
  68   return $ccb;
  69 }
  70
  71
  72 sub init_profile {
  73   my ($self) = @_;
  74
  75   my $profile = $self->SUPER::init_profile;
  76
  77   # SUPER::init_profile sets row_ident to the translated class name
  78   # overwrite it with the user specified settings
  79   foreach my $p (@{ $profile }) {
  80     if ($p->{class} eq 'SL::DB::Order') {
  81       $p->{row_ident} = $self->_order_column;
  82     }
  83     if ($p->{class} eq 'SL::DB::OrderItem') {
  84       $p->{row_ident} = $self->_item_column;
  85     }
  86   }
  87
  88   foreach my $p (@{ $profile }) {
  89     my $prof = $p->{profile};
  90     if ($p->{row_ident} eq $self->_order_column) {
  91       # no need to handle
  92       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  93     }
  94     if ($p->{row_ident} eq $self->_item_column) {
  95       # no need to handle
  96       delete @{$prof}{qw(trans_id)};
  97     }
  98   }
  99
 100   return $profile;
 101 }
 102
 103
 104 sub setup_displayable_columns {
 105   my ($self) = @_;
 106
 107   $self->SUPER::setup_displayable_columns;
 108
 109   $self->add_displayable_columns($self->_order_column,
 110                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
 111                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 112                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 113                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 114                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 115                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 116                                  { name => 'delivery_term_id',        description => $::locale->text('Delivery terms (database ID)')          },
 117                                  { name => 'delivery_term',           description => $::locale->text('Delivery terms (name)')                 },
 118                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 119                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 120                                  { name => 'marge_percent',           description => $::locale->text('Margepercent')                          },
 121                                  { name => 'marge_total',             description => $::locale->text('Margetotal')                            },
 122                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 123                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 124                                  { name => 'quonumber',               description => $::locale->text('Quotation Number')                      },
 125                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 126                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 127                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 128                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 129                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 130                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 131                                  { name => 'verify_amount',           description => $::locale->text('Amount (for verification)') . ' [2]'    },
 132                                  { name => 'verify_netamount',        description => $::locale->text('Net amount (for verification)') . ' [2]'},
 133                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 134                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 135                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 136                                  { name => 'customer_gln',            description => $::locale->text('Customer GLN')                          },
 137                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 138                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 139                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 140                                  { name => 'vendor_gln',              description => $::locale->text('Vendor GLN')                            },
 141                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 142                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 143                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 144                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 145                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 146                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 147                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 148                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 149                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 150                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 151                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 152                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 153                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 154                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 155                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 156                                 );
 157
 158   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 159
 160   $self->add_displayable_columns($self->_item_column,
 161                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 162                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 163                                  { name => 'description',     description => $::locale->text('Description')                },
 164                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 165                                  { name => 'ean',             description => $::locale->text('EAN')                        },
 166                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 167                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 168                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 169                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 170                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 171                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 172                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 173                                  { name => 'position',        description => $::locale->text('position')                   },
 174                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 175                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 176                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 177                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 178                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 179                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 180                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 181                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 182                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 183                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 184                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 185                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 186                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 187                                 );
 188 }
 189
 190
 191 sub init_languages_by {
 192   my ($self) = @_;
 193
 194   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 195 }
 196
 197 sub init_all_parts {
 198   my ($self) = @_;
 199
 200   return SL::DB::Manager::Part->get_all;
 201 }
 202
 203 sub init_parts_by {
 204   my ($self) = @_;
 205
 206   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_parts } } ) } qw(id partnumber ean description) };
 207 }
 208
 209 sub init_part_counts_by {
 210   my ($self) = @_;
 211
 212   my $part_counts_by;
 213
 214   $part_counts_by->{ean}->        {$_->ean}++         for @{ $self->all_parts };
 215   $part_counts_by->{description}->{$_->description}++ for @{ $self->all_parts };
 216
 217   return $part_counts_by;
 218 }
 219
 220 sub init_contacts_by {
 221   my ($self) = @_;
 222
 223   my $all_contacts = SL::DB::Manager::Contact->get_all;
 224
 225   my $cby;
 226   # by customer/vendor id  _and_  contact person id
 227   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 228   # by customer/vendor id  _and_  contact person name
 229   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 230
 231   return $cby;
 232 }
 233
 234 sub init_ct_shiptos_by {
 235   my ($self) = @_;
 236
 237   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 238
 239   my $sby;
 240   # by trans_id  _and_  shipto_id
 241   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 242
 243   return $sby;
 244 }
 245
 246 sub init_price_factors_by {
 247   my ($self) = @_;
 248
 249   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 250   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 251 }
 252
 253 sub init_pricegroups_by {
 254   my ($self) = @_;
 255
 256   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 257   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 258 }
 259
 260 sub init_units_by {
 261   my ($self) = @_;
 262
 263   my $all_units = SL::DB::Manager::Unit->get_all;
 264   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
 265 }
 266
 267 sub check_objects {
 268   my ($self) = @_;
 269
 270   $self->controller->track_progress(phase => 'building data', progress => 0);
 271
 272   my $i = 0;
 273   my $num_data = scalar @{ $self->controller->data };
 274   foreach my $entry (@{ $self->controller->data }) {
 275     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 276
 277     $entry->{info_data}->{datatype} = $entry->{raw_data}->{datatype};
 278
 279     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 280       $self->handle_order($entry);
 281     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 282       $self->handle_item($entry);
 283     }
 284     $self->handle_cvars($entry, sub_module => 'orderitems');
 285
 286   } continue {
 287     $i++;
 288   }
 289
 290   $self->add_info_columns($self->_order_column,
 291                           { header => $::locale->text('Data type'), method => 'datatype' });
 292   $self->add_info_columns($self->_item_column,
 293                           { header => $::locale->text('Data type'), method => 'datatype' });
 294
 295   $self->add_info_columns($self->_order_column,
 296                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 297   # Todo: access via ->[0] ok? Better: search first order column and use this
 298   $self->add_columns($self->_order_column,
 299                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment delivery_term language department globalproject taxzone cp currency));
 300   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 301   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 302
 303   $self->add_info_columns($self->_item_column,
 304                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 305   # Todo: access via ->[1] ok? Better: search first item column and use this
 306   $self->add_columns($self->_item_column,
 307                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 308   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 309
 310   $self->add_cvar_raw_data_columns();
 311
 312   $self->add_items_to_order();
 313   $self->handle_prices_and_taxes();
 314 }
 315
 316 sub handle_order {
 317   my ($self, $entry) = @_;
 318
 319   my $object = $entry->{object};
 320
 321   my $vc_obj;
 322   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_gln customer_id)) {
 323     $self->check_vc($entry, 'customer_id');
 324     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 325   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_gln vendor_id)) {
 326     $self->check_vc($entry, 'vendor_id');
 327     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 328   } else {
 329     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 330   }
 331
 332   $self->check_contact($entry);
 333   $self->check_language($entry);
 334   $self->check_payment($entry);
 335   $self->check_delivery_term($entry);
 336   $self->check_department($entry);
 337   $self->check_project($entry, global => 1);
 338   $self->check_ct_shipto($entry);
 339   $self->check_taxzone($entry);
 340   $self->check_currency($entry, take_default => 0);
 341
 342   if ($vc_obj) {
 343     # copy from customer if not given
 344     foreach (qw(payment_id delivery_term_id language_id taxzone_id currency_id)) {
 345       $object->$_($vc_obj->$_) unless $object->$_;
 346     }
 347     $object->intnotes($vc_obj->notes) unless $object->intnotes;
 348   }
 349
 350   $self->handle_salesman($entry);
 351   $self->handle_employee($entry);
 352 }
 353
 354 sub check_language {
 355   my ($self, $entry) = @_;
 356
 357   my $object = $entry->{object};
 358
 359   # Check whether or not language ID is valid.
 360   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 361     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 362     return 0;
 363   }
 364
 365   # Map name to ID if given.
 366   if (!$object->language_id && $entry->{raw_data}->{language}) {
 367     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 368                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 369
 370     if (!$language) {
 371       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 372       return 0;
 373     }
 374
 375     $object->language_id($language->id);
 376   }
 377
 378   if ($object->language_id) {
 379     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 380   }
 381
 382   return 1;
 383 }
 384
 385 sub handle_item {
 386   my ($self, $entry) = @_;
 387
 388   my $object = $entry->{object};
 389   return unless $self->check_part($entry);
 390
 391   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 392
 393   $self->handle_unit($entry);
 394   $self->handle_sellprice($entry);
 395   $self->handle_discount($entry);
 396
 397   # copy from part if not given
 398   $object->description($part_obj->description) unless $object->description;
 399   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 400   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 401
 402   # set to 0 if not given
 403   $object->ship(0)     unless $object->ship;
 404
 405   $self->check_project($entry, global => 0);
 406   $self->check_price_factor($entry);
 407   $self->check_pricegroup($entry);
 408 }
 409
 410 sub handle_unit {
 411   my ($self, $entry) = @_;
 412
 413   my $object = $entry->{object};
 414
 415   # Set unit from part if not given.
 416   if (!$object->unit) {
 417     $object->unit($object->part->unit);
 418     return 1;
 419   }
 420
 421   # Check whether or not unit is valid.
 422   if ($object->unit && !$self->units_by->{name}->{ $object->unit }) {
 423     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 424     return 0;
 425   }
 426
 427   # Check whether unit is convertible to parts unit
 428   if (none { $object->unit eq $_ } map { $_->name } @{ $object->part->unit_obj->convertible_units }) {
 429     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 430     return 0;
 431   }
 432
 433   return 1;
 434 }
 435
 436 sub handle_sellprice {
 437   my ($self, $entry) = @_;
 438
 439   my $object = $entry->{object};
 440
 441   # Set sellprice from part if not given. Convert with respect to unit.
 442   if (!defined $object->sellprice) {
 443     my $sellprice = $object->part->sellprice;
 444
 445     if ($object->unit ne $object->part->unit) {
 446       $sellprice = $object->unit_obj->convert_to($sellprice, $object->part->unit_obj);
 447     }
 448     $object->sellprice($sellprice);
 449   }
 450 }
 451
 452 sub handle_discount {
 453   my ($self, $entry) = @_;
 454
 455   my $object = $entry->{object};
 456
 457   $object->discount($object->discount/100.0)     if $object->discount;
 458   $object->discount(0)                       unless $object->discount;
 459 }
 460
 461 sub check_part {
 462   my ($self, $entry) = @_;
 463
 464   my $object = $entry->{object};
 465   my $is_ambiguous;
 466
 467   # Check whether or not part ID is valid.
 468   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 469     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 470     return 0;
 471   }
 472
 473   # Map number to ID if given.
 474   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 475     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 476     if (!$part) {
 477       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 478       return 0;
 479     }
 480
 481     $object->parts_id($part->id);
 482   }
 483
 484   # Map description to ID if given.
 485   if (!$object->parts_id && $entry->{raw_data}->{description}) {
 486     my $part = $self->parts_by->{description}->{ $entry->{raw_data}->{description} };
 487     if (!$part) {
 488       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 489       return 0;
 490     }
 491
 492     if ($self->part_counts_by->{description}->{ $entry->{raw_data}->{description} } > 1) {
 493       $is_ambiguous = 1;
 494     } else {
 495       $object->parts_id($part->id);
 496     }
 497   }
 498
 499   # Map ean to ID if given.
 500   if (!$object->parts_id && $entry->{raw_data}->{ean}) {
 501     my $part = $self->parts_by->{ean}->{ $entry->{raw_data}->{ean} };
 502     if (!$part) {
 503       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 504       return 0;
 505     }
 506
 507     if ($self->part_counts_by->{ean}->{ $entry->{raw_data}->{ean} } > 1) {
 508       $is_ambiguous = 1;
 509     } else {
 510       $object->parts_id($part->id);
 511     }
 512   }
 513
 514   if ($object->parts_id) {
 515     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 516   } else {
 517     if ($is_ambiguous) {
 518       push @{ $entry->{errors} }, $::locale->text('Error: Part is ambiguous');
 519     } else {
 520       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 521     }
 522     return 0;
 523   }
 524
 525   if ($self->parts_by->{id}->{ $object->parts_id }->obsolete) {
 526     push @{ $entry->{errors} }, $::locale->text('Error: Part is obsolete');
 527     return 0;
 528   }
 529
 530   return 1;
 531 }
 532
 533 sub check_contact {
 534   my ($self, $entry) = @_;
 535
 536   my $object = $entry->{object};
 537
 538   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 539   return 0 unless $cp_cv_id;
 540
 541   # Check whether or not contact ID is valid.
 542   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 543     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 544     return 0;
 545   }
 546
 547   # Map name to ID if given.
 548   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 549     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 550     if (!$cp) {
 551       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 552       return 0;
 553     }
 554
 555     $object->cp_id($cp->cp_id);
 556   }
 557
 558   if ($object->cp_id) {
 559     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 560   }
 561
 562   return 1;
 563 }
 564
 565 sub check_ct_shipto {
 566   my ($self, $entry) = @_;
 567
 568   my $object = $entry->{object};
 569
 570   my $trans_id = $object->customer_id || $object->vendor_id;
 571   return 0 unless $trans_id;
 572
 573   # Check whether or not shipto ID is valid.
 574   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 575     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 576     return 0;
 577   }
 578
 579   return 1;
 580 }
 581
 582 sub check_price_factor {
 583   my ($self, $entry) = @_;
 584
 585   my $object = $entry->{object};
 586
 587   # Check whether or not price_factor ID is valid.
 588   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 589     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 590     return 0;
 591   }
 592
 593   # Map description to ID if given.
 594   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 595     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 596     if (!$price_factor) {
 597       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 598       return 0;
 599     }
 600
 601     $object->price_factor_id($price_factor->id);
 602   }
 603
 604   return 1;
 605 }
 606
 607 sub check_pricegroup {
 608   my ($self, $entry) = @_;
 609
 610   my $object = $entry->{object};
 611
 612   # Check whether or not pricegroup ID is valid.
 613   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
 614     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 615     return 0;
 616   }
 617
 618   # Map pricegroup to ID if given.
 619   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
 620     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
 621     if (!$pricegroup) {
 622       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 623       return 0;
 624     }
 625
 626     $object->pricegroup_id($pricegroup->id);
 627   }
 628
 629   return 1;
 630 }
 631
 632 sub add_items_to_order {
 633   my ($self) = @_;
 634
 635   # add orderitems to order
 636   my $order_entry;
 637   my @orderitems;
 638   foreach my $entry (@{ $self->controller->data }) {
 639     # search first/next order
 640     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 641
 642       # next order entry: add collected orderitems to the previous one
 643       if (defined $order_entry) {
 644         $order_entry->{object}->orderitems(@orderitems);
 645         @orderitems = ();
 646       }
 647
 648       $order_entry = $entry;
 649
 650     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 651       # collect orderitems to add to order (if they have no errors)
 652       # ( add_orderitems does not work here if we want to call
 653       #   calculate_prices_and_taxes afterwards ...
 654       #   so collect orderitems and add them at once )
 655       push @orderitems, $entry->{object} if (scalar @{ $entry->{errors} } == 0);
 656     }
 657   }
 658   # add last collected orderitems to last order
 659   $order_entry->{object}->orderitems(@orderitems) if $order_entry;
 660 }
 661
 662 sub handle_prices_and_taxes() {
 663   my ($self) = @_;
 664
 665   # calculate prices and taxes
 666   foreach my $entry (@{ $self->controller->data }) {
 667     next if @{ $entry->{errors} };
 668
 669     if ($entry->{raw_data}->{datatype} eq $self->_order_column && $entry->{object}->orderitems) {
 670
 671       $entry->{object}->calculate_prices_and_taxes;
 672
 673       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 674       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 675     }
 676   }
 677
 678   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 679   # And throw an error if the differences are too big.
 680   my @to_verify = ( { column      => 'amount',
 681                       raw_column  => 'verify_amount',
 682                       info_header => 'Calc. Amount',
 683                       info_method => 'calc_amount',
 684                       err_msg     => 'Amounts differ too much',
 685                     },
 686                     { column      => 'netamount',
 687                       raw_column  => 'verify_netamount',
 688                       info_header => 'Calc. Net amount',
 689                       info_method => 'calc_netamount',
 690                       err_msg     => 'Net amounts differ too much',
 691                     } );
 692
 693   foreach my $tv (@to_verify) {
 694     # Todo: access via ->[0] ok? Better: search first order column and use this
 695     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 696       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 697       $self->add_info_columns($self->_order_column,
 698                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 699     }
 700
 701     # check differences
 702     foreach my $entry (@{ $self->controller->data }) {
 703       next if @{ $entry->{errors} };
 704       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 705         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 706         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 707         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 708           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 709         }
 710       }
 711     }
 712   }
 713
 714 }
 715
 716 sub save_objects {
 717   my ($self, %params) = @_;
 718
 719   # Collect orders without errors to save.
 720   my $entries_to_save = [];
 721   foreach my $entry (@{ $self->controller->data }) {
 722     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
 723     next if @{ $entry->{errors} };
 724
 725     push @{ $entries_to_save }, $entry;
 726   }
 727
 728   $self->SUPER::save_objects(data => $entries_to_save);
 729 }
 730
 731 sub _order_column {
 732   $_[0]->settings->{'order_column'}
 733 }
 734
 735 sub _item_column {
 736   $_[0]->settings->{'item_column'}
 737 }
 738
 739 1;