SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::DB::CsvImportReport;
   8 use SL::DB::Unit;
   9 use SL::DB::Helper::Paginated ();
  10 use SL::Helper::Flash;
  11 use SL::SessionFile;
  12 use SL::Controller::CsvImport::Contact;
  13 use SL::Controller::CsvImport::CustomerVendor;
  14 use SL::Controller::CsvImport::Part;
  15 use SL::Controller::CsvImport::Shipto;
  16 use SL::Controller::CsvImport::Project;
  17 use SL::BackgroundJob::CsvImport;
  18 use SL::System::TaskServer;
  19
  20 use List::MoreUtils qw(none);
  21 use List::Util qw(min);
  22
  23 use parent qw(SL::Controller::Base);
  24
  25 use Rose::Object::MakeMethods::Generic
  26 (
  27  scalar                  => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  28                                  import_status errors headers raw_data_headers info_headers data num_imported num_importable displayable_columns file) ],
  29  'scalar --get_set_init' => [ qw(worker) ],
  30  'array'                 => [
  31    progress_tracker     => { },
  32    add_progress_tracker => {  interface => 'add', hash_key => 'progress_tracker' },
  33  ],
  34 );
  35
  36 __PACKAGE__->run_before('check_auth');
  37 __PACKAGE__->run_before('ensure_form_structure');
  38 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  39 __PACKAGE__->run_before('load_all_profiles');
  40
  41 #
  42 # actions
  43 #
  44
  45 sub action_new {
  46   my ($self) = @_;
  47
  48   $self->load_default_profile unless $self->profile;
  49   $self->render_inputs;
  50 }
  51
  52 sub action_test {
  53   my ($self) = @_;
  54   $self->test_and_import_deferred(test => 1);
  55 }
  56
  57 sub action_import {
  58   my $self = shift;
  59   $self->test_and_import_deferred(test => 0);
  60 }
  61
  62 sub action_save {
  63   my ($self) = @_;
  64
  65   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  66   $self->profile->save;
  67
  68   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  69   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  70 }
  71
  72 sub action_destroy {
  73   my $self = shift;
  74
  75   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  76   $profile->delete(cascade => 1);
  77
  78   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  79   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  80 }
  81
  82 sub action_result {
  83   my $self = shift;
  84
  85   # load resultobject
  86   $self->{background_job} = SL::DB::Manager::BackgroundJob->find_by(id => $::form->{job});
  87
  88   my $data = $self->{background_job}->data_as_hash;
  89
  90   my $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $data->{profile_id});
  91
  92   $self->profile($profile);
  93
  94   if ($data->{errors} and my $first_error =  $data->{errors}->[0]) {
  95     flash('error', $::locale->text('There was an error parsing the csv file: #1 in line #2.', $first_error->[2], $first_error->[0]));
  96   }
  97
  98   if ($data->{progress}{finished} || $data->{errors}) {
  99     $self->render('csv_import/_deferred_report', { no_layout => 1 });
 100   } else {
 101     $self->render('csv_import/_deferred_results', { no_layout => 1 });
 102   }
 103 }
 104
 105 sub action_download_sample {
 106   my $self = shift;
 107
 108   $self->profile_from_form;
 109   $self->setup_help;
 110
 111   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
 112   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
 113   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
 114
 115   $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
 116   $file->fh->print("\r\n");
 117   $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
 118   $file->fh->print("\r\n");
 119
 120   $file->fh->close;
 121
 122   $self->send_file($file->file_name, name => $file_name);
 123 }
 124
 125 sub action_report {
 126   my ($self, %params) = @_;
 127
 128   my $report_id = $params{report_id} || $::form->{id};
 129
 130   $self->{report}      = SL::DB::Manager::CsvImportReport->find_by(id => $report_id);
 131   my $num_rows         = SL::DB::Manager::CsvImportReportRow->get_all_count(query => [ csv_import_report_id => $report_id ]);
 132   my $num_cols         = SL::DB::Manager::CsvImportReportRow->get_all_count(query => [ csv_import_report_id => $report_id, row => 0 ]);
 133
 134   # manual paginating, yuck
 135   my $page = $::form->{page} || 1;
 136   my $pages = {};
 137   $pages->{per_page}        = $::form->{per_page} || 20;
 138   $pages->{max}             = SL::DB::Helper::Paginated::ceil($num_rows / ($num_cols || 1), $pages->{per_page}) || 1;
 139   $pages->{cur}             = $page < 1 ? 1
 140                             : $page > $pages->{max} ? $pages->{max}
 141                             : $page;
 142   $pages->{common}          = SL::DB::Helper::Paginated::make_common_pages($pages->{cur}, $pages->{max});
 143
 144   $self->{display_rows} = [
 145     0,
 146     $pages->{per_page} * ($pages->{cur}-1) + 1
 147       ..
 148     min($pages->{per_page} * $pages->{cur}, $num_rows / ($num_cols || 1) - 1)
 149   ];
 150
 151   my @query = (
 152     csv_import_report_id => $report_id,
 153     or => [
 154       row => 0,
 155       and => [
 156         row => { gt => $pages->{per_page} * ($pages->{cur}-1) },
 157         row => { le => $pages->{per_page} * $pages->{cur} },
 158       ]
 159     ]
 160   );
 161
 162   my $rows             = SL::DB::Manager::CsvImportReportRow->get_all(query => \@query);
 163   my $status           = SL::DB::Manager::CsvImportReportStatus->get_all(query => \@query);
 164
 165   $self->{report_rows}   = $self->{report}->folded_rows(rows => $rows);
 166   $self->{report_status} = $self->{report}->folded_status(status => $status);
 167   $self->{pages} = $pages;
 168   $self->{base_url} = $self->url_for(action => 'report', id => $report_id, no_layout => $params{no_layout} || $::form->{no_layout} );
 169
 170   $self->render('csv_import/report', { no_layout => $params{no_layout} || $::form->{no_layout} });
 171 }
 172
 173
 174 #
 175 # filters
 176 #
 177
 178 sub check_auth {
 179   $::auth->assert('config');
 180 }
 181
 182 sub check_type {
 183   my ($self) = @_;
 184
 185   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts customers_vendors addresses contacts projects);
 186   $self->type($::form->{profile}->{type});
 187 }
 188
 189 sub ensure_form_structure {
 190   my ($self, %params) = @_;
 191
 192   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 193   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 194 }
 195
 196 #
 197 # helpers
 198 #
 199
 200 sub render_inputs {
 201   my ($self, %params) = @_;
 202
 203   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 204                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 205                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 206                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 207                         [ 'CP1252',      'CP1252 (Windows)'      ],
 208                       ]);
 209
 210   my %char_map = $self->char_map;
 211
 212   foreach my $type (qw(sep quote escape)) {
 213     my $sub = "all_${type}_chars";
 214     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 215
 216     my $char = $self->profile->get($type . '_char');
 217     $sub     = "${type}_char";
 218     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 219   }
 220
 221   $self->file(SL::SessionFile->new($self->csv_file_name));
 222
 223   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 224             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 225             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 226             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 227             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 228             : die;
 229
 230   if ($self->{type} eq 'parts') {
 231     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 232     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 233   }
 234
 235   $self->setup_help;
 236
 237   $self->render('csv_import/form', title => $title);
 238 }
 239
 240 sub test_and_import_deferred {
 241   my ($self, %params) = @_;
 242
 243   $self->profile_from_form;
 244
 245   if ($::form->{file}) {
 246     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 247     $file->fh->print($::form->{file});
 248     $file->fh->close;
 249   }
 250
 251   $self->{background_job} = SL::BackgroundJob::CsvImport->create_job(
 252     file    => $self->csv_file_name,
 253     profile => $self->profile,
 254     type    => $self->profile->type,
 255     test    => $params{test},
 256   )->save;
 257
 258   SL::System::TaskServer->start_if_not_running;
 259   SL::System::TaskServer->wake_up;
 260
 261   flash('info', $::locale->text('Your import is beig processed.'));
 262
 263   $self->{deferred} = 1;
 264
 265   $self->render_inputs;
 266 }
 267
 268 sub test_and_import {
 269   my ($self, %params) = @_;
 270
 271   my $file = SL::SessionFile->new(
 272     $self->csv_file_name,
 273     mode       => '<',
 274     encoding   => $self->profile->get('charset'),
 275     session_id => $params{session_id}
 276   );
 277
 278   $self->file($file);
 279
 280   my $worker = $self->worker();
 281
 282   $worker->run;
 283
 284   return if $self->errors;
 285
 286   $self->num_imported(0);
 287   $worker->save_objects if !$params{test};
 288
 289   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 290   $self->import_status($params{test} ? 'tested' : 'imported');
 291
 292 #  flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 293 }
 294
 295 sub load_default_profile {
 296   my ($self) = @_;
 297
 298   my $profile;
 299   if ($::form->{profile}->{id}) {
 300     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id}, login => $::myconfig{login});
 301   }
 302   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 303   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 304
 305   $self->profile($profile);
 306   $self->profile->set_defaults;
 307 }
 308
 309 sub load_all_profiles {
 310   my ($self, %params) = @_;
 311
 312   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 313     where => [
 314       type  => $self->type,
 315       login => $::myconfig{login},
 316     ],
 317   sort_by => 'name'));
 318 }
 319
 320 sub profile_from_form {
 321   my ($self, $existing_profile) = @_;
 322
 323   delete $::form->{profile}->{id};
 324
 325   my %char_map = $self->char_map;
 326   my @settings;
 327
 328   foreach my $type (qw(sep quote escape)) {
 329     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 330     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 331
 332     push @settings, { key => "${type}_char", value => $char };
 333   }
 334
 335   if ($self->type eq 'parts') {
 336     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 337   }
 338
 339   delete $::form->{profile}->{id};
 340   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 341   $self->profile->assign_attributes(%{ $::form->{profile} });
 342   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 343                            @settings);
 344   $self->profile->set_defaults;
 345 }
 346
 347 sub char_map {
 348   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 349                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 350                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 351                        ' '  => [ 'space',     $::locale->text('Space')     ],
 352                      },
 353            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 354                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 355                      },
 356            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 357                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 358                      },
 359          );
 360 }
 361
 362 sub save_report {
 363   my ($self, $report_id) = @_;
 364
 365   $self->track_progress(phase => 'building report', progress => 0);
 366
 367   my $clone_profile = $self->profile->clone_and_reset_deep;
 368   $clone_profile->save; # weird bug. if this isn't saved before adding it to the report, it will default back to the last profile.
 369
 370   my $report = SL::DB::CsvImportReport->new(
 371     session_id => $::auth->create_or_refresh_session,
 372     profile    => $clone_profile,
 373     type       => $self->type,
 374     file       => '',
 375   )->save(cascade => 1);
 376
 377   my $dbh = $::form->get_standard_dbh;
 378   $dbh->begin_work;
 379
 380   my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 381   my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 382
 383   my $sth = $dbh->prepare($query);
 384   my $sth2 = $dbh->prepare($query2);
 385
 386   # save headers
 387   my (@headers, @info_methods, @raw_methods, @methods);
 388
 389   for my $i (0 .. $#{ $self->info_headers->{headers} }) {
 390     next unless         $self->info_headers->{used}->{ $self->info_headers->{headers}->[$i] };
 391     push @headers,      $self->info_headers->{headers}->[$i];
 392     push @info_methods, $self->info_headers->{methods}->[$i];
 393   }
 394   for my $i (0 .. $#{ $self->headers->{headers} }) {
 395     next unless         $self->headers->{used}->{ $self->headers->{headers}->[$i] };
 396     push @headers,      $self->headers->{headers}->[$i];
 397     push @methods,      $self->headers->{methods}->[$i];
 398   }
 399   for my $i (0 .. $#{ $self->raw_data_headers->{headers} }) {
 400     next unless         $self->raw_data_headers->{used}->{ $self->raw_data_headers->{headers}->[$i] };
 401     push @headers,      $self->raw_data_headers->{headers}->[$i];
 402     push @raw_methods,  $self->raw_data_headers->{headers}->[$i];
 403   }
 404
 405   $sth->execute($report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 406
 407   # col offsets
 408   my $o1 =       @info_methods;
 409   my $o2 = $o1 + @methods;
 410
 411   for my $row (0 .. $#{ $self->data }) {
 412     $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 100 == 0;
 413     my $data_row = $self->{data}[$row];
 414
 415     $sth->execute($report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 416     $sth->execute($report->id, $o1 + $_, $row + 1, $data_row->{object}->${ \ $methods[$_] })    for 0 .. $#methods;
 417     $sth->execute($report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 418
 419     $sth2->execute($report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 420     $sth2->execute($report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 421   }
 422
 423   $dbh->commit;
 424
 425   return $report->id;
 426 }
 427
 428 sub csv_file_name {
 429   my ($self) = @_;
 430   return "csv-import-" . $self->type . ".csv";
 431 }
 432
 433 sub init_worker {
 434   my $self = shift;
 435
 436   my @args = (controller => $self);
 437
 438   if ( $self->file() ) {
 439     push(@args, file => $self->file());
 440   }
 441
 442   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 443        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 444        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 445        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 446        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 447        :                                        die "Program logic error";
 448 }
 449
 450 sub setup_help {
 451   my ($self) = @_;
 452
 453   $self->worker->setup_displayable_columns;
 454 }
 455
 456 sub track_progress {
 457   my ($self, %params) = @_;
 458
 459   for my $tracker ($self->progress_tracker) {
 460     $tracker->track_progress(%params);
 461   }
 462 }
 463
 464
 465 1;