SL/Controller/DeliveryOrder.pm

   1 package SL::Controller::DeliveryOrder;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Helper::Number qw(_format_number_units);
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Locale::String qw(t8);
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Webdav;
  13 use SL::File;
  14 use SL::MIME;
  15 use SL::Util qw(trim);
  16 use SL::YAML;
  17 use SL::DB::History;
  18 use SL::DB::Order;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Part;
  22 use SL::DB::PartClassification;
  23 use SL::DB::PartsGroup;
  24 use SL::DB::Printer;
  25 use SL::DB::Language;
  26 use SL::DB::RecordLink;
  27 use SL::DB::Shipto;
  28 use SL::DB::Translation;
  29
  30 use SL::Helper::CreatePDF qw(:all);
  31 use SL::Helper::PrintOptions;
  32 use SL::Helper::ShippedQty;
  33 use SL::Helper::UserPreferences::PositionsScrollbar;
  34 use SL::Helper::UserPreferences::UpdatePositions;
  35
  36 use SL::Controller::Helper::GetModels;
  37 use SL::Controller::DeliveryOrder::TypeData;
  38
  39 use List::Util qw(first sum0);
  40 use List::UtilsBy qw(sort_by uniq_by);
  41 use List::MoreUtils qw(any none pairwise first_index);
  42 use English qw(-no_match_vars);
  43 use File::Spec;
  44 use Cwd;
  45 use Sort::Naturally;
  46
  47 use Rose::Object::MakeMethods::Generic
  48 (
  49  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  50  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids type_data) ],
  51 );
  52
  53
  54 # safety
  55 __PACKAGE__->run_before('check_auth');
  56
  57 __PACKAGE__->run_before('get_unalterable_data',
  58                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  59                                      print send_email) ]);
  60
  61 #
  62 # actions
  63 #
  64
  65 # add a new order
  66 sub action_add {
  67   my ($self) = @_;
  68
  69   $self->order->transdate(DateTime->now_local());
  70   $self->type_data->set_reqdate_by_type;
  71
  72
  73   $self->pre_render();
  74   $self->render(
  75     'delivery_order/form',
  76     title => $self->get_title_for('add'),
  77     %{$self->{template_args}}
  78   );
  79 }
  80
  81 sub action_add_from_order {
  82   my ($self) = @_;
  83   # this interfers with init_order
  84   $self->{converted_from_oe_id} = delete $::form->{id};
  85
  86   # TODO copy data and remember to link them on save
  87
  88   $self->action_add;
  89 }
  90
  91 # edit an existing order
  92 sub action_edit {
  93   my ($self) = @_;
  94
  95   if ($::form->{id}) {
  96     $self->load_order;
  97
  98   } else {
  99     # this is to edit an order from an unsaved order object
 100
 101     # set item ids to new fake id, to identify them as new items
 102     foreach my $item (@{$self->order->items_sorted}) {
 103       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 104     }
 105     # trigger rendering values for second row as hidden, because they
 106     # are loaded only on demand. So we need to keep the values from
 107     # the source.
 108     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 109   }
 110
 111   $self->pre_render();
 112   $self->render(
 113     'delivery_order/form',
 114     title => $self->get_title_for('edit'),
 115     %{$self->{template_args}}
 116   );
 117 }
 118
 119 # edit a collective order (consisting of one or more existing orders)
 120 sub action_edit_collective {
 121   my ($self) = @_;
 122
 123   # collect order ids
 124   my @multi_ids = map {
 125     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 126   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 127
 128   # fall back to add if no ids are given
 129   if (scalar @multi_ids == 0) {
 130     $self->action_add();
 131     return;
 132   }
 133
 134   # fall back to save as new if only one id is given
 135   if (scalar @multi_ids == 1) {
 136     $self->order(SL::DB::DeliveryOrder->new(id => $multi_ids[0])->load);
 137     $self->action_save_as_new();
 138     return;
 139   }
 140
 141   # make new order from given orders
 142   my @multi_orders = map { SL::DB::DeliveryOrder->new(id => $_)->load } @multi_ids;
 143   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 144   $self->order(SL::DB::DeliveryOrder->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 145
 146   $self->action_edit();
 147 }
 148
 149 # delete the order
 150 sub action_delete {
 151   my ($self) = @_;
 152
 153   my $errors = $self->delete();
 154
 155   if (scalar @{ $errors }) {
 156     $self->js->flash('error', $_) foreach @{ $errors };
 157     return $self->js->render();
 158   }
 159
 160   flash_later('info', $self->type_data->text("delete"));
 161
 162   my @redirect_params = (
 163     action => 'add',
 164     type   => $self->type,
 165   );
 166
 167   $self->redirect_to(@redirect_params);
 168 }
 169
 170 # save the order
 171 sub action_save {
 172   my ($self) = @_;
 173
 174   my $errors = $self->save();
 175
 176   if (scalar @{ $errors }) {
 177     $self->js->flash('error', $_) foreach @{ $errors };
 178     return $self->js->render();
 179   }
 180
 181   flash_later('info', $self->type_data->text("saved"));
 182
 183   my @redirect_params = (
 184     action => 'edit',
 185     type   => $self->type,
 186     id     => $self->order->id,
 187   );
 188
 189   $self->redirect_to(@redirect_params);
 190 }
 191
 192 # save the order as new document an open it for edit
 193 sub action_save_as_new {
 194   my ($self) = @_;
 195
 196   my $order = $self->order;
 197
 198   if (!$order->id) {
 199     $self->js->flash('error', t8('This object has not been saved yet.'));
 200     return $self->js->render();
 201   }
 202
 203   # load order from db to check if values changed
 204   my $saved_order = SL::DB::DeliveryOrder->new(id => $order->id)->load;
 205
 206   my %new_attrs;
 207   # Lets assign a new number if the user hasn't changed the previous one.
 208   # If it has been changed manually then use it as-is.
 209   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 210                         ? ''
 211                         : trim($order->number);
 212
 213   # Clear transdate unless changed
 214   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 215                         ? DateTime->today_local
 216                         : $order->transdate;
 217
 218   # Set new reqdate unless changed if it is enabled in client config
 219   $new_attrs{reqdate} = $self->type_data->get_reqdate_by_type($order->reqdate, $saved_order->reqdate);
 220
 221   # Update employee
 222   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 223
 224   # Create new record from current one
 225   $self->order(SL::DB::DeliveryOrder->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 226
 227   # no linked records on save as new
 228   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 229
 230   # save
 231   $self->action_save();
 232 }
 233
 234 # print the order
 235 #
 236 # This is called if "print" is pressed in the print dialog.
 237 # If PDF creation was requested and succeeded, the pdf is offered for download
 238 # via send_file (which uses ajax in this case).
 239 sub action_print {
 240   my ($self) = @_;
 241
 242   my $errors = $self->save();
 243
 244   if (scalar @{ $errors }) {
 245     $self->js->flash('error', $_) foreach @{ $errors };
 246     return $self->js->render();
 247   }
 248
 249   $self->js_reset_order_and_item_ids_after_save;
 250
 251   my $format      = $::form->{print_options}->{format};
 252   my $media       = $::form->{print_options}->{media};
 253   my $formname    = $::form->{print_options}->{formname};
 254   my $copies      = $::form->{print_options}->{copies};
 255   my $groupitems  = $::form->{print_options}->{groupitems};
 256   my $printer_id  = $::form->{print_options}->{printer_id};
 257
 258   # only pdf and opendocument by now
 259   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 260     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 261   }
 262
 263   # only screen or printer by now
 264   if (none { $media eq $_ } qw(screen printer)) {
 265     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 266   }
 267
 268   # create a form for generate_attachment_filename
 269   my $form   = Form->new;
 270   $form->{$self->nr_key()}  = $self->order->number;
 271   $form->{type}             = $self->type;
 272   $form->{format}           = $format;
 273   $form->{formname}         = $formname;
 274   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 275   my $pdf_filename          = $form->generate_attachment_filename();
 276
 277   my $pdf;
 278   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 279                                                    formname   => $formname,
 280                                                    language   => $self->order->language,
 281                                                    printer_id => $printer_id,
 282                                                    groupitems => $groupitems });
 283   if (scalar @errors) {
 284     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 285   }
 286
 287   if ($media eq 'screen') {
 288     # screen/download
 289     $self->js->flash('info', t8('The PDF has been created'));
 290     $self->send_file(
 291       \$pdf,
 292       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 293       name         => $pdf_filename,
 294       js_no_render => 1,
 295     );
 296
 297   } elsif ($media eq 'printer') {
 298     # printer
 299     my $printer_id = $::form->{print_options}->{printer_id};
 300     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 301       copies  => $copies,
 302       content => $pdf,
 303     );
 304
 305     $self->js->flash('info', t8('The PDF has been printed'));
 306   }
 307
 308   my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $pdf_filename);
 309   if (scalar @warnings) {
 310     $self->js->flash('warning', $_) for @warnings;
 311   }
 312
 313   $self->save_history('PRINTED');
 314
 315   $self->js
 316     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 317     ->render;
 318 }
 319 sub action_preview_pdf {
 320   my ($self) = @_;
 321
 322   my $errors = $self->save();
 323   if (scalar @{ $errors }) {
 324     $self->js->flash('error', $_) foreach @{ $errors };
 325     return $self->js->render();
 326   }
 327
 328   $self->js_reset_order_and_item_ids_after_save;
 329
 330   my $format      = 'pdf';
 331   my $media       = 'screen';
 332   my $formname    = $self->type;
 333
 334   # only pdf
 335   # create a form for generate_attachment_filename
 336   my $form   = Form->new;
 337   $form->{$self->nr_key()}  = $self->order->number;
 338   $form->{type}             = $self->type;
 339   $form->{format}           = $format;
 340   $form->{formname}         = $formname;
 341   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 342   my $pdf_filename          = $form->generate_attachment_filename();
 343
 344   my $pdf;
 345   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 346                                                    formname   => $formname,
 347                                                    language   => $self->order->language,
 348                                                  });
 349   if (scalar @errors) {
 350     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 351   }
 352   $self->save_history('PREVIEWED');
 353   $self->js->flash('info', t8('The PDF has been previewed'));
 354   # screen/download
 355   $self->send_file(
 356     \$pdf,
 357     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 358     name         => $pdf_filename,
 359     js_no_render => 0,
 360   );
 361 }
 362
 363 # open the email dialog
 364 sub action_save_and_show_email_dialog {
 365   my ($self) = @_;
 366
 367   my $errors = $self->save();
 368
 369   if (scalar @{ $errors }) {
 370     $self->js->flash('error', $_) foreach @{ $errors };
 371     return $self->js->render();
 372   }
 373
 374   my $cv_method = $self->cv;
 375
 376   if (!$self->order->$cv_method) {
 377     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 378                     ->render($self);
 379   }
 380
 381   my $email_form;
 382   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 383   $email_form->{to} ||= $self->order->$cv_method->email;
 384   $email_form->{cc}   = $self->order->$cv_method->cc;
 385   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 386   # Todo: get addresses from shipto, if any
 387
 388   my $form = Form->new;
 389   $form->{$self->nr_key()}  = $self->order->number;
 390   $form->{cusordnumber}     = $self->order->cusordnumber;
 391   $form->{formname}         = $self->type;
 392   $form->{type}             = $self->type;
 393   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 394   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 395   $form->{format}           = 'pdf';
 396   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 397
 398   $email_form->{subject}             = $form->generate_email_subject();
 399   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 400   $email_form->{message}             = $form->generate_email_body();
 401   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 402
 403   my %files = $self->get_files_for_email_dialog();
 404   $self->{all_employees} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 405   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 406                                   email_form  => $email_form,
 407                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 408                                   FILES       => \%files,
 409                                   is_customer => $self->cv eq 'customer',
 410                                   ALL_EMPLOYEES => $self->{all_employees},
 411   );
 412
 413   $self->js
 414       ->run('kivi.Order.show_email_dialog', $dialog_html)
 415       ->reinit_widgets
 416       ->render($self);
 417 }
 418
 419 # send email
 420 #
 421 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 422 sub action_send_email {
 423   my ($self) = @_;
 424
 425   my $errors = $self->save();
 426
 427   if (scalar @{ $errors }) {
 428     $self->js->run('kivi.Order.close_email_dialog');
 429     $self->js->flash('error', $_) foreach @{ $errors };
 430     return $self->js->render();
 431   }
 432
 433   $self->js_reset_order_and_item_ids_after_save;
 434
 435   my $email_form  = delete $::form->{email_form};
 436   my %field_names = (to => 'email');
 437
 438   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 439
 440   # for Form::cleanup which may be called in Form::send_email
 441   $::form->{cwd}    = getcwd();
 442   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 443
 444   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 445   $::form->{media}  = 'email';
 446
 447   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 448     my $pdf;
 449     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 450                                                     format     => $::form->{print_options}->{format},
 451                                                     formname   => $::form->{print_options}->{formname},
 452                                                     language   => $self->order->language,
 453                                                     printer_id => $::form->{print_options}->{printer_id},
 454                                                     groupitems => $::form->{print_options}->{groupitems}});
 455     if (scalar @errors) {
 456       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 457     }
 458
 459     my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $::form->{attachment_filename});
 460     if (scalar @warnings) {
 461       flash_later('warning', $_) for @warnings;
 462     }
 463
 464     my $sfile = SL::SessionFile::Random->new(mode => "w");
 465     $sfile->fh->print($pdf);
 466     $sfile->fh->close;
 467
 468     $::form->{tmpfile} = $sfile->file_name;
 469     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 470   }
 471
 472   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 473   $::form->send_email(\%::myconfig, 'pdf');
 474
 475   # internal notes
 476   my $intnotes = $self->order->intnotes;
 477   $intnotes   .= "\n\n" if $self->order->intnotes;
 478   $intnotes   .= t8('[email]')                                                                                        . "\n";
 479   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 480   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 481   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 482   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 483   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 484   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 485
 486   $self->order->update_attributes(intnotes => $intnotes);
 487
 488   $self->save_history('MAILED');
 489
 490   flash_later('info', t8('The email has been sent.'));
 491
 492   my @redirect_params = (
 493     action => 'edit',
 494     type   => $self->type,
 495     id     => $self->order->id,
 496   );
 497
 498   $self->redirect_to(@redirect_params);
 499 }
 500
 501 # save the order and redirect to the frontend subroutine for a new
 502 # delivery order
 503 sub action_save_and_delivery_order {
 504   my ($self) = @_;
 505
 506   $self->save_and_redirect_to(
 507     controller => 'oe.pl',
 508     action     => 'oe_delivery_order_from_order',
 509   );
 510 }
 511
 512 # save the order and redirect to the frontend subroutine for a new
 513 # invoice
 514 sub action_save_and_invoice {
 515   my ($self) = @_;
 516
 517   $self->save_and_redirect_to(
 518     controller => 'oe.pl',
 519     action     => 'oe_invoice_from_order',
 520   );
 521 }
 522
 523 # workflow from sales order to sales quotation
 524 sub action_sales_quotation {
 525   $_[0]->workflow_sales_or_request_for_quotation();
 526 }
 527
 528 # workflow from sales order to sales quotation
 529 sub action_request_for_quotation {
 530   $_[0]->workflow_sales_or_request_for_quotation();
 531 }
 532
 533 # workflow from sales quotation to sales order
 534 sub action_sales_order {
 535   $_[0]->workflow_sales_or_purchase_order();
 536 }
 537
 538 # workflow from rfq to purchase order
 539 sub action_purchase_order {
 540   $_[0]->workflow_sales_or_purchase_order();
 541 }
 542
 543 # workflow from purchase order to ap transaction
 544 sub action_save_and_ap_transaction {
 545   my ($self) = @_;
 546
 547   $self->save_and_redirect_to(
 548     controller => 'ap.pl',
 549     action     => 'add_from_purchase_order',
 550   );
 551 }
 552
 553 # set form elements in respect to a changed customer or vendor
 554 #
 555 # This action is called on an change of the customer/vendor picker.
 556 sub action_customer_vendor_changed {
 557   my ($self) = @_;
 558
 559   setup_order_from_cv($self->order);
 560
 561   my $cv_method = $self->cv;
 562
 563   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 564     $self->js->show('#cp_row');
 565   } else {
 566     $self->js->hide('#cp_row');
 567   }
 568
 569   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 570     $self->js->show('#shipto_selection');
 571   } else {
 572     $self->js->hide('#shipto_selection');
 573   }
 574
 575   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 576
 577   $self->js
 578     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 579     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 580     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 581     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 582     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 583     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 584     ->val(        '#order_currency_id',      $self->order->currency_id)
 585     ->val(        '#order_payment_id',       $self->order->payment_id)
 586     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 587     ->val(        '#order_intnotes',         $self->order->intnotes)
 588     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 589     ->focus(      '#order_' . $self->cv . '_id')
 590     ->run('kivi.Order.update_exchangerate');
 591
 592   $self->js_redisplay_cvpartnumbers;
 593   $self->js->render();
 594 }
 595
 596 # open the dialog for customer/vendor details
 597 sub action_show_customer_vendor_details_dialog {
 598   my ($self) = @_;
 599
 600   my $is_customer = 'customer' eq $::form->{vc};
 601   my $cv;
 602   if ($is_customer) {
 603     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 604   } else {
 605     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 606   }
 607
 608   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 609   $details{discount_as_percent} = $cv->discount_as_percent;
 610   $details{creditlimt}          = $cv->creditlimit_as_number;
 611   $details{business}            = $cv->business->description      if $cv->business;
 612   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 613   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 614   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 615   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 616
 617   foreach my $entry (@{ $cv->shipto }) {
 618     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 619   }
 620   foreach my $entry (@{ $cv->contacts }) {
 621     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 622   }
 623
 624   $_[0]->render('common/show_vc_details', { layout => 0 },
 625                 is_customer => $is_customer,
 626                 %details);
 627
 628 }
 629
 630 # called if a unit in an existing item row is changed
 631 sub action_unit_changed {
 632   my ($self) = @_;
 633
 634   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 635   my $item = $self->order->items_sorted->[$idx];
 636
 637   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 638   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 639
 640   $self->js
 641     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 642   $self->js_redisplay_line_values;
 643   $self->js->render();
 644 }
 645
 646 # add an item row for a new item entered in the input row
 647 sub action_add_item {
 648   my ($self) = @_;
 649
 650   delete $::form->{add_item}->{create_part_type};
 651
 652   my $form_attr = $::form->{add_item};
 653
 654   return unless $form_attr->{parts_id};
 655
 656   my $item = new_item($self->order, $form_attr);
 657
 658   $self->order->add_items($item);
 659
 660   $self->get_item_cvpartnumber($item);
 661
 662   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 663   my $row_as_html = $self->p->render('delivery_order/tabs/_row',
 664                                      ITEM => $item,
 665                                      ID   => $item_id,
 666                                      SELF => $self,
 667   );
 668
 669   if ($::form->{insert_before_item_id}) {
 670     $self->js
 671       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 672   } else {
 673     $self->js
 674       ->append('#row_table_id', $row_as_html);
 675   }
 676
 677   if ( $item->part->is_assortment ) {
 678     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 679     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 680       my $attr = { parts_id => $assortment_item->parts_id,
 681                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 682                    unit     => $assortment_item->unit,
 683                    description => $assortment_item->part->description,
 684                  };
 685       my $item = new_item($self->order, $attr);
 686
 687       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 688       $item->discount(1) unless $assortment_item->charge;
 689
 690       $self->order->add_items( $item );
 691       $self->get_item_cvpartnumber($item);
 692       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 693       my $row_as_html = $self->p->render('delivery_order/tabs/_row',
 694                                          ITEM => $item,
 695                                          ID   => $item_id,
 696                                          SELF => $self,
 697       );
 698       if ($::form->{insert_before_item_id}) {
 699         $self->js
 700           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 701       } else {
 702         $self->js
 703           ->append('#row_table_id', $row_as_html);
 704       }
 705     };
 706   };
 707
 708   $self->js
 709     ->val('.add_item_input', '')
 710     ->run('kivi.Order.init_row_handlers')
 711     ->run('kivi.Order.renumber_positions')
 712     ->focus('#add_item_parts_id_name');
 713
 714   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 715
 716   $self->js->render();
 717 }
 718
 719 # add item rows for multiple items at once
 720 sub action_add_multi_items {
 721   my ($self) = @_;
 722
 723   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 724   return $self->js->render() unless scalar @form_attr;
 725
 726   my @items;
 727   foreach my $attr (@form_attr) {
 728     my $item = new_item($self->order, $attr);
 729     push @items, $item;
 730     if ( $item->part->is_assortment ) {
 731       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 732         my $attr = { parts_id => $assortment_item->parts_id,
 733                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 734                      unit     => $assortment_item->unit,
 735                      description => $assortment_item->part->description,
 736                    };
 737         my $item = new_item($self->order, $attr);
 738
 739         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 740         $item->discount(1) unless $assortment_item->charge;
 741         push @items, $item;
 742       }
 743     }
 744   }
 745   $self->order->add_items(@items);
 746
 747   foreach my $item (@items) {
 748     $self->get_item_cvpartnumber($item);
 749     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 750     my $row_as_html = $self->p->render('delivery_order/tabs/_row',
 751                                        ITEM => $item,
 752                                        ID   => $item_id,
 753                                        SELF => $self,
 754     );
 755
 756     if ($::form->{insert_before_item_id}) {
 757       $self->js
 758         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 759     } else {
 760       $self->js
 761         ->append('#row_table_id', $row_as_html);
 762     }
 763   }
 764
 765   $self->js
 766     ->run('kivi.Part.close_picker_dialogs')
 767     ->run('kivi.Order.init_row_handlers')
 768     ->run('kivi.Order.renumber_positions')
 769     ->focus('#add_item_parts_id_name');
 770
 771   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 772
 773   $self->js->render();
 774 }
 775
 776 sub action_update_exchangerate {
 777   my ($self) = @_;
 778
 779   my $data = {
 780     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 781     currency_name => $self->order->currency->name,
 782   };
 783
 784   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 785 }
 786
 787 # redisplay item rows if they are sorted by an attribute
 788 sub action_reorder_items {
 789   my ($self) = @_;
 790
 791   my %sort_keys = (
 792     partnumber   => sub { $_[0]->part->partnumber },
 793     description  => sub { $_[0]->description },
 794     qty          => sub { $_[0]->qty },
 795     sellprice    => sub { $_[0]->sellprice },
 796     discount     => sub { $_[0]->discount },
 797     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 798   );
 799
 800   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 801
 802   my $method = $sort_keys{$::form->{order_by}};
 803   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 804   if ($::form->{sort_dir}) {
 805     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 806       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 807     } else {
 808       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 809     }
 810   } else {
 811     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 812       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 813     } else {
 814       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 815     }
 816   }
 817   $self->js
 818     ->run('kivi.Order.redisplay_items', \@to_sort)
 819     ->render;
 820 }
 821
 822 # show the popup to choose a price/discount source
 823 sub action_price_popup {
 824   my ($self) = @_;
 825
 826   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 827   my $item = $self->order->items_sorted->[$idx];
 828
 829   $self->render_price_dialog($item);
 830 }
 831
 832 # save the order in a session variable and redirect to the part controller
 833 sub action_create_part {
 834   my ($self) = @_;
 835
 836   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
 837
 838   my $callback     = $self->url_for(
 839     action       => 'return_from_create_part',
 840     type         => $self->type, # type is needed for check_auth on return
 841     previousform => $previousform,
 842   );
 843
 844   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
 845
 846   my @redirect_params = (
 847     controller => 'Part',
 848     action     => 'add',
 849     part_type  => $::form->{add_item}->{create_part_type},
 850     callback   => $callback,
 851     show_abort => 1,
 852   );
 853
 854   $self->redirect_to(@redirect_params);
 855 }
 856
 857 sub action_return_from_create_part {
 858   my ($self) = @_;
 859
 860   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
 861
 862   $::auth->restore_form_from_session(delete $::form->{previousform});
 863
 864   # set item ids to new fake id, to identify them as new items
 865   foreach my $item (@{$self->order->items_sorted}) {
 866     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 867   }
 868
 869   $self->get_unalterable_data();
 870   $self->pre_render();
 871
 872   # trigger rendering values for second row/longdescription as hidden,
 873   # because they are loaded only on demand. So we need to keep the values
 874   # from the source.
 875   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
 876   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 877
 878   $self->render(
 879     'delivery_order/form',
 880     title => $self->get_title_for('edit'),
 881     %{$self->{template_args}}
 882   );
 883
 884 }
 885
 886 # load the second row for one or more items
 887 #
 888 # This action gets the html code for all items second rows by rendering a template for
 889 # the second row and sets the html code via client js.
 890 sub action_load_second_rows {
 891   my ($self) = @_;
 892
 893   foreach my $item_id (@{ $::form->{item_ids} }) {
 894     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 895     my $item = $self->order->items_sorted->[$idx];
 896
 897     $self->js_load_second_row($item, $item_id, 0);
 898   }
 899
 900   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 901
 902   $self->js->render();
 903 }
 904
 905 # update description, notes and sellprice from master data
 906 sub action_update_row_from_master_data {
 907   my ($self) = @_;
 908
 909   foreach my $item_id (@{ $::form->{item_ids} }) {
 910     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 911     my $item  = $self->order->items_sorted->[$idx];
 912     my $texts = get_part_texts($item->part, $self->order->language_id);
 913
 914     $item->description($texts->{description});
 915     $item->longdescription($texts->{longdescription});
 916
 917     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 918
 919     my $price_src;
 920     if ($item->part->is_assortment) {
 921     # add assortment items with price 0, as the components carry the price
 922       $price_src = $price_source->price_from_source("");
 923       $price_src->price(0);
 924     } else {
 925       $price_src = $price_source->best_price
 926                  ? $price_source->best_price
 927                  : $price_source->price_from_source("");
 928       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
 929       $price_src->price(0) if !$price_source->best_price;
 930     }
 931
 932
 933     $item->sellprice($price_src->price);
 934     $item->active_price_source($price_src);
 935
 936     $self->js
 937       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
 938       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
 939       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
 940       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
 941
 942     if ($self->search_cvpartnumber) {
 943       $self->get_item_cvpartnumber($item);
 944       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
 945     }
 946   }
 947
 948   $self->js_redisplay_line_values;
 949
 950   $self->js->render();
 951 }
 952
 953 sub js_load_second_row {
 954   my ($self, $item, $item_id, $do_parse) = @_;
 955
 956   if ($do_parse) {
 957     # Parse values from form (they are formated while rendering (template)).
 958     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 959     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
 960     foreach my $var (@{ $item->cvars_by_config }) {
 961       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 962     }
 963     $item->parse_custom_variable_values;
 964   }
 965
 966   my $row_as_html = $self->p->render('delivery_order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
 967
 968   $self->js
 969     ->html('#second_row_' . $item_id, $row_as_html)
 970     ->data('#second_row_' . $item_id, 'loaded', 1);
 971 }
 972
 973 sub js_redisplay_line_values {
 974   my ($self) = @_;
 975
 976   my $is_sales = $self->order->is_sales;
 977
 978   # sales orders with margins
 979   my @data;
 980   if ($is_sales) {
 981     @data = map {
 982       [
 983        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
 984        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
 985        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
 986       ]} @{ $self->order->items_sorted };
 987   } else {
 988     @data = map {
 989       [
 990        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
 991       ]} @{ $self->order->items_sorted };
 992   }
 993
 994   $self->js
 995     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
 996 }
 997
 998 sub js_redisplay_cvpartnumbers {
 999   my ($self) = @_;
1000
1001   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1002
1003   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1004
1005   $self->js
1006     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1007 }
1008
1009 sub js_reset_order_and_item_ids_after_save {
1010   my ($self) = @_;
1011
1012   $self->js
1013     ->val('#id', $self->order->id)
1014     ->val('#converted_from_oe_id', '')
1015     ->val('#order_' . $self->nr_key(), $self->order->number);
1016
1017   my $idx = 0;
1018   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1019     next if !$self->order->items_sorted->[$idx]->id;
1020     next if $form_item_id !~ m{^new};
1021     $self->js
1022       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1023       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1024       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1025   } continue {
1026     $idx++;
1027   }
1028   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1029 }
1030
1031 #
1032 # helpers
1033 #
1034
1035 sub init_type {
1036   my ($self) = @_;
1037
1038   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1039     die "Not a valid type for delivery order";
1040   }
1041
1042   $self->type($::form->{type});
1043 }
1044
1045 sub init_cv {
1046   my ($self) = @_;
1047
1048   return $self->type_data->customervendor;
1049 }
1050
1051 sub init_search_cvpartnumber {
1052   my ($self) = @_;
1053
1054   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1055   my $search_cvpartnumber;
1056   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1057   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1058
1059   return $search_cvpartnumber;
1060 }
1061
1062 sub init_show_update_button {
1063   my ($self) = @_;
1064
1065   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1066 }
1067
1068 sub init_p {
1069   SL::Presenter->get;
1070 }
1071
1072 sub init_order {
1073   $_[0]->make_order;
1074 }
1075
1076 sub init_all_price_factors {
1077   SL::DB::Manager::PriceFactor->get_all;
1078 }
1079
1080 sub init_part_picker_classification_ids {
1081   my ($self)    = @_;
1082
1083   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => $self->type_data->part_classification_query) } ];
1084 }
1085
1086 sub check_auth {
1087   my ($self) = @_;
1088
1089   $::auth->assert($self->type_data->access || 'DOES_NOT_EXIST');
1090 }
1091
1092 # build the selection box for contacts
1093 #
1094 # Needed, if customer/vendor changed.
1095 sub build_contact_select {
1096   my ($self) = @_;
1097
1098   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1099     value_key  => 'cp_id',
1100     title_key  => 'full_name_dep',
1101     default    => $self->order->cp_id,
1102     with_empty => 1,
1103     style      => 'width: 300px',
1104   );
1105 }
1106
1107 # build the selection box for shiptos
1108 #
1109 # Needed, if customer/vendor changed.
1110 sub build_shipto_select {
1111   my ($self) = @_;
1112
1113   select_tag('order.shipto_id',
1114              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1115              value_key  => 'shipto_id',
1116              title_key  => 'displayable_id',
1117              default    => $self->order->shipto_id,
1118              with_empty => 0,
1119              style      => 'width: 300px',
1120   );
1121 }
1122
1123 # build the inputs for the cusom shipto dialog
1124 #
1125 # Needed, if customer/vendor changed.
1126 sub build_shipto_inputs {
1127   my ($self) = @_;
1128
1129   my $content = $self->p->render('common/_ship_to_dialog',
1130                                  vc_obj      => $self->order->customervendor,
1131                                  cs_obj      => $self->order->custom_shipto,
1132                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1133                                  id_selector => '#order_shipto_id');
1134
1135   div_tag($content, id => 'shipto_inputs');
1136 }
1137
1138 # render the info line for business
1139 #
1140 # Needed, if customer/vendor changed.
1141 sub build_business_info_row
1142 {
1143   $_[0]->p->render('delivery_order/tabs/_business_info_row', SELF => $_[0]);
1144 }
1145
1146
1147 sub load_order {
1148   my ($self) = @_;
1149
1150   return if !$::form->{id};
1151
1152   $self->order(SL::DB::DeliveryOrder->new(id => $::form->{id})->load);
1153
1154   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1155   # You need a custom shipto object to call cvars_by_config to get the cvars.
1156   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1157
1158   return $self->order;
1159 }
1160
1161 # load or create a new order object
1162 #
1163 # And assign changes from the form to this object.
1164 # If the order is loaded from db, check if items are deleted in the form,
1165 # remove them form the object and collect them for removing from db on saving.
1166 # Then create/update items from form (via make_item) and add them.
1167 sub make_order {
1168   my ($self) = @_;
1169
1170   # add_items adds items to an order with no items for saving, but they cannot
1171   # be retrieved via items until the order is saved. Adding empty items to new
1172   # order here solves this problem.
1173   my $order;
1174   $order   = SL::DB::DeliveryOrder->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1175   $order ||= SL::DB::DeliveryOrder->new(orderitems  => [], currency_id => $::instance_conf->get_currency_id(), order_type => $self->type_data->validate($::form->{type}));
1176
1177   my $cv_id_method = $self->cv . '_id';
1178   if (!$::form->{id} && $::form->{$cv_id_method}) {
1179     $order->$cv_id_method($::form->{$cv_id_method});
1180     setup_order_from_cv($order);
1181   }
1182
1183   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1184
1185   $order->assign_attributes(%{$::form->{order}});
1186
1187   $self->setup_custom_shipto_from_form($order, $::form);
1188
1189   # remove deleted items
1190   $self->item_ids_to_delete([]);
1191   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1192     my $item = $order->orderitems->[$idx];
1193     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1194       splice @{$order->orderitems}, $idx, 1;
1195       push @{$self->item_ids_to_delete}, $item->id;
1196     }
1197   }
1198
1199   my @items;
1200   my $pos = 1;
1201   foreach my $form_attr (@{$form_orderitems}) {
1202     my $item = make_item($order, $form_attr);
1203     $item->position($pos);
1204     push @items, $item;
1205     $pos++;
1206   }
1207   $order->add_items(grep {!$_->id} @items);
1208
1209   return $order;
1210 }
1211
1212 # create or update items from form
1213 #
1214 # Make item objects from form values. For items already existing read from db.
1215 # Create a new item else. And assign attributes.
1216 sub make_item {
1217   my ($record, $attr) = @_;
1218
1219   my $item;
1220   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1221
1222   my $is_new = !$item;
1223
1224   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1225   # they cannot be retrieved via custom_variables until the order/orderitem is
1226   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1227   $item ||= SL::DB::DeliveryOrderItem->new(custom_variables => []);
1228
1229   $item->assign_attributes(%$attr);
1230
1231   if ($is_new) {
1232     my $texts = get_part_texts($item->part, $record->language_id);
1233     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1234     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1235     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1236   }
1237
1238   return $item;
1239 }
1240
1241 # create a new item
1242 #
1243 # This is used to add one item
1244 sub new_item {
1245   my ($record, $attr) = @_;
1246
1247   my $item = SL::DB::DeliveryOrderItem->new;
1248
1249   # Remove attributes where the user left or set the inputs empty.
1250   # So these attributes will be undefined and we can distinguish them
1251   # from zero later on.
1252   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1253     delete $attr->{$_} if $attr->{$_} eq '';
1254   }
1255
1256   $item->assign_attributes(%$attr);
1257
1258   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1259   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1260
1261   $item->unit($part->unit) if !$item->unit;
1262
1263   my $price_src;
1264   if ( $part->is_assortment ) {
1265     # add assortment items with price 0, as the components carry the price
1266     $price_src = $price_source->price_from_source("");
1267     $price_src->price(0);
1268   } elsif (defined $item->sellprice) {
1269     $price_src = $price_source->price_from_source("");
1270     $price_src->price($item->sellprice);
1271   } else {
1272     $price_src = $price_source->best_price
1273                ? $price_source->best_price
1274                : $price_source->price_from_source("");
1275     $price_src->price(0) if !$price_source->best_price;
1276   }
1277
1278   my $discount_src;
1279   if (defined $item->discount) {
1280     $discount_src = $price_source->discount_from_source("");
1281     $discount_src->discount($item->discount);
1282   } else {
1283     $discount_src = $price_source->best_discount
1284                   ? $price_source->best_discount
1285                   : $price_source->discount_from_source("");
1286     $discount_src->discount(0) if !$price_source->best_discount;
1287   }
1288
1289   my %new_attr;
1290   $new_attr{part}                   = $part;
1291   $new_attr{description}            = $part->description     if ! $item->description;
1292   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1293   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1294   $new_attr{sellprice}              = $price_src->price;
1295   $new_attr{discount}               = $discount_src->discount;
1296   $new_attr{active_price_source}    = $price_src;
1297   $new_attr{active_discount_source} = $discount_src;
1298   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1299   $new_attr{project_id}             = $record->globalproject_id;
1300   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1301
1302   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1303   # they cannot be retrieved via custom_variables until the order/orderitem is
1304   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1305   $new_attr{custom_variables} = [];
1306
1307   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1308
1309   $item->assign_attributes(%new_attr, %{ $texts });
1310
1311   return $item;
1312 }
1313
1314 sub setup_order_from_cv {
1315   my ($order) = @_;
1316
1317   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1318
1319   $order->intnotes($order->customervendor->notes);
1320
1321   if ($order->is_sales) {
1322     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1323     $order->taxincluded(defined($order->customer->taxincluded_checked)
1324                         ? $order->customer->taxincluded_checked
1325                         : $::myconfig{taxincluded_checked});
1326   }
1327
1328 }
1329
1330 # setup custom shipto from form
1331 #
1332 # The dialog returns form variables starting with 'shipto' and cvars starting
1333 # with 'shiptocvar_'.
1334 # Mark it to be deleted if a shipto from master data is selected
1335 # (i.e. order has a shipto).
1336 # Else, update or create a new custom shipto. If the fields are empty, it
1337 # will not be saved on save.
1338 sub setup_custom_shipto_from_form {
1339   my ($self, $order, $form) = @_;
1340
1341   if ($order->shipto) {
1342     $self->is_custom_shipto_to_delete(1);
1343   } else {
1344     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1345
1346     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1347     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1348
1349     $custom_shipto->assign_attributes(%$shipto_attrs);
1350     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1351   }
1352 }
1353
1354 # get data for saving, printing, ..., that is not changed in the form
1355 #
1356 # Only cvars for now.
1357 sub get_unalterable_data {
1358   my ($self) = @_;
1359
1360   foreach my $item (@{ $self->order->items }) {
1361     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1362     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1363     foreach my $var (@{ $item->cvars_by_config }) {
1364       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1365     }
1366     $item->parse_custom_variable_values;
1367   }
1368 }
1369
1370 # delete the order
1371 #
1372 # And remove related files in the spool directory
1373 sub delete {
1374   my ($self) = @_;
1375
1376   my $errors = [];
1377   my $db     = $self->order->db;
1378
1379   $db->with_transaction(
1380     sub {
1381       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1382       $self->order->delete;
1383       my $spool = $::lx_office_conf{paths}->{spool};
1384       unlink map { "$spool/$_" } @spoolfiles if $spool;
1385
1386       $self->save_history('DELETED');
1387
1388       1;
1389   }) || push(@{$errors}, $db->error);
1390
1391   return $errors;
1392 }
1393
1394 # save the order
1395 #
1396 # And delete items that are deleted in the form.
1397 sub save {
1398   my ($self) = @_;
1399
1400   my $errors = [];
1401   my $db     = $self->order->db;
1402
1403   $db->with_transaction(sub {
1404     # delete custom shipto if it is to be deleted or if it is empty
1405     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1406       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1407       $self->order->custom_shipto(undef);
1408     }
1409
1410     SL::DB::DeliveryOrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1411     $self->order->save(cascade => 1);
1412
1413     # link records
1414     if ($::form->{converted_from_oe_id}) {
1415       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1416       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1417         my $src = SL::DB::DeliveryOrder->new(id => $converted_from_oe_id)->load;
1418         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1419         $src->link_to_record($self->order);
1420       }
1421       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1422         my $idx = 0;
1423         foreach (@{ $self->order->items_sorted }) {
1424           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1425           next if !$from_id;
1426           SL::DB::RecordLink->new(from_table => 'orderitems',
1427                                   from_id    => $from_id,
1428                                   to_table   => 'orderitems',
1429                                   to_id      => $_->id
1430           )->save;
1431           $idx++;
1432         }
1433       }
1434     }
1435
1436     $self->save_history('SAVED');
1437
1438     1;
1439   }) || push(@{$errors}, $db->error);
1440
1441   return $errors;
1442 }
1443
1444 sub workflow_sales_or_request_for_quotation {
1445   my ($self) = @_;
1446
1447   # always save
1448   my $errors = $self->save();
1449
1450   if (scalar @{ $errors }) {
1451     $self->js->flash('error', $_) for @{ $errors };
1452     return $self->js->render();
1453   }
1454
1455   my $destination_type = $self->type_data->workflow("to_quotation_type");
1456
1457   $self->order(SL::DB::DeliveryOrder->new_from($self->order, destination_type => $destination_type));
1458   $self->{converted_from_oe_id} = delete $::form->{id};
1459
1460   # set item ids to new fake id, to identify them as new items
1461   foreach my $item (@{$self->order->items_sorted}) {
1462     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1463   }
1464
1465   # change form type
1466   $::form->{type} = $destination_type;
1467   $self->type($self->init_type);
1468   $self->cv  ($self->init_cv);
1469   $self->check_auth;
1470
1471   $self->get_unalterable_data();
1472   $self->pre_render();
1473
1474   # trigger rendering values for second row as hidden, because they
1475   # are loaded only on demand. So we need to keep the values from the
1476   # source.
1477   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1478
1479   $self->render(
1480     'delivery_order/form',
1481     title => $self->get_title_for('edit'),
1482     %{$self->{template_args}}
1483   );
1484 }
1485
1486 sub workflow_sales_or_purchase_order {
1487   my ($self) = @_;
1488
1489   # always save
1490   my $errors = $self->save();
1491
1492   if (scalar @{ $errors }) {
1493     $self->js->flash('error', $_) foreach @{ $errors };
1494     return $self->js->render();
1495   }
1496
1497   my $destination_type = $self->type_data->workflow("to_order_type");
1498
1499   # check for direct delivery
1500   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1501   my $custom_shipto;
1502   if ($self->type_data->workflow("to_order_copy_shipto") && $::form->{use_shipto} && $self->order->shipto) {
1503     $custom_shipto = $self->order->shipto->clone('SL::DB::DeliveryOrder');
1504   }
1505
1506   $self->order(SL::DB::DeliveryOrder->new_from($self->order, destination_type => $destination_type));
1507   $self->{converted_from_oe_id} = delete $::form->{id};
1508
1509   # set item ids to new fake id, to identify them as new items
1510   foreach my $item (@{$self->order->items_sorted}) {
1511     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1512   }
1513
1514   if ($self->type_data->workflow("to_order_copy_shipto")) {
1515     if ($::form->{use_shipto}) {
1516       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1517     } else {
1518       # remove any custom shipto if not wanted
1519       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1520     }
1521   }
1522
1523   # change form type
1524   $::form->{type} = $destination_type;
1525   $self->type($self->init_type);
1526   $self->cv  ($self->init_cv);
1527   $self->check_auth;
1528
1529   $self->get_unalterable_data();
1530   $self->pre_render();
1531
1532   # trigger rendering values for second row as hidden, because they
1533   # are loaded only on demand. So we need to keep the values from the
1534   # source.
1535   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1536
1537   $self->render(
1538     'delivery_order/form',
1539     title => $self->get_title_for('edit'),
1540     %{$self->{template_args}}
1541   );
1542 }
1543
1544
1545 sub pre_render {
1546   my ($self) = @_;
1547
1548   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1549   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1550   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1551   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1552   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1553                                                                                               deleted => 0 ] ],
1554                                                                            sort_by => 'name');
1555   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1556                                                                                               deleted => 0 ] ],
1557                                                                            sort_by => 'name');
1558   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1559                                                                                                         obsolete => 0 ] ]);
1560   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1561   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1562   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1563   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1564
1565   my $print_form = Form->new('');
1566   $print_form->{type}        = $self->type;
1567   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1568   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1569     form => $print_form,
1570     options => {dialog_name_prefix => 'print_options.',
1571                 show_headers       => 1,
1572                 no_queue           => 1,
1573                 no_postscript      => 1,
1574                 no_opendocument    => 0,
1575                 no_html            => 1},
1576   );
1577
1578   foreach my $item (@{$self->order->orderitems}) {
1579     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1580     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1581     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1582   }
1583
1584   if ($self->order->${\ $self->type_data->nr_key } && $::instance_conf->get_webdav) {
1585     my $webdav = SL::Webdav->new(
1586       type     => $self->type,
1587       number   => $self->order->number,
1588     );
1589     my @all_objects = $webdav->get_all_objects;
1590     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1591                                                     type => t8('File'),
1592                                                     link => File::Spec->catfile($_->full_filedescriptor),
1593                                                 } } @all_objects;
1594   }
1595
1596   $self->{template_args}{inout} = $self->type_data->properties('transfer');
1597
1598   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1599
1600   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.DeliveryOrder kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1601                                                          calculate_qty kivi.Validator follow_up show_history);
1602   $self->setup_edit_action_bar;
1603 }
1604
1605 sub setup_edit_action_bar {
1606   my ($self, %params) = @_;
1607
1608   my $deletion_allowed = $self->type_data->show_menu("delete");
1609
1610   for my $bar ($::request->layout->get('actionbar')) {
1611     $bar->add(
1612       combobox => [
1613         action => [
1614           t8('Save'),
1615           call      => [ 'kivi.DeliveryOrder.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1616                                                     $::instance_conf->get_order_warn_no_deliverydate,
1617                                                                                                       ],
1618         ],
1619         action => [
1620           t8('Save as new'),
1621           call      => [ 'kivi.DeliveryOrder.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1622           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1623         ],
1624       ], # end of combobox "Save"
1625
1626       combobox => [
1627         action => [
1628           t8('Workflow'),
1629         ],
1630         action => [
1631           t8('Save and Quotation'),
1632           submit   => [ '#order_form', { action => "DeliveryOrder/sales_quotation" } ],
1633           only_if  => $self->type_data->show_menu("save_and_quotation"),
1634         ],
1635         action => [
1636           t8('Save and RFQ'),
1637           submit   => [ '#order_form', { action => "DeliveryOrder/request_for_quotation" } ],
1638           only_if  => $self->type_data->show_menu("save_and_rfq"),
1639         ],
1640         action => [
1641           t8('Save and Sales Order'),
1642           submit   => [ '#order_form', { action => "DeliveryOrder/sales_order" } ],
1643           only_if  => $self->type_data->show_menu("save_and_sales_order"),
1644         ],
1645         action => [
1646           t8('Save and Purchase Order'),
1647           call      => [ 'kivi.DeliveryOrder.purchase_order_check_for_direct_delivery' ],
1648           only_if  => $self->type_data->show_menu("save_and_purchase_order"),
1649         ],
1650         action => [
1651           t8('Save and Delivery Order'),
1652           call      => [ 'kivi.DeliveryOrder.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1653                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1654                                                                                                                         ],
1655           only_if  => $self->type_data->show_menu("save_and_delivery_order"),
1656         ],
1657         action => [
1658           t8('Save and Invoice'),
1659           call      => [ 'kivi.DeliveryOrder.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1660           only_if  => $self->type_data->show_menu("save_and_invoice"),
1661         ],
1662         action => [
1663           t8('Save and AP Transaction'),
1664           call      => [ 'kivi.DeliveryOrder.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1665           only_if  => $self->type_data->show_menu("save_and_ap_transaction"),
1666         ],
1667
1668       ], # end of combobox "Workflow"
1669
1670       combobox => [
1671         action => [
1672           t8('Export'),
1673         ],
1674         action => [
1675           t8('Save and preview PDF'),
1676            call => [ 'kivi.DeliveryOrder.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
1677                                                        $::instance_conf->get_order_warn_no_deliverydate,
1678                                                                                                          ],
1679         ],
1680         action => [
1681           t8('Save and print'),
1682           call => [ 'kivi.DeliveryOrder.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
1683                                                      $::instance_conf->get_order_warn_no_deliverydate,
1684                                                                                                       ],
1685         ],
1686         action => [
1687           t8('Save and E-mail'),
1688           id   => 'save_and_email_action',
1689           call => [ 'kivi.DeliveryOrder.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
1690                                                                      $::instance_conf->get_order_warn_no_deliverydate,
1691                   ],
1692           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1693         ],
1694         action => [
1695           t8('Download attachments of all parts'),
1696           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1697           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1698           only_if  => $::instance_conf->get_doc_storage,
1699         ],
1700       ], # end of combobox "Export"
1701
1702       action => [
1703         t8('Delete'),
1704         call     => [ 'kivi.DeliveryOrder.delete_order' ],
1705         confirm  => $::locale->text('Do you really want to delete this object?'),
1706         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1707         only_if  => $self->type_data->show_menu("delete"),
1708       ],
1709
1710       combobox => [
1711         action => [
1712           t8('more')
1713         ],
1714         action => [
1715           t8('Follow-Up'),
1716           call     => [ 'kivi.DeliveryOrder.follow_up_window' ],
1717           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1718           only_if  => $::auth->assert('productivity', 1),
1719         ],
1720         action => [
1721           t8('History'),
1722           call     => [ 'set_history_window', $self->order->id, 'id' ],
1723           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
1724         ],
1725       ], # end of combobox "more"
1726     );
1727   }
1728 }
1729
1730 sub generate_pdf {
1731   my ($order, $pdf_ref, $params) = @_;
1732
1733   my @errors = ();
1734
1735   my $print_form = Form->new('');
1736   $print_form->{type}        = $order->type;
1737   $print_form->{formname}    = $params->{formname} || $order->type;
1738   $print_form->{format}      = $params->{format}   || 'pdf';
1739   $print_form->{media}       = $params->{media}    || 'file';
1740   $print_form->{groupitems}  = $params->{groupitems};
1741   $print_form->{printer_id}  = $params->{printer_id};
1742   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1743
1744   $order->language($params->{language});
1745   $order->flatten_to_form($print_form, format_amounts => 1);
1746
1747   my $template_ext;
1748   my $template_type;
1749   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1750     $template_ext  = 'odt';
1751     $template_type = 'OpenDocument';
1752   }
1753
1754   # search for the template
1755   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1756     name        => $print_form->{formname},
1757     extension   => $template_ext,
1758     email       => $print_form->{media} eq 'email',
1759     language    => $params->{language},
1760     printer_id  => $print_form->{printer_id},
1761   );
1762
1763   if (!defined $template_file) {
1764     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1765   }
1766
1767   return @errors if scalar @errors;
1768
1769   $print_form->throw_on_error(sub {
1770     eval {
1771       $print_form->prepare_for_printing;
1772
1773       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1774         format        => $print_form->{format},
1775         template_type => $template_type,
1776         template      => $template_file,
1777         variables     => $print_form,
1778         variable_content_types => {
1779           longdescription => 'html',
1780           partnotes       => 'html',
1781           notes           => 'html',
1782         },
1783       );
1784       1;
1785     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1786   });
1787
1788   return @errors;
1789 }
1790
1791 sub get_files_for_email_dialog {
1792   my ($self) = @_;
1793
1794   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1795
1796   return %files if !$::instance_conf->get_doc_storage;
1797
1798   if ($self->order->id) {
1799     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1800     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1801     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1802     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
1803   }
1804
1805   my @parts =
1806     uniq_by { $_->{id} }
1807     map {
1808       +{ id         => $_->part->id,
1809          partnumber => $_->part->partnumber }
1810     } @{$self->order->items_sorted};
1811
1812   foreach my $part (@parts) {
1813     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1814     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1815   }
1816
1817   foreach my $key (keys %files) {
1818     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1819   }
1820
1821   return %files;
1822 }
1823
1824 sub get_title_for {
1825   my ($self, $action) = @_;
1826
1827   return '' if none { lc($action)} qw(add edit);
1828   return $self->type_data->text($action);
1829 }
1830
1831 sub get_item_cvpartnumber {
1832   my ($self, $item) = @_;
1833
1834   return if !$self->search_cvpartnumber;
1835   return if !$self->order->customervendor;
1836
1837   if ($self->cv eq 'vendor') {
1838     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
1839     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
1840   } elsif ($self->cv eq 'customer') {
1841     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
1842     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
1843   }
1844 }
1845
1846 sub get_part_texts {
1847   my ($part_or_id, $language_or_id, %defaults) = @_;
1848
1849   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
1850   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
1851   my $texts       = {
1852     description     => $defaults{description}     // $part->description,
1853     longdescription => $defaults{longdescription} // $part->notes,
1854   };
1855
1856   return $texts unless $language_id;
1857
1858   my $translation = SL::DB::Manager::Translation->get_first(
1859     where => [
1860       parts_id    => $part->id,
1861       language_id => $language_id,
1862     ]);
1863
1864   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
1865   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
1866
1867   return $texts;
1868 }
1869
1870 sub nr_key {
1871   return $_[0]->type_data->nr_key;
1872 }
1873
1874 sub save_and_redirect_to {
1875   my ($self, %params) = @_;
1876
1877   my $errors = $self->save();
1878
1879   if (scalar @{ $errors }) {
1880     $self->js->flash('error', $_) foreach @{ $errors };
1881     return $self->js->render();
1882   }
1883
1884   flash_later('info', $self->type_data->text("saved"));
1885
1886   $self->redirect_to(%params, id => $self->order->id);
1887 }
1888
1889 sub save_history {
1890   my ($self, $addition) = @_;
1891
1892   my $number_type = $self->nr_key;
1893   my $snumbers    = $number_type . '_' . $self->order->$number_type;
1894
1895   SL::DB::History->new(
1896     trans_id    => $self->order->id,
1897     employee_id => SL::DB::Manager::Employee->current->id,
1898     what_done   => $self->order->type,
1899     snumbers    => $snumbers,
1900     addition    => $addition,
1901   )->save;
1902 }
1903
1904 sub store_pdf_to_webdav_and_filemanagement {
1905   my($order, $content, $filename) = @_;
1906
1907   my @errors;
1908
1909   # copy file to webdav folder
1910   if ($order->number && $::instance_conf->get_webdav_documents) {
1911     my $webdav = SL::Webdav->new(
1912       type     => $order->type,
1913       number   => $order->number,
1914     );
1915     my $webdav_file = SL::Webdav::File->new(
1916       webdav   => $webdav,
1917       filename => $filename,
1918     );
1919     eval {
1920       $webdav_file->store(data => \$content);
1921       1;
1922     } or do {
1923       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
1924     };
1925   }
1926   if ($order->id && $::instance_conf->get_doc_storage) {
1927     eval {
1928       SL::File->save(object_id     => $order->id,
1929                      object_type   => $order->type,
1930                      mime_type     => 'application/pdf',
1931                      source        => 'created',
1932                      file_type     => 'document',
1933                      file_name     => $filename,
1934                      file_contents => $content);
1935       1;
1936     } or do {
1937       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
1938     };
1939   }
1940
1941   return @errors;
1942 }
1943
1944 sub calculate_stock_in_out {
1945   my ($self, $item) = @_;
1946
1947   return "" if !$item->part || !$item->part->unit;
1948
1949   my $in_out   = $self->type_data->properties("transfer");
1950
1951   my $do_qty   = $item->qty;
1952   my $sum      = sum0 map { $_->unit_obj->convert_to($_->qty, $item->unit_obj) } @{ $item->delivery_order_stock_entries };
1953
1954   my $matches  = $do_qty == $sum;
1955   my $content  = _format_number_units($sum, 2, $item->unit_obj, $item->part->unit_obj);
1956
1957   return $content;
1958 }
1959
1960 sub init_type_data {
1961   SL::Controller::DeliveryOrder::TypeData->new($_[0]);
1962 }
1963
1964 sub init_valid_types {
1965   $_[0]->type_data->valid_types;
1966 }
1967
1968 1;
1969
1970 __END__
1971
1972 =encoding utf-8
1973
1974 =head1 NAME
1975
1976 SL::Controller::Order - controller for orders
1977
1978 =head1 SYNOPSIS
1979
1980 This is a new form to enter orders, completely rewritten with the use
1981 of controller and java script techniques.
1982
1983 The aim is to provide the user a better experience and a faster workflow. Also
1984 the code should be more readable, more reliable and better to maintain.
1985
1986 =head2 Key Features
1987
1988 =over 4
1989
1990 =item *
1991
1992 One input row, so that input happens every time at the same place.
1993
1994 =item *
1995
1996 Use of pickers where possible.
1997
1998 =item *
1999
2000 Possibility to enter more than one item at once.
2001
2002 =item *
2003
2004 Item list in a scrollable area, so that the workflow buttons stay at
2005 the bottom.
2006
2007 =item *
2008
2009 Reordering item rows with drag and drop is possible. Sorting item rows is
2010 possible (by partnumber, description, qty, sellprice and discount for now).
2011
2012 =item *
2013
2014 No C<update> is necessary. All entries and calculations are managed
2015 with ajax-calls and the page only reloads on C<save>.
2016
2017 =item *
2018
2019 User can see changes immediately, because of the use of java script
2020 and ajax.
2021
2022 =back
2023
2024 =head1 CODE
2025
2026 =head2 Layout
2027
2028 =over 4
2029
2030 =item * C<SL/Controller/Order.pm>
2031
2032 the controller
2033
2034 =item * C<template/webpages/delivery_order/form.html>
2035
2036 main form
2037
2038 =item * C<template/webpages/delivery_order/tabs/basic_data.html>
2039
2040 Main tab for basic_data.
2041
2042 This is the only tab here for now. "linked records" and "webdav" tabs are
2043 reused from generic code.
2044
2045 =over 4
2046
2047 =item * C<template/webpages/delivery_order/tabs/_business_info_row.html>
2048
2049 For displaying information on business type
2050
2051 =item * C<template/webpages/delivery_order/tabs/_item_input.html>
2052
2053 The input line for items
2054
2055 =item * C<template/webpages/delivery_order/tabs/_row.html>
2056
2057 One row for already entered items
2058
2059 =item * C<template/webpages/delivery_order/tabs/_tax_row.html>
2060
2061 Displaying tax information
2062
2063 =back
2064
2065 =item * C<js/kivi.DeliveryOrder.js>
2066
2067 java script functions
2068
2069 =back
2070
2071 =head1 TODO
2072
2073 =over 4
2074
2075 =item * testing
2076
2077 =item * price sources: little symbols showing better price / better discount
2078
2079 =item * select units in input row?
2080
2081 =item * check for direct delivery (workflow sales order -> purchase order)
2082
2083 =item * access rights
2084
2085 =item * display weights
2086
2087 =item * mtime check
2088
2089 =item * optional client/user behaviour
2090
2091 (transactions has to be set - department has to be set -
2092  force project if enabled in client config - transport cost reminder)
2093
2094 =back
2095
2096 =head1 KNOWN BUGS AND CAVEATS
2097
2098 =over 4
2099
2100 =item *
2101
2102 Customer discount is not displayed as a valid discount in price source popup
2103 (this might be a bug in price sources)
2104
2105 (I cannot reproduce this (Bernd))
2106
2107 =item *
2108
2109 No indication that <shift>-up/down expands/collapses second row.
2110
2111 =item *
2112
2113 Inline creation of parts is not currently supported
2114
2115 =item *
2116
2117 Table header is not sticky in the scrolling area.
2118
2119 =item *
2120
2121 Sorting does not include C<position>, neither does reordering.
2122
2123 This behavior was implemented intentionally. But we can discuss, which behavior
2124 should be implemented.
2125
2126 =back
2127
2128 =head1 To discuss / Nice to have
2129
2130 =over 4
2131
2132 =item *
2133
2134 How to expand/collapse second row. Now it can be done clicking the icon or
2135 <shift>-up/down.
2136
2137 =item *
2138
2139 Possibility to select PriceSources in input row?
2140
2141 =item *
2142
2143 This controller uses a (changed) copy of the template for the PriceSource
2144 dialog. Maybe there could be used one code source.
2145
2146 =item *
2147
2148 Rounding-differences between this controller (PriceTaxCalculator) and the old
2149 form. This is not only a problem here, but also in all parts using the PTC.
2150 There exists a ticket and a patch. This patch should be testet.
2151
2152 =item *
2153
2154 An indicator, if the actual inputs are saved (like in an
2155 editor or on text processing application).
2156
2157 =item *
2158
2159 A warning when leaving the page without saveing unchanged inputs.
2160
2161
2162 =back
2163
2164 =head1 AUTHOR
2165
2166 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2167
2168 =cut