SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::DB::CsvImportReport;
   8 use SL::DB::Unit;
   9 use SL::Helper::Flash;
  10 use SL::SessionFile;
  11 use SL::Controller::CsvImport::Contact;
  12 use SL::Controller::CsvImport::CustomerVendor;
  13 use SL::Controller::CsvImport::Part;
  14 use SL::Controller::CsvImport::Shipto;
  15 use SL::Controller::CsvImport::Project;
  16
  17 use List::MoreUtils qw(none);
  18
  19 use parent qw(SL::Controller::Base);
  20
  21 use Rose::Object::MakeMethods::Generic
  22 (
  23  scalar                  => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  24                                  import_status errors headers raw_data_headers info_headers data num_imported num_importable displayable_columns file) ],
  25  'scalar --get_set_init' => [ qw(worker) ]
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('ensure_form_structure');
  30 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  31 __PACKAGE__->run_before('load_all_profiles');
  32
  33 #
  34 # actions
  35 #
  36
  37 sub action_new {
  38   my ($self) = @_;
  39
  40   $self->load_default_profile unless $self->profile;
  41   $self->render_inputs;
  42 }
  43
  44 sub action_test {
  45   my ($self) = @_;
  46   $self->test_and_import(test => 1);
  47 }
  48
  49 sub action_import {
  50   my $self = shift;
  51   $self->test_and_import(test => 0);
  52 }
  53
  54 sub action_save {
  55   my ($self) = @_;
  56
  57   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  58   $self->profile->save;
  59
  60   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  61   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  62 }
  63
  64 sub action_destroy {
  65   my $self = shift;
  66
  67   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  68   $profile->delete(cascade => 1);
  69
  70   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  71   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  72 }
  73
  74 sub action_download_sample {
  75   my $self = shift;
  76
  77   $self->profile_from_form;
  78   $self->setup_help;
  79
  80   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
  81   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
  82   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
  83
  84   $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
  85   $file->fh->print("\r\n");
  86   $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
  87   $file->fh->print("\r\n");
  88
  89   $file->fh->close;
  90
  91   $self->send_file($file->file_name, name => $file_name);
  92 }
  93
  94 #
  95 # filters
  96 #
  97
  98 sub check_auth {
  99   $::auth->assert('config');
 100 }
 101
 102 sub check_type {
 103   my ($self) = @_;
 104
 105   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts customers_vendors addresses contacts projects);
 106   $self->type($::form->{profile}->{type});
 107 }
 108
 109 sub ensure_form_structure {
 110   my ($self, %params) = @_;
 111
 112   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 113   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 114 }
 115
 116 #
 117 # helpers
 118 #
 119
 120 sub render_inputs {
 121   my ($self, %params) = @_;
 122
 123   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 124                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 125                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 126                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 127                         [ 'CP1252',      'CP1252 (Windows)'      ],
 128                       ]);
 129
 130   my %char_map = $self->char_map;
 131
 132   foreach my $type (qw(sep quote escape)) {
 133     my $sub = "all_${type}_chars";
 134     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 135
 136     my $char = $self->profile->get($type . '_char');
 137     $sub     = "${type}_char";
 138     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 139   }
 140
 141   $self->file(SL::SessionFile->new($self->csv_file_name));
 142
 143   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 144             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 145             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 146             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 147             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 148             : die;
 149
 150   if ($self->{type} eq 'parts') {
 151     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 152     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 153   }
 154
 155   $self->setup_help;
 156
 157   $self->render('csv_import/form', title => $title);
 158 }
 159
 160 sub test_and_import {
 161   my ($self, %params) = @_;
 162
 163   $self->profile_from_form;
 164
 165   if ($::form->{file}) {
 166     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 167     $file->fh->print($::form->{file});
 168     $file->fh->close;
 169   }
 170
 171   my $file = SL::SessionFile->new($self->csv_file_name, mode => '<', encoding => $self->profile->get('charset'));
 172   if (!$file->fh) {
 173     flash('error', $::locale->text('No file has been uploaded yet.'));
 174     return $self->action_new;
 175   }
 176
 177   $self->file($file);
 178
 179   my $worker = $self->worker();
 180
 181   $worker->run;
 182
 183   $self->num_imported(0);
 184   $worker->save_objects if !$params{test};
 185
 186   $self->save_report;
 187
 188   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 189   $self->import_status($params{test} ? 'tested' : 'imported');
 190
 191   flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 192
 193   $self->action_new;
 194 }
 195
 196 sub load_default_profile {
 197   my ($self) = @_;
 198
 199   my $profile;
 200   if ($::form->{profile}->{id}) {
 201     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id}, login => $::myconfig{login});
 202   }
 203   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 204   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 205
 206   $self->profile($profile);
 207   $self->profile->set_defaults;
 208 }
 209
 210 sub load_all_profiles {
 211   my ($self, %params) = @_;
 212
 213   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 214     where => [
 215       type  => $self->type,
 216       login => $::myconfig{login},
 217     ],
 218   sort_by => 'name'));
 219 }
 220
 221 sub profile_from_form {
 222   my ($self, $existing_profile) = @_;
 223
 224   delete $::form->{profile}->{id};
 225
 226   my %char_map = $self->char_map;
 227   my @settings;
 228
 229   foreach my $type (qw(sep quote escape)) {
 230     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 231     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 232
 233     push @settings, { key => "${type}_char", value => $char };
 234   }
 235
 236   if ($self->type eq 'parts') {
 237     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 238   }
 239
 240   delete $::form->{profile}->{id};
 241   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 242   $self->profile->assign_attributes(%{ $::form->{profile} });
 243   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 244                            @settings);
 245   $self->profile->set_defaults;
 246 }
 247
 248 sub char_map {
 249   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 250                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 251                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 252                        ' '  => [ 'space',     $::locale->text('Space')     ],
 253                      },
 254            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 255                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 256                      },
 257            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 258                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 259                      },
 260          );
 261 }
 262
 263 sub save_report {
 264   my ($self, $report_id) = @_;
 265
 266   my $clone_profile = $self->profile->clone_and_reset_deep;
 267   $clone_profile->save; # weird bug. if this isn't saved before adding it to the report, it will default back to the last profile.
 268
 269   my $report = SL::DB::CsvImportReport->new(
 270     session_id => $::auth->create_or_refresh_session,
 271     profile    => $clone_profile,
 272     type       => $self->type,
 273     file       => '',
 274   )->save(cascade => 1);
 275
 276   my $dbh = $::form->get_standard_dbh;
 277   $dbh->begin_work;
 278
 279   my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 280   my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 281
 282   my $sth = $dbh->prepare($query);
 283   my $sth2 = $dbh->prepare($query2);
 284
 285 #  $::lxdebug->dump(0,  "self", $self->info_headers);
 286 #  $::lxdebug->dump(0,  "self", $self->headers);
 287 #  $::lxdebug->dump(0,  "self", $self->raw_data_headers);
 288
 289   # save headers
 290   my @headers = (
 291     grep({ $self->info_headers->{used}->{$_}     } @{ $self->info_headers->{headers} }),
 292     grep({ $self->headers->{used}->{$_}          } @{ $self->headers->{headers} }),
 293     grep({ $self->raw_data_headers->{used}->{$_} } @{ $self->raw_data_headers->{headers} }),
 294   );
 295   my @info_methods = grep { $self->info_headers->{used}->{$_}     } @{ $self->info_headers->{headers} };
 296   my @methods      = grep { $self->headers->{used}->{$_}          } @{ $self->headers->{methods} };
 297   my @raw_methods  = grep { $self->raw_data_headers->{used}->{$_} } @{ $self->raw_data_headers->{headers} };
 298
 299   $sth->execute($report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 300
 301   # col offsets
 302   my $o1 =       @info_methods;
 303   my $o2 = $o1 + @methods;
 304
 305   for my $row (0 .. $#{ $self->data }) {
 306     my $data_row = $self->{data}[$row];
 307
 308     $sth->execute($report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 309     $sth->execute($report->id, $o1 + $_, $row + 1, $data_row->{object}->${ \ $methods[$_] })    for 0 .. $#methods;
 310     $sth->execute($report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 311
 312     $sth2->execute($report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 313     $sth2->execute($report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 314   }
 315
 316   $dbh->commit;
 317 }
 318
 319 sub action_report {
 320   my ($self) = @_;
 321
 322   $self->{report} = SL::DB::Manager::CsvImportReport->find_by(id => $::form->{id});
 323
 324   $self->render('csv_import/report');
 325 }
 326
 327 sub csv_file_name {
 328   my ($self) = @_;
 329   return "csv-import-" . $self->type . ".csv";
 330 }
 331
 332 sub init_worker {
 333   my $self = shift;
 334
 335   my @args = (controller => $self);
 336
 337   if ( $self->file() ) {
 338     push(@args, file => $self->file());
 339   }
 340
 341   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 342        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 343        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 344        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 345        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 346        :                                        die "Program logic error";
 347 }
 348
 349 sub setup_help {
 350   my ($self) = @_;
 351
 352   $self->worker->setup_displayable_columns;
 353 }
 354
 355
 356 1;