SL/Controller/CsvImport/Part.pm

   1 package SL::Controller::CsvImport::Part;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6
   7 use SL::DB::Buchungsgruppe;
   8 use SL::DB::CustomVariable;
   9 use SL::DB::CustomVariableConfig;
  10 use SL::DB::PartsGroup;
  11 use SL::DB::PaymentTerm;
  12 use SL::DB::PriceFactor;
  13 use SL::DB::Translation;
  14 use SL::DB::Unit;
  15
  16 use parent qw(SL::Controller::CsvImport::Base);
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20  scalar                  => [ qw(table) ],
  21  'scalar --get_set_init' => [ qw(bg_by settings parts_by price_factors_by units_by packing_types_by partsgroups_by
  22                                  translation_columns) ],
  23 );
  24
  25 sub init_class {
  26   my ($self) = @_;
  27   $self->class('SL::DB::Part');
  28 }
  29
  30 sub init_bg_by {
  31   my ($self) = @_;
  32
  33   my $all_bg = SL::DB::Manager::Buchungsgruppe->get_all;
  34   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_bg } } ) } qw(id description) };
  35 }
  36
  37 sub init_price_factors_by {
  38   my ($self) = @_;
  39
  40   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
  41   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
  42 }
  43
  44 sub init_packing_types_by {
  45   my ($self) = @_;
  46
  47   my $all_packing_types = SL::DB::Manager::PackingType->get_all;
  48   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_packing_types } } ) } qw(id description) };
  49 }
  50
  51 sub init_partsgroups_by {
  52   my ($self) = @_;
  53
  54   my $all_partsgroups = SL::DB::Manager::PartsGroup->get_all;
  55   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_partsgroups } } ) } qw(id partsgroup) };
  56 }
  57
  58 sub init_units_by {
  59   my ($self) = @_;
  60
  61   my $all_units = SL::DB::Manager::Unit->get_all;
  62   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
  63 }
  64
  65 sub init_parts_by {
  66   my ($self) = @_;
  67
  68   my $parts_by = { id         => { map { ( $_->id => $_ ) } grep { !$_->assembly } @{ $self->existing_objects } },
  69                    partnumber => { part    => { },
  70                                    service => { } } };
  71
  72   foreach my $part (@{ $self->existing_objects }) {
  73     next if $part->assembly;
  74     $parts_by->{partnumber}->{ $part->type }->{ $part->partnumber } = $part;
  75   }
  76
  77   return $parts_by;
  78 }
  79
  80 sub init_settings {
  81   my ($self) = @_;
  82
  83   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(apply_buchungsgruppe default_buchungsgruppe article_number_policy
  84                                                                     sellprice_places sellprice_adjustment sellprice_adjustment_type
  85                                                                     shoparticle_if_missing parts_type) };
  86 }
  87
  88 sub init_all_cvar_configs {
  89   my ($self) = @_;
  90
  91   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  92 }
  93
  94 sub init_translation_columns {
  95   my ($self) = @_;
  96
  97   return [ map { ("description_" . $_->article_code, "notes_" . $_->article_code) } (@{ $self->all_languages }) ];
  98 }
  99
 100 sub check_objects {
 101   my ($self) = @_;
 102
 103   return unless @{ $self->controller->data };
 104
 105   foreach my $entry (@{ $self->controller->data }) {
 106     my $object   = $entry->{object};
 107     my $raw_data = $entry->{raw_data};
 108
 109     next unless $self->check_buchungsgruppe($entry);
 110     next unless $self->check_type($entry);
 111     next unless $self->check_unit($entry);
 112     next unless $self->check_price_factor($entry);
 113     next unless $self->check_payment($entry);
 114     next unless $self->check_packing_type($entry);
 115     next unless $self->check_partsgroup($entry);
 116     $self->check_existing($entry);
 117     $self->handle_prices($entry) if $self->settings->{sellprice_adjustment};
 118     $self->handle_shoparticle($entry);
 119     $self->handle_translations($entry);
 120     $self->handle_cvars($entry);
 121     $self->set_various_fields($entry);
 122   }
 123
 124   $self->add_columns(qw(type)) if $self->settings->{parts_type} eq 'mixed';
 125   $self->add_columns(qw(buchungsgruppen_id unit));
 126   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw (price_factor payment packing_type partsgroup));
 127   $self->add_columns(qw(shop)) if $self->settings->{shoparticle_if_missing};
 128   $self->add_cvar_raw_data_columns;
 129   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->translation_columns };
 130 }
 131
 132 sub check_duplicates {
 133   my ($self, %params) = @_;
 134
 135   my $normalizer = sub { my $name = $_[0]; $name =~ s/[\s,\.\-]//g; return $name; };
 136   my $name_maker = sub { return $normalizer->($_[0]->description) };
 137
 138   my %by_name;
 139   if ('check_db' eq $self->controller->profile->get('duplicates')) {
 140     %by_name = map { ( $name_maker->($_) => 'db' ) } @{ $self->existing_objects };
 141   }
 142
 143   foreach my $entry (@{ $self->controller->data }) {
 144     next if @{ $entry->{errors} };
 145
 146     my $name = $name_maker->($entry->{object});
 147
 148     if (!$by_name{ $name }) {
 149       $by_name{ $name } = 'csv';
 150
 151     } else {
 152       push @{ $entry->{errors} }, $by_name{ $name } eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file');
 153     }
 154   }
 155 }
 156
 157 sub check_buchungsgruppe {
 158   my ($self, $entry) = @_;
 159
 160   my $object = $entry->{object};
 161
 162   # Check Buchungsgruppe
 163
 164   # Store and verify default ID.
 165   my $default_id = $self->settings->{default_buchungsgruppe};
 166   $default_id    = undef unless $self->bg_by->{id}->{ $default_id };
 167
 168   # 1. Use default ID if enforced.
 169   $object->buchungsgruppen_id($default_id) if $default_id && ($self->settings->{apply_buchungsgruppe} eq 'all');
 170
 171   # 2. Use supplied ID if valid
 172   $object->buchungsgruppen_id(undef) if $object->buchungsgruppen_id && !$self->bg_by->{id}->{ $object->buchungsgruppen_id };
 173
 174   # 3. Look up name if supplied.
 175   if (!$object->buchungsgruppen_id) {
 176     my $bg = $self->bg_by->{description}->{ $entry->{raw_data}->{buchungsgruppe} };
 177     $object->buchungsgruppen_id($bg->id) if $bg;
 178   }
 179
 180   # 4. Use default ID if not valid.
 181   $object->buchungsgruppen_id($default_id) if !$object->buchungsgruppen_id && $default_id && ($self->settings->{apply_buchungsgruppe} eq 'missing');
 182
 183   return 1 if $object->buchungsgruppen_id;
 184
 185   push @{ $entry->{errors} }, $::locale->text('Error: Buchungsgruppe missing or invalid');
 186   return 0;
 187 }
 188
 189 sub check_existing {
 190   my ($self, $entry) = @_;
 191
 192   my $object = $entry->{object};
 193
 194   my $entry->{part} = $self->parts_by->{partnumber}->{ $object->type }->{ $object->partnumber };
 195
 196   if ($self->settings->{article_number_policy} eq 'update_prices') {
 197     if ($entry->{part}) {
 198       map { $object->$_( $entry->{part}->$_ ) } qw(sellprice listprice lastcost);
 199       $entry->{priceupdate} = 1;
 200     }
 201
 202   } else {
 203     $object->partnumber('####') if $entry->{part};
 204   }
 205 }
 206
 207 sub handle_prices {
 208   my ($self, $entry) = @_;
 209
 210   foreach my $column (qw(sellprice listprice lastcost)) {
 211     next unless $self->controller->headers->{used}->{ $column };
 212
 213     my $adjustment = $self->settings->{sellprice_adjustment};
 214     my $value      = $entry->{object}->$column;
 215
 216     $value = $self->settings->{sellprice_adjustment_type} eq 'percent' ? $value * (100 + $adjustment) / 100 : $value + $adjustment;
 217     $entry->{object}->$column($::form->round_amount($value, $self->settings->{sellprice_places}));
 218   }
 219 }
 220
 221 sub handle_shoparticle {
 222   my ($self, $entry) = @_;
 223
 224   $entry->{object}->shop(1) if $self->settings->{shoparticle_if_missing} && !$self->controller->headers->{used}->{shop};
 225 }
 226
 227 sub check_type {
 228   my ($self, $entry) = @_;
 229
 230   my $bg = $self->bg_by->{id}->{ $entry->{object}->buchungsgruppen_id };
 231   die "Program logic error" if !$bg;
 232
 233   my $type = $self->settings->{parts_type};
 234   if ($type eq 'mixed') {
 235     $type = $entry->{raw_data}->{type} =~ m/^p/i ? 'part'
 236           : $entry->{raw_data}->{type} =~ m/^s/i ? 'service'
 237           :                                        undef;
 238   }
 239
 240   $entry->{object}->income_accno_id(  $bg->income_accno_id_0 );
 241   $entry->{object}->expense_accno_id( $bg->expense_accno_id_0 );
 242
 243   if ($type eq 'part') {
 244     $entry->{object}->inventory_accno_id( $bg->inventory_accno_id );
 245
 246   } elsif ($type ne 'service') {
 247     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part type');
 248     return 0;
 249   }
 250
 251   return 1;
 252 }
 253
 254 sub check_price_factor {
 255   my ($self, $entry) = @_;
 256
 257   my $object = $entry->{object};
 258
 259   # Check whether or not price factor ID is valid.
 260   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 261     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 262     return 0;
 263   }
 264
 265   # Map name to ID if given.
 266   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 267     my $pf = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 268
 269     if (!$pf) {
 270       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 271       return 0;
 272     }
 273
 274     $object->price_factor_id($pf->id);
 275   }
 276
 277   return 1;
 278 }
 279
 280 sub check_packing_type {
 281   my ($self, $entry) = @_;
 282
 283   my $object = $entry->{object};
 284
 285   # Check whether or not packing type ID is valid.
 286   if ($object->packing_type_id && !$self->packing_types_by->{id}->{ $object->packing_type_id }) {
 287     push @{ $entry->{errors} }, $::locale->text('Error: Invalid packing type');
 288     return 0;
 289   }
 290
 291   # Map name to ID if given.
 292   if (!$object->packing_type_id && $entry->{raw_data}->{packing_type}) {
 293     my $type = $self->packing_types_by->{description}->{ $entry->{raw_data}->{packing_type} };
 294
 295     if (!$type) {
 296       push @{ $entry->{errors} }, $::locale->text('Error: Invalid packing type');
 297       return 0;
 298     }
 299
 300     $object->packing_type_id($type->id);
 301   }
 302
 303   return 1;
 304 }
 305
 306 sub check_partsgroup {
 307   my ($self, $entry) = @_;
 308
 309   my $object = $entry->{object};
 310
 311   # Check whether or not part group ID is valid.
 312   if ($object->partsgroup_id && !$self->partsgroups_by->{id}->{ $object->partsgroup_id }) {
 313     push @{ $entry->{errors} }, $::locale->text('Error: Invalid parts group');
 314     return 0;
 315   }
 316
 317   # Map name to ID if given.
 318   if (!$object->partsgroup_id && $entry->{raw_data}->{partsgroup}) {
 319     my $pg = $self->partsgroups_by->{partsgroup}->{ $entry->{raw_data}->{partsgroup} };
 320
 321     if (!$pg) {
 322       push @{ $entry->{errors} }, $::locale->text('Error: Invalid parts group');
 323       return 0;
 324     }
 325
 326     $object->partsgroup_id($pg->id);
 327   }
 328
 329   return 1;
 330 }
 331
 332 sub check_unit {
 333   my ($self, $entry) = @_;
 334
 335   my $object = $entry->{object};
 336
 337   # Check whether or unit is valid.
 338   if (!$self->units_by->{name}->{ $object->unit }) {
 339     push @{ $entry->{errors} }, $::locale->text('Error: Unit missing or invalid');
 340     return 0;
 341   }
 342
 343   return 1;
 344 }
 345
 346 sub handle_translations {
 347   my ($self, $entry) = @_;
 348
 349   my @translations;
 350   foreach my $language (@{ $self->all_languages }) {
 351     my ($desc, $notes) = @{ $entry->{raw_data} }{ "description_" . $language->article_code, "notes_" . $language->article_code };
 352     next unless $desc || $notes;
 353
 354     push @translations, SL::DB::Translation->new(language_id     => $language->id,
 355                                                  translation     => $desc,
 356                                                  longdescription => $notes);
 357   }
 358
 359   $entry->{object}->translations(\@translations);
 360 }
 361
 362 sub set_various_fields {
 363   my ($self, $entry) = @_;
 364
 365   $entry->{object}->priceupdate(DateTime->now_local);
 366 }
 367
 368 sub init_profile {
 369   my ($self) = @_;
 370
 371   my $profile = $self->SUPER::init_profile;
 372   delete @{$profile}{qw(alternate assembly bom expense_accno_id income_accno_id inventory_accno_id makemodel priceupdate stockable type)};
 373
 374   return $profile;
 375 }
 376
 377 sub save_objects {
 378   my ($self, %params) = @_;
 379
 380   my $with_number    = [ grep { $_->{object}->partnumber ne '####' } @{ $self->controller->data } ];
 381   my $without_number = [ grep { $_->{object}->partnumber eq '####' } @{ $self->controller->data } ];
 382
 383   map { $_->{object}->partnumber('') } @{ $without_number };
 384
 385   $self->SUPER::save_objects(data => $with_number);
 386   $self->SUPER::save_objects(data => $without_number);
 387 }
 388
 389 sub setup_displayable_columns {
 390   my ($self) = @_;
 391
 392   $self->SUPER::setup_displayable_columns;
 393   $self->add_cvar_columns_to_displayable_columns;
 394
 395   $self->add_displayable_columns({ name => 'bin',                description => $::locale->text('Bin')                          },
 396                                  { name => 'binding_max_qty',    description => $::locale->text('Binding Max Qty')              },
 397                                  { name => 'buchungsgruppen_id', description => $::locale->text('Buchungsgruppe (database ID)') },
 398                                  { name => 'buchungsgruppe',     description => $::locale->text('Buchungsgruppe (name)')        },
 399                                  { name => 'description',        description => $::locale->text('Description')                  },
 400                                  { name => 'drawing',            description => $::locale->text('Drawing')                      },
 401                                  { name => 'ean',                description => $::locale->text('EAN')                          },
 402                                  { name => 'formel',             description => $::locale->text('Formula')                      },
 403                                  { name => 'gv',                 description => $::locale->text('Business Volume')              },
 404                                  { name => 'has_sernumber',      description => $::locale->text('Has serial number')            },
 405                                  { name => 'image',              description => $::locale->text('Image')                        },
 406                                  { name => 'lastcost',           description => $::locale->text('Last Cost')                    },
 407                                  { name => 'listprice',          description => $::locale->text('List Price')                   },
 408                                  { name => 'microfiche',         description => $::locale->text('Microfiche')                   },
 409                                  { name => 'min_sellprice',      description => $::locale->text('Minimum Sell Price')           },
 410                                  { name => 'not_discountable',   description => $::locale->text('Not Discountable')             },
 411                                  { name => 'notes',              description => $::locale->text('Notes')                        },
 412                                  { name => 'obsolete',           description => $::locale->text('Obsolete')                     },
 413                                  { name => 'onhand',             description => $::locale->text('On Hand')                      },
 414                                  { name => 'packing_type_id',    description => $::locale->text('Packing type (database ID)')   },
 415                                  { name => 'packing_type',       description => $::locale->text('Packing type (name)')          },
 416                                  { name => 'partnumber',         description => $::locale->text('Part Number')                  },
 417                                  { name => 'partsgroup_id',      description => $::locale->text('Partsgroup (database ID)')     },
 418                                  { name => 'partsgroup',         description => $::locale->text('Partsgroup (name)')            },
 419                                  { name => 'payment_id',         description => $::locale->text('Payment terms (database ID)')  },
 420                                  { name => 'payment',            description => $::locale->text('Payment terms (name)')         },
 421                                  { name => 'price_factor_id',    description => $::locale->text('Price factor (database ID)')   },
 422                                  { name => 'price_factor',       description => $::locale->text('Price factor (name)')          },
 423                                  { name => 'rop',                description => $::locale->text('ROP')                          },
 424                                  { name => 'sellprice',          description => $::locale->text('Sellprice')                    },
 425                                  { name => 'shop',               description => $::locale->text('Shopartikel')                  },
 426                                  { name => 'unit',               description => $::locale->text('Unit')                         },
 427                                  { name => 've',                 description => $::locale->text('Verrechnungseinheit')          },
 428                                  { name => 'weight',             description => $::locale->text('Weight')                       },
 429                                 );
 430
 431   foreach my $language (@{ $self->all_languages }) {
 432     $self->add_displayable_columns({ name        => 'description_' . $language->article_code,
 433                                      description => $::locale->text('Description (translation for #1)', $language->description) },
 434                                    { name        => 'notes_' . $language->article_code,
 435                                      description => $::locale->text('Notes (translation for #1)', $language->description) });
 436   }
 437 }
 438
 439 # TODO:
 440 # Preisgruppen
 441
 442 1;