SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB;
   6 use SL::DB::Buchungsgruppe;
   7 use SL::DB::CsvImportProfile;
   8 use SL::DB::CsvImportReport;
   9 use SL::DB::Unit;
  10 use SL::DB::Helper::Paginated ();
  11 use SL::DBUtils qw(do_statement);
  12 use SL::Helper::Flash;
  13 use SL::Locale::String;
  14 use SL::SessionFile;
  15 use SL::SessionFile::Random;
  16 use SL::Controller::CsvImport::Contact;
  17 use SL::Controller::CsvImport::CustomerVendor;
  18 use SL::Controller::CsvImport::Part;
  19 use SL::Controller::CsvImport::Inventory;
  20 use SL::Controller::CsvImport::Shipto;
  21 use SL::Controller::CsvImport::Project;
  22 use SL::Controller::CsvImport::Order;
  23 use SL::Controller::CsvImport::ARTransaction;
  24 use SL::JSON;
  25 use SL::Controller::CsvImport::BankTransaction;
  26 use SL::BackgroundJob::CsvImport;
  27 use SL::System::TaskServer;
  28
  29 use List::MoreUtils qw(none);
  30 use List::Util qw(min);
  31
  32 use parent qw(SL::Controller::Base);
  33
  34 use Rose::Object::MakeMethods::Generic
  35 (
  36  scalar                  => [ qw(type profile all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  37                                  import_status errors headers raw_data_headers info_headers data num_importable displayable_columns file all_taxzones) ],
  38  'scalar --get_set_init' => [ qw(worker task_server num_imported mappings) ],
  39  'array'                 => [
  40    progress_tracker     => { },
  41    add_progress_tracker => {  interface => 'add', hash_key => 'progress_tracker' },
  42  ],
  43 );
  44
  45 __PACKAGE__->run_before('check_auth', except => [ qw(report) ]);
  46 __PACKAGE__->run_before('ensure_form_structure');
  47 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  48 __PACKAGE__->run_before('load_all_profiles');
  49 __PACKAGE__->run_before('check_task_server');
  50
  51 __PACKAGE__->run_after('cleanup_reports');
  52
  53 #
  54 # actions
  55 #
  56
  57 sub action_new {
  58   my ($self) = @_;
  59
  60   $self->load_default_profile unless $self->profile;
  61   $self->render_inputs;
  62 }
  63
  64 sub action_test {
  65   my ($self) = @_;
  66   $self->test_and_import_deferred(test => 1);
  67 }
  68
  69 sub action_import {
  70   my $self = shift;
  71   $self->test_and_import_deferred(test => 0);
  72 }
  73
  74 sub action_save {
  75   my ($self) = @_;
  76
  77   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  78   $self->profile->save;
  79
  80   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  81   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  82 }
  83
  84 sub action_destroy {
  85   my $self = shift;
  86
  87   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  88   $profile->delete(cascade => 1);
  89
  90   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  91   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  92 }
  93
  94 sub action_result {
  95   my $self = shift;
  96
  97   # load resultobject
  98   $self->{background_job} = SL::DB::Manager::BackgroundJob->find_by(id => $::form->{job});
  99
 100   my $data = $self->{background_job}->data_as_hash;
 101
 102   my $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $data->{profile_id});
 103   $self->profile($profile);
 104
 105   if ($data->{errors} and my $first_error =  $data->{errors}->[0]) {
 106     flash('error', $::locale->text('There was an error parsing the csv file: #1 in line #2: #3', $first_error->[2], $first_error->[0], $first_error->[1]));
 107   }
 108
 109   if ($data->{progress}{finished} || $data->{errors}) {
 110     $self->render('csv_import/_deferred_report', { layout => 0 });
 111   } else {
 112     if (!$self->task_server->is_running) {
 113       $self->task_server->start;
 114       $self->{status_text} = t8('Task Server is not running, starting it now. If this does not change, please check your task server config');
 115     } elsif (my $phase = $data->{progress}{phase}) {
 116       $self->{status_text} = "$data->{progress}{plan}{$phase} / $data->{progress}{num_phases} " . t8($phase);
 117     } else {
 118       $self->{status_text} = t8('Import not started yet, please wait...');
 119     }
 120
 121     $self->render('csv_import/_deferred_results', { layout => 0 });
 122   }
 123 }
 124
 125 sub action_download_sample {
 126   my $self = shift;
 127
 128   $self->profile_from_form;
 129   $self->setup_help;
 130
 131   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
 132   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
 133   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
 134
 135   if ($self->worker->is_multiplexed) {
 136     foreach my $p (@{ $self->worker->profile }) {
 137       $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns->{$p->{row_ident}} } ]);
 138       $file->fh->print("\r\n");
 139     }
 140     foreach my $p (@{ $self->worker->profile }) {
 141       $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns->{$p->{row_ident}} } ]);
 142       $file->fh->print("\r\n");
 143     }
 144   } else {
 145     $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
 146     $file->fh->print("\r\n");
 147     $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
 148     $file->fh->print("\r\n");
 149   }
 150
 151   $file->fh->close;
 152
 153   $self->send_file($file->file_name, name => $file_name);
 154 }
 155
 156 sub action_report {
 157   my ($self, %params) = @_;
 158
 159   my $report_id   = $params{report_id} || $::form->{id};
 160   $self->{report} = SL::DB::Manager::CsvImportReport->find_by(id => $report_id);
 161
 162   if (!$self->{report}) {
 163     $::form->error(t8('No report with id #1', $report_id));
 164   }
 165
 166   my $num_rows               = $self->{report}->numrows;
 167
 168   # manual paginating, yuck
 169   my $page                   = $::form->{page} || 1;
 170   my $pages                  = {};
 171   $pages->{per_page}         = $::form->{per_page} || 20;
 172   $pages->{max}              = SL::DB::Helper::Paginated::ceil($num_rows, $pages->{per_page}) || 1;
 173   $pages->{page}             = $page < 1             ? 1
 174                              : $page > $pages->{max} ? $pages->{max}
 175                              : $                       page;
 176   $pages->{common}           = [ grep { $_->{visible} } @{ SL::DB::Helper::Paginated::make_common_pages($pages->{page}, $pages->{max}) } ];
 177
 178   $self->{report_numheaders} = $self->{report}->numheaders;
 179   my $first_row_header       = 0;
 180   my $last_row_header        = $self->{report_numheaders} - 1;
 181   my $first_row_data         = $pages->{per_page} * ($pages->{page}-1) + $self->{report_numheaders};
 182   my $last_row_data          = min($pages->{per_page} * $pages->{page}, $num_rows) + $self->{report_numheaders} - 1;
 183   $self->{display_rows}      = [
 184     $first_row_header
 185       ..
 186     $last_row_header,
 187     $first_row_data
 188       ..
 189     $last_row_data
 190   ];
 191
 192   my @query = (
 193     csv_import_report_id => $report_id,
 194     or => [
 195       and => [
 196         row => { ge => $first_row_header },
 197         row => { le => $last_row_header },
 198       ],
 199       and => [
 200         row => { ge => $first_row_data },
 201         row => { le => $last_row_data },
 202       ]
 203     ]
 204   );
 205
 206   my $rows               = SL::DB::Manager::CsvImportReportRow   ->get_all(query => \@query);
 207   my $status             = SL::DB::Manager::CsvImportReportStatus->get_all(query => \@query);
 208   $self->{num_errors}    = SL::DB::Manager::CsvImportReportStatus->get_all_count(query => [csv_import_report_id => $report_id, type => 'errors']);
 209
 210   $self->{report_rows}   = $self->{report}->folded_rows(rows => $rows);
 211   $self->{report_status} = $self->{report}->folded_status(status => $status);
 212   $self->{pages}         = $pages;
 213   $self->{base_url}      = $self->url_for(action => 'report', id => $report_id, no_layout => $params{no_layout} || $::form->{no_layout} );
 214
 215   $self->render('csv_import/report', { layout => !($params{no_layout} || $::form->{no_layout}) });
 216 }
 217
 218 sub action_add_empty_mapping_line {
 219   my ($self) = @_;
 220
 221   $self->profile_from_form;
 222   $self->setup_help;
 223
 224   $self->js
 225     ->append('#csv_import_mappings', $self->render('csv_import/_mapping_item', { layout => 0, output => 0 }))
 226     ->hide('#mapping_empty')
 227     ->render;
 228 }
 229
 230 sub action_add_mapping_from_upload {
 231   my ($self) = @_;
 232
 233   if ($::form->{tmp_profile_id}) {
 234     $self->profile_from_form(SL::DB::CsvImportProfile->new(id => $::form->{tmp_profile_id})->load);
 235   } else {
 236     $self->profile_from_form;
 237   }
 238   $self->setup_help;
 239
 240   my $file_name;
 241   if ($self->profile->get('file_name')) {
 242     $file_name = $self->profile->get('file_name');
 243   } else {
 244     $self->js
 245       ->flash('error', t8('No file has been uploaded yet.'))
 246       ->render;
 247     return;
 248   }
 249
 250   my $file = SL::SessionFile->new($file_name, mode => '<', encoding => $self->profile->get('charset'));
 251   if (!$file->fh) {
 252     $self->js
 253       ->flash('error', t8('No file has been uploaded yet.'))
 254       ->render;
 255     return;
 256   }
 257
 258   my $csv = SL::Helper::Csv->new(
 259     file => $file->file_name,
 260     map { $_ => $self->profile->get($_) } qw(sep_char escape_char quote_char),
 261   );
 262
 263   $csv->_open_file;
 264   my $header = $csv->check_header;
 265
 266   for my $field (@$header) {
 267     next if $self->mappings_for_profile->{$field};
 268     $self->js->append(
 269       '#csv_import_mappings',
 270       $self->render('csv_import/_mapping_item', { layout => 0, output => 0 }, item => { from => $field }),
 271     );
 272   }
 273
 274   $self->js
 275     ->hide('#mapping_empty')
 276     ->render;
 277 }
 278
 279
 280 #
 281 # filters
 282 #
 283
 284 sub check_auth {
 285   $_[0]->check_type;
 286   $_[0]->worker->check_auth;
 287 }
 288
 289 sub check_type {
 290   my ($self) = @_;
 291
 292   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts inventories customers_vendors addresses contacts projects orders bank_transactions ar_transactions);
 293   $self->type($::form->{profile}->{type});
 294 }
 295
 296 sub ensure_form_structure {
 297   my ($self, %params) = @_;
 298
 299   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 300   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 301 }
 302
 303 #
 304 # helpers
 305 #
 306
 307 sub render_inputs {
 308   my ($self, %params) = @_;
 309
 310   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 311                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 312                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 313                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 314                         [ 'CP1252',      'CP1252 (Windows)'      ],
 315                       ]);
 316
 317   my %char_map = $self->char_map;
 318
 319   foreach my $type (qw(sep quote escape)) {
 320     my $sub = "all_${type}_chars";
 321     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 322
 323     my $char = $self->profile->get($type . '_char');
 324     $sub     = "${type}_char";
 325     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 326   }
 327
 328   if ($self->profile->get('file_name')) {
 329     $self->file(SL::SessionFile->new($self->profile->get('file_name')));
 330   }
 331
 332   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 333             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 334             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 335             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 336             : $self->type eq 'inventories'       ? $::locale->text('CSV import: inventories')
 337             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 338             : $self->type eq 'orders'            ? $::locale->text('CSV import: orders')
 339             : $self->type eq 'bank_transactions' ? $::locale->text('CSV import: bank transactions')
 340             : $self->type eq 'ar_transactions'   ? $::locale->text('CSV import: ar transactions')
 341             : die;
 342
 343   if ($self->{type} eq 'customers_vendors' or $self->{type} eq 'orders' or $self->{type} eq 'ar_transactions' ) {
 344     $self->all_taxzones(SL::DB::Manager::TaxZone->get_all_sorted(query => [ obsolete => 0 ]));
 345   };
 346
 347   if ($self->{type} eq 'parts') {
 348     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 349     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 350   }
 351
 352   $self->setup_help;
 353
 354   $self->setup_render_inputs_action_bar;
 355
 356   $self->render('csv_import/form', title => $title);
 357 }
 358
 359 sub test_and_import_deferred {
 360   my ($self, %params) = @_;
 361
 362   if ( $::form->{force_profile} && ($::form->{tmp_profile_id} || $::form->{profile}->{id}) ) {
 363     $::form->{profile}->{id} = $::form->{tmp_profile_id} if $::form->{tmp_profile_id};
 364     $self->load_default_profile;
 365   } elsif ($::form->{tmp_profile_id}) {
 366     $self->profile_from_form(SL::DB::CsvImportProfile->new(id => $::form->{tmp_profile_id})->load);
 367   } else {
 368     $self->profile_from_form;
 369   };
 370
 371   my $file_name;
 372   if ($::form->{file}) {
 373     my $file = SL::SessionFile::Random->new(mode => '>');
 374     $file->fh->print($::form->{file});
 375     $file->fh->close;
 376     $file_name = $file->file_name;
 377     $self->profile->set('file_name', $file_name);
 378   } elsif ($self->profile->get('file_name')) {
 379     $file_name = $self->profile->get('file_name');
 380   } else {
 381     flash('error', $::locale->text('No file has been uploaded yet.'));
 382     return $self->action_new;
 383   }
 384
 385   my $file = SL::SessionFile->new($file_name, mode => '<', encoding => $self->profile->get('charset'));
 386   if (!$file->fh) {
 387     flash('error', $::locale->text('No file has been uploaded yet.'));
 388     return $self->action_new;
 389   }
 390
 391   # save tempory profile
 392   $self->profile($self->profile->clone_and_reset_deep)->save;
 393
 394   $self->{background_job} = SL::BackgroundJob::CsvImport->create_job(
 395     profile_id  => $self->profile->id,
 396     type        => $self->profile->type,
 397     test        => $params{test},
 398     employee_id => SL::DB::Manager::Employee->current->id,
 399   )->save;
 400
 401   if ($self->task_server->is_running) {
 402     $self->task_server->wake_up;
 403   } else {
 404     $self->task_server->start;
 405   }
 406
 407   flash('info', $::locale->text('Your import is being processed.'));
 408
 409   $self->{deferred} = 1;
 410
 411   if ($::request->type eq 'json') {
 412     $self->render(\ SL::JSON::to_json($self->{background_job}->as_tree), { type => 'json' })
 413   } else {
 414     $self->render_inputs;
 415   }
 416 }
 417
 418 sub test_and_import {
 419   my ($self, %params) = @_;
 420
 421   my $file = SL::SessionFile->new(
 422     $self->profile->get('file_name'),
 423     mode       => '<',
 424     encoding   => $self->profile->get('charset'),
 425     session_id => $params{session_id}
 426   );
 427
 428   $self->file($file);
 429
 430   my $worker = $self->worker();
 431
 432   $worker->run(%params);
 433
 434   return if $self->errors;
 435
 436   $self->num_imported(0);
 437   $worker->save_objects if !$params{test};
 438
 439   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 440   $self->import_status($params{test} ? 'tested' : 'imported');
 441
 442 #  flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 443 }
 444
 445 sub load_default_profile {
 446   my ($self) = @_;
 447
 448   my $profile;
 449   if ($::form->{profile}->{id}) {
 450     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id});
 451   }
 452   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 453   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 454
 455   $self->profile($profile);
 456   $self->mappings(SL::JSON::from_json($self->profile->get('json_mappings'))) if $self->profile->get('json_mappings');
 457   $self->worker->set_profile_defaults;
 458   $self->profile->set_defaults;
 459 }
 460
 461 sub load_all_profiles {
 462   my ($self, %params) = @_;
 463
 464   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 465     where => [
 466       type  => $self->type,
 467       login => $::myconfig{login},
 468       '!name'  => '',
 469     ],
 470   sort_by => 'name'));
 471 }
 472
 473 sub profile_from_form {
 474   my ($self, $existing_profile) = @_;
 475
 476   delete $::form->{profile}->{id};
 477
 478   my %char_map = $self->char_map;
 479   my @settings;
 480
 481   foreach my $type (qw(sep quote escape)) {
 482     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 483     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 484
 485     push @settings, { key => "${type}_char", value => $char };
 486   }
 487
 488   if ($self->type eq 'parts') {
 489     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 490   }
 491
 492   if ($self->type eq 'orders' or $self->{type} eq 'ar_transactions') {
 493     $::form->{settings}->{max_amount_diff} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{max_amount_diff});
 494   }
 495
 496   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 497   $self->profile->assign_attributes(%{ $::form->{profile} });
 498
 499   # save settings for file_name, as this is not in form, but maybe in existing_profile
 500   push @settings, { key => 'file_name', value => $self->profile->get('file_name') } if $self->profile->get('file_name');
 501
 502   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 503                            @settings);
 504   $self->profile->set('json_mappings', JSON::to_json($self->mappings));
 505   $self->profile->set_defaults;
 506 }
 507
 508 sub char_map {
 509   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 510                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 511                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 512                        ' '  => [ 'space',     $::locale->text('Space')     ],
 513                      },
 514            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 515                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 516                      },
 517            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 518                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 519                      },
 520          );
 521 }
 522
 523 sub save_report {
 524   my ($self, %params) = @_;
 525
 526   if ($self->worker->is_multiplexed) {
 527     return $self->save_report_multi(%params);
 528   } else {
 529     return $self->save_report_single(%params);
 530   }
 531 }
 532
 533 sub save_report_single {
 534   my ($self, %params) = @_;
 535
 536   $self->track_progress(phase => 'building report', progress => 0);
 537
 538   my $report = SL::DB::CsvImportReport->new(
 539     session_id => $params{session_id},
 540     profile_id => $self->profile->id,
 541     type       => $self->type,
 542     file       => '',
 543     numrows    => scalar @{ $self->data },
 544     numheaders => 1,
 545     test_mode  => $params{test} ? 1 : 0,
 546   );
 547
 548   $report->save(cascade => 1) or die $report->db->error;
 549
 550   SL::DB->client->with_transaction(sub {
 551     my $dbh = SL::DB->client->dbh;
 552
 553     my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 554     my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 555
 556     my $sth = $dbh->prepare($query);
 557     my $sth2 = $dbh->prepare($query2);
 558
 559     # save headers
 560     my (@headers, @info_methods, @raw_methods, @methods);
 561
 562     for my $i (0 .. $#{ $self->info_headers->{headers} }) {
 563       next unless         $self->info_headers->{used}->{ $self->info_headers->{methods}->[$i] };
 564       push @headers,      $self->info_headers->{headers}->[$i];
 565       push @info_methods, $self->info_headers->{methods}->[$i];
 566     }
 567     for my $i (0 .. $#{ $self->headers->{headers} }) {
 568       next unless         $self->headers->{used}->{ $self->headers->{headers}->[$i] };
 569       push @headers,      $self->headers->{headers}->[$i];
 570       push @methods,      $self->headers->{methods}->[$i];
 571     }
 572     for my $i (0 .. $#{ $self->raw_data_headers->{headers} }) {
 573       next unless         $self->raw_data_headers->{used}->{ $self->raw_data_headers->{headers}->[$i] };
 574       push @headers,      $self->raw_data_headers->{headers}->[$i];
 575       push @raw_methods,  $self->raw_data_headers->{headers}->[$i];
 576     }
 577
 578     do_statement($::form, $sth, $query, $report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 579
 580     # col offsets
 581     my $o1 =       @info_methods;
 582     my $o2 = $o1 + @methods;
 583
 584     for my $row (0 .. $#{ $self->data }) {
 585       $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 1000 == 0;
 586       my $data_row = $self->{data}[$row];
 587
 588       do_statement($::form, $sth, $query, $report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 589       do_statement($::form, $sth, $query, $report->id, $o1 + $_, $row + 1, $data_row->{object}->${ \ $methods[$_] })    for 0 .. $#methods;
 590       do_statement($::form, $sth, $query, $report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 591
 592       do_statement($::form, $sth2, $query2, $report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 593       do_statement($::form, $sth2, $query2, $report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 594     }
 595     1;
 596   }) or do { die SL::DB->client->error };
 597
 598   return $report->id;
 599 }
 600
 601 sub save_report_multi {
 602   my ($self, %params) = @_;
 603
 604   $self->track_progress(phase => 'building report', progress => 0);
 605
 606   my $report = SL::DB::CsvImportReport->new(
 607     session_id => $params{session_id},
 608     profile_id => $self->profile->id,
 609     type       => $self->type,
 610     file       => '',
 611     numrows    => scalar @{ $self->data },
 612     numheaders => scalar @{ $self->worker->profile },
 613     test_mode  => $params{test} ? 1 : 0,
 614   );
 615
 616   $report->save(cascade => 1) or die $report->db->error;
 617
 618   SL::DB->client->with_transaction(sub {
 619     my $dbh = SL::DB->client->dbh;
 620
 621     my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 622     my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 623
 624     my $sth = $dbh->prepare($query);
 625     my $sth2 = $dbh->prepare($query2);
 626
 627     # save headers
 628     my ($headers, $info_methods, $raw_methods, $methods);
 629
 630     for my $i (0 .. $#{ $self->worker->profile }) {
 631       my $row_ident = $self->worker->profile->[$i]->{row_ident};
 632
 633       for my $i (0 .. $#{ $self->info_headers->{$row_ident}->{headers} }) {
 634         next unless                            $self->info_headers->{$row_ident}->{used}->{ $self->info_headers->{$row_ident}->{methods}->[$i] };
 635         push @{ $headers->{$row_ident} },      $self->info_headers->{$row_ident}->{headers}->[$i];
 636         push @{ $info_methods->{$row_ident} }, $self->info_headers->{$row_ident}->{methods}->[$i];
 637       }
 638       for my $i (0 .. $#{ $self->headers->{$row_ident}->{headers} }) {
 639         next unless                       $self->headers->{$row_ident}->{used}->{ $self->headers->{$row_ident}->{headers}->[$i] };
 640         push @{ $headers->{$row_ident} }, $self->headers->{$row_ident}->{headers}->[$i];
 641         push @{ $methods->{$row_ident} }, $self->headers->{$row_ident}->{methods}->[$i];
 642       }
 643
 644       for my $i (0 .. $#{ $self->raw_data_headers->{$row_ident}->{headers} }) {
 645       next unless                           $self->raw_data_headers->{$row_ident}->{used}->{ $self->raw_data_headers->{$row_ident}->{headers}->[$i] };
 646       push @{ $headers->{$row_ident} },     $self->raw_data_headers->{$row_ident}->{headers}->[$i];
 647       push @{ $raw_methods->{$row_ident} }, $self->raw_data_headers->{$row_ident}->{headers}->[$i];
 648     }
 649
 650     }
 651
 652     for my $i (0 .. $#{ $self->worker->profile }) {
 653       my $row_ident = $self->worker->profile->[$i]->{row_ident};
 654       do_statement($::form, $sth, $query, $report->id, $_, $i, $headers->{$row_ident}->[$_]) for 0 .. $#{ $headers->{$row_ident} };
 655     }
 656
 657     # col offsets
 658     my ($off1, $off2);
 659     for my $i (0 .. $#{ $self->worker->profile }) {
 660       my $row_ident = $self->worker->profile->[$i]->{row_ident};
 661       my $n_info_methods = $info_methods->{$row_ident} ? scalar @{ $info_methods->{$row_ident} } : 0;
 662       my $n_methods      = $methods->{$row_ident} ?      scalar @{ $methods->{$row_ident} }      : 0;
 663
 664       $off1->{$row_ident} = $n_info_methods;
 665       $off2->{$row_ident} = $off1->{$row_ident} + $n_methods;
 666     }
 667
 668     my $n_header_rows = scalar @{ $self->worker->profile };
 669
 670     for my $row (0 .. $#{ $self->data }) {
 671       $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 1000 == 0;
 672       my $data_row = $self->{data}[$row];
 673       my $row_ident = $data_row->{raw_data}{datatype};
 674
 675       my $o1 = $off1->{$row_ident};
 676       my $o2 = $off2->{$row_ident};
 677
 678       do_statement($::form, $sth, $query, $report->id,       $_, $row + $n_header_rows, $data_row->{info_data}{ $info_methods->{$row_ident}->[$_] }) for 0 .. $#{ $info_methods->{$row_ident} };
 679       do_statement($::form, $sth, $query, $report->id, $o1 + $_, $row + $n_header_rows, $data_row->{object}->${ \ $methods->{$row_ident}->[$_] })    for 0 .. $#{ $methods->{$row_ident} };
 680       do_statement($::form, $sth, $query, $report->id, $o2 + $_, $row + $n_header_rows, $data_row->{raw_data}{ $raw_methods->{$row_ident}->[$_] })   for 0 .. $#{ $raw_methods->{$row_ident} };
 681
 682       do_statement($::form, $sth2, $query2, $report->id, $row + $n_header_rows, 'information', $_) for @{ $data_row->{information} || [] };
 683       do_statement($::form, $sth2, $query2, $report->id, $row + $n_header_rows, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 684     }
 685     1;
 686   }) or do { die SL::DB->client->error };
 687
 688   return $report->id;
 689 }
 690
 691 sub init_worker {
 692   my $self = shift;
 693
 694   my @args = (controller => $self);
 695
 696   if ( $self->file() ) {
 697     push(@args, file => $self->file());
 698   }
 699
 700   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 701        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 702        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 703        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 704        : $self->{type} eq 'inventories'       ? SL::Controller::CsvImport::Inventory->new(@args)
 705        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 706        : $self->{type} eq 'orders'            ? SL::Controller::CsvImport::Order->new(@args)
 707        : $self->{type} eq 'bank_transactions' ? SL::Controller::CsvImport::BankTransaction->new(@args)
 708        : $self->{type} eq 'ar_transactions'   ? SL::Controller::CsvImport::ARTransaction->new(@args)
 709        :                                        die "Program logic error";
 710 }
 711
 712 sub init_num_imported { 0 }
 713
 714 sub setup_help {
 715   my ($self) = @_;
 716
 717   $self->worker->setup_displayable_columns;
 718 }
 719
 720 sub track_progress {
 721   my ($self, %params) = @_;
 722
 723   for my $tracker ($self->progress_tracker) {
 724     $tracker->track_progress(%params);
 725   }
 726 }
 727
 728 sub init_task_server {
 729   SL::System::TaskServer->new;
 730 }
 731
 732 sub cleanup_reports {
 733   SL::DB::Manager::CsvImportReport->cleanup;
 734 }
 735
 736 sub check_task_server {
 737   if (!$::auth->client->{task_server_user_id}) {
 738     flash('error', t8('The task server is required for this module but not enabled for the current client. Please enable it for the client "#1" in the administration section.', $::auth->client->{name}));
 739   }
 740
 741   return 1 if $_[0]->task_server->is_running;
 742
 743   flash('warning', t8('The task server is not running at the moment but needed for this module'));
 744
 745   1;
 746 }
 747
 748 sub mappings_for_profile {
 749   +{ map { $_->{from} => $_->{to} } @{ $_[0]->mappings } }
 750 }
 751
 752 sub init_mappings {
 753   [ grep { $_->{from} } @{ $::form->{mappings} || [] } ]
 754 }
 755
 756 sub setup_render_inputs_action_bar {
 757   my ($self, %params) = @_;
 758
 759   for my $bar ($::request->layout->get('actionbar')) {
 760     $bar->add(
 761       action => [
 762         t8('Preview'),
 763         submit    => [ '#form', { action => 'CsvImport/test' } ],
 764         accesskey => 'enter',
 765         not_if    => ($self->profile && $self->profile->get('dont_edit_profile')),
 766       ],
 767       action => [
 768         t8('Import'),
 769         submit    => [ '#form', { action => 'CsvImport/import' } ],
 770         disabled  => t8('The test import has not been executed yet.'),
 771         id        => 'action_import',
 772       ],
 773     );
 774   }
 775 }
 776
 777 1;