SL/Controller/CsvImport/Part.pm

   1 package SL::Controller::CsvImport::Part;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6
   7 use SL::DB::Buchungsgruppe;
   8 use SL::DB::CustomVariable;
   9 use SL::DB::CustomVariableConfig;
  10 use SL::DB::PartsGroup;
  11 use SL::DB::PaymentTerm;
  12 use SL::DB::PriceFactor;
  13 use SL::DB::Pricegroup;
  14 use SL::DB::Price;
  15 use SL::DB::Translation;
  16 use SL::DB::Unit;
  17
  18 use parent qw(SL::Controller::CsvImport::Base);
  19
  20 use Rose::Object::MakeMethods::Generic
  21 (
  22  scalar                  => [ qw(table makemodel_columns) ],
  23  'scalar --get_set_init' => [ qw(bg_by settings parts_by price_factors_by units_by packing_types_by partsgroups_by
  24                                  translation_columns all_pricegroups) ],
  25 );
  26
  27 sub init_class {
  28   my ($self) = @_;
  29   $self->class('SL::DB::Part');
  30 }
  31
  32 sub init_bg_by {
  33   my ($self) = @_;
  34
  35   my $all_bg = SL::DB::Manager::Buchungsgruppe->get_all;
  36   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_bg } } ) } qw(id description) };
  37 }
  38
  39 sub init_price_factors_by {
  40   my ($self) = @_;
  41
  42   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
  43   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
  44 }
  45
  46 sub init_packing_types_by {
  47   my ($self) = @_;
  48
  49   my $all_packing_types = SL::DB::Manager::PackingType->get_all;
  50   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_packing_types } } ) } qw(id description) };
  51 }
  52
  53 sub init_partsgroups_by {
  54   my ($self) = @_;
  55
  56   my $all_partsgroups = SL::DB::Manager::PartsGroup->get_all;
  57   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_partsgroups } } ) } qw(id partsgroup) };
  58 }
  59
  60 sub init_units_by {
  61   my ($self) = @_;
  62
  63   my $all_units = SL::DB::Manager::Unit->get_all;
  64   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
  65 }
  66
  67 sub init_parts_by {
  68   my ($self) = @_;
  69
  70   my $parts_by = { id         => { map { ( $_->id => $_ ) } grep { !$_->assembly } @{ $self->existing_objects } },
  71                    partnumber => { part    => { },
  72                                    service => { } } };
  73
  74   foreach my $part (@{ $self->existing_objects }) {
  75     next if $part->assembly;
  76     $parts_by->{partnumber}->{ $part->type }->{ $part->partnumber } = $part;
  77   }
  78
  79   return $parts_by;
  80 }
  81
  82 sub init_all_pricegroups {
  83   my ($self) = @_;
  84
  85   return SL::DB::Manager::Pricegroup->get_all(sort => 'id');
  86 }
  87
  88 sub init_settings {
  89   my ($self) = @_;
  90
  91   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(apply_buchungsgruppe default_buchungsgruppe article_number_policy
  92                                                                     sellprice_places sellprice_adjustment sellprice_adjustment_type
  93                                                                     shoparticle_if_missing parts_type) };
  94 }
  95
  96 sub init_all_cvar_configs {
  97   my ($self) = @_;
  98
  99   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
 100 }
 101
 102 sub init_translation_columns {
 103   my ($self) = @_;
 104
 105   return [ map { ("description_" . $_->article_code, "notes_" . $_->article_code) } (@{ $self->all_languages }) ];
 106 }
 107
 108 sub check_objects {
 109   my ($self) = @_;
 110
 111   return unless @{ $self->controller->data };
 112
 113   $self->makemodel_columns({});
 114
 115   foreach my $entry (@{ $self->controller->data }) {
 116     $self->check_buchungsgruppe($entry);
 117     $self->check_type($entry);
 118     $self->check_unit($entry);
 119     $self->check_price_factor($entry);
 120     $self->check_payment($entry);
 121     $self->check_packing_type($entry);
 122     $self->check_partsgroup($entry);
 123     $self->handle_pricegroups($entry);
 124     $self->check_existing($entry) unless @{ $entry->{errors} };
 125     $self->handle_prices($entry) if $self->settings->{sellprice_adjustment};
 126     $self->handle_shoparticle($entry);
 127     $self->handle_translations($entry);
 128     $self->handle_cvars($entry);
 129     $self->handle_makemodel($entry);
 130     $self->set_various_fields($entry);
 131   }
 132
 133   $self->add_columns(qw(type)) if $self->settings->{parts_type} eq 'mixed';
 134   $self->add_columns(qw(buchungsgruppen_id unit));
 135   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw (price_factor payment packing_type partsgroup));
 136   $self->add_columns(qw(shop)) if $self->settings->{shoparticle_if_missing};
 137   $self->add_cvar_raw_data_columns;
 138   map { $self->add_raw_data_columns("pricegroup_${_}") } (1..scalar(@{ $self->all_pricegroups }));
 139   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->translation_columns };
 140   map { $self->add_raw_data_columns("make_${_}", "model_${_}") } sort { $a <=> $b } keys %{ $self->makemodel_columns };
 141 }
 142
 143 sub check_duplicates {
 144   my ($self, %params) = @_;
 145
 146   my $normalizer = sub { my $name = $_[0]; $name =~ s/[\s,\.\-]//g; return $name; };
 147   my $name_maker = sub { return $normalizer->($_[0]->description) };
 148
 149   my %by_name;
 150   if ('check_db' eq $self->controller->profile->get('duplicates')) {
 151     %by_name = map { ( $name_maker->($_) => 'db' ) } @{ $self->existing_objects };
 152   }
 153
 154   foreach my $entry (@{ $self->controller->data }) {
 155     next if @{ $entry->{errors} };
 156
 157     my $name = $name_maker->($entry->{object});
 158
 159     if (!$by_name{ $name }) {
 160       $by_name{ $name } = 'csv';
 161
 162     } else {
 163       push @{ $entry->{errors} }, $by_name{ $name } eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file');
 164     }
 165   }
 166 }
 167
 168 sub check_buchungsgruppe {
 169   my ($self, $entry) = @_;
 170
 171   my $object = $entry->{object};
 172
 173   # Check Buchungsgruppe
 174
 175   # Store and verify default ID.
 176   my $default_id = $self->settings->{default_buchungsgruppe};
 177   $default_id    = undef unless $self->bg_by->{id}->{ $default_id };
 178
 179   # 1. Use default ID if enforced.
 180   $object->buchungsgruppen_id($default_id) if $default_id && ($self->settings->{apply_buchungsgruppe} eq 'all');
 181
 182   # 2. Use supplied ID if valid
 183   $object->buchungsgruppen_id(undef) if $object->buchungsgruppen_id && !$self->bg_by->{id}->{ $object->buchungsgruppen_id };
 184
 185   # 3. Look up name if supplied.
 186   if (!$object->buchungsgruppen_id) {
 187     my $bg = $self->bg_by->{description}->{ $entry->{raw_data}->{buchungsgruppe} };
 188     $object->buchungsgruppen_id($bg->id) if $bg;
 189   }
 190
 191   # 4. Use default ID if not valid.
 192   $object->buchungsgruppen_id($default_id) if !$object->buchungsgruppen_id && $default_id && ($self->settings->{apply_buchungsgruppe} eq 'missing');
 193
 194   return 1 if $object->buchungsgruppen_id;
 195
 196   push @{ $entry->{errors} }, $::locale->text('Error: Buchungsgruppe missing or invalid');
 197   return 0;
 198 }
 199
 200 sub check_existing {
 201   my ($self, $entry) = @_;
 202
 203   my $object = $entry->{object};
 204
 205   $entry->{part} = $self->parts_by->{partnumber}->{ $object->type }->{ $object->partnumber };
 206
 207   if ($self->settings->{article_number_policy} eq 'update_prices') {
 208     if ($entry->{part}) {
 209       map { $entry->{part}->$_( $object->$_ ) } qw(sellprice listprice lastcost min_sellprice prices);
 210       push @{ $entry->{information} }, $::locale->text('Updating prices of existing entry in database');
 211       $entry->{object_to_save} = $entry->{part};
 212     }
 213
 214   } else {
 215     $object->partnumber('####') if $entry->{part};
 216   }
 217 }
 218
 219 sub handle_prices {
 220   my ($self, $entry) = @_;
 221
 222   foreach my $column (qw(sellprice listprice lastcost)) {
 223     next unless $self->controller->headers->{used}->{ $column };
 224
 225     my $adjustment = $self->settings->{sellprice_adjustment};
 226     my $value      = $entry->{object}->$column;
 227
 228     $value = $self->settings->{sellprice_adjustment_type} eq 'percent' ? $value * (100 + $adjustment) / 100 : $value + $adjustment;
 229     $entry->{object}->$column($::form->round_amount($value, $self->settings->{sellprice_places}));
 230   }
 231 }
 232
 233 sub handle_shoparticle {
 234   my ($self, $entry) = @_;
 235
 236   $entry->{object}->shop(1) if $self->settings->{shoparticle_if_missing} && !$self->controller->headers->{used}->{shop};
 237 }
 238
 239 sub check_type {
 240   my ($self, $entry) = @_;
 241
 242   my $bg = $self->bg_by->{id}->{ $entry->{object}->buchungsgruppen_id };
 243   $bg  ||= SL::DB::Buchungsgruppe->new(inventory_accno_id => 1, income_accno_id_0 => 1, expense_accno_id_0 => 1);
 244
 245   my $type = $self->settings->{parts_type};
 246   if ($type eq 'mixed') {
 247     $type = $entry->{raw_data}->{type} =~ m/^p/i ? 'part'
 248           : $entry->{raw_data}->{type} =~ m/^s/i ? 'service'
 249           :                                        undef;
 250   }
 251
 252   $entry->{object}->income_accno_id(  $bg->income_accno_id_0 );
 253   $entry->{object}->expense_accno_id( $bg->expense_accno_id_0 );
 254
 255   if ($type eq 'part') {
 256     $entry->{object}->inventory_accno_id( $bg->inventory_accno_id );
 257
 258   } elsif ($type ne 'service') {
 259     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part type');
 260     return 0;
 261   }
 262
 263   return 1;
 264 }
 265
 266 sub check_price_factor {
 267   my ($self, $entry) = @_;
 268
 269   my $object = $entry->{object};
 270
 271   # Check whether or not price factor ID is valid.
 272   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 273     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 274     return 0;
 275   }
 276
 277   # Map name to ID if given.
 278   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 279     my $pf = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 280
 281     if (!$pf) {
 282       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 283       return 0;
 284     }
 285
 286     $object->price_factor_id($pf->id);
 287   }
 288
 289   return 1;
 290 }
 291
 292 sub check_packing_type {
 293   my ($self, $entry) = @_;
 294
 295   my $object = $entry->{object};
 296
 297   # Check whether or not packing type ID is valid.
 298   if ($object->packing_type_id && !$self->packing_types_by->{id}->{ $object->packing_type_id }) {
 299     push @{ $entry->{errors} }, $::locale->text('Error: Invalid packing type');
 300     return 0;
 301   }
 302
 303   # Map name to ID if given.
 304   if (!$object->packing_type_id && $entry->{raw_data}->{packing_type}) {
 305     my $type = $self->packing_types_by->{description}->{ $entry->{raw_data}->{packing_type} };
 306
 307     if (!$type) {
 308       push @{ $entry->{errors} }, $::locale->text('Error: Invalid packing type');
 309       return 0;
 310     }
 311
 312     $object->packing_type_id($type->id);
 313   }
 314
 315   return 1;
 316 }
 317
 318 sub check_partsgroup {
 319   my ($self, $entry) = @_;
 320
 321   my $object = $entry->{object};
 322
 323   # Check whether or not part group ID is valid.
 324   if ($object->partsgroup_id && !$self->partsgroups_by->{id}->{ $object->partsgroup_id }) {
 325     push @{ $entry->{errors} }, $::locale->text('Error: Invalid parts group');
 326     return 0;
 327   }
 328
 329   # Map name to ID if given.
 330   if (!$object->partsgroup_id && $entry->{raw_data}->{partsgroup}) {
 331     my $pg = $self->partsgroups_by->{partsgroup}->{ $entry->{raw_data}->{partsgroup} };
 332
 333     if (!$pg) {
 334       push @{ $entry->{errors} }, $::locale->text('Error: Invalid parts group');
 335       return 0;
 336     }
 337
 338     $object->partsgroup_id($pg->id);
 339   }
 340
 341   return 1;
 342 }
 343
 344 sub check_unit {
 345   my ($self, $entry) = @_;
 346
 347   my $object = $entry->{object};
 348
 349   # Check whether or unit is valid.
 350   if (!$self->units_by->{name}->{ $object->unit }) {
 351     push @{ $entry->{errors} }, $::locale->text('Error: Unit missing or invalid');
 352     return 0;
 353   }
 354
 355   return 1;
 356 }
 357
 358 sub handle_translations {
 359   my ($self, $entry) = @_;
 360
 361   my @translations;
 362   foreach my $language (@{ $self->all_languages }) {
 363     my ($desc, $notes) = @{ $entry->{raw_data} }{ "description_" . $language->article_code, "notes_" . $language->article_code };
 364     next unless $desc || $notes;
 365
 366     push @translations, SL::DB::Translation->new(language_id     => $language->id,
 367                                                  translation     => $desc,
 368                                                  longdescription => $notes);
 369   }
 370
 371   $entry->{object}->translations(\@translations);
 372 }
 373
 374 sub handle_pricegroups {
 375   my ($self, $entry) = @_;
 376
 377   my @prices;
 378   my $idx = 0;
 379   foreach my $pricegroup (@{ $self->all_pricegroups }) {
 380     $idx++;
 381     my $sellprice = $entry->{raw_data}->{"pricegroup_${idx}"};
 382     next if $sellprice eq '';
 383
 384     push @prices, SL::DB::Price->new(pricegroup_id => $pricegroup->id,
 385                                      price         => $::form->parse_amount(\%::myconfig, $sellprice));
 386   }
 387
 388   $entry->{object}->prices(\@prices);
 389 }
 390
 391 sub handle_makemodel {
 392   my ($self, $entry) = @_;
 393
 394   my @makemodels;
 395   foreach my $idx (map { substr $_, 5 } grep { m/^make_\d+$/ && $entry->{raw_data}->{$_} } keys %{ $entry->{raw_data} }) {
 396     my $vendor = $entry->{raw_data}->{"make_${idx}"};
 397     $vendor    = $self->vc_by->{id}->               { $vendor }
 398               || $self->vc_by->{number}->{vendors}->{ $vendor }
 399               || $self->vc_by->{name}->  {vendors}->{ $vendor };
 400
 401     if (ref($vendor) ne 'SL::DB::Vendor') {
 402       push @{ $entry->{errors} }, $::locale->text('Error: Invalid vendor in column make_#1', $idx);
 403
 404     } else {
 405       push @makemodels, SL::DB::MakeModel->new(make  => $vendor->id,
 406                                                model => $entry->{raw_data}->{"model_${idx}"});
 407       $self->makemodel_columns->{$idx}    = 1;
 408       $entry->{raw_data}->{"make_${idx}"} = $vendor->name;
 409     }
 410   }
 411
 412   $entry->{object}->makemodels(\@makemodels);
 413   $entry->{object}->makemodel(scalar(@makemodels) ? 1 : 0);
 414 }
 415
 416 sub set_various_fields {
 417   my ($self, $entry) = @_;
 418
 419   $entry->{object}->priceupdate(DateTime->now_local);
 420 }
 421
 422 sub init_profile {
 423   my ($self) = @_;
 424
 425   my $profile = $self->SUPER::init_profile;
 426   delete @{$profile}{qw(alternate assembly bom expense_accno_id income_accno_id inventory_accno_id makemodel priceupdate stockable type)};
 427
 428   return $profile;
 429 }
 430
 431 sub save_objects {
 432   my ($self, %params) = @_;
 433
 434   my $with_number    = [ grep { $_->{object}->partnumber ne '####' } @{ $self->controller->data } ];
 435   my $without_number = [ grep { $_->{object}->partnumber eq '####' } @{ $self->controller->data } ];
 436
 437   map { $_->{object}->partnumber('') } @{ $without_number };
 438
 439   $self->SUPER::save_objects(data => $with_number);
 440   $self->SUPER::save_objects(data => $without_number);
 441 }
 442
 443 sub setup_displayable_columns {
 444   my ($self) = @_;
 445
 446   $self->SUPER::setup_displayable_columns;
 447   $self->add_cvar_columns_to_displayable_columns;
 448
 449   $self->add_displayable_columns({ name => 'bin',                description => $::locale->text('Bin')                           },
 450                                  { name => 'binding_max_qty',    description => $::locale->text('Binding Max Qty')               },
 451                                  { name => 'buchungsgruppen_id', description => $::locale->text('Buchungsgruppe (database ID)')  },
 452                                  { name => 'buchungsgruppe',     description => $::locale->text('Buchungsgruppe (name)')         },
 453                                  { name => 'description',        description => $::locale->text('Description')                   },
 454                                  { name => 'drawing',            description => $::locale->text('Drawing')                       },
 455                                  { name => 'ean',                description => $::locale->text('EAN')                           },
 456                                  { name => 'formel',             description => $::locale->text('Formula')                       },
 457                                  { name => 'gv',                 description => $::locale->text('Business Volume')               },
 458                                  { name => 'has_sernumber',      description => $::locale->text('Has serial number')             },
 459                                  { name => 'image',              description => $::locale->text('Image')                         },
 460                                  { name => 'lastcost',           description => $::locale->text('Last Cost')                     },
 461                                  { name => 'listprice',          description => $::locale->text('List Price')                    },
 462                                  { name => 'make_X',             description => $::locale->text('Make (with X being a number)')  },
 463                                  { name => 'microfiche',         description => $::locale->text('Microfiche')                    },
 464                                  { name => 'min_sellprice',      description => $::locale->text('Minimum Sell Price')            },
 465                                  { name => 'model_X',            description => $::locale->text('Model (with X being a number)') },
 466                                  { name => 'not_discountable',   description => $::locale->text('Not Discountable')              },
 467                                  { name => 'notes',              description => $::locale->text('Notes')                         },
 468                                  { name => 'obsolete',           description => $::locale->text('Obsolete')                      },
 469                                  { name => 'onhand',             description => $::locale->text('On Hand')                       },
 470                                  { name => 'packing_type_id',    description => $::locale->text('Packing type (database ID)')    },
 471                                  { name => 'packing_type',       description => $::locale->text('Packing type (name)')           },
 472                                  { name => 'partnumber',         description => $::locale->text('Part Number')                   },
 473                                  { name => 'partsgroup_id',      description => $::locale->text('Partsgroup (database ID)')      },
 474                                  { name => 'partsgroup',         description => $::locale->text('Partsgroup (name)')             },
 475                                  { name => 'payment_id',         description => $::locale->text('Payment terms (database ID)')   },
 476                                  { name => 'payment',            description => $::locale->text('Payment terms (name)')          },
 477                                  { name => 'price_factor_id',    description => $::locale->text('Price factor (database ID)')    },
 478                                  { name => 'price_factor',       description => $::locale->text('Price factor (name)')           },
 479                                  { name => 'rop',                description => $::locale->text('ROP')                           },
 480                                  { name => 'sellprice',          description => $::locale->text('Sellprice')                     },
 481                                  { name => 'shop',               description => $::locale->text('Shopartikel')                   },
 482                                  { name => 'type',               description => $::locale->text('Article type (see below)')      },
 483                                  { name => 'unit',               description => $::locale->text('Unit')                          },
 484                                  { name => 've',                 description => $::locale->text('Verrechnungseinheit')           },
 485                                  { name => 'weight',             description => $::locale->text('Weight')                        },
 486                                 );
 487
 488   foreach my $language (@{ $self->all_languages }) {
 489     $self->add_displayable_columns({ name        => 'description_' . $language->article_code,
 490                                      description => $::locale->text('Description (translation for #1)', $language->description) },
 491                                    { name        => 'notes_' . $language->article_code,
 492                                      description => $::locale->text('Notes (translation for #1)', $language->description) });
 493   }
 494
 495   my $idx = 0;
 496   foreach my $pricegroup (@{ $self->all_pricegroups }) {
 497     $idx++;
 498     $self->add_displayable_columns({ name        => 'pricegroup_' . $idx,
 499                                      description => $::locale->text("Sellprice for price group '#1'", $pricegroup->pricegroup) });
 500   }
 501 }
 502
 503 1;