SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::Helper::Flash;
   8 use SL::SessionFile;
   9 use SL::Controller::CsvImport::Contact;
  10 use SL::Controller::CsvImport::CustomerVendor;
  11
  12 use List::MoreUtils qw(none);
  13
  14 use parent qw(SL::Controller::Base);
  15
  16 use Rose::Object::MakeMethods::Generic
  17 (
  18  scalar => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen
  19                 import_status errors headers data num_imported num_importable) ],
  20 );
  21
  22 __PACKAGE__->run_before('check_auth');
  23 __PACKAGE__->run_before('ensure_form_structure');
  24 __PACKAGE__->run_before('check_type');
  25 __PACKAGE__->run_before('load_all_profiles');
  26
  27 #
  28 # actions
  29 #
  30
  31 sub action_new {
  32   my ($self) = @_;
  33
  34   $self->load_default_profile unless $self->profile;
  35   $self->render_inputs;
  36 }
  37
  38 sub action_test {
  39   my ($self) = @_;
  40   $self->test_and_import(test => 1);
  41 }
  42
  43 sub action_import {
  44   my $self = shift;
  45   $self->test_and_import(test => 0);
  46 }
  47
  48 sub action_save {
  49   my ($self) = @_;
  50
  51   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}));
  52   $self->profile->save;
  53
  54   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  55   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  56 }
  57
  58 sub action_destroy {
  59   my $self = shift;
  60
  61   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id});
  62   $profile->delete(cascade => 1);
  63
  64   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  65   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  66 }
  67
  68 #
  69 # filters
  70 #
  71
  72 sub check_auth {
  73   $::auth->assert('config');
  74 }
  75
  76 sub check_type {
  77   my ($self) = @_;
  78
  79   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts customers_vendors addresses contacts);
  80   $self->type($::form->{profile}->{type});
  81 }
  82
  83 sub ensure_form_structure {
  84   my ($self, %params) = @_;
  85
  86   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
  87   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
  88 }
  89
  90 #
  91 # helpers
  92 #
  93
  94 sub render_inputs {
  95   my ($self, %params) = @_;
  96
  97   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
  98                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
  99                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 100                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 101                         [ 'CP1252',      'CP1252 (Windows)'      ],
 102                       ]);
 103
 104   my %char_map = $self->char_map;
 105
 106   foreach my $type (qw(sep quote escape)) {
 107     my $sub = "all_${type}_chars";
 108     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 109
 110     my $char = $self->profile->get($type . '_char');
 111     $sub     = "${type}_char";
 112     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 113   }
 114
 115   $self->file(SL::SessionFile->new($self->csv_file_name));
 116
 117   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 118             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 119             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 120             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 121             : die;
 122
 123   $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 124
 125   $self->render('csv_import/form', title => $title);
 126 }
 127
 128 sub test_and_import {
 129   my ($self, %params) = @_;
 130
 131   $self->profile_from_form;
 132
 133   if ($::form->{file}) {
 134     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 135     $file->fh->print($::form->{file});
 136     $file->fh->close;
 137   }
 138
 139   my $file = SL::SessionFile->new($self->csv_file_name, mode => '<', encoding => $self->profile->get('charset'));
 140   if (!$file->fh) {
 141     flash('error', $::locale->text('No file has been uploaded yet.'));
 142     return $self->action_new;
 143   }
 144
 145   my $worker = $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(controller => $self, file => $file)
 146              : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(       controller => $self, file => $file)
 147              :                                        die "Program logic error";
 148
 149   $worker->run;
 150   $worker->save_objects if !$params{test};
 151
 152   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data });
 153   $self->import_status($params{test} ? 'tested' : 'imported');
 154
 155   $self->action_new;
 156 }
 157
 158 sub load_default_profile {
 159   my ($self) = @_;
 160
 161   if ($::form->{profile}->{id}) {
 162     $self->profile(SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id})->load);
 163
 164   } else {
 165     $self->profile(SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1));
 166     $self->profile(SL::DB::CsvImportProfile->new(type => $self->{type})) unless $self->profile;
 167   }
 168
 169   $self->profile->set_defaults;
 170 }
 171
 172 sub load_all_profiles {
 173   my ($self, %params) = @_;
 174
 175   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(where => [ type => $self->type ], sort_by => 'name'));
 176 }
 177
 178 sub profile_from_form {
 179   my ($self, $existing_profile) = @_;
 180
 181   delete $::form->{profile}->{id};
 182
 183   my %char_map = $self->char_map;
 184   my @settings;
 185
 186   foreach my $type (qw(sep quote escape)) {
 187     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 188     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 189
 190     push @settings, { key => "${type}_char", value => $char };
 191   }
 192
 193   delete $::form->{profile}->{id};
 194   $self->profile($existing_profile || SL::DB::CsvImportProfile->new);
 195   $self->profile->assign_attributes(%{ $::form->{profile} });
 196   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 197                            @settings);
 198   $self->profile->set_defaults;
 199 }
 200
 201 sub char_map {
 202   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 203                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 204                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 205                        ' '  => [ 'space',     $::locale->text('Space')     ],
 206                      },
 207            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 208                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 209                      },
 210            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 211                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 212                      },
 213          );
 214 }
 215
 216 sub csv_file_name {
 217   my ($self) = @_;
 218   return "csv-import-" . $self->type . ".csv";
 219 }
 220
 221 1;