SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::DB::CsvImportReport;
   8 use SL::DB::Unit;
   9 use SL::DB::Helper::Paginated ();
  10 use SL::Helper::Flash;
  11 use SL::Locale::String;
  12 use SL::SessionFile;
  13 use SL::Controller::CsvImport::Contact;
  14 use SL::Controller::CsvImport::CustomerVendor;
  15 use SL::Controller::CsvImport::Part;
  16 use SL::Controller::CsvImport::Inventory;
  17 use SL::Controller::CsvImport::Shipto;
  18 use SL::Controller::CsvImport::Project;
  19 use SL::Controller::CsvImport::Order;
  20 use SL::Controller::CsvImport::ARTransaction;
  21 use SL::JSON;
  22 use SL::Controller::CsvImport::BankTransaction;
  23 use SL::BackgroundJob::CsvImport;
  24 use SL::System::TaskServer;
  25
  26 use List::MoreUtils qw(none);
  27 use List::Util qw(min);
  28
  29 use parent qw(SL::Controller::Base);
  30
  31 use Rose::Object::MakeMethods::Generic
  32 (
  33  scalar                  => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  34                                  import_status errors headers raw_data_headers info_headers data num_importable displayable_columns file all_taxzones) ],
  35  'scalar --get_set_init' => [ qw(worker task_server num_imported mappings) ],
  36  'array'                 => [
  37    progress_tracker     => { },
  38    add_progress_tracker => {  interface => 'add', hash_key => 'progress_tracker' },
  39  ],
  40 );
  41
  42 __PACKAGE__->run_before('check_auth');
  43 __PACKAGE__->run_before('ensure_form_structure');
  44 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  45 __PACKAGE__->run_before('load_all_profiles');
  46 __PACKAGE__->run_before('check_task_server');
  47
  48 __PACKAGE__->run_after('cleanup_reports');
  49
  50 #
  51 # actions
  52 #
  53
  54 sub action_new {
  55   my ($self) = @_;
  56
  57   $self->load_default_profile unless $self->profile;
  58   $self->render_inputs;
  59 }
  60
  61 sub action_test {
  62   my ($self) = @_;
  63   $self->test_and_import_deferred(test => 1);
  64 }
  65
  66 sub action_import {
  67   my $self = shift;
  68   $self->test_and_import_deferred(test => 0);
  69 }
  70
  71 sub action_save {
  72   my ($self) = @_;
  73
  74   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  75   $self->profile->save;
  76
  77   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  78   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  79 }
  80
  81 sub action_destroy {
  82   my $self = shift;
  83
  84   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  85   $profile->delete(cascade => 1);
  86
  87   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  88   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  89 }
  90
  91 sub action_result {
  92   my $self = shift;
  93
  94   # load resultobject
  95   $self->{background_job} = SL::DB::Manager::BackgroundJob->find_by(id => $::form->{job});
  96
  97   my $data = $self->{background_job}->data_as_hash;
  98
  99   my $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $data->{profile_id});
 100
 101   $self->profile($profile);
 102
 103   if ($data->{errors} and my $first_error =  $data->{errors}->[0]) {
 104     flash('error', $::locale->text('There was an error parsing the csv file: #1 in line #2: #3', $first_error->[2], $first_error->[0], $first_error->[1]));
 105   }
 106
 107   if ($data->{progress}{finished} || $data->{errors}) {
 108     $self->render('csv_import/_deferred_report', { layout => 0 });
 109   } else {
 110     if (!$self->task_server->is_running) {
 111       $self->task_server->start;
 112       $self->{status_text} = t8('Task Server is not running, starting it now. If this does not change, please check your task server config');
 113     } elsif (my $phase = $data->{progress}{phase}) {
 114       $self->{status_text} = "$data->{progress}{plan}{$phase} / $data->{progress}{num_phases} " . t8($phase);
 115     } else {
 116       $self->{status_text} = t8('Import not started yet, please wait...');
 117     }
 118
 119     $self->render('csv_import/_deferred_results', { layout => 0 });
 120   }
 121 }
 122
 123 sub action_download_sample {
 124   my $self = shift;
 125
 126   $self->profile_from_form;
 127   $self->setup_help;
 128
 129   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
 130   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
 131   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
 132
 133   if ($self->worker->is_multiplexed) {
 134     foreach my $p (@{ $self->worker->profile }) {
 135       $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns->{$p->{row_ident}} } ]);
 136       $file->fh->print("\r\n");
 137     }
 138     foreach my $p (@{ $self->worker->profile }) {
 139       $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns->{$p->{row_ident}} } ]);
 140       $file->fh->print("\r\n");
 141     }
 142   } else {
 143     $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
 144     $file->fh->print("\r\n");
 145     $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
 146     $file->fh->print("\r\n");
 147   }
 148
 149   $file->fh->close;
 150
 151   $self->send_file($file->file_name, name => $file_name);
 152 }
 153
 154 sub action_report {
 155   my ($self, %params) = @_;
 156
 157   my $report_id = $params{report_id} || $::form->{id};
 158
 159   $self->{report}      = SL::DB::Manager::CsvImportReport->find_by(id => $report_id);
 160
 161   if (!$self->{report}) {
 162     $::form->error(t8('No report with id #1', $report_id));
 163   }
 164   my $num_rows         = $self->{report}->numrows;
 165   my $num_cols         = SL::DB::Manager::CsvImportReportRow->get_all_count(query => [ csv_import_report_id => $report_id, row => 0 ]);
 166
 167   # manual paginating, yuck
 168   my $page = $::form->{page} || 1;
 169   my $pages = {};
 170   $pages->{per_page}        = $::form->{per_page} || 20;
 171   $pages->{max}             = SL::DB::Helper::Paginated::ceil($num_rows, $pages->{per_page}) || 1;
 172   $pages->{page}             = $page < 1 ? 1
 173                             : $page > $pages->{max} ? $pages->{max}
 174                             : $page;
 175   $pages->{common}          = [ grep { $_->{visible} } @{ SL::DB::Helper::Paginated::make_common_pages($pages->{page}, $pages->{max}) } ];
 176
 177   $self->{report_numheaders} = $self->{report}->numheaders;
 178   my $first_row_header = 0;
 179   my $last_row_header  = $self->{report_numheaders} - 1;
 180   my $first_row_data   = $pages->{per_page} * ($pages->{page}-1) + $self->{report_numheaders};
 181   my $last_row_data    = min($pages->{per_page} * $pages->{page}, $num_rows) + $self->{report_numheaders} - 1;
 182   $self->{display_rows} = [
 183     $first_row_header
 184       ..
 185     $last_row_header,
 186     $first_row_data
 187       ..
 188     $last_row_data
 189   ];
 190
 191   my @query = (
 192     csv_import_report_id => $report_id,
 193     or => [
 194       and => [
 195         row => { ge => $first_row_header },
 196         row => { le => $last_row_header },
 197       ],
 198       and => [
 199         row => { ge => $first_row_data },
 200         row => { le => $last_row_data },
 201       ]
 202     ]
 203   );
 204
 205   my $rows             = SL::DB::Manager::CsvImportReportRow->get_all(query => \@query);
 206   my $status           = SL::DB::Manager::CsvImportReportStatus->get_all(query => \@query);
 207
 208   $self->{report_rows}   = $self->{report}->folded_rows(rows => $rows);
 209   $self->{report_status} = $self->{report}->folded_status(status => $status);
 210   $self->{pages} = $pages;
 211   $self->{base_url} = $self->url_for(action => 'report', id => $report_id, no_layout => $params{no_layout} || $::form->{no_layout} );
 212
 213   $self->render('csv_import/report', { layout => !($params{no_layout} || $::form->{no_layout}) });
 214 }
 215
 216 sub action_add_empty_mapping_line {
 217   my ($self) = @_;
 218
 219   $self->profile_from_form;
 220   $self->setup_help;
 221
 222   $self->js
 223     ->append('#csv_import_mappings', $self->render('csv_import/_mapping_item', { layout => 0, output => 0 }))
 224     ->hide('#mapping_empty')
 225     ->render;
 226 }
 227
 228 sub action_add_mapping_from_upload {
 229   my ($self) = @_;
 230
 231   $self->profile_from_form;
 232   $self->setup_help;
 233
 234   my $file = SL::SessionFile->new($self->csv_file_name, mode => '<', encoding => $self->profile->get('charset'));
 235   if (!$file->fh) {
 236     $self->js
 237       ->flash('error', t8('No file has been uploaded yet.'))
 238       ->render;
 239     return;
 240   }
 241
 242   my $csv = SL::Helper::Csv->new(
 243     file => $file->file_name,
 244     map { $_ => $self->profile->get($_) } qw(sep_char escape_char quote_char),
 245   );
 246
 247   $csv->_open_file;
 248   my $header = $csv->check_header;
 249
 250   for my $field (@$header) {
 251     next if $self->mappings_for_profile->{$field};
 252     $self->js->append(
 253       '#csv_import_mappings',
 254       $self->render('csv_import/_mapping_item', { layout => 0, output => 0 }, item => { from => $field }),
 255     );
 256   }
 257
 258   $self->js
 259     ->hide('#mapping_empty')
 260     ->render;
 261 }
 262
 263
 264 #
 265 # filters
 266 #
 267
 268 sub check_auth {
 269   $::auth->assert('config');
 270 }
 271
 272 sub check_type {
 273   my ($self) = @_;
 274
 275   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts inventories customers_vendors addresses contacts projects orders bank_transactions ar_transactions);
 276   $self->type($::form->{profile}->{type});
 277 }
 278
 279 sub ensure_form_structure {
 280   my ($self, %params) = @_;
 281
 282   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 283   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 284 }
 285
 286 #
 287 # helpers
 288 #
 289
 290 sub render_inputs {
 291   my ($self, %params) = @_;
 292
 293   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 294                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 295                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 296                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 297                         [ 'CP1252',      'CP1252 (Windows)'      ],
 298                       ]);
 299
 300   my %char_map = $self->char_map;
 301
 302   foreach my $type (qw(sep quote escape)) {
 303     my $sub = "all_${type}_chars";
 304     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 305
 306     my $char = $self->profile->get($type . '_char');
 307     $sub     = "${type}_char";
 308     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 309   }
 310
 311   $self->file(SL::SessionFile->new($self->csv_file_name));
 312
 313   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 314             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 315             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 316             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 317             : $self->type eq 'inventories'       ? $::locale->text('CSV import: inventories')
 318             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 319             : $self->type eq 'orders'            ? $::locale->text('CSV import: orders')
 320             : $self->type eq 'bank_transactions' ? $::locale->text('CSV import: bank transactions')
 321             : $self->type eq 'ar_transactions'   ? $::locale->text('CSV import: ar transactions')
 322             : die;
 323
 324   if ($self->{type} eq 'customers_vendors' or $self->{type} eq 'orders' or $self->{type} eq 'ar_transactions' ) {
 325     $self->all_taxzones(SL::DB::Manager::TaxZone->get_all_sorted(query => [ obsolete => 0 ]));
 326   };
 327
 328   if ($self->{type} eq 'parts') {
 329     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 330     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 331   }
 332
 333   $self->setup_help;
 334
 335   $self->render('csv_import/form', title => $title);
 336 }
 337
 338 sub test_and_import_deferred {
 339   my ($self, %params) = @_;
 340
 341   if ( $::form->{force_profile} && $::form->{profile}->{id} ) {
 342     $self->load_default_profile;
 343   }  else {
 344     $self->profile_from_form;
 345   };
 346
 347   if ($::form->{file}) {
 348     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 349     $file->fh->print($::form->{file});
 350     $file->fh->close;
 351   }
 352
 353   my $file = SL::SessionFile->new($self->csv_file_name, mode => '<', encoding => $self->profile->get('charset'));
 354   if (!$file->fh) {
 355     flash('error', $::locale->text('No file has been uploaded yet.'));
 356     return $self->action_new;
 357   }
 358
 359   $self->{background_job} = SL::BackgroundJob::CsvImport->create_job(
 360     file        => $self->csv_file_name,
 361     profile     => $self->profile,
 362     type        => $self->profile->type,
 363     test        => $params{test},
 364     employee_id => SL::DB::Manager::Employee->current->id,
 365   )->save;
 366
 367   if ($self->task_server->is_running) {
 368     $self->task_server->wake_up;
 369   } else {
 370     $self->task_server->start;
 371   }
 372
 373   flash('info', $::locale->text('Your import is being processed.'));
 374
 375   $self->{deferred} = 1;
 376
 377   if ($::request->type eq 'json') {
 378     $self->render(\ SL::JSON::to_json($self->{background_job}->as_tree), { type => 'json' })
 379   } else {
 380     $self->render_inputs;
 381   }
 382 }
 383
 384 sub test_and_import {
 385   my ($self, %params) = @_;
 386
 387   my $file = SL::SessionFile->new(
 388     $self->csv_file_name,
 389     mode       => '<',
 390     encoding   => $self->profile->get('charset'),
 391     session_id => $params{session_id}
 392   );
 393
 394   $self->file($file);
 395
 396   my $worker = $self->worker();
 397
 398   $worker->run(%params);
 399
 400   return if $self->errors;
 401
 402   $self->num_imported(0);
 403   $worker->save_objects if !$params{test};
 404
 405   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 406   $self->import_status($params{test} ? 'tested' : 'imported');
 407
 408 #  flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 409 }
 410
 411 sub load_default_profile {
 412   my ($self) = @_;
 413
 414   my $profile;
 415   if ($::form->{profile}->{id}) {
 416     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id}, login => $::myconfig{login});
 417   }
 418   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 419   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 420
 421   $self->profile($profile);
 422   $self->mappings(SL::JSON::from_json($self->profile->get('json_mappings'))) if $self->profile->get('json_mappings');
 423   $self->worker->set_profile_defaults;
 424   $self->profile->set_defaults;
 425 }
 426
 427 sub load_all_profiles {
 428   my ($self, %params) = @_;
 429
 430   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 431     where => [
 432       type  => $self->type,
 433       login => $::myconfig{login},
 434       '!name'  => '',
 435     ],
 436   sort_by => 'name'));
 437 }
 438
 439 sub profile_from_form {
 440   my ($self, $existing_profile) = @_;
 441
 442   delete $::form->{profile}->{id};
 443
 444   my %char_map = $self->char_map;
 445   my @settings;
 446
 447   foreach my $type (qw(sep quote escape)) {
 448     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 449     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 450
 451     push @settings, { key => "${type}_char", value => $char };
 452   }
 453
 454   if ($self->type eq 'parts') {
 455     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 456   }
 457
 458   if ($self->type eq 'orders') {
 459     $::form->{settings}->{max_amount_diff} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{max_amount_diff});
 460   }
 461
 462   delete $::form->{profile}->{id};
 463   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 464   $self->profile->assign_attributes(%{ $::form->{profile} });
 465   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 466                            @settings);
 467
 468   $self->profile->set('json_mappings', JSON::to_json($self->mappings));
 469
 470   $self->profile->set_defaults;
 471 }
 472
 473 sub char_map {
 474   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 475                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 476                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 477                        ' '  => [ 'space',     $::locale->text('Space')     ],
 478                      },
 479            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 480                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 481                      },
 482            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 483                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 484                      },
 485          );
 486 }
 487
 488 sub save_report {
 489   my ($self, %params) = @_;
 490
 491   if ($self->worker->is_multiplexed) {
 492     return $self->save_report_multi(%params);
 493   } else {
 494     return $self->save_report_single(%params);
 495   }
 496 }
 497
 498 sub save_report_single {
 499   my ($self, %params) = @_;
 500
 501   $self->track_progress(phase => 'building report', progress => 0);
 502
 503   my $clone_profile = $self->profile->clone_and_reset_deep;
 504   $clone_profile->save; # weird bug. if this isn't saved before adding it to the report, it will default back to the last profile.
 505
 506   my $report = SL::DB::CsvImportReport->new(
 507     session_id => $params{session_id},
 508     profile    => $clone_profile,
 509     type       => $self->type,
 510     file       => '',
 511     numrows    => scalar @{ $self->data },
 512     numheaders => 1,
 513   );
 514
 515   $report->save(cascade => 1) or die $report->db->error;
 516
 517   my $dbh = $::form->get_standard_dbh;
 518   $dbh->begin_work;
 519
 520   my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 521   my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 522
 523   my $sth = $dbh->prepare($query);
 524   my $sth2 = $dbh->prepare($query2);
 525
 526   # save headers
 527   my (@headers, @info_methods, @raw_methods, @methods);
 528
 529   for my $i (0 .. $#{ $self->info_headers->{headers} }) {
 530     next unless         $self->info_headers->{used}->{ $self->info_headers->{methods}->[$i] };
 531     push @headers,      $self->info_headers->{headers}->[$i];
 532     push @info_methods, $self->info_headers->{methods}->[$i];
 533   }
 534   for my $i (0 .. $#{ $self->headers->{headers} }) {
 535     next unless         $self->headers->{used}->{ $self->headers->{headers}->[$i] };
 536     push @headers,      $self->headers->{headers}->[$i];
 537     push @methods,      $self->headers->{methods}->[$i];
 538   }
 539   for my $i (0 .. $#{ $self->raw_data_headers->{headers} }) {
 540     next unless         $self->raw_data_headers->{used}->{ $self->raw_data_headers->{headers}->[$i] };
 541     push @headers,      $self->raw_data_headers->{headers}->[$i];
 542     push @raw_methods,  $self->raw_data_headers->{headers}->[$i];
 543   }
 544
 545   $sth->execute($report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 546
 547   # col offsets
 548   my $o1 =       @info_methods;
 549   my $o2 = $o1 + @methods;
 550
 551   for my $row (0 .. $#{ $self->data }) {
 552     $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 1000 == 0;
 553     my $data_row = $self->{data}[$row];
 554
 555     $sth->execute($report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 556     $sth->execute($report->id, $o1 + $_, $row + 1, $data_row->{object}->${ \ $methods[$_] })    for 0 .. $#methods;
 557     $sth->execute($report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 558
 559     $sth2->execute($report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 560     $sth2->execute($report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 561   }
 562
 563   $dbh->commit;
 564
 565   return $report->id;
 566 }
 567
 568 sub save_report_multi {
 569   my ($self, %params) = @_;
 570
 571   $self->track_progress(phase => 'building report', progress => 0);
 572
 573   my $clone_profile = $self->profile->clone_and_reset_deep;
 574   $clone_profile->save; # weird bug. if this isn't saved before adding it to the report, it will default back to the last profile.
 575
 576   my $report = SL::DB::CsvImportReport->new(
 577     session_id => $params{session_id},
 578     profile    => $clone_profile,
 579     type       => $self->type,
 580     file       => '',
 581     numrows    => scalar @{ $self->data },
 582     numheaders => scalar @{ $self->worker->profile },
 583   );
 584
 585   $report->save(cascade => 1) or die $report->db->error;
 586
 587   my $dbh = $::form->get_standard_dbh;
 588   $dbh->begin_work;
 589
 590   my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 591   my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 592
 593   my $sth = $dbh->prepare($query);
 594   my $sth2 = $dbh->prepare($query2);
 595
 596   # save headers
 597   my ($headers, $info_methods, $raw_methods, $methods);
 598
 599   for my $i (0 .. $#{ $self->worker->profile }) {
 600     my $row_ident = $self->worker->profile->[$i]->{row_ident};
 601
 602     for my $i (0 .. $#{ $self->info_headers->{$row_ident}->{headers} }) {
 603       next unless                            $self->info_headers->{$row_ident}->{used}->{ $self->info_headers->{$row_ident}->{methods}->[$i] };
 604       push @{ $headers->{$row_ident} },      $self->info_headers->{$row_ident}->{headers}->[$i];
 605       push @{ $info_methods->{$row_ident} }, $self->info_headers->{$row_ident}->{methods}->[$i];
 606     }
 607     for my $i (0 .. $#{ $self->headers->{$row_ident}->{headers} }) {
 608       next unless                       $self->headers->{$row_ident}->{used}->{ $self->headers->{$row_ident}->{headers}->[$i] };
 609       push @{ $headers->{$row_ident} }, $self->headers->{$row_ident}->{headers}->[$i];
 610       push @{ $methods->{$row_ident} }, $self->headers->{$row_ident}->{methods}->[$i];
 611     }
 612
 613     for my $i (0 .. $#{ $self->raw_data_headers->{$row_ident}->{headers} }) {
 614     next unless                           $self->raw_data_headers->{$row_ident}->{used}->{ $self->raw_data_headers->{$row_ident}->{headers}->[$i] };
 615     push @{ $headers->{$row_ident} },     $self->raw_data_headers->{$row_ident}->{headers}->[$i];
 616     push @{ $raw_methods->{$row_ident} }, $self->raw_data_headers->{$row_ident}->{headers}->[$i];
 617   }
 618
 619   }
 620
 621   for my $i (0 .. $#{ $self->worker->profile }) {
 622     my $row_ident = $self->worker->profile->[$i]->{row_ident};
 623     $sth->execute($report->id, $_, $i, $headers->{$row_ident}->[$_]) for 0 .. $#{ $headers->{$row_ident} };
 624   }
 625
 626   # col offsets
 627   my ($off1, $off2);
 628   for my $i (0 .. $#{ $self->worker->profile }) {
 629     my $row_ident = $self->worker->profile->[$i]->{row_ident};
 630     my $n_info_methods = $info_methods->{$row_ident} ? scalar @{ $info_methods->{$row_ident} } : 0;
 631     my $n_methods      = $methods->{$row_ident} ?      scalar @{ $methods->{$row_ident} }      : 0;
 632
 633     $off1->{$row_ident} = $n_info_methods;
 634     $off2->{$row_ident} = $off1->{$row_ident} + $n_methods;
 635   }
 636
 637   my $n_header_rows = scalar @{ $self->worker->profile };
 638
 639   for my $row (0 .. $#{ $self->data }) {
 640     $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 1000 == 0;
 641     my $data_row = $self->{data}[$row];
 642     my $row_ident = $data_row->{raw_data}{datatype};
 643
 644     my $o1 = $off1->{$row_ident};
 645     my $o2 = $off2->{$row_ident};
 646
 647     $sth->execute($report->id,       $_, $row + $n_header_rows, $data_row->{info_data}{ $info_methods->{$row_ident}->[$_] }) for 0 .. $#{ $info_methods->{$row_ident} };
 648     $sth->execute($report->id, $o1 + $_, $row + $n_header_rows, $data_row->{object}->${ \ $methods->{$row_ident}->[$_] })    for 0 .. $#{ $methods->{$row_ident} };
 649     $sth->execute($report->id, $o2 + $_, $row + $n_header_rows, $data_row->{raw_data}{ $raw_methods->{$row_ident}->[$_] })   for 0 .. $#{ $raw_methods->{$row_ident} };
 650
 651     $sth2->execute($report->id, $row + $n_header_rows, 'information', $_) for @{ $data_row->{information} || [] };
 652     $sth2->execute($report->id, $row + $n_header_rows, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 653   }
 654
 655   $dbh->commit;
 656
 657   return $report->id;
 658 }
 659
 660 sub csv_file_name {
 661   my ($self) = @_;
 662   return "csv-import-" . $self->type . ".csv";
 663 }
 664
 665 sub init_worker {
 666   my $self = shift;
 667
 668   my @args = (controller => $self);
 669
 670   if ( $self->file() ) {
 671     push(@args, file => $self->file());
 672   }
 673
 674   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 675        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 676        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 677        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 678        : $self->{type} eq 'inventories'       ? SL::Controller::CsvImport::Inventory->new(@args)
 679        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 680        : $self->{type} eq 'orders'            ? SL::Controller::CsvImport::Order->new(@args)
 681        : $self->{type} eq 'bank_transactions' ? SL::Controller::CsvImport::BankTransaction->new(@args)
 682        : $self->{type} eq 'ar_transactions'   ? SL::Controller::CsvImport::ARTransaction->new(@args)
 683        :                                        die "Program logic error";
 684 }
 685
 686 sub init_num_imported { 0 }
 687
 688 sub setup_help {
 689   my ($self) = @_;
 690
 691   $self->worker->setup_displayable_columns;
 692 }
 693
 694 sub track_progress {
 695   my ($self, %params) = @_;
 696
 697   for my $tracker ($self->progress_tracker) {
 698     $tracker->track_progress(%params);
 699   }
 700 }
 701
 702 sub init_task_server {
 703   SL::System::TaskServer->new;
 704 }
 705
 706 sub cleanup_reports {
 707   SL::DB::Manager::CsvImportReport->cleanup;
 708 }
 709
 710 sub check_task_server {
 711   return 1 if $_[0]->task_server->is_running;
 712
 713   flash('info', t8('The task server is not running at the moment but needed for this module'));
 714
 715   1;
 716 }
 717
 718 sub mappings_for_profile {
 719   +{ map { $_->{from} => $_->{to} } @{ $_[0]->mappings } }
 720 }
 721
 722 sub init_mappings {
 723   $::form->{mappings} || []
 724 }
 725
 726 1;