SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any);
   7
   8 use SL::Helper::Csv;
   9 use SL::DB::Order;
  10 use SL::DB::OrderItem;
  11 use SL::DB::Part;
  12 use SL::DB::PaymentTerm;
  13 use SL::DB::Contact;
  14 use SL::DB::Department;
  15 use SL::DB::PriceFactor;
  16 use SL::DB::Pricegroup;
  17 use SL::DB::Project;
  18 use SL::DB::Shipto;
  19 use SL::DB::TaxZone;
  20 use SL::TransNumber;
  21
  22 use parent qw(SL::Controller::CsvImport::BaseMulti);
  23
  24
  25 use Rose::Object::MakeMethods::Generic
  26 (
  27  'scalar --get_set_init' => [ qw(settings languages_by parts_by contacts_by departments_by projects_by ct_shiptos_by taxzones_by price_factors_by pricegroups_by currencies_by) ],
  28 );
  29
  30
  31 sub init_class {
  32   my ($self) = @_;
  33   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  34 }
  35
  36
  37 sub init_settings {
  38   my ($self) = @_;
  39
  40   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  41 }
  42
  43
  44 sub init_profile {
  45   my ($self) = @_;
  46
  47   my $profile = $self->SUPER::init_profile;
  48
  49   # SUPER::init_profile sets row_ident to the translated class name
  50   # overwrite it with the user specified settings
  51   foreach my $p (@{ $profile }) {
  52     if ($p->{class} eq 'SL::DB::Order') {
  53       $p->{row_ident} = $self->_order_column;
  54     }
  55     if ($p->{class} eq 'SL::DB::OrderItem') {
  56       $p->{row_ident} = $self->_item_column;
  57     }
  58   }
  59
  60   foreach my $p (@{ $profile }) {
  61     my $prof = $p->{profile};
  62     if ($p->{row_ident} eq $self->_order_column) {
  63       # no need to handle
  64       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  65     }
  66     if ($p->{row_ident} eq $self->_item_column) {
  67       # no need to handle
  68       delete @{$prof}{qw(trans_id)};
  69     }
  70   }
  71
  72   return $profile;
  73 }
  74
  75
  76 sub setup_displayable_columns {
  77   my ($self) = @_;
  78
  79   $self->SUPER::setup_displayable_columns;
  80
  81   $self->add_displayable_columns($self->_order_column,
  82                                  { name => 'datatype',         description => $self->_order_column                              },
  83                                  { name => 'closed',           description => $::locale->text('Closed')                         },
  84                                  { name => 'currency',         description => $::locale->text('Currency')                       },
  85                                  { name => 'currency_id',      description => $::locale->text('Currency (database ID)')         },
  86                                  { name => 'cusordnumber',     description => $::locale->text('Customer Order Number')          },
  87                                  { name => 'delivered',        description => $::locale->text('Delivered')                      },
  88                                  { name => 'employee_id',      description => $::locale->text('Employee (database ID)')         },
  89                                  { name => 'intnotes',         description => $::locale->text('Internal Notes')                 },
  90                                  { name => 'marge_percent',    description => $::locale->text('Margepercent')                   },
  91                                  { name => 'marge_total',      description => $::locale->text('Margetotal')                     },
  92                                  { name => 'notes',            description => $::locale->text('Notes')                          },
  93                                  { name => 'ordnumber',        description => $::locale->text('Order Number')                   },
  94                                  { name => 'quonumber',        description => $::locale->text('Quotation Number')               },
  95                                  { name => 'reqdate',          description => $::locale->text('Reqdate')                        },
  96                                  { name => 'salesman_id',      description => $::locale->text('Salesman (database ID)')         },
  97                                  { name => 'shippingpoint',    description => $::locale->text('Shipping Point')                 },
  98                                  { name => 'shipvia',          description => $::locale->text('Ship via')                       },
  99                                  { name => 'transaction_description', description => $::locale->text('Transaction description') },
 100                                  { name => 'transdate',        description => $::locale->text('Order Date')                     },
 101                                  { name => 'verify_amount',    description => $::locale->text('Amount (for verification)')      },
 102                                  { name => 'verify_netamount', description => $::locale->text('Net amount (for verification)')  },
 103                                  { name => 'taxincluded',      description => $::locale->text('Tax Included')                   },
 104                                  { name => 'customer',         description => $::locale->text('Customer (name)')                },
 105                                  { name => 'customernumber',   description => $::locale->text('Customer Number')                },
 106                                  { name => 'customer_id',      description => $::locale->text('Customer (database ID)')         },
 107                                  { name => 'vendor',           description => $::locale->text('Vendor (name)')                  },
 108                                  { name => 'vendornumber',     description => $::locale->text('Vendor Number')                  },
 109                                  { name => 'vendor_id',        description => $::locale->text('Vendor (database ID)')           },
 110                                  { name => 'language_id',      description => $::locale->text('Language (database ID)')         },
 111                                  { name => 'language',         description => $::locale->text('Language (name)')                },
 112                                  { name => 'payment_id',       description => $::locale->text('Payment terms (database ID)')    },
 113                                  { name => 'payment',          description => $::locale->text('Payment terms (name)')           },
 114                                  { name => 'taxzone_id',       description => $::locale->text('Steuersatz (database ID')        },
 115                                  { name => 'taxzone',          description => $::locale->text('Steuersatz (description)')       },
 116                                  { name => 'cp_id',            description => $::locale->text('Contact Person (database ID)')   },
 117                                  { name => 'contact',          description => $::locale->text('Contact Person (name)')          },
 118                                  { name => 'department_id',    description => $::locale->text('Department (database ID)')       },
 119                                  { name => 'department',       description => $::locale->text('Department (description)')       },
 120                                  { name => 'globalproject_id', description => $::locale->text('Document Project (database ID)') },
 121                                  { name => 'globalprojectnumber', description => $::locale->text('Document Project (number)')   },
 122                                  { name => 'globalproject',    description => $::locale->text('Document Project (description)') },
 123                                  { name => 'shipto_id',        description => $::locale->text('Ship to (database ID)')          },
 124                                 );
 125
 126   $self->add_displayable_columns($self->_item_column,
 127                                  { name => 'datatype',        description => $self->_item_column                           },
 128                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 129                                  { name => 'description',     description => $::locale->text('Description')                },
 130                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 131                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 132                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 133                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 134                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 135                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 136                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 137                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 138                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 139                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 140                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 141                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 142                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 143                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 144                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 145                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 146                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 147                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 148                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 149                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 150                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 151                                 );
 152 }
 153
 154
 155 sub init_languages_by {
 156   my ($self) = @_;
 157
 158   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 159 }
 160
 161 sub init_parts_by {
 162   my ($self) = @_;
 163
 164   my $all_parts = SL::DB::Manager::Part->get_all;
 165   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_parts } } ) } qw(id partnumber ean description) };
 166 }
 167
 168 sub init_contacts_by {
 169   my ($self) = @_;
 170
 171   my $all_contacts = SL::DB::Manager::Contact->get_all;
 172
 173   my $cby;
 174   # by customer/vendor id  _and_  contact person id
 175   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 176   # by customer/vendor id  _and_  contact person name
 177   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 178
 179   return $cby;
 180 }
 181
 182 sub init_departments_by {
 183   my ($self) = @_;
 184
 185   my $all_departments = SL::DB::Manager::Department->get_all;
 186   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_departments } } ) } qw(id description) };
 187 }
 188
 189 sub init_projects_by {
 190   my ($self) = @_;
 191
 192   my $all_projects = SL::DB::Manager::Project->get_all;
 193   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_projects } } ) } qw(id projectnumber description) };
 194 }
 195
 196 sub init_ct_shiptos_by {
 197   my ($self) = @_;
 198
 199   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 200
 201   my $sby;
 202   # by trans_id  _and_  shipto_id
 203   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 204
 205   return $sby;
 206 }
 207
 208 sub init_taxzones_by {
 209   my ($self) = @_;
 210
 211   my $all_taxzones = SL::DB::Manager::TaxZone->get_all;
 212   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_taxzones } } ) } qw(id description) };
 213 }
 214
 215 sub init_price_factors_by {
 216   my ($self) = @_;
 217
 218   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 219   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 220 }
 221
 222 sub init_pricegroups_by {
 223   my ($self) = @_;
 224
 225   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 226   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 227 }
 228
 229 sub init_currencies_by {
 230   my ($self) = @_;
 231
 232   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_currencies } } ) } qw(id name) };
 233 }
 234
 235 sub check_objects {
 236   my ($self) = @_;
 237
 238   $self->controller->track_progress(phase => 'building data', progress => 0);
 239
 240   my $i = 0;
 241   my $num_data = scalar @{ $self->controller->data };
 242   foreach my $entry (@{ $self->controller->data }) {
 243     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 244
 245     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 246       $self->handle_order($entry);
 247     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 248       $self->handle_item($entry);
 249     }
 250
 251   } continue {
 252     $i++;
 253   }
 254
 255   $self->add_info_columns($self->_order_column,
 256                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 257   # Todo: access via ->[0] ok? Better: search first order column and use this
 258   $self->add_columns($self->_order_column,
 259                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment language department globalproject taxzone cp currency));
 260   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 261   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 262
 263   $self->add_info_columns($self->_item_column,
 264                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 265   # Todo: access via ->[1] ok? Better: search first item column and use this
 266   $self->add_columns($self->_item_column,
 267                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 268   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 269
 270
 271   $self->add_items_to_order();
 272   $self->handle_prices_and_taxes();
 273
 274
 275   # If order has errors set error for orderitems as well
 276   my $order_entry;
 277   foreach my $entry (@{ $self->controller->data }) {
 278     # Search first order
 279     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 280       $order_entry = $entry;
 281     } elsif ( defined $order_entry
 282               && $entry->{raw_data}->{datatype} eq $self->_item_column
 283               && scalar @{ $order_entry->{errors} } > 0 ) {
 284       push @{ $entry->{errors} }, $::locale->text('order not valid for this orderitem!');
 285     }
 286   }
 287
 288 }
 289
 290 sub handle_order {
 291   my ($self, $entry) = @_;
 292
 293   my $object = $entry->{object};
 294
 295   my $vc_obj;
 296   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_id)) {
 297     $self->check_vc($entry, 'customer_id');
 298     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 299   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_id)) {
 300     $self->check_vc($entry, 'vendor_id');
 301     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 302   } else {
 303     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 304   }
 305
 306   $self->check_contact($entry);
 307   $self->check_language($entry);
 308   $self->check_payment($entry);
 309   $self->check_department($entry);
 310   $self->check_project($entry, global => 1);
 311   $self->check_ct_shipto($entry);
 312   $self->check_taxzone($entry);
 313   $self->check_currency($entry);
 314
 315   if ($vc_obj) {
 316     # copy from customer if not given
 317     foreach (qw(payment_id language_id taxzone_id currency_id)) {
 318       $object->$_($vc_obj->$_) unless $object->$_;
 319     }
 320   }
 321
 322   $self->handle_salesman($entry);
 323   $self->handle_employee($entry);
 324 }
 325
 326 # ToDo: salesman by name
 327 sub handle_salesman {
 328   my ($self, $entry) = @_;
 329
 330   my $object = $entry->{object};
 331   my $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 332   $vc_obj    = SL::DB::Vendor->new(id   => $object->vendor_id)->load   if (!$vc_obj && $object->vendor_id);
 333
 334   # salesman from customer/vendor or login if not given
 335   if (!$object->salesman) {
 336     if ($vc_obj && $vc_obj->salesman_id) {
 337       $object->salesman(SL::DB::Manager::Employee->find_by(id => $vc_obj->salesman_id));
 338     } else {
 339       $object->salesman(SL::DB::Manager::Employee->find_by(login => $::myconfig{login}));
 340     }
 341   }
 342 }
 343
 344 # ToDo: employee by name
 345 sub handle_employee {
 346   my ($self, $entry) = @_;
 347
 348   my $object = $entry->{object};
 349
 350   # employee from login if not given
 351   if (!$object->employee_id) {
 352     $object->employee_id(SL::DB::Manager::Employee->find_by(login => $::myconfig{login})->id);
 353   }
 354 }
 355
 356 sub check_language {
 357   my ($self, $entry) = @_;
 358
 359   my $object = $entry->{object};
 360
 361   # Check whether or not language ID is valid.
 362   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 363     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 364     return 0;
 365   }
 366
 367   # Map name to ID if given.
 368   if (!$object->language_id && $entry->{raw_data}->{language}) {
 369     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 370                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 371
 372     if (!$language) {
 373       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 374       return 0;
 375     }
 376
 377     $object->language_id($language->id);
 378   }
 379
 380   if ($object->language_id) {
 381     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 382   }
 383
 384   return 1;
 385 }
 386
 387 sub handle_item {
 388   my ($self, $entry) = @_;
 389
 390   my $object = $entry->{object};
 391   return unless $self->check_part($entry);
 392
 393   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 394
 395   # copy from part if not given
 396   $object->description($part_obj->description) unless $object->description;
 397   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 398   $object->unit($part_obj->unit)               unless $object->unit;
 399
 400   # set to 0 if not given
 401   $object->discount(0) unless $object->discount;
 402   $object->ship(0)     unless $object->ship;
 403
 404   $self->check_project($entry, global => 0);
 405   $self->check_price_factor($entry);
 406   $self->check_pricegroup($entry);
 407 }
 408
 409 sub check_part {
 410   my ($self, $entry) = @_;
 411
 412   my $object = $entry->{object};
 413
 414   # Check wether or non part ID is valid.
 415   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 416     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 417     return 0;
 418   }
 419
 420   # Map number to ID if given.
 421   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 422     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 423     if (!$part) {
 424       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 425       return 0;
 426     }
 427
 428     $object->parts_id($part->id);
 429   }
 430
 431   if ($object->parts_id) {
 432     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 433   } else {
 434     push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 435     return 0;
 436   }
 437
 438   return 1;
 439 }
 440
 441 sub check_contact {
 442   my ($self, $entry) = @_;
 443
 444   my $object = $entry->{object};
 445
 446   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 447   return 0 unless $cp_cv_id;
 448
 449   # Check wether or not contact ID is valid.
 450   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 451     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 452     return 0;
 453   }
 454
 455   # Map name to ID if given.
 456   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 457     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 458     if (!$cp) {
 459       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 460       return 0;
 461     }
 462
 463     $object->cp_id($cp->cp_id);
 464   }
 465
 466   if ($object->cp_id) {
 467     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 468   }
 469
 470   return 1;
 471 }
 472
 473 sub check_department {
 474   my ($self, $entry) = @_;
 475
 476   my $object = $entry->{object};
 477
 478   # Check wether or not department ID is valid.
 479   if ($object->department_id && !$self->departments_by->{id}->{ $object->department_id }) {
 480     push @{ $entry->{errors} }, $::locale->text('Error: Invalid department');
 481     return 0;
 482   }
 483
 484   # Map description to ID if given.
 485   if (!$object->department_id && $entry->{raw_data}->{department}) {
 486     my $dep = $self->departments_by->{description}->{ $entry->{raw_data}->{department} };
 487     if (!$dep) {
 488       push @{ $entry->{errors} }, $::locale->text('Error: Invalid department');
 489       return 0;
 490     }
 491
 492     $object->department_id($dep->id);
 493   }
 494
 495   return 1;
 496 }
 497
 498 sub check_project {
 499   my ($self, $entry, %params) = @_;
 500
 501   my $id_column          = ($params{global} ? 'global' : '') . 'project_id';
 502   my $number_column      = ($params{global} ? 'global' : '') . 'projectnumber';
 503   my $description_column = ($params{global} ? 'global' : '') . 'project';
 504
 505   my $object = $entry->{object};
 506
 507   # Check wether or not projetc ID is valid.
 508   if ($object->$id_column && !$self->projects_by->{id}->{ $object->$id_column }) {
 509     push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 510     return 0;
 511   }
 512
 513   # Map number to ID if given.
 514   if (!$object->$id_column && $entry->{raw_data}->{$number_column}) {
 515     my $proj = $self->projects_by->{projectnumber}->{ $entry->{raw_data}->{$number_column} };
 516     if (!$proj) {
 517       push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 518       return 0;
 519     }
 520
 521     $object->$id_column($proj->id);
 522   }
 523
 524   # Map description to ID if given.
 525   if (!$object->$id_column && $entry->{raw_data}->{$description_column}) {
 526     my $proj = $self->projects_by->{description}->{ $entry->{raw_data}->{$description_column} };
 527     if (!$proj) {
 528       push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 529       return 0;
 530     }
 531
 532     $object->$id_column($proj->id);
 533   }
 534
 535   return 1;
 536 }
 537
 538 sub check_ct_shipto {
 539   my ($self, $entry) = @_;
 540
 541   my $object = $entry->{object};
 542
 543   my $trans_id = $object->customer_id || $object->vendor_id;
 544   return 0 unless $trans_id;
 545
 546   # Check wether or not shipto ID is valid.
 547   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 548     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 549     return 0;
 550   }
 551
 552   return 1;
 553 }
 554
 555 sub check_taxzone {
 556   my ($self, $entry) = @_;
 557
 558   my $object = $entry->{object};
 559
 560   # Check wether or not taxzone ID is valid.
 561   if ($object->taxzone_id && !$self->taxzones_by->{id}->{ $object->taxzone_id }) {
 562     push @{ $entry->{errors} }, $::locale->text('Error: Invalid taxzone');
 563     return 0;
 564   }
 565
 566   # Map description to ID if given.
 567   if (!$object->taxzone_id && $entry->{raw_data}->{taxzone}) {
 568     my $taxzone = $self->taxzones_by->{description}->{ $entry->{raw_data}->{taxzone} };
 569     if (!$taxzone) {
 570       push @{ $entry->{errors} }, $::locale->text('Error: Invalid taxzone');
 571       return 0;
 572     }
 573
 574     $object->taxzone_id($taxzone->id);
 575   }
 576
 577   return 1;
 578 }
 579
 580 sub check_price_factor {
 581   my ($self, $entry) = @_;
 582
 583   my $object = $entry->{object};
 584
 585   # Check wether or not price_factor ID is valid.
 586   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 587     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 588     return 0;
 589   }
 590
 591   # Map description to ID if given.
 592   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 593     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 594     if (!$price_factor) {
 595       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 596       return 0;
 597     }
 598
 599     $object->price_factor_id($price_factor->id);
 600   }
 601
 602   return 1;
 603 }
 604
 605 sub check_pricegroup {
 606   my ($self, $entry) = @_;
 607
 608   my $object = $entry->{object};
 609
 610   # Check wether or not pricegroup ID is valid.
 611   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
 612     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 613     return 0;
 614   }
 615
 616   # Map pricegroup to ID if given.
 617   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
 618     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
 619     if (!$pricegroup) {
 620       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 621       return 0;
 622     }
 623
 624     $object->pricegroup_id($pricegroup->id);
 625   }
 626
 627   return 1;
 628 }
 629
 630 sub check_currency {
 631   my ($self, $entry) = @_;
 632
 633   my $object = $entry->{object};
 634
 635   # Check whether or not currency ID is valid.
 636   if ($object->currency_id && !$self->currencies_by->{id}->{ $object->currency_id }) {
 637     push @{ $entry->{errors} }, $::locale->text('Error: Invalid currency');
 638     return 0;
 639   }
 640
 641   # Map name to ID if given.
 642   if (!$object->currency_id && $entry->{raw_data}->{currency}) {
 643     my $currency = $self->currencies_by->{name}->{  $entry->{raw_data}->{currency} };
 644     if (!$currency) {
 645       push @{ $entry->{errors} }, $::locale->text('Error: Invalid currency');
 646       return 0;
 647     }
 648
 649     $object->currency_id($currency->id);
 650   }
 651
 652   return 1;
 653 }
 654
 655 sub add_items_to_order {
 656   my ($self) = @_;
 657
 658   # add orderitems to order
 659   my $order_entry;
 660   my @orderitems;
 661   foreach my $entry (@{ $self->controller->data }) {
 662     # search first order
 663     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 664
 665       # new order entry: add collected orderitems to the previous one
 666       if (defined $order_entry) {
 667         $order_entry->{object}->orderitems(@orderitems);
 668         @orderitems = ();
 669       }
 670
 671       $order_entry = $entry;
 672
 673     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 674       # collect orderitems to add to order (if they have no errors)
 675       # ( add_orderitems does not work here if we want to call
 676       #   calculate_prices_and_taxes afterwards ...
 677       #   so collect orderitems and add them at once )
 678       push @orderitems, $entry->{object} if (scalar @{ $entry->{errors} } == 0);
 679     }
 680   }
 681   # add last collected orderitems to last order
 682   $order_entry->{object}->orderitems(@orderitems) if $order_entry;
 683 }
 684
 685 sub handle_prices_and_taxes() {
 686   my ($self) = @_;
 687
 688   # calculate prices and taxes
 689   foreach my $entry (@{ $self->controller->data }) {
 690     next if @{ $entry->{errors} };
 691
 692     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 693
 694       $entry->{object}->calculate_prices_and_taxes;
 695
 696       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 697       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 698     }
 699   }
 700
 701   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 702   # And throw an error if the differences are too big.
 703   my @to_verify = ( { column      => 'amount',
 704                       raw_column  => 'verify_amount',
 705                       info_header => 'Calc. Amount',
 706                       info_method => 'calc_amount',
 707                       err_msg     => 'Amounts differ too much',
 708                     },
 709                     { column      => 'netamount',
 710                       raw_column  => 'verify_netamount',
 711                       info_header => 'Calc. Net amount',
 712                       info_method => 'calc_netamount',
 713                       err_msg     => 'Net amounts differ too much',
 714                     } );
 715
 716   foreach my $tv (@to_verify) {
 717     # Todo: access via ->[0] ok? Better: search first order column and use this
 718     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 719       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 720       $self->add_info_columns($self->_order_column,
 721                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 722     }
 723
 724     # check differences
 725     foreach my $entry (@{ $self->controller->data }) {
 726       next if @{ $entry->{errors} };
 727       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 728         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 729         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 730         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 731           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 732         }
 733       }
 734     }
 735   }
 736
 737 }
 738
 739 sub save_objects {
 740   my ($self, %params) = @_;
 741
 742   # set order number and collect to save
 743   my $objects_to_save;
 744   foreach my $entry (@{ $self->controller->data }) {
 745     next if @{ $entry->{errors} };
 746
 747     if ($entry->{raw_data}->{datatype} eq $self->_order_column && !$entry->{object}->ordnumber) {
 748       my $number = SL::TransNumber->new(type        => 'sales_order',
 749                                         save        => 1);
 750       $entry->{object}->ordnumber($number->create_unique());
 751     }
 752
 753     push @{ $objects_to_save }, $entry;
 754   }
 755
 756   $self->SUPER::save_objects(data => $objects_to_save);
 757 }
 758
 759 sub _order_column {
 760   $_[0]->settings->{'order_column'}
 761 }
 762
 763 sub _item_column {
 764   $_[0]->settings->{'item_column'}
 765 }
 766
 767 1;