SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::DB::CsvImportReport;
   8 use SL::DB::Unit;
   9 use SL::DB::Helper::Paginated ();
  10 use SL::Helper::Flash;
  11 use SL::SessionFile;
  12 use SL::Controller::CsvImport::Contact;
  13 use SL::Controller::CsvImport::CustomerVendor;
  14 use SL::Controller::CsvImport::Part;
  15 use SL::Controller::CsvImport::Shipto;
  16 use SL::Controller::CsvImport::Project;
  17 use SL::BackgroundJob::CsvImport;
  18 use SL::System::TaskServer;
  19
  20 use List::MoreUtils qw(none);
  21 use List::Util qw(min);
  22
  23 use parent qw(SL::Controller::Base);
  24
  25 use Rose::Object::MakeMethods::Generic
  26 (
  27  scalar                  => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  28                                  import_status errors headers raw_data_headers info_headers data num_imported num_importable displayable_columns file) ],
  29  'scalar --get_set_init' => [ qw(worker task_server) ],
  30  'array'                 => [
  31    progress_tracker     => { },
  32    add_progress_tracker => {  interface => 'add', hash_key => 'progress_tracker' },
  33  ],
  34 );
  35
  36 __PACKAGE__->run_before('check_auth');
  37 __PACKAGE__->run_before('ensure_form_structure');
  38 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  39 __PACKAGE__->run_before('load_all_profiles');
  40
  41 __PACKAGE__->run_after('cleanup_reports');
  42
  43 #
  44 # actions
  45 #
  46
  47 sub action_new {
  48   my ($self) = @_;
  49
  50   $self->load_default_profile unless $self->profile;
  51   $self->render_inputs;
  52 }
  53
  54 sub action_test {
  55   my ($self) = @_;
  56   $self->test_and_import_deferred(test => 1);
  57 }
  58
  59 sub action_import {
  60   my $self = shift;
  61   $self->test_and_import_deferred(test => 0);
  62 }
  63
  64 sub action_save {
  65   my ($self) = @_;
  66
  67   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  68   $self->profile->save;
  69
  70   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  71   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  72 }
  73
  74 sub action_destroy {
  75   my $self = shift;
  76
  77   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  78   $profile->delete(cascade => 1);
  79
  80   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  81   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  82 }
  83
  84 sub action_result {
  85   my $self = shift;
  86
  87   # load resultobject
  88   $self->{background_job} = SL::DB::Manager::BackgroundJob->find_by(id => $::form->{job});
  89
  90   my $data = $self->{background_job}->data_as_hash;
  91
  92   my $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $data->{profile_id});
  93
  94   $self->profile($profile);
  95
  96   if ($data->{errors} and my $first_error =  $data->{errors}->[0]) {
  97     flash('error', $::locale->text('There was an error parsing the csv file: #1 in line #2.', $first_error->[2], $first_error->[0]));
  98   }
  99
 100   if ($data->{progress}{finished} || $data->{errors}) {
 101     $self->render('csv_import/_deferred_report', { no_layout => 1 });
 102   } else {
 103     $self->render('csv_import/_deferred_results', { no_layout => 1 });
 104   }
 105 }
 106
 107 sub action_download_sample {
 108   my $self = shift;
 109
 110   $self->profile_from_form;
 111   $self->setup_help;
 112
 113   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
 114   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
 115   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
 116
 117   $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
 118   $file->fh->print("\r\n");
 119   $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
 120   $file->fh->print("\r\n");
 121
 122   $file->fh->close;
 123
 124   $self->send_file($file->file_name, name => $file_name);
 125 }
 126
 127 sub action_report {
 128   my ($self, %params) = @_;
 129
 130   my $report_id = $params{report_id} || $::form->{id};
 131
 132   $self->{report}      = SL::DB::Manager::CsvImportReport->find_by(id => $report_id);
 133   my $num_rows         = $self->{report}->numrows;
 134   my $num_cols         = SL::DB::Manager::CsvImportReportRow->get_all_count(query => [ csv_import_report_id => $report_id, row => 0 ]);
 135
 136   # manual paginating, yuck
 137   my $page = $::form->{page} || 1;
 138   my $pages = {};
 139   $pages->{per_page}        = $::form->{per_page} || 20;
 140   $pages->{max}             = SL::DB::Helper::Paginated::ceil($num_rows / ($num_cols || 1), $pages->{per_page}) || 1;
 141   $pages->{cur}             = $page < 1 ? 1
 142                             : $page > $pages->{max} ? $pages->{max}
 143                             : $page;
 144   $pages->{common}          = [ grep { $_->{visible} } @{ SL::DB::Helper::Paginated::make_common_pages($pages->{cur}, $pages->{max}) } ];
 145
 146   $self->{display_rows} = [
 147     0,
 148     $pages->{per_page} * ($pages->{cur}-1) + 1
 149       ..
 150     min($pages->{per_page} * $pages->{cur}, $num_rows / ($num_cols || 1) - 1)
 151   ];
 152
 153   my @query = (
 154     csv_import_report_id => $report_id,
 155     or => [
 156       row => 0,
 157       and => [
 158         row => { gt => $pages->{per_page} * ($pages->{cur}-1) },
 159         row => { le => $pages->{per_page} * $pages->{cur} },
 160       ]
 161     ]
 162   );
 163
 164   my $rows             = SL::DB::Manager::CsvImportReportRow->get_all(query => \@query);
 165   my $status           = SL::DB::Manager::CsvImportReportStatus->get_all(query => \@query);
 166
 167   $self->{report_rows}   = $self->{report}->folded_rows(rows => $rows);
 168   $self->{report_status} = $self->{report}->folded_status(status => $status);
 169   $self->{pages} = $pages;
 170   $self->{base_url} = $self->url_for(action => 'report', id => $report_id, no_layout => $params{no_layout} || $::form->{no_layout} );
 171
 172   $self->render('csv_import/report', { no_layout => $params{no_layout} || $::form->{no_layout} });
 173 }
 174
 175
 176 #
 177 # filters
 178 #
 179
 180 sub check_auth {
 181   $::auth->assert('config');
 182 }
 183
 184 sub check_type {
 185   my ($self) = @_;
 186
 187   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts customers_vendors addresses contacts projects);
 188   $self->type($::form->{profile}->{type});
 189 }
 190
 191 sub ensure_form_structure {
 192   my ($self, %params) = @_;
 193
 194   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 195   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 196 }
 197
 198 #
 199 # helpers
 200 #
 201
 202 sub render_inputs {
 203   my ($self, %params) = @_;
 204
 205   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 206                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 207                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 208                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 209                         [ 'CP1252',      'CP1252 (Windows)'      ],
 210                       ]);
 211
 212   my %char_map = $self->char_map;
 213
 214   foreach my $type (qw(sep quote escape)) {
 215     my $sub = "all_${type}_chars";
 216     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 217
 218     my $char = $self->profile->get($type . '_char');
 219     $sub     = "${type}_char";
 220     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 221   }
 222
 223   $self->file(SL::SessionFile->new($self->csv_file_name));
 224
 225   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 226             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 227             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 228             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 229             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 230             : die;
 231
 232   if ($self->{type} eq 'parts') {
 233     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 234     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 235   }
 236
 237   $self->setup_help;
 238
 239   $self->render('csv_import/form', title => $title);
 240 }
 241
 242 sub test_and_import_deferred {
 243   my ($self, %params) = @_;
 244
 245   $self->profile_from_form;
 246
 247   if ($::form->{file}) {
 248     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 249     $file->fh->print($::form->{file});
 250     $file->fh->close;
 251   }
 252
 253   my $file = SL::SessionFile->new($self->csv_file_name, mode => '<', encoding => $self->profile->get('charset'));
 254   if (!$file->fh) {
 255     flash('error', $::locale->text('No file has been uploaded yet.'));
 256     return $self->action_new;
 257   }
 258
 259   $self->{background_job} = SL::BackgroundJob::CsvImport->create_job(
 260     file    => $self->csv_file_name,
 261     profile => $self->profile,
 262     type    => $self->profile->type,
 263     test    => $params{test},
 264   )->save;
 265
 266   if ($self->task_server->is_running) {
 267     $self->task_server->wake_up;
 268   } else {
 269     $self->task_server->start;
 270   }
 271
 272   flash('info', $::locale->text('Your import is beig processed.'));
 273
 274   $self->{deferred} = 1;
 275
 276   $self->render_inputs;
 277 }
 278
 279 sub test_and_import {
 280   my ($self, %params) = @_;
 281
 282   my $file = SL::SessionFile->new(
 283     $self->csv_file_name,
 284     mode       => '<',
 285     encoding   => $self->profile->get('charset'),
 286     session_id => $params{session_id}
 287   );
 288
 289   $self->file($file);
 290
 291   my $worker = $self->worker();
 292
 293   $worker->run;
 294
 295   return if $self->errors;
 296
 297   $self->num_imported(0);
 298   $worker->save_objects if !$params{test};
 299
 300   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 301   $self->import_status($params{test} ? 'tested' : 'imported');
 302
 303 #  flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 304 }
 305
 306 sub load_default_profile {
 307   my ($self) = @_;
 308
 309   my $profile;
 310   if ($::form->{profile}->{id}) {
 311     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id}, login => $::myconfig{login});
 312   }
 313   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 314   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 315
 316   $self->profile($profile);
 317   $self->profile->set_defaults;
 318 }
 319
 320 sub load_all_profiles {
 321   my ($self, %params) = @_;
 322
 323   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 324     where => [
 325       type  => $self->type,
 326       login => $::myconfig{login},
 327     ],
 328   sort_by => 'name'));
 329 }
 330
 331 sub profile_from_form {
 332   my ($self, $existing_profile) = @_;
 333
 334   delete $::form->{profile}->{id};
 335
 336   my %char_map = $self->char_map;
 337   my @settings;
 338
 339   foreach my $type (qw(sep quote escape)) {
 340     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 341     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 342
 343     push @settings, { key => "${type}_char", value => $char };
 344   }
 345
 346   if ($self->type eq 'parts') {
 347     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 348   }
 349
 350   delete $::form->{profile}->{id};
 351   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 352   $self->profile->assign_attributes(%{ $::form->{profile} });
 353   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 354                            @settings);
 355   $self->profile->set_defaults;
 356 }
 357
 358 sub char_map {
 359   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 360                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 361                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 362                        ' '  => [ 'space',     $::locale->text('Space')     ],
 363                      },
 364            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 365                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 366                      },
 367            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 368                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 369                      },
 370          );
 371 }
 372
 373 sub save_report {
 374   my ($self, $report_id) = @_;
 375
 376   $self->track_progress(phase => 'building report', progress => 0);
 377
 378   my $clone_profile = $self->profile->clone_and_reset_deep;
 379   $clone_profile->save; # weird bug. if this isn't saved before adding it to the report, it will default back to the last profile.
 380
 381   my $report = SL::DB::CsvImportReport->new(
 382     session_id => $::auth->create_or_refresh_session,
 383     profile    => $clone_profile,
 384     type       => $self->type,
 385     file       => '',
 386     numrows    => scalar @{ $self->data },
 387   )->save(cascade => 1);
 388
 389   my $dbh = $::form->get_standard_dbh;
 390   $dbh->begin_work;
 391
 392   my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 393   my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 394
 395   my $sth = $dbh->prepare($query);
 396   my $sth2 = $dbh->prepare($query2);
 397
 398   # save headers
 399   my (@headers, @info_methods, @raw_methods, @methods);
 400
 401   for my $i (0 .. $#{ $self->info_headers->{headers} }) {
 402     next unless         $self->info_headers->{used}->{ $self->info_headers->{headers}->[$i] };
 403     push @headers,      $self->info_headers->{headers}->[$i];
 404     push @info_methods, $self->info_headers->{methods}->[$i];
 405   }
 406   for my $i (0 .. $#{ $self->headers->{headers} }) {
 407     next unless         $self->headers->{used}->{ $self->headers->{headers}->[$i] };
 408     push @headers,      $self->headers->{headers}->[$i];
 409     push @methods,      $self->headers->{methods}->[$i];
 410   }
 411   for my $i (0 .. $#{ $self->raw_data_headers->{headers} }) {
 412     next unless         $self->raw_data_headers->{used}->{ $self->raw_data_headers->{headers}->[$i] };
 413     push @headers,      $self->raw_data_headers->{headers}->[$i];
 414     push @raw_methods,  $self->raw_data_headers->{headers}->[$i];
 415   }
 416
 417   $sth->execute($report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 418
 419   # col offsets
 420   my $o1 =       @info_methods;
 421   my $o2 = $o1 + @methods;
 422
 423   for my $row (0 .. $#{ $self->data }) {
 424     $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 100 == 0;
 425     my $data_row = $self->{data}[$row];
 426
 427     $sth->execute($report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 428     $sth->execute($report->id, $o1 + $_, $row + 1, $data_row->{object}->${ \ $methods[$_] })    for 0 .. $#methods;
 429     $sth->execute($report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 430
 431     $sth2->execute($report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 432     $sth2->execute($report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 433   }
 434
 435   $dbh->commit;
 436
 437   return $report->id;
 438 }
 439
 440 sub csv_file_name {
 441   my ($self) = @_;
 442   return "csv-import-" . $self->type . ".csv";
 443 }
 444
 445 sub init_worker {
 446   my $self = shift;
 447
 448   my @args = (controller => $self);
 449
 450   if ( $self->file() ) {
 451     push(@args, file => $self->file());
 452   }
 453
 454   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 455        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 456        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 457        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 458        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 459        :                                        die "Program logic error";
 460 }
 461
 462 sub setup_help {
 463   my ($self) = @_;
 464
 465   $self->worker->setup_displayable_columns;
 466 }
 467
 468 sub track_progress {
 469   my ($self, %params) = @_;
 470
 471   for my $tracker ($self->progress_tracker) {
 472     $tracker->track_progress(%params);
 473   }
 474 }
 475
 476 sub init_task_server {
 477   SL::System::TaskServer->new;
 478 }
 479
 480 sub cleanup_reports {
 481   SL::DB::Manager::CsvImportReport->cleanup;
 482 }
 483
 484 1;