SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::CsvImportProfile;
   6 use SL::Helper::Flash;
   7
   8 use List::MoreUtils qw(none);
   9
  10 use parent qw(SL::Controller::Base);
  11
  12 use Rose::Object::MakeMethods::Generic
  13 (
  14  scalar => [ qw(type profile all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars) ],
  15 );
  16
  17 __PACKAGE__->run_before('check_auth');
  18 __PACKAGE__->run_before('ensure_form_structure');
  19 __PACKAGE__->run_before('check_type');
  20 __PACKAGE__->run_before('load_all_profiles');
  21
  22 #
  23 # actions
  24 #
  25
  26 sub action_new {
  27   my ($self) = @_;
  28
  29   $self->load_default_profile unless $self->profile;
  30   $self->render_inputs;
  31 }
  32
  33 sub action_test {
  34   my ($self) = @_;
  35   $self->test_and_import(test => 1);
  36 }
  37
  38 sub action_import {
  39   my $self = shift;
  40   $self->test_and_import(test => 0);
  41 }
  42
  43 sub action_save {
  44   my ($self) = @_;
  45
  46   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}));
  47   $self->profile->save;
  48
  49   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  50   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  51 }
  52
  53 sub action_destroy {
  54   my $self = shift;
  55
  56   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id});
  57   $profile->delete(cascade => 1);
  58
  59   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  60   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  61 }
  62
  63 #
  64 # filters
  65 #
  66
  67 sub check_auth {
  68   $::auth->assert('config');
  69 }
  70
  71 sub check_type {
  72   my ($self) = @_;
  73
  74   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts customers_vendors addresses contacts);
  75   $self->type($::form->{profile}->{type});
  76 }
  77
  78 sub ensure_form_structure {
  79   my ($self, %params) = @_;
  80
  81   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
  82   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
  83 }
  84
  85 #
  86 # helpers
  87 #
  88
  89 sub render_inputs {
  90   my ($self, %params) = @_;
  91
  92   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
  93                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
  94                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
  95                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
  96                         [ 'CP1252',      'CP1252 (Windows)'      ],
  97                       ]);
  98
  99   my %char_map = $self->char_map;
 100
 101   foreach my $type (qw(sep quote escape)) {
 102     my $sub = "all_${type}_chars";
 103     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 104
 105     my $char = $self->profile->get($type . '_char');
 106     $sub     = "${type}_char";
 107     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 108   }
 109
 110   if ($self->type eq 'customers_vendors') {
 111     $self->render('csv_import/form_customers_vendors', title => $::locale->text('CSV import: customers and vendors'));
 112
 113   } elsif ($self->type eq 'addresses') {
 114     $self->render('csv_import/form_addresses',         title => $::locale->text('CSV import: shipping addresses'));
 115
 116   } elsif ($self->type eq 'contacts') {
 117     $self->render('csv_import/form_contacts',          title => $::locale->text('CSV import: contacts'));
 118
 119   } elsif ($self->type eq 'parts') {
 120     $self->render('csv_import/form_parts',             title => $::locale->text('CSV import: parts, services and assemblies'));
 121
 122   } else {
 123     die;
 124   }
 125 }
 126
 127 sub test_and_import {
 128   my ($self, %params) = @_;
 129
 130   $self->profile_from_form;
 131
 132   # do the import thingy...
 133   $self->action_new;
 134 }
 135
 136 sub load_default_profile {
 137   my ($self) = @_;
 138
 139   if ($::form->{profile}->{id}) {
 140     $self->profile(SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id})->load);
 141
 142   } else {
 143     $self->profile(SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1));
 144     $self->profile(SL::DB::CsvImportProfile->new(type => $self->{type})) unless $self->profile;
 145   }
 146
 147   $self->profile->set_defaults;
 148 }
 149
 150 sub load_all_profiles {
 151   my ($self, %params) = @_;
 152
 153   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(where => [ type => $self->type ], sort_by => 'name'));
 154 }
 155
 156 sub profile_from_form {
 157   my ($self, $existing_profile) = @_;
 158
 159   delete $::form->{profile}->{id};
 160
 161   my %char_map = $self->char_map;
 162   my @settings;
 163
 164   foreach my $type (qw(sep quote escape)) {
 165     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 166     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 167
 168     push @settings, { key => "${type}_char", value => $char };
 169   }
 170
 171   delete $::form->{profile}->{id};
 172   $self->profile($existing_profile || SL::DB::CsvImportProfile->new);
 173   $self->profile->assign_attributes(%{ $::form->{profile} });
 174   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 175                            @settings);
 176   $self->profile->set_defaults;
 177 }
 178
 179 sub char_map {
 180   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 181                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 182                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 183                        ' '  => [ 'space',     $::locale->text('Space')     ],
 184                      },
 185            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 186                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 187                      },
 188            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 189                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 190                      },
 191          );
 192 }
 193
 194 1;