SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB;
   6 use SL::DB::Buchungsgruppe;
   7 use SL::DB::CsvImportProfile;
   8 use SL::DB::CsvImportReport;
   9 use SL::DB::Unit;
  10 use SL::DB::Helper::Paginated ();
  11 use SL::DBUtils qw(do_statement);
  12 use SL::Helper::Flash;
  13 use SL::Locale::String;
  14 use SL::SessionFile;
  15 use SL::SessionFile::Random;
  16 use SL::Controller::CsvImport::Contact;
  17 use SL::Controller::CsvImport::CustomerVendor;
  18 use SL::Controller::CsvImport::Part;
  19 use SL::Controller::CsvImport::Inventory;
  20 use SL::Controller::CsvImport::Shipto;
  21 use SL::Controller::CsvImport::Project;
  22 use SL::Controller::CsvImport::Order;
  23 use SL::Controller::CsvImport::ARTransaction;
  24 use SL::JSON;
  25 use SL::Controller::CsvImport::BankTransaction;
  26 use SL::BackgroundJob::CsvImport;
  27 use SL::System::TaskServer;
  28
  29 use List::MoreUtils qw(none);
  30 use List::Util qw(min);
  31
  32 use parent qw(SL::Controller::Base);
  33
  34 use Rose::Object::MakeMethods::Generic
  35 (
  36  scalar                  => [ qw(type profile all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  37                                  import_status errors headers raw_data_headers info_headers data num_importable displayable_columns file all_taxzones) ],
  38  'scalar --get_set_init' => [ qw(worker task_server num_imported mappings) ],
  39  'array'                 => [
  40    progress_tracker     => { },
  41    add_progress_tracker => {  interface => 'add', hash_key => 'progress_tracker' },
  42  ],
  43 );
  44
  45 __PACKAGE__->run_before('check_auth', except => [ qw(report) ]);
  46 __PACKAGE__->run_before('ensure_form_structure');
  47 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  48 __PACKAGE__->run_before('load_all_profiles');
  49 __PACKAGE__->run_before('check_task_server');
  50
  51 __PACKAGE__->run_after('cleanup_reports');
  52
  53 #
  54 # actions
  55 #
  56
  57 sub action_new {
  58   my ($self) = @_;
  59
  60   $self->load_default_profile unless $self->profile;
  61   $self->render_inputs;
  62 }
  63
  64 sub action_test {
  65   my ($self) = @_;
  66   $self->test_and_import_deferred(test => 1);
  67 }
  68
  69 sub action_import {
  70   my $self = shift;
  71   $self->test_and_import_deferred(test => 0);
  72 }
  73
  74 sub action_save {
  75   my ($self) = @_;
  76
  77   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  78   $self->profile->save;
  79
  80   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  81   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  82 }
  83
  84 sub action_destroy {
  85   my $self = shift;
  86
  87   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  88   $profile->delete(cascade => 1);
  89
  90   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  91   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  92 }
  93
  94 sub action_result {
  95   my $self = shift;
  96
  97   # load resultobject
  98   $self->{background_job} = SL::DB::Manager::BackgroundJob->find_by(id => $::form->{job});
  99
 100   my $data = $self->{background_job}->data_as_hash;
 101
 102   my $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $data->{profile_id});
 103   $self->profile($profile);
 104
 105   if ($data->{errors} and my $first_error =  $data->{errors}->[0]) {
 106     flash('error', $::locale->text('There was an error parsing the csv file: #1 in line #2: #3', $first_error->[2], $first_error->[0], $first_error->[1]));
 107   }
 108
 109   if ($data->{progress}{finished} || $data->{errors}) {
 110     $self->render('csv_import/_deferred_report', { layout => 0 });
 111   } else {
 112     if (!$self->task_server->is_running) {
 113       $self->task_server->start;
 114       $self->{status_text} = t8('Task Server is not running, starting it now. If this does not change, please check your task server config');
 115     } elsif (my $phase = $data->{progress}{phase}) {
 116       $self->{status_text} = "$data->{progress}{plan}{$phase} / $data->{progress}{num_phases} " . t8($phase);
 117     } else {
 118       $self->{status_text} = t8('Import not started yet, please wait...');
 119     }
 120
 121     $self->render('csv_import/_deferred_results', { layout => 0 });
 122   }
 123 }
 124
 125 sub action_download_sample {
 126   my $self = shift;
 127
 128   $self->profile_from_form;
 129   $self->setup_help;
 130
 131   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
 132   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
 133   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
 134
 135   if ($self->worker->is_multiplexed) {
 136     foreach my $p (@{ $self->worker->profile }) {
 137       $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns->{$p->{row_ident}} } ]);
 138       $file->fh->print("\r\n");
 139     }
 140     foreach my $p (@{ $self->worker->profile }) {
 141       $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns->{$p->{row_ident}} } ]);
 142       $file->fh->print("\r\n");
 143     }
 144   } else {
 145     $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
 146     $file->fh->print("\r\n");
 147     $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
 148     $file->fh->print("\r\n");
 149   }
 150
 151   $file->fh->close;
 152
 153   $self->send_file($file->file_name, name => $file_name);
 154 }
 155
 156 sub action_report {
 157   my ($self, %params) = @_;
 158
 159   my $report_id   = $params{report_id} || $::form->{id};
 160   $self->{report} = SL::DB::Manager::CsvImportReport->find_by(id => $report_id);
 161
 162   if (!$self->{report}) {
 163     $::form->error(t8('No report with id #1', $report_id));
 164   }
 165
 166   my $show_info_err = ($self->{report}->profile->get('full_preview', 0) == 1);
 167   my $show_first_20 = ($self->{report}->profile->get('full_preview', 0) == 2);
 168
 169   my $num_rows = 0;
 170   if ($show_first_20) {
 171     $num_rows  = min($self->{report}->numrows, 20);
 172   } elsif ($show_info_err) {
 173     # count each status row only once
 174     $num_rows  = SL::DB::Manager::CsvImportReportStatus->get_all_count(query    => [csv_import_report_id => $report_id],
 175                                                                        select   => ['row'],
 176                                                                        distinct => 1,);
 177   } else {
 178     # show all
 179     $num_rows  = $self->{report}->numrows;
 180   }
 181
 182   # manual paginating, yuck
 183   my $page                   = $::form->{page} || 1;
 184   my $pages                  = {};
 185   $pages->{per_page}         = $::form->{per_page} || 20;
 186   $pages->{max}              = SL::DB::Helper::Paginated::ceil($num_rows, $pages->{per_page}) || 1;
 187   $pages->{page}             = $page < 1             ? 1
 188                              : $page > $pages->{max} ? $pages->{max}
 189                              : $                       page;
 190   $pages->{common}           = [ grep { $_->{visible} } @{ SL::DB::Helper::Paginated::make_common_pages($pages->{page}, $pages->{max}) } ];
 191
 192   $self->{report_numheaders} = $self->{report}->numheaders;
 193   my $first_row_header       = 0;
 194   my $last_row_header        = $self->{report_numheaders} - 1;
 195   my $first_row_data         = $pages->{per_page} * ($pages->{page}-1) + $self->{report_numheaders};
 196   my $last_row_data          = min($pages->{per_page} * $pages->{page}, $num_rows) + $self->{report_numheaders} - 1;
 197
 198
 199   $self->{display_rows} = [];
 200   if ($show_info_err) {
 201     my $limit    = $last_row_data  - $first_row_data + 1;
 202     my $offset   = $first_row_data - $self->{report_numheaders};
 203     my @err_rows = map { $_->row } @{SL::DB::Manager::CsvImportReportStatus->get_all(query    => [csv_import_report_id => $report_id],
 204                                                                                      distinct => 1,
 205                                                                                      select   => ['row'],
 206                                                                                      limit    => $limit,
 207                                                                                      offset   => $offset,
 208                                                                                      sort_by  => 'row')};
 209     $self->{display_rows} = [ $first_row_header .. $last_row_header,
 210                               @err_rows ];
 211
 212   } else {
 213
 214     $self->{display_rows} = [ $first_row_header .. $last_row_header,
 215                               $first_row_data   .. $last_row_data ];
 216   }
 217
 218   my @query = (
 219     row                  => $self->{display_rows},
 220     csv_import_report_id => $report_id,
 221   );
 222
 223   my $rows               = SL::DB::Manager::CsvImportReportRow   ->get_all(query => \@query, sort_by => 'row');
 224   my $status             = SL::DB::Manager::CsvImportReportStatus->get_all(query => \@query, sort_by => 'row');
 225   $self->{num_errors}    = SL::DB::Manager::CsvImportReportStatus->get_all_count(query => [csv_import_report_id => $report_id, type => 'errors']);
 226
 227   $self->{report_rows}   = $self->{report}->folded_rows(rows => $rows);
 228   $self->{report_status} = $self->{report}->folded_status(status => $status);
 229   $self->{pages}         = $pages;
 230   $self->{base_url}      = $self->url_for(action => 'report', id => $report_id, no_layout => $params{no_layout} || $::form->{no_layout} );
 231
 232   $self->render('csv_import/report', { layout => !($params{no_layout} || $::form->{no_layout}) });
 233 }
 234
 235 sub action_add_empty_mapping_line {
 236   my ($self) = @_;
 237
 238   $self->profile_from_form;
 239   $self->setup_help;
 240
 241   $self->js
 242     ->append('#csv_import_mappings', $self->render('csv_import/_mapping_item', { layout => 0, output => 0 }))
 243     ->hide('#mapping_empty')
 244     ->render;
 245 }
 246
 247 sub action_add_mapping_from_upload {
 248   my ($self) = @_;
 249
 250   if ($::form->{tmp_profile_id}) {
 251     $self->profile_from_form(SL::DB::CsvImportProfile->new(id => $::form->{tmp_profile_id})->load);
 252   } else {
 253     $self->profile_from_form;
 254   }
 255   $self->setup_help;
 256
 257   my $file_name;
 258   if ($self->profile->get('file_name')) {
 259     $file_name = $self->profile->get('file_name');
 260   } else {
 261     $self->js
 262       ->flash('error', t8('No file has been uploaded yet.'))
 263       ->render;
 264     return;
 265   }
 266
 267   my $file = SL::SessionFile->new($file_name, mode => '<', encoding => $self->profile->get('charset'));
 268   if (!$file->fh) {
 269     $self->js
 270       ->flash('error', t8('No file has been uploaded yet.'))
 271       ->render;
 272     return;
 273   }
 274
 275   my $csv = SL::Helper::Csv->new(
 276     file => $file->file_name,
 277     map { $_ => $self->profile->get($_) } qw(sep_char escape_char quote_char),
 278   );
 279
 280   $csv->_open_file;
 281   my $header = $csv->check_header;
 282
 283   for my $field (@$header) {
 284     next if $self->mappings_for_profile->{$field};
 285     $self->js->append(
 286       '#csv_import_mappings',
 287       $self->render('csv_import/_mapping_item', { layout => 0, output => 0 }, item => { from => $field }),
 288     );
 289   }
 290
 291   $self->js
 292     ->hide('#mapping_empty')
 293     ->render;
 294 }
 295
 296
 297 #
 298 # filters
 299 #
 300
 301 sub check_auth {
 302   $_[0]->check_type;
 303   $_[0]->worker->check_auth;
 304 }
 305
 306 sub check_type {
 307   my ($self) = @_;
 308
 309   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts inventories customers_vendors addresses contacts projects orders bank_transactions ar_transactions);
 310   $self->type($::form->{profile}->{type});
 311 }
 312
 313 sub ensure_form_structure {
 314   my ($self, %params) = @_;
 315
 316   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 317   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 318 }
 319
 320 #
 321 # helpers
 322 #
 323
 324 sub render_inputs {
 325   my ($self, %params) = @_;
 326
 327   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 328                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 329                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 330                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 331                         [ 'CP1252',      'CP1252 (Windows)'      ],
 332                       ]);
 333
 334   my %char_map = $self->char_map;
 335
 336   foreach my $type (qw(sep quote escape)) {
 337     my $sub = "all_${type}_chars";
 338     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 339
 340     my $char = $self->profile->get($type . '_char');
 341     $sub     = "${type}_char";
 342     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 343   }
 344
 345   if ($self->profile->get('file_name')) {
 346     $self->file(SL::SessionFile->new($self->profile->get('file_name')));
 347   }
 348
 349   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 350             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 351             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 352             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 353             : $self->type eq 'inventories'       ? $::locale->text('CSV import: inventories')
 354             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 355             : $self->type eq 'orders'            ? $::locale->text('CSV import: orders')
 356             : $self->type eq 'bank_transactions' ? $::locale->text('CSV import: bank transactions')
 357             : $self->type eq 'ar_transactions'   ? $::locale->text('CSV import: ar transactions')
 358             : die;
 359
 360   if ($self->{type} eq 'customers_vendors' or $self->{type} eq 'orders' or $self->{type} eq 'ar_transactions' ) {
 361     $self->all_taxzones(SL::DB::Manager::TaxZone->get_all_sorted(query => [ obsolete => 0 ]));
 362   };
 363
 364   if ($self->{type} eq 'parts') {
 365     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 366     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 367   }
 368
 369   $self->setup_help;
 370
 371   $self->setup_render_inputs_action_bar;
 372
 373   $self->render('csv_import/form', title => $title);
 374 }
 375
 376 sub test_and_import_deferred {
 377   my ($self, %params) = @_;
 378
 379   if ( $::form->{force_profile} && ($::form->{tmp_profile_id} || $::form->{profile}->{id}) ) {
 380     $::form->{profile}->{id} = $::form->{tmp_profile_id} if $::form->{tmp_profile_id};
 381     $self->load_default_profile;
 382   } elsif ($::form->{tmp_profile_id}) {
 383     $self->profile_from_form(SL::DB::CsvImportProfile->new(id => $::form->{tmp_profile_id})->load);
 384   } else {
 385     $self->profile_from_form;
 386   };
 387
 388   my $file_name;
 389   if ($::form->{file}) {
 390     my $file = SL::SessionFile::Random->new(mode => '>');
 391     $file->fh->print($::form->{file});
 392     $file->fh->close;
 393     $file_name = $file->file_name;
 394     $self->profile->set('file_name', $file_name);
 395   } elsif ($self->profile->get('file_name')) {
 396     $file_name = $self->profile->get('file_name');
 397   } else {
 398     flash('error', $::locale->text('No file has been uploaded yet.'));
 399     return $self->action_new;
 400   }
 401
 402   my $file = SL::SessionFile->new($file_name, mode => '<', encoding => $self->profile->get('charset'));
 403   if (!$file->fh) {
 404     flash('error', $::locale->text('No file has been uploaded yet.'));
 405     return $self->action_new;
 406   }
 407
 408   # save tempory profile
 409   $self->profile($self->profile->clone_and_reset_deep)->save;
 410
 411   $self->{background_job} = SL::BackgroundJob::CsvImport->create_job(
 412     profile_id  => $self->profile->id,
 413     type        => $self->profile->type,
 414     test        => $params{test},
 415     employee_id => SL::DB::Manager::Employee->current->id,
 416   )->save;
 417
 418   if ($self->task_server->is_running) {
 419     $self->task_server->wake_up;
 420   } else {
 421     $self->task_server->start;
 422   }
 423
 424   flash('info', $::locale->text('Your import is being processed.'));
 425
 426   $self->{deferred} = 1;
 427
 428   if ($::request->type eq 'json') {
 429     $self->render(\ SL::JSON::to_json($self->{background_job}->as_tree), { type => 'json' })
 430   } else {
 431     $self->render_inputs;
 432   }
 433 }
 434
 435 sub test_and_import {
 436   my ($self, %params) = @_;
 437
 438   my $file = SL::SessionFile->new(
 439     $self->profile->get('file_name'),
 440     mode       => '<',
 441     encoding   => $self->profile->get('charset'),
 442     session_id => $params{session_id}
 443   );
 444
 445   $self->file($file);
 446
 447   my $worker = $self->worker();
 448
 449   $worker->run(%params);
 450
 451   return if $self->errors;
 452
 453   $self->num_imported(0);
 454   $worker->save_objects if !$params{test};
 455
 456   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 457   $self->import_status($params{test} ? 'tested' : 'imported');
 458
 459 #  flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 460 }
 461
 462 sub load_default_profile {
 463   my ($self) = @_;
 464
 465   my $profile;
 466   if ($::form->{profile}->{id}) {
 467     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id});
 468   }
 469   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 470   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 471
 472   $self->profile($profile);
 473   $self->mappings(SL::JSON::from_json($self->profile->get('json_mappings'))) if $self->profile->get('json_mappings');
 474   $self->worker->set_profile_defaults;
 475   $self->profile->set_defaults;
 476 }
 477
 478 sub load_all_profiles {
 479   my ($self, %params) = @_;
 480
 481   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 482     where => [
 483       type  => $self->type,
 484       login => $::myconfig{login},
 485       '!name'  => '',
 486     ],
 487   sort_by => 'name'));
 488 }
 489
 490 sub profile_from_form {
 491   my ($self, $existing_profile) = @_;
 492
 493   delete $::form->{profile}->{id};
 494
 495   my %char_map = $self->char_map;
 496   my @settings;
 497
 498   foreach my $type (qw(sep quote escape)) {
 499     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 500     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 501
 502     push @settings, { key => "${type}_char", value => $char };
 503   }
 504
 505   if ($self->type eq 'parts') {
 506     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 507   }
 508
 509   if ($self->type eq 'orders' or $self->{type} eq 'ar_transactions') {
 510     $::form->{settings}->{max_amount_diff} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{max_amount_diff});
 511   }
 512
 513   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 514   $self->profile->assign_attributes(%{ $::form->{profile} });
 515
 516   # save settings for file_name, as this is not in form, but maybe in existing_profile
 517   push @settings, { key => 'file_name', value => $self->profile->get('file_name') } if $self->profile->get('file_name');
 518
 519   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 520                            @settings);
 521   $self->profile->set('json_mappings', JSON::to_json($self->mappings));
 522   $self->profile->set_defaults;
 523 }
 524
 525 sub char_map {
 526   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 527                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 528                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 529                        ' '  => [ 'space',     $::locale->text('Space')     ],
 530                      },
 531            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 532                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 533                      },
 534            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 535                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 536                      },
 537          );
 538 }
 539
 540 sub save_report {
 541   my ($self, %params) = @_;
 542
 543   if ($self->worker->is_multiplexed) {
 544     return $self->save_report_multi(%params);
 545   } else {
 546     return $self->save_report_single(%params);
 547   }
 548 }
 549
 550 sub save_report_single {
 551   my ($self, %params) = @_;
 552
 553   $self->track_progress(phase => 'building report', progress => 0);
 554
 555   my $report = SL::DB::CsvImportReport->new(
 556     session_id => $params{session_id},
 557     profile_id => $self->profile->id,
 558     type       => $self->type,
 559     file       => '',
 560     numrows    => scalar @{ $self->data },
 561     numheaders => 1,
 562     test_mode  => $params{test} ? 1 : 0,
 563   );
 564
 565   $report->save(cascade => 1) or die $report->db->error;
 566
 567   SL::DB->client->with_transaction(sub {
 568     my $dbh = SL::DB->client->dbh;
 569
 570     my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 571     my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 572
 573     my $sth = $dbh->prepare($query);
 574     my $sth2 = $dbh->prepare($query2);
 575
 576     # save headers
 577     my (@headers, @info_methods, @raw_methods, @methods);
 578
 579     for my $i (0 .. $#{ $self->info_headers->{headers} }) {
 580       next unless         $self->info_headers->{used}->{ $self->info_headers->{methods}->[$i] };
 581       push @headers,      $self->info_headers->{headers}->[$i];
 582       push @info_methods, $self->info_headers->{methods}->[$i];
 583     }
 584     for my $i (0 .. $#{ $self->headers->{headers} }) {
 585       next unless         $self->headers->{used}->{ $self->headers->{headers}->[$i] };
 586       push @headers,      $self->headers->{headers}->[$i];
 587       push @methods,      $self->headers->{methods}->[$i];
 588     }
 589     for my $i (0 .. $#{ $self->raw_data_headers->{headers} }) {
 590       next unless         $self->raw_data_headers->{used}->{ $self->raw_data_headers->{headers}->[$i] };
 591       push @headers,      $self->raw_data_headers->{headers}->[$i];
 592       push @raw_methods,  $self->raw_data_headers->{headers}->[$i];
 593     }
 594
 595     do_statement($::form, $sth, $query, $report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 596
 597     # col offsets
 598     my $o1 =       @info_methods;
 599     my $o2 = $o1 + @methods;
 600
 601     for my $row (0 .. $#{ $self->data }) {
 602       $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 1000 == 0;
 603       my $data_row = $self->{data}[$row];
 604
 605       do_statement($::form, $sth, $query, $report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 606       do_statement($::form, $sth, $query, $report->id, $o1 + $_, $row + 1, $data_row->{object}->${ \ $methods[$_] })    for 0 .. $#methods;
 607       do_statement($::form, $sth, $query, $report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 608
 609       do_statement($::form, $sth2, $query2, $report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 610       do_statement($::form, $sth2, $query2, $report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 611     }
 612     1;
 613   }) or do { die SL::DB->client->error };
 614
 615   return $report->id;
 616 }
 617
 618 sub save_report_multi {
 619   my ($self, %params) = @_;
 620
 621   $self->track_progress(phase => 'building report', progress => 0);
 622
 623   my $report = SL::DB::CsvImportReport->new(
 624     session_id => $params{session_id},
 625     profile_id => $self->profile->id,
 626     type       => $self->type,
 627     file       => '',
 628     numrows    => scalar @{ $self->data },
 629     numheaders => scalar @{ $self->worker->profile },
 630     test_mode  => $params{test} ? 1 : 0,
 631   );
 632
 633   $report->save(cascade => 1) or die $report->db->error;
 634
 635   SL::DB->client->with_transaction(sub {
 636     my $dbh = SL::DB->client->dbh;
 637
 638     my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 639     my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 640
 641     my $sth = $dbh->prepare($query);
 642     my $sth2 = $dbh->prepare($query2);
 643
 644     # save headers
 645     my ($headers, $info_methods, $raw_methods, $methods);
 646
 647     for my $i (0 .. $#{ $self->worker->profile }) {
 648       my $row_ident = $self->worker->profile->[$i]->{row_ident};
 649
 650       for my $i (0 .. $#{ $self->info_headers->{$row_ident}->{headers} }) {
 651         next unless                            $self->info_headers->{$row_ident}->{used}->{ $self->info_headers->{$row_ident}->{methods}->[$i] };
 652         push @{ $headers->{$row_ident} },      $self->info_headers->{$row_ident}->{headers}->[$i];
 653         push @{ $info_methods->{$row_ident} }, $self->info_headers->{$row_ident}->{methods}->[$i];
 654       }
 655       for my $i (0 .. $#{ $self->headers->{$row_ident}->{headers} }) {
 656         next unless                       $self->headers->{$row_ident}->{used}->{ $self->headers->{$row_ident}->{headers}->[$i] };
 657         push @{ $headers->{$row_ident} }, $self->headers->{$row_ident}->{headers}->[$i];
 658         push @{ $methods->{$row_ident} }, $self->headers->{$row_ident}->{methods}->[$i];
 659       }
 660
 661       for my $i (0 .. $#{ $self->raw_data_headers->{$row_ident}->{headers} }) {
 662       next unless                           $self->raw_data_headers->{$row_ident}->{used}->{ $self->raw_data_headers->{$row_ident}->{headers}->[$i] };
 663       push @{ $headers->{$row_ident} },     $self->raw_data_headers->{$row_ident}->{headers}->[$i];
 664       push @{ $raw_methods->{$row_ident} }, $self->raw_data_headers->{$row_ident}->{headers}->[$i];
 665     }
 666
 667     }
 668
 669     for my $i (0 .. $#{ $self->worker->profile }) {
 670       my $row_ident = $self->worker->profile->[$i]->{row_ident};
 671       do_statement($::form, $sth, $query, $report->id, $_, $i, $headers->{$row_ident}->[$_]) for 0 .. $#{ $headers->{$row_ident} };
 672     }
 673
 674     # col offsets
 675     my ($off1, $off2);
 676     for my $i (0 .. $#{ $self->worker->profile }) {
 677       my $row_ident = $self->worker->profile->[$i]->{row_ident};
 678       my $n_info_methods = $info_methods->{$row_ident} ? scalar @{ $info_methods->{$row_ident} } : 0;
 679       my $n_methods      = $methods->{$row_ident} ?      scalar @{ $methods->{$row_ident} }      : 0;
 680
 681       $off1->{$row_ident} = $n_info_methods;
 682       $off2->{$row_ident} = $off1->{$row_ident} + $n_methods;
 683     }
 684
 685     my $n_header_rows = scalar @{ $self->worker->profile };
 686
 687     for my $row (0 .. $#{ $self->data }) {
 688       $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 1000 == 0;
 689       my $data_row = $self->{data}[$row];
 690       my $row_ident = $data_row->{raw_data}{datatype};
 691
 692       my $o1 = $off1->{$row_ident};
 693       my $o2 = $off2->{$row_ident};
 694
 695       do_statement($::form, $sth, $query, $report->id,       $_, $row + $n_header_rows, $data_row->{info_data}{ $info_methods->{$row_ident}->[$_] }) for 0 .. $#{ $info_methods->{$row_ident} };
 696       do_statement($::form, $sth, $query, $report->id, $o1 + $_, $row + $n_header_rows, $data_row->{object}->${ \ $methods->{$row_ident}->[$_] })    for 0 .. $#{ $methods->{$row_ident} };
 697       do_statement($::form, $sth, $query, $report->id, $o2 + $_, $row + $n_header_rows, $data_row->{raw_data}{ $raw_methods->{$row_ident}->[$_] })   for 0 .. $#{ $raw_methods->{$row_ident} };
 698
 699       do_statement($::form, $sth2, $query2, $report->id, $row + $n_header_rows, 'information', $_) for @{ $data_row->{information} || [] };
 700       do_statement($::form, $sth2, $query2, $report->id, $row + $n_header_rows, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 701     }
 702     1;
 703   }) or do { die SL::DB->client->error };
 704
 705   return $report->id;
 706 }
 707
 708 sub init_worker {
 709   my $self = shift;
 710
 711   my @args = (controller => $self);
 712
 713   if ( $self->file() ) {
 714     push(@args, file => $self->file());
 715   }
 716
 717   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 718        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 719        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 720        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 721        : $self->{type} eq 'inventories'       ? SL::Controller::CsvImport::Inventory->new(@args)
 722        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 723        : $self->{type} eq 'orders'            ? SL::Controller::CsvImport::Order->new(@args)
 724        : $self->{type} eq 'bank_transactions' ? SL::Controller::CsvImport::BankTransaction->new(@args)
 725        : $self->{type} eq 'ar_transactions'   ? SL::Controller::CsvImport::ARTransaction->new(@args)
 726        :                                        die "Program logic error";
 727 }
 728
 729 sub init_num_imported { 0 }
 730
 731 sub setup_help {
 732   my ($self) = @_;
 733
 734   $self->worker->setup_displayable_columns;
 735 }
 736
 737 sub track_progress {
 738   my ($self, %params) = @_;
 739
 740   for my $tracker ($self->progress_tracker) {
 741     $tracker->track_progress(%params);
 742   }
 743 }
 744
 745 sub init_task_server {
 746   SL::System::TaskServer->new;
 747 }
 748
 749 sub cleanup_reports {
 750   SL::DB::Manager::CsvImportReport->cleanup;
 751 }
 752
 753 sub check_task_server {
 754   if (!$::auth->client->{task_server_user_id}) {
 755     flash('error', t8('The task server is required for this module but not enabled for the current client. Please enable it for the client "#1" in the administration section.', $::auth->client->{name}));
 756   }
 757
 758   return 1 if $_[0]->task_server->is_running;
 759
 760   flash('warning', t8('The task server is not running at the moment but needed for this module'));
 761
 762   1;
 763 }
 764
 765 sub mappings_for_profile {
 766   +{ map { $_->{from} => $_->{to} } @{ $_[0]->mappings } }
 767 }
 768
 769 sub init_mappings {
 770   [ grep { $_->{from} } @{ $::form->{mappings} || [] } ]
 771 }
 772
 773 sub setup_render_inputs_action_bar {
 774   my ($self, %params) = @_;
 775
 776   for my $bar ($::request->layout->get('actionbar')) {
 777     $bar->add(
 778       action => [
 779         t8('Preview'),
 780         submit    => [ '#form', { action => 'CsvImport/test' } ],
 781         accesskey => 'enter',
 782         not_if    => ($self->profile && $self->profile->get('dont_edit_profile')),
 783       ],
 784       action => [
 785         t8('Import'),
 786         submit    => [ '#form', { action => 'CsvImport/import' } ],
 787         disabled  => t8('The test import has not been executed yet.'),
 788         id        => 'action_import',
 789       ],
 790     );
 791   }
 792 }
 793
 794 1;