SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::DB::CsvImportReport;
   8 use SL::DB::Unit;
   9 use SL::Helper::Flash;
  10 use SL::SessionFile;
  11 use SL::Controller::CsvImport::Contact;
  12 use SL::Controller::CsvImport::CustomerVendor;
  13 use SL::Controller::CsvImport::Part;
  14 use SL::Controller::CsvImport::Shipto;
  15 use SL::Controller::CsvImport::Project;
  16 use SL::BackgroundJob::CsvImport;
  17 use SL::System::TaskServer;
  18
  19 use List::MoreUtils qw(none);
  20
  21 use parent qw(SL::Controller::Base);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25  scalar                  => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  26                                  import_status errors headers raw_data_headers info_headers data num_imported num_importable displayable_columns file) ],
  27  'scalar --get_set_init' => [ qw(worker) ],
  28  'array'                 => [
  29    progress_tracker     => { },
  30    add_progress_tracker => {  interface => 'add', hash_key => 'progress_tracker' },
  31  ],
  32 );
  33
  34 __PACKAGE__->run_before('check_auth');
  35 __PACKAGE__->run_before('ensure_form_structure');
  36 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  37 __PACKAGE__->run_before('load_all_profiles');
  38
  39 #
  40 # actions
  41 #
  42
  43 sub action_new {
  44   my ($self) = @_;
  45
  46   $self->load_default_profile unless $self->profile;
  47   $self->render_inputs;
  48 }
  49
  50 sub action_test {
  51   my ($self) = @_;
  52   $self->test_and_import_deferred(test => 1);
  53 }
  54
  55 sub action_import {
  56   my $self = shift;
  57   $self->test_and_import_deferred(test => 0);
  58 }
  59
  60 sub action_save {
  61   my ($self) = @_;
  62
  63   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  64   $self->profile->save;
  65
  66   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  67   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  68 }
  69
  70 sub action_destroy {
  71   my $self = shift;
  72
  73   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  74   $profile->delete(cascade => 1);
  75
  76   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  77   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  78 }
  79
  80 sub action_result {
  81   my $self = shift;
  82
  83   # load resultobject
  84   $self->{background_job} = SL::DB::Manager::BackgroundJob->find_by(id => $::form->{job});
  85
  86   my $data = $self->{background_job}->data_as_hash;
  87
  88   my $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $data->{profile_id});
  89
  90   $self->profile($profile);
  91
  92   if ($data->{progress} < 100) {
  93     $self->render('csv_import/_deferred_results', { no_layout => 1 });
  94   } else {
  95     $self->action_report(report_id => $data->{report_id}, no_layout => 1);
  96   }
  97 }
  98
  99 sub action_download_sample {
 100   my $self = shift;
 101
 102   $self->profile_from_form;
 103   $self->setup_help;
 104
 105   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
 106   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
 107   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
 108
 109   $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
 110   $file->fh->print("\r\n");
 111   $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
 112   $file->fh->print("\r\n");
 113
 114   $file->fh->close;
 115
 116   $self->send_file($file->file_name, name => $file_name);
 117 }
 118
 119 sub action_report {
 120   my ($self, %params) = @_;
 121
 122   $self->{report} = SL::DB::Manager::CsvImportReport->find_by(id => $params{report_id} || $::form->{id});
 123
 124   $self->render('csv_import/report', { no_layout => $params{no_layout} });
 125 }
 126
 127
 128 #
 129 # filters
 130 #
 131
 132 sub check_auth {
 133   $::auth->assert('config');
 134 }
 135
 136 sub check_type {
 137   my ($self) = @_;
 138
 139   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts customers_vendors addresses contacts projects);
 140   $self->type($::form->{profile}->{type});
 141 }
 142
 143 sub ensure_form_structure {
 144   my ($self, %params) = @_;
 145
 146   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 147   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 148 }
 149
 150 #
 151 # helpers
 152 #
 153
 154 sub render_inputs {
 155   my ($self, %params) = @_;
 156
 157   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 158                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 159                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 160                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 161                         [ 'CP1252',      'CP1252 (Windows)'      ],
 162                       ]);
 163
 164   my %char_map = $self->char_map;
 165
 166   foreach my $type (qw(sep quote escape)) {
 167     my $sub = "all_${type}_chars";
 168     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 169
 170     my $char = $self->profile->get($type . '_char');
 171     $sub     = "${type}_char";
 172     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 173   }
 174
 175   $self->file(SL::SessionFile->new($self->csv_file_name));
 176
 177   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 178             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 179             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 180             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 181             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 182             : die;
 183
 184   if ($self->{type} eq 'parts') {
 185     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 186     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 187   }
 188
 189   $self->setup_help;
 190
 191   $self->render('csv_import/form', title => $title);
 192 }
 193
 194 sub test_and_import_deferred {
 195   my ($self, %params) = @_;
 196
 197   $self->profile_from_form;
 198
 199   if ($::form->{file}) {
 200     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 201     $file->fh->print($::form->{file});
 202     $file->fh->close;
 203   }
 204
 205   $self->{background_job} = SL::BackgroundJob::CsvImport->create_job(
 206     file    => $self->csv_file_name,
 207     profile => $self->profile,
 208     type    => $self->profile->type,
 209   )->save;
 210
 211   SL::System::TaskServer->start_if_not_running;
 212   SL::System::TaskServer->wake_up;
 213
 214   flash('info', $::locale->text('Your import is beig processed.'));
 215
 216   $self->{deferred} = 1;
 217
 218   $self->render_inputs;
 219 }
 220
 221 sub test_and_import {
 222   my ($self, %params) = @_;
 223
 224   my $file = SL::SessionFile->new(
 225     $self->csv_file_name,
 226     mode       => '<',
 227     encoding   => $self->profile->get('charset'),
 228     session_id => $params{session_id}
 229   );
 230
 231   $self->file($file);
 232
 233   my $worker = $self->worker();
 234
 235   $worker->run;
 236
 237   $self->num_imported(0);
 238   $worker->save_objects if !$params{test};
 239
 240   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 241   $self->import_status($params{test} ? 'tested' : 'imported');
 242
 243 #  flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 244 }
 245
 246 sub load_default_profile {
 247   my ($self) = @_;
 248
 249   my $profile;
 250   if ($::form->{profile}->{id}) {
 251     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id}, login => $::myconfig{login});
 252   }
 253   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 254   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 255
 256   $self->profile($profile);
 257   $self->profile->set_defaults;
 258 }
 259
 260 sub load_all_profiles {
 261   my ($self, %params) = @_;
 262
 263   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 264     where => [
 265       type  => $self->type,
 266       login => $::myconfig{login},
 267     ],
 268   sort_by => 'name'));
 269 }
 270
 271 sub profile_from_form {
 272   my ($self, $existing_profile) = @_;
 273
 274   delete $::form->{profile}->{id};
 275
 276   my %char_map = $self->char_map;
 277   my @settings;
 278
 279   foreach my $type (qw(sep quote escape)) {
 280     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 281     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 282
 283     push @settings, { key => "${type}_char", value => $char };
 284   }
 285
 286   if ($self->type eq 'parts') {
 287     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 288   }
 289
 290   delete $::form->{profile}->{id};
 291   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 292   $self->profile->assign_attributes(%{ $::form->{profile} });
 293   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 294                            @settings);
 295   $self->profile->set_defaults;
 296 }
 297
 298 sub char_map {
 299   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 300                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 301                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 302                        ' '  => [ 'space',     $::locale->text('Space')     ],
 303                      },
 304            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 305                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 306                      },
 307            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 308                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 309                      },
 310          );
 311 }
 312
 313 sub save_report {
 314   my ($self, $report_id) = @_;
 315
 316   my $clone_profile = $self->profile->clone_and_reset_deep;
 317   $clone_profile->save; # weird bug. if this isn't saved before adding it to the report, it will default back to the last profile.
 318
 319   my $report = SL::DB::CsvImportReport->new(
 320     session_id => $::auth->create_or_refresh_session,
 321     profile    => $clone_profile,
 322     type       => $self->type,
 323     file       => '',
 324   )->save(cascade => 1);
 325
 326   my $dbh = $::form->get_standard_dbh;
 327   $dbh->begin_work;
 328
 329   my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 330   my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 331
 332   my $sth = $dbh->prepare($query);
 333   my $sth2 = $dbh->prepare($query2);
 334
 335   # save headers
 336   my @headers = (
 337     grep({ $self->info_headers->{used}->{$_}     } @{ $self->info_headers->{headers} }),
 338     grep({ $self->headers->{used}->{$_}          } @{ $self->headers->{headers} }),
 339     grep({ $self->raw_data_headers->{used}->{$_} } @{ $self->raw_data_headers->{headers} }),
 340   );
 341   my @info_methods = grep { $self->info_headers->{used}->{$_}     } @{ $self->info_headers->{headers} };
 342   my @methods      = grep { $self->headers->{used}->{$_}          } @{ $self->headers->{methods} };
 343   my @raw_methods  = grep { $self->raw_data_headers->{used}->{$_} } @{ $self->raw_data_headers->{headers} };
 344
 345   $sth->execute($report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 346
 347   # col offsets
 348   my $o1 =       @info_methods;
 349   my $o2 = $o1 + @methods;
 350
 351   for my $row (0 .. $#{ $self->data }) {
 352     my $data_row = $self->{data}[$row];
 353
 354     $sth->execute($report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 355     $sth->execute($report->id, $o1 + $_, $row + 1, $data_row->{object}->${ \ $methods[$_] })    for 0 .. $#methods;
 356     $sth->execute($report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 357
 358     $sth2->execute($report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 359     $sth2->execute($report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 360   }
 361
 362   $dbh->commit;
 363
 364   return $report->id;
 365 }
 366
 367 sub csv_file_name {
 368   my ($self) = @_;
 369   return "csv-import-" . $self->type . ".csv";
 370 }
 371
 372 sub init_worker {
 373   my $self = shift;
 374
 375   my @args = (controller => $self);
 376
 377   if ( $self->file() ) {
 378     push(@args, file => $self->file());
 379   }
 380
 381   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 382        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 383        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 384        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 385        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 386        :                                        die "Program logic error";
 387 }
 388
 389 sub setup_help {
 390   my ($self) = @_;
 391
 392   $self->worker->setup_displayable_columns;
 393 }
 394
 395 sub track_progress {
 396   my ($self, $progress) = @_;
 397
 398   for my $tracker ($self->progress_tracker) {
 399     $tracker->track_progress($progress);
 400   }
 401 }
 402
 403
 404 1;