SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::DB::CsvImportReport;
   8 use SL::DB::Unit;
   9 use SL::DB::Helper::Paginated ();
  10 use SL::Helper::Flash;
  11 use SL::Locale::String;
  12 use SL::SessionFile;
  13 use SL::Controller::CsvImport::Contact;
  14 use SL::Controller::CsvImport::CustomerVendor;
  15 use SL::Controller::CsvImport::Part;
  16 use SL::Controller::CsvImport::Shipto;
  17 use SL::Controller::CsvImport::Project;
  18 use SL::BackgroundJob::CsvImport;
  19 use SL::System::TaskServer;
  20
  21 use List::MoreUtils qw(none);
  22 use List::Util qw(min);
  23
  24 use parent qw(SL::Controller::Base);
  25
  26 use Rose::Object::MakeMethods::Generic
  27 (
  28  scalar                  => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  29                                  import_status errors headers raw_data_headers info_headers data num_imported num_importable displayable_columns file) ],
  30  'scalar --get_set_init' => [ qw(worker task_server) ],
  31  'array'                 => [
  32    progress_tracker     => { },
  33    add_progress_tracker => {  interface => 'add', hash_key => 'progress_tracker' },
  34  ],
  35 );
  36
  37 __PACKAGE__->run_before('check_auth');
  38 __PACKAGE__->run_before('ensure_form_structure');
  39 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  40 __PACKAGE__->run_before('load_all_profiles');
  41 __PACKAGE__->run_before('check_task_server');
  42
  43 __PACKAGE__->run_after('cleanup_reports');
  44
  45 #
  46 # actions
  47 #
  48
  49 sub action_new {
  50   my ($self) = @_;
  51
  52   $self->load_default_profile unless $self->profile;
  53   $self->render_inputs;
  54 }
  55
  56 sub action_test {
  57   my ($self) = @_;
  58   $self->test_and_import_deferred(test => 1);
  59 }
  60
  61 sub action_import {
  62   my $self = shift;
  63   $self->test_and_import_deferred(test => 0);
  64 }
  65
  66 sub action_save {
  67   my ($self) = @_;
  68
  69   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  70   $self->profile->save;
  71
  72   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  73   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  74 }
  75
  76 sub action_destroy {
  77   my $self = shift;
  78
  79   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  80   $profile->delete(cascade => 1);
  81
  82   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  83   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  84 }
  85
  86 sub action_result {
  87   my $self = shift;
  88
  89   # load resultobject
  90   $self->{background_job} = SL::DB::Manager::BackgroundJob->find_by(id => $::form->{job});
  91
  92   my $data = $self->{background_job}->data_as_hash;
  93
  94   my $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $data->{profile_id});
  95
  96   $self->profile($profile);
  97
  98   if ($data->{errors} and my $first_error =  $data->{errors}->[0]) {
  99     flash('error', $::locale->text('There was an error parsing the csv file: #1 in line #2.', $first_error->[2], $first_error->[0]));
 100   }
 101
 102   if ($data->{progress}{finished} || $data->{errors}) {
 103     $self->render('csv_import/_deferred_report', { layout => 0 });
 104   } else {
 105     if (!$self->task_server->is_running) {
 106       $self->task_server->start;
 107       $self->{status_text} = t8('Task Server is not running, starting it now. If this does not change, please check your task server config');
 108     } elsif (my $phase = $data->{progress}{phase}) {
 109       $self->{status_text} = "$data->{progress}{plan}{$phase} / $data->{progress}{num_phases} " . t8($phase);
 110     } else {
 111       $self->{status_text} = t8('Import not started yet, please wait...');
 112     }
 113
 114     $self->render('csv_import/_deferred_results', { layout => 0 });
 115   }
 116 }
 117
 118 sub action_download_sample {
 119   my $self = shift;
 120
 121   $self->profile_from_form;
 122   $self->setup_help;
 123
 124   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
 125   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
 126   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
 127
 128   $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
 129   $file->fh->print("\r\n");
 130   $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
 131   $file->fh->print("\r\n");
 132
 133   $file->fh->close;
 134
 135   $self->send_file($file->file_name, name => $file_name);
 136 }
 137
 138 sub action_report {
 139   my ($self, %params) = @_;
 140
 141   my $report_id = $params{report_id} || $::form->{id};
 142
 143   $self->{report}      = SL::DB::Manager::CsvImportReport->find_by(id => $report_id);
 144
 145   if (!$self->{report}) {
 146     $::form->error(t8('No report with id #1', $report_id));
 147   }
 148   my $num_rows         = $self->{report}->numrows;
 149   my $num_cols         = SL::DB::Manager::CsvImportReportRow->get_all_count(query => [ csv_import_report_id => $report_id, row => 0 ]);
 150
 151   # manual paginating, yuck
 152   my $page = $::form->{page} || 1;
 153   my $pages = {};
 154   $pages->{per_page}        = $::form->{per_page} || 20;
 155   $pages->{max}             = SL::DB::Helper::Paginated::ceil($num_rows, $pages->{per_page}) || 1;
 156   $pages->{cur}             = $page < 1 ? 1
 157                             : $page > $pages->{max} ? $pages->{max}
 158                             : $page;
 159   $pages->{common}          = [ grep { $_->{visible} } @{ SL::DB::Helper::Paginated::make_common_pages($pages->{cur}, $pages->{max}) } ];
 160
 161   $self->{display_rows} = [
 162     0,
 163     $pages->{per_page} * ($pages->{cur}-1) + 1
 164       ..
 165     min($pages->{per_page} * $pages->{cur}, $num_rows)
 166   ];
 167
 168   my @query = (
 169     csv_import_report_id => $report_id,
 170     or => [
 171       row => 0,
 172       and => [
 173         row => { gt => $pages->{per_page} * ($pages->{cur}-1) },
 174         row => { le => $pages->{per_page} * $pages->{cur} },
 175       ]
 176     ]
 177   );
 178
 179   my $rows             = SL::DB::Manager::CsvImportReportRow->get_all(query => \@query);
 180   my $status           = SL::DB::Manager::CsvImportReportStatus->get_all(query => \@query);
 181
 182   $self->{report_rows}   = $self->{report}->folded_rows(rows => $rows);
 183   $self->{report_status} = $self->{report}->folded_status(status => $status);
 184   $self->{pages} = $pages;
 185   $self->{base_url} = $self->url_for(action => 'report', id => $report_id, no_layout => $params{no_layout} || $::form->{no_layout} );
 186
 187   $self->render('csv_import/report', { layout => !($params{no_layout} || $::form->{no_layout}) });
 188 }
 189
 190
 191 #
 192 # filters
 193 #
 194
 195 sub check_auth {
 196   $::auth->assert('config');
 197 }
 198
 199 sub check_type {
 200   my ($self) = @_;
 201
 202   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts customers_vendors addresses contacts projects);
 203   $self->type($::form->{profile}->{type});
 204 }
 205
 206 sub ensure_form_structure {
 207   my ($self, %params) = @_;
 208
 209   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 210   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 211 }
 212
 213 #
 214 # helpers
 215 #
 216
 217 sub render_inputs {
 218   my ($self, %params) = @_;
 219
 220   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 221                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 222                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 223                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 224                         [ 'CP1252',      'CP1252 (Windows)'      ],
 225                       ]);
 226
 227   my %char_map = $self->char_map;
 228
 229   foreach my $type (qw(sep quote escape)) {
 230     my $sub = "all_${type}_chars";
 231     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 232
 233     my $char = $self->profile->get($type . '_char');
 234     $sub     = "${type}_char";
 235     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 236   }
 237
 238   $self->file(SL::SessionFile->new($self->csv_file_name));
 239
 240   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 241             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 242             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 243             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 244             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 245             : die;
 246
 247   if ($self->{type} eq 'parts') {
 248     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 249     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 250   }
 251
 252   $self->setup_help;
 253
 254   $self->render('csv_import/form', title => $title);
 255 }
 256
 257 sub test_and_import_deferred {
 258   my ($self, %params) = @_;
 259
 260   $self->profile_from_form;
 261
 262   if ($::form->{file}) {
 263     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 264     $file->fh->print($::form->{file});
 265     $file->fh->close;
 266   }
 267
 268   my $file = SL::SessionFile->new($self->csv_file_name, mode => '<', encoding => $self->profile->get('charset'));
 269   if (!$file->fh) {
 270     flash('error', $::locale->text('No file has been uploaded yet.'));
 271     return $self->action_new;
 272   }
 273
 274   $self->{background_job} = SL::BackgroundJob::CsvImport->create_job(
 275     file        => $self->csv_file_name,
 276     profile     => $self->profile,
 277     type        => $self->profile->type,
 278     test        => $params{test},
 279     employee_id => SL::DB::Manager::Employee->current->id,
 280   )->save;
 281
 282   if ($self->task_server->is_running) {
 283     $self->task_server->wake_up;
 284   } else {
 285     $self->task_server->start;
 286   }
 287
 288   flash('info', $::locale->text('Your import is beig processed.'));
 289
 290   $self->{deferred} = 1;
 291
 292   $self->render_inputs;
 293 }
 294
 295 sub test_and_import {
 296   my ($self, %params) = @_;
 297
 298   my $file = SL::SessionFile->new(
 299     $self->csv_file_name,
 300     mode       => '<',
 301     encoding   => $self->profile->get('charset'),
 302     session_id => $params{session_id}
 303   );
 304
 305   $self->file($file);
 306
 307   my $worker = $self->worker();
 308
 309   $worker->run(%params);
 310
 311   return if $self->errors;
 312
 313   $self->num_imported(0);
 314   $worker->save_objects if !$params{test};
 315
 316   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 317   $self->import_status($params{test} ? 'tested' : 'imported');
 318
 319 #  flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 320 }
 321
 322 sub load_default_profile {
 323   my ($self) = @_;
 324
 325   my $profile;
 326   if ($::form->{profile}->{id}) {
 327     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id}, login => $::myconfig{login});
 328   }
 329   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 330   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 331
 332   $self->profile($profile);
 333   $self->profile->set_defaults;
 334 }
 335
 336 sub load_all_profiles {
 337   my ($self, %params) = @_;
 338
 339   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 340     where => [
 341       type  => $self->type,
 342       login => $::myconfig{login},
 343     ],
 344   sort_by => 'name'));
 345 }
 346
 347 sub profile_from_form {
 348   my ($self, $existing_profile) = @_;
 349
 350   delete $::form->{profile}->{id};
 351
 352   my %char_map = $self->char_map;
 353   my @settings;
 354
 355   foreach my $type (qw(sep quote escape)) {
 356     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 357     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 358
 359     push @settings, { key => "${type}_char", value => $char };
 360   }
 361
 362   if ($self->type eq 'parts') {
 363     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 364   }
 365
 366   delete $::form->{profile}->{id};
 367   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 368   $self->profile->assign_attributes(%{ $::form->{profile} });
 369   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 370                            @settings);
 371   $self->profile->set_defaults;
 372 }
 373
 374 sub char_map {
 375   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 376                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 377                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 378                        ' '  => [ 'space',     $::locale->text('Space')     ],
 379                      },
 380            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 381                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 382                      },
 383            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 384                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 385                      },
 386          );
 387 }
 388
 389 sub save_report {
 390   my ($self, $report_id) = @_;
 391
 392   $self->track_progress(phase => 'building report', progress => 0);
 393
 394   my $clone_profile = $self->profile->clone_and_reset_deep;
 395   $clone_profile->save; # weird bug. if this isn't saved before adding it to the report, it will default back to the last profile.
 396
 397   my $report = SL::DB::CsvImportReport->new(
 398     session_id => $::auth->create_or_refresh_session,
 399     profile    => $clone_profile,
 400     type       => $self->type,
 401     file       => '',
 402     numrows    => scalar @{ $self->data },
 403   );
 404
 405   $report->save(cascade => 1) or die $report->db->error;
 406
 407   my $dbh = $::form->get_standard_dbh;
 408   $dbh->begin_work;
 409
 410   my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 411   my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 412
 413   my $sth = $dbh->prepare($query);
 414   my $sth2 = $dbh->prepare($query2);
 415
 416   # save headers
 417   my (@headers, @info_methods, @raw_methods, @methods);
 418
 419   for my $i (0 .. $#{ $self->info_headers->{headers} }) {
 420     next unless         $self->info_headers->{used}->{ $self->info_headers->{methods}->[$i] };
 421     push @headers,      $self->info_headers->{headers}->[$i];
 422     push @info_methods, $self->info_headers->{methods}->[$i];
 423   }
 424   for my $i (0 .. $#{ $self->headers->{headers} }) {
 425     next unless         $self->headers->{used}->{ $self->headers->{headers}->[$i] };
 426     push @headers,      $self->headers->{headers}->[$i];
 427     push @methods,      $self->headers->{methods}->[$i];
 428   }
 429   for my $i (0 .. $#{ $self->raw_data_headers->{headers} }) {
 430     next unless         $self->raw_data_headers->{used}->{ $self->raw_data_headers->{headers}->[$i] };
 431     push @headers,      $self->raw_data_headers->{headers}->[$i];
 432     push @raw_methods,  $self->raw_data_headers->{headers}->[$i];
 433   }
 434
 435   $sth->execute($report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 436
 437   # col offsets
 438   my $o1 =       @info_methods;
 439   my $o2 = $o1 + @methods;
 440
 441   for my $row (0 .. $#{ $self->data }) {
 442     $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 1000 == 0;
 443     my $data_row = $self->{data}[$row];
 444
 445     $sth->execute($report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 446     $sth->execute($report->id, $o1 + $_, $row + 1, $data_row->{object}->${ \ $methods[$_] })    for 0 .. $#methods;
 447     $sth->execute($report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 448
 449     $sth2->execute($report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 450     $sth2->execute($report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 451   }
 452
 453   $dbh->commit;
 454
 455   return $report->id;
 456 }
 457
 458 sub csv_file_name {
 459   my ($self) = @_;
 460   return "csv-import-" . $self->type . ".csv";
 461 }
 462
 463 sub init_worker {
 464   my $self = shift;
 465
 466   my @args = (controller => $self);
 467
 468   if ( $self->file() ) {
 469     push(@args, file => $self->file());
 470   }
 471
 472   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 473        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 474        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 475        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 476        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 477        :                                        die "Program logic error";
 478 }
 479
 480 sub setup_help {
 481   my ($self) = @_;
 482
 483   $self->worker->setup_displayable_columns;
 484 }
 485
 486 sub track_progress {
 487   my ($self, %params) = @_;
 488
 489   for my $tracker ($self->progress_tracker) {
 490     $tracker->track_progress(%params);
 491   }
 492 }
 493
 494 sub init_task_server {
 495   SL::System::TaskServer->new;
 496 }
 497
 498 sub cleanup_reports {
 499   SL::DB::Manager::CsvImportReport->cleanup;
 500 }
 501
 502 sub check_task_server {
 503   return 1 if $_[0]->task_server->is_running;
 504
 505   flash('info', t8('The task server is not running at the moment but needed for this module'));
 506
 507   1;
 508 }
 509
 510 1;