SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::Helper::Flash;
   8 use SL::SessionFile;
   9 use SL::Controller::CsvImport::Contact;
  10 use SL::Controller::CsvImport::CustomerVendor;
  11 use SL::Controller::CsvImport::Part;
  12 use SL::Controller::CsvImport::Shipto;
  13
  14 use List::MoreUtils qw(none);
  15
  16 use parent qw(SL::Controller::Base);
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20  scalar => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen
  21                 import_status errors headers raw_data_headers info_headers data num_imported num_importable displayable_columns) ],
  22 );
  23
  24 __PACKAGE__->run_before('check_auth');
  25 __PACKAGE__->run_before('ensure_form_structure');
  26 __PACKAGE__->run_before('check_type');
  27 __PACKAGE__->run_before('load_all_profiles');
  28
  29 #
  30 # actions
  31 #
  32
  33 sub action_new {
  34   my ($self) = @_;
  35
  36   $self->load_default_profile unless $self->profile;
  37   $self->render_inputs;
  38 }
  39
  40 sub action_test {
  41   my ($self) = @_;
  42   $self->test_and_import(test => 1);
  43 }
  44
  45 sub action_import {
  46   my $self = shift;
  47   $self->test_and_import(test => 0);
  48 }
  49
  50 sub action_save {
  51   my ($self) = @_;
  52
  53   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}));
  54   $self->profile->save;
  55
  56   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  57   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  58 }
  59
  60 sub action_destroy {
  61   my $self = shift;
  62
  63   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id});
  64   $profile->delete(cascade => 1);
  65
  66   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  67   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  68 }
  69
  70 sub action_download_sample {
  71   my $self = shift;
  72
  73   $self->profile_from_form;
  74   $self->setup_help;
  75
  76   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
  77   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
  78   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
  79
  80   $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
  81   $file->fh->print("\r\n");
  82   $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
  83   $file->fh->print("\r\n");
  84
  85   $file->fh->close;
  86
  87   $self->send_file($file->file_name);
  88 }
  89
  90 #
  91 # filters
  92 #
  93
  94 sub check_auth {
  95   $::auth->assert('config');
  96 }
  97
  98 sub check_type {
  99   my ($self) = @_;
 100
 101   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts customers_vendors addresses contacts);
 102   $self->type($::form->{profile}->{type});
 103 }
 104
 105 sub ensure_form_structure {
 106   my ($self, %params) = @_;
 107
 108   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 109   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 110 }
 111
 112 #
 113 # helpers
 114 #
 115
 116 sub render_inputs {
 117   my ($self, %params) = @_;
 118
 119   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 120                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 121                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 122                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 123                         [ 'CP1252',      'CP1252 (Windows)'      ],
 124                       ]);
 125
 126   my %char_map = $self->char_map;
 127
 128   foreach my $type (qw(sep quote escape)) {
 129     my $sub = "all_${type}_chars";
 130     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 131
 132     my $char = $self->profile->get($type . '_char');
 133     $sub     = "${type}_char";
 134     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 135   }
 136
 137   $self->file(SL::SessionFile->new($self->csv_file_name));
 138
 139   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 140             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 141             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 142             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 143             : die;
 144
 145   $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 146
 147   $self->setup_help;
 148
 149   $self->render('csv_import/form', title => $title);
 150 }
 151
 152 sub test_and_import {
 153   my ($self, %params) = @_;
 154
 155   $self->profile_from_form;
 156
 157   if ($::form->{file}) {
 158     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 159     $file->fh->print($::form->{file});
 160     $file->fh->close;
 161   }
 162
 163   my $file = SL::SessionFile->new($self->csv_file_name, mode => '<', encoding => $self->profile->get('charset'));
 164   if (!$file->fh) {
 165     flash('error', $::locale->text('No file has been uploaded yet.'));
 166     return $self->action_new;
 167   }
 168
 169   my $worker = $self->create_worker($file);
 170   $worker->run;
 171   $worker->save_objects if !$params{test};
 172
 173   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 174   $self->import_status($params{test} ? 'tested' : 'imported');
 175
 176   flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 177
 178   $self->action_new;
 179 }
 180
 181 sub load_default_profile {
 182   my ($self) = @_;
 183
 184   if ($::form->{profile}->{id}) {
 185     $self->profile(SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id})->load);
 186
 187   } else {
 188     $self->profile(SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1));
 189     $self->profile(SL::DB::CsvImportProfile->new(type => $self->{type})) unless $self->profile;
 190   }
 191
 192   $self->profile->set_defaults;
 193 }
 194
 195 sub load_all_profiles {
 196   my ($self, %params) = @_;
 197
 198   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(where => [ type => $self->type ], sort_by => 'name'));
 199 }
 200
 201 sub profile_from_form {
 202   my ($self, $existing_profile) = @_;
 203
 204   delete $::form->{profile}->{id};
 205
 206   my %char_map = $self->char_map;
 207   my @settings;
 208
 209   foreach my $type (qw(sep quote escape)) {
 210     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 211     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 212
 213     push @settings, { key => "${type}_char", value => $char };
 214   }
 215
 216   if ($self->type eq 'parts') {
 217     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 218   }
 219
 220   delete $::form->{profile}->{id};
 221   $self->profile($existing_profile || SL::DB::CsvImportProfile->new);
 222   $self->profile->assign_attributes(%{ $::form->{profile} });
 223   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 224                            @settings);
 225   $self->profile->set_defaults;
 226 }
 227
 228 sub char_map {
 229   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 230                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 231                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 232                        ' '  => [ 'space',     $::locale->text('Space')     ],
 233                      },
 234            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 235                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 236                      },
 237            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 238                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 239                      },
 240          );
 241 }
 242
 243 sub csv_file_name {
 244   my ($self) = @_;
 245   return "csv-import-" . $self->type . ".csv";
 246 }
 247
 248 sub create_worker {
 249   my ($self, $file) = @_;
 250
 251   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(controller => $self, file => $file)
 252        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(       controller => $self, file => $file)
 253        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(        controller => $self, file => $file)
 254        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(          controller => $self, file => $file)
 255        :                                        die "Program logic error";
 256 }
 257
 258 sub setup_help {
 259   my ($self) = @_;
 260
 261   $self->create_worker->setup_displayable_columns;
 262 }
 263
 264
 265 1;