SL/Controller/DeliveryOrder.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::History;
  17 use SL::DB::Order;
  18 use SL::DB::Default;
  19 use SL::DB::Unit;
  20 use SL::DB::Part;
  21 use SL::DB::PartClassification;
  22 use SL::DB::PartsGroup;
  23 use SL::DB::Printer;
  24 use SL::DB::Language;
  25 use SL::DB::RecordLink;
  26 use SL::DB::Shipto;
  27 use SL::DB::Translation;
  28
  29 use SL::Helper::CreatePDF qw(:all);
  30 use SL::Helper::PrintOptions;
  31 use SL::Helper::ShippedQty;
  32 use SL::Helper::UserPreferences::PositionsScrollbar;
  33 use SL::Helper::UserPreferences::UpdatePositions;
  34
  35 use SL::Controller::Helper::GetModels;
  36
  37 use List::Util qw(first sum0);
  38 use List::UtilsBy qw(sort_by uniq_by);
  39 use List::MoreUtils qw(any none pairwise first_index);
  40 use English qw(-no_match_vars);
  41 use File::Spec;
  42 use Cwd;
  43 use Sort::Naturally;
  44
  45 use Rose::Object::MakeMethods::Generic
  46 (
  47  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  48  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  49 );
  50
  51
  52 # safety
  53 __PACKAGE__->run_before('check_auth');
  54
  55 __PACKAGE__->run_before('get_unalterable_data',
  56                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  57                                      print send_email) ]);
  58
  59 #
  60 # actions
  61 #
  62
  63 # add a new order
  64 sub action_add {
  65   my ($self) = @_;
  66
  67   $self->order->transdate(DateTime->now_local());
  68   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  69                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  70
  71   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  72       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  73       && (!$self->order->reqdate)) {
  74     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  75   }
  76
  77
  78   $self->pre_render();
  79   $self->render(
  80     'order/form',
  81     title => $self->get_title_for('add'),
  82     %{$self->{template_args}}
  83   );
  84 }
  85
  86 # edit an existing order
  87 sub action_edit {
  88   my ($self) = @_;
  89
  90   if ($::form->{id}) {
  91     $self->load_order;
  92
  93   } else {
  94     # this is to edit an order from an unsaved order object
  95
  96     # set item ids to new fake id, to identify them as new items
  97     foreach my $item (@{$self->order->items_sorted}) {
  98       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  99     }
 100     # trigger rendering values for second row as hidden, because they
 101     # are loaded only on demand. So we need to keep the values from
 102     # the source.
 103     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 104   }
 105
 106   $self->pre_render();
 107   $self->render(
 108     'order/form',
 109     title => $self->get_title_for('edit'),
 110     %{$self->{template_args}}
 111   );
 112 }
 113
 114 # edit a collective order (consisting of one or more existing orders)
 115 sub action_edit_collective {
 116   my ($self) = @_;
 117
 118   # collect order ids
 119   my @multi_ids = map {
 120     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 121   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 122
 123   # fall back to add if no ids are given
 124   if (scalar @multi_ids == 0) {
 125     $self->action_add();
 126     return;
 127   }
 128
 129   # fall back to save as new if only one id is given
 130   if (scalar @multi_ids == 1) {
 131     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 132     $self->action_save_as_new();
 133     return;
 134   }
 135
 136   # make new order from given orders
 137   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 138   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 139   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 140
 141   $self->action_edit();
 142 }
 143
 144 # delete the order
 145 sub action_delete {
 146   my ($self) = @_;
 147
 148   my $errors = $self->delete();
 149
 150   if (scalar @{ $errors }) {
 151     $self->js->flash('error', $_) foreach @{ $errors };
 152     return $self->js->render();
 153   }
 154
 155   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 156            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 157            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 158            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 159            : '';
 160   flash_later('info', $text);
 161
 162   my @redirect_params = (
 163     action => 'add',
 164     type   => $self->type,
 165   );
 166
 167   $self->redirect_to(@redirect_params);
 168 }
 169
 170 # save the order
 171 sub action_save {
 172   my ($self) = @_;
 173
 174   my $errors = $self->save();
 175
 176   if (scalar @{ $errors }) {
 177     $self->js->flash('error', $_) foreach @{ $errors };
 178     return $self->js->render();
 179   }
 180
 181   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 182            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 183            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 184            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 185            : '';
 186   flash_later('info', $text);
 187
 188   my @redirect_params = (
 189     action => 'edit',
 190     type   => $self->type,
 191     id     => $self->order->id,
 192   );
 193
 194   $self->redirect_to(@redirect_params);
 195 }
 196
 197 # save the order as new document an open it for edit
 198 sub action_save_as_new {
 199   my ($self) = @_;
 200
 201   my $order = $self->order;
 202
 203   if (!$order->id) {
 204     $self->js->flash('error', t8('This object has not been saved yet.'));
 205     return $self->js->render();
 206   }
 207
 208   # load order from db to check if values changed
 209   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 210
 211   my %new_attrs;
 212   # Lets assign a new number if the user hasn't changed the previous one.
 213   # If it has been changed manually then use it as-is.
 214   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 215                         ? ''
 216                         : trim($order->number);
 217
 218   # Clear transdate unless changed
 219   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 220                         ? DateTime->today_local
 221                         : $order->transdate;
 222
 223   # Set new reqdate unless changed if it is enabled in client config
 224   if ($order->reqdate == $saved_order->reqdate) {
 225     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 226                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 227
 228     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 229         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 230       $new_attrs{reqdate} = '';
 231     } else {
 232       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 233     }
 234   } else {
 235     $new_attrs{reqdate} = $order->reqdate;
 236   }
 237
 238   # Update employee
 239   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 240
 241   # Create new record from current one
 242   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 243
 244   # no linked records on save as new
 245   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 246
 247   # save
 248   $self->action_save();
 249 }
 250
 251 # print the order
 252 #
 253 # This is called if "print" is pressed in the print dialog.
 254 # If PDF creation was requested and succeeded, the pdf is offered for download
 255 # via send_file (which uses ajax in this case).
 256 sub action_print {
 257   my ($self) = @_;
 258
 259   my $errors = $self->save();
 260
 261   if (scalar @{ $errors }) {
 262     $self->js->flash('error', $_) foreach @{ $errors };
 263     return $self->js->render();
 264   }
 265
 266   $self->js_reset_order_and_item_ids_after_save;
 267
 268   my $format      = $::form->{print_options}->{format};
 269   my $media       = $::form->{print_options}->{media};
 270   my $formname    = $::form->{print_options}->{formname};
 271   my $copies      = $::form->{print_options}->{copies};
 272   my $groupitems  = $::form->{print_options}->{groupitems};
 273   my $printer_id  = $::form->{print_options}->{printer_id};
 274
 275   # only pdf and opendocument by now
 276   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 277     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 278   }
 279
 280   # only screen or printer by now
 281   if (none { $media eq $_ } qw(screen printer)) {
 282     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 283   }
 284
 285   # create a form for generate_attachment_filename
 286   my $form   = Form->new;
 287   $form->{$self->nr_key()}  = $self->order->number;
 288   $form->{type}             = $self->type;
 289   $form->{format}           = $format;
 290   $form->{formname}         = $formname;
 291   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 292   my $pdf_filename          = $form->generate_attachment_filename();
 293
 294   my $pdf;
 295   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 296                                                    formname   => $formname,
 297                                                    language   => $self->order->language,
 298                                                    printer_id => $printer_id,
 299                                                    groupitems => $groupitems });
 300   if (scalar @errors) {
 301     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 302   }
 303
 304   if ($media eq 'screen') {
 305     # screen/download
 306     $self->js->flash('info', t8('The PDF has been created'));
 307     $self->send_file(
 308       \$pdf,
 309       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 310       name         => $pdf_filename,
 311       js_no_render => 1,
 312     );
 313
 314   } elsif ($media eq 'printer') {
 315     # printer
 316     my $printer_id = $::form->{print_options}->{printer_id};
 317     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 318       copies  => $copies,
 319       content => $pdf,
 320     );
 321
 322     $self->js->flash('info', t8('The PDF has been printed'));
 323   }
 324
 325   my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $pdf_filename);
 326   if (scalar @warnings) {
 327     $self->js->flash('warning', $_) for @warnings;
 328   }
 329
 330   $self->save_history('PRINTED');
 331
 332   $self->js
 333     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 334     ->render;
 335 }
 336 sub action_preview_pdf {
 337   my ($self) = @_;
 338
 339   my $errors = $self->save();
 340   if (scalar @{ $errors }) {
 341     $self->js->flash('error', $_) foreach @{ $errors };
 342     return $self->js->render();
 343   }
 344
 345   $self->js_reset_order_and_item_ids_after_save;
 346
 347   my $format      = 'pdf';
 348   my $media       = 'screen';
 349   my $formname    = $self->type;
 350
 351   # only pdf
 352   # create a form for generate_attachment_filename
 353   my $form   = Form->new;
 354   $form->{$self->nr_key()}  = $self->order->number;
 355   $form->{type}             = $self->type;
 356   $form->{format}           = $format;
 357   $form->{formname}         = $formname;
 358   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 359   my $pdf_filename          = $form->generate_attachment_filename();
 360
 361   my $pdf;
 362   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 363                                                    formname   => $formname,
 364                                                    language   => $self->order->language,
 365                                                  });
 366   if (scalar @errors) {
 367     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 368   }
 369   $self->save_history('PREVIEWED');
 370   $self->js->flash('info', t8('The PDF has been previewed'));
 371   # screen/download
 372   $self->send_file(
 373     \$pdf,
 374     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 375     name         => $pdf_filename,
 376     js_no_render => 0,
 377   );
 378 }
 379
 380 # open the email dialog
 381 sub action_save_and_show_email_dialog {
 382   my ($self) = @_;
 383
 384   my $errors = $self->save();
 385
 386   if (scalar @{ $errors }) {
 387     $self->js->flash('error', $_) foreach @{ $errors };
 388     return $self->js->render();
 389   }
 390
 391   my $cv_method = $self->cv;
 392
 393   if (!$self->order->$cv_method) {
 394     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 395                     ->render($self);
 396   }
 397
 398   my $email_form;
 399   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 400   $email_form->{to} ||= $self->order->$cv_method->email;
 401   $email_form->{cc}   = $self->order->$cv_method->cc;
 402   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 403   # Todo: get addresses from shipto, if any
 404
 405   my $form = Form->new;
 406   $form->{$self->nr_key()}  = $self->order->number;
 407   $form->{cusordnumber}     = $self->order->cusordnumber;
 408   $form->{formname}         = $self->type;
 409   $form->{type}             = $self->type;
 410   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 411   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 412   $form->{format}           = 'pdf';
 413   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 414
 415   $email_form->{subject}             = $form->generate_email_subject();
 416   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 417   $email_form->{message}             = $form->generate_email_body();
 418   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 419
 420   my %files = $self->get_files_for_email_dialog();
 421   $self->{all_employees} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 422   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 423                                   email_form  => $email_form,
 424                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 425                                   FILES       => \%files,
 426                                   is_customer => $self->cv eq 'customer',
 427                                   ALL_EMPLOYEES => $self->{all_employees},
 428   );
 429
 430   $self->js
 431       ->run('kivi.Order.show_email_dialog', $dialog_html)
 432       ->reinit_widgets
 433       ->render($self);
 434 }
 435
 436 # send email
 437 #
 438 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 439 sub action_send_email {
 440   my ($self) = @_;
 441
 442   my $errors = $self->save();
 443
 444   if (scalar @{ $errors }) {
 445     $self->js->run('kivi.Order.close_email_dialog');
 446     $self->js->flash('error', $_) foreach @{ $errors };
 447     return $self->js->render();
 448   }
 449
 450   $self->js_reset_order_and_item_ids_after_save;
 451
 452   my $email_form  = delete $::form->{email_form};
 453   my %field_names = (to => 'email');
 454
 455   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 456
 457   # for Form::cleanup which may be called in Form::send_email
 458   $::form->{cwd}    = getcwd();
 459   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 460
 461   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 462   $::form->{media}  = 'email';
 463
 464   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 465     my $pdf;
 466     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 467                                                     format     => $::form->{print_options}->{format},
 468                                                     formname   => $::form->{print_options}->{formname},
 469                                                     language   => $self->order->language,
 470                                                     printer_id => $::form->{print_options}->{printer_id},
 471                                                     groupitems => $::form->{print_options}->{groupitems}});
 472     if (scalar @errors) {
 473       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 474     }
 475
 476     my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $::form->{attachment_filename});
 477     if (scalar @warnings) {
 478       flash_later('warning', $_) for @warnings;
 479     }
 480
 481     my $sfile = SL::SessionFile::Random->new(mode => "w");
 482     $sfile->fh->print($pdf);
 483     $sfile->fh->close;
 484
 485     $::form->{tmpfile} = $sfile->file_name;
 486     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 487   }
 488
 489   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 490   $::form->send_email(\%::myconfig, 'pdf');
 491
 492   # internal notes
 493   my $intnotes = $self->order->intnotes;
 494   $intnotes   .= "\n\n" if $self->order->intnotes;
 495   $intnotes   .= t8('[email]')                                                                                        . "\n";
 496   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 497   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 498   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 499   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 500   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 501   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 502
 503   $self->order->update_attributes(intnotes => $intnotes);
 504
 505   $self->save_history('MAILED');
 506
 507   flash_later('info', t8('The email has been sent.'));
 508
 509   my @redirect_params = (
 510     action => 'edit',
 511     type   => $self->type,
 512     id     => $self->order->id,
 513   );
 514
 515   $self->redirect_to(@redirect_params);
 516 }
 517
 518 # save the order and redirect to the frontend subroutine for a new
 519 # delivery order
 520 sub action_save_and_delivery_order {
 521   my ($self) = @_;
 522
 523   $self->save_and_redirect_to(
 524     controller => 'oe.pl',
 525     action     => 'oe_delivery_order_from_order',
 526   );
 527 }
 528
 529 # save the order and redirect to the frontend subroutine for a new
 530 # invoice
 531 sub action_save_and_invoice {
 532   my ($self) = @_;
 533
 534   $self->save_and_redirect_to(
 535     controller => 'oe.pl',
 536     action     => 'oe_invoice_from_order',
 537   );
 538 }
 539
 540 # workflow from sales order to sales quotation
 541 sub action_sales_quotation {
 542   $_[0]->workflow_sales_or_request_for_quotation();
 543 }
 544
 545 # workflow from sales order to sales quotation
 546 sub action_request_for_quotation {
 547   $_[0]->workflow_sales_or_request_for_quotation();
 548 }
 549
 550 # workflow from sales quotation to sales order
 551 sub action_sales_order {
 552   $_[0]->workflow_sales_or_purchase_order();
 553 }
 554
 555 # workflow from rfq to purchase order
 556 sub action_purchase_order {
 557   $_[0]->workflow_sales_or_purchase_order();
 558 }
 559
 560 # workflow from purchase order to ap transaction
 561 sub action_save_and_ap_transaction {
 562   my ($self) = @_;
 563
 564   $self->save_and_redirect_to(
 565     controller => 'ap.pl',
 566     action     => 'add_from_purchase_order',
 567   );
 568 }
 569
 570 # set form elements in respect to a changed customer or vendor
 571 #
 572 # This action is called on an change of the customer/vendor picker.
 573 sub action_customer_vendor_changed {
 574   my ($self) = @_;
 575
 576   setup_order_from_cv($self->order);
 577
 578   my $cv_method = $self->cv;
 579
 580   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 581     $self->js->show('#cp_row');
 582   } else {
 583     $self->js->hide('#cp_row');
 584   }
 585
 586   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 587     $self->js->show('#shipto_selection');
 588   } else {
 589     $self->js->hide('#shipto_selection');
 590   }
 591
 592   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 593
 594   $self->js
 595     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 596     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 597     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 598     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 599     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 600     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 601     ->val(        '#order_currency_id',      $self->order->currency_id)
 602     ->val(        '#order_payment_id',       $self->order->payment_id)
 603     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 604     ->val(        '#order_intnotes',         $self->order->intnotes)
 605     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 606     ->focus(      '#order_' . $self->cv . '_id')
 607     ->run('kivi.Order.update_exchangerate');
 608
 609   $self->js_redisplay_cvpartnumbers;
 610   $self->js->render();
 611 }
 612
 613 # open the dialog for customer/vendor details
 614 sub action_show_customer_vendor_details_dialog {
 615   my ($self) = @_;
 616
 617   my $is_customer = 'customer' eq $::form->{vc};
 618   my $cv;
 619   if ($is_customer) {
 620     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 621   } else {
 622     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 623   }
 624
 625   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 626   $details{discount_as_percent} = $cv->discount_as_percent;
 627   $details{creditlimt}          = $cv->creditlimit_as_number;
 628   $details{business}            = $cv->business->description      if $cv->business;
 629   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 630   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 631   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 632   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 633
 634   foreach my $entry (@{ $cv->shipto }) {
 635     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 636   }
 637   foreach my $entry (@{ $cv->contacts }) {
 638     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 639   }
 640
 641   $_[0]->render('common/show_vc_details', { layout => 0 },
 642                 is_customer => $is_customer,
 643                 %details);
 644
 645 }
 646
 647 # called if a unit in an existing item row is changed
 648 sub action_unit_changed {
 649   my ($self) = @_;
 650
 651   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 652   my $item = $self->order->items_sorted->[$idx];
 653
 654   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 655   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 656
 657   $self->js
 658     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 659   $self->js_redisplay_line_values;
 660   $self->js->render();
 661 }
 662
 663 # add an item row for a new item entered in the input row
 664 sub action_add_item {
 665   my ($self) = @_;
 666
 667   delete $::form->{add_item}->{create_part_type};
 668
 669   my $form_attr = $::form->{add_item};
 670
 671   return unless $form_attr->{parts_id};
 672
 673   my $item = new_item($self->order, $form_attr);
 674
 675   $self->order->add_items($item);
 676
 677   $self->get_item_cvpartnumber($item);
 678
 679   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 680   my $row_as_html = $self->p->render('order/tabs/_row',
 681                                      ITEM => $item,
 682                                      ID   => $item_id,
 683                                      SELF => $self,
 684   );
 685
 686   if ($::form->{insert_before_item_id}) {
 687     $self->js
 688       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 689   } else {
 690     $self->js
 691       ->append('#row_table_id', $row_as_html);
 692   }
 693
 694   if ( $item->part->is_assortment ) {
 695     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 696     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 697       my $attr = { parts_id => $assortment_item->parts_id,
 698                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 699                    unit     => $assortment_item->unit,
 700                    description => $assortment_item->part->description,
 701                  };
 702       my $item = new_item($self->order, $attr);
 703
 704       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 705       $item->discount(1) unless $assortment_item->charge;
 706
 707       $self->order->add_items( $item );
 708       $self->get_item_cvpartnumber($item);
 709       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 710       my $row_as_html = $self->p->render('order/tabs/_row',
 711                                          ITEM => $item,
 712                                          ID   => $item_id,
 713                                          SELF => $self,
 714       );
 715       if ($::form->{insert_before_item_id}) {
 716         $self->js
 717           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 718       } else {
 719         $self->js
 720           ->append('#row_table_id', $row_as_html);
 721       }
 722     };
 723   };
 724
 725   $self->js
 726     ->val('.add_item_input', '')
 727     ->run('kivi.Order.init_row_handlers')
 728     ->run('kivi.Order.renumber_positions')
 729     ->focus('#add_item_parts_id_name');
 730
 731   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 732
 733   $self->js->render();
 734 }
 735
 736 # add item rows for multiple items at once
 737 sub action_add_multi_items {
 738   my ($self) = @_;
 739
 740   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 741   return $self->js->render() unless scalar @form_attr;
 742
 743   my @items;
 744   foreach my $attr (@form_attr) {
 745     my $item = new_item($self->order, $attr);
 746     push @items, $item;
 747     if ( $item->part->is_assortment ) {
 748       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 749         my $attr = { parts_id => $assortment_item->parts_id,
 750                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 751                      unit     => $assortment_item->unit,
 752                      description => $assortment_item->part->description,
 753                    };
 754         my $item = new_item($self->order, $attr);
 755
 756         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 757         $item->discount(1) unless $assortment_item->charge;
 758         push @items, $item;
 759       }
 760     }
 761   }
 762   $self->order->add_items(@items);
 763
 764   foreach my $item (@items) {
 765     $self->get_item_cvpartnumber($item);
 766     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 767     my $row_as_html = $self->p->render('order/tabs/_row',
 768                                        ITEM => $item,
 769                                        ID   => $item_id,
 770                                        SELF => $self,
 771     );
 772
 773     if ($::form->{insert_before_item_id}) {
 774       $self->js
 775         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 776     } else {
 777       $self->js
 778         ->append('#row_table_id', $row_as_html);
 779     }
 780   }
 781
 782   $self->js
 783     ->run('kivi.Part.close_picker_dialogs')
 784     ->run('kivi.Order.init_row_handlers')
 785     ->run('kivi.Order.renumber_positions')
 786     ->focus('#add_item_parts_id_name');
 787
 788   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 789
 790   $self->js->render();
 791 }
 792
 793 sub action_update_exchangerate {
 794   my ($self) = @_;
 795
 796   my $data = {
 797     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 798     currency_name => $self->order->currency->name,
 799   };
 800
 801   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 802 }
 803
 804 # redisplay item rows if they are sorted by an attribute
 805 sub action_reorder_items {
 806   my ($self) = @_;
 807
 808   my %sort_keys = (
 809     partnumber   => sub { $_[0]->part->partnumber },
 810     description  => sub { $_[0]->description },
 811     qty          => sub { $_[0]->qty },
 812     sellprice    => sub { $_[0]->sellprice },
 813     discount     => sub { $_[0]->discount },
 814     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 815   );
 816
 817   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 818
 819   my $method = $sort_keys{$::form->{order_by}};
 820   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 821   if ($::form->{sort_dir}) {
 822     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 823       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 824     } else {
 825       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 826     }
 827   } else {
 828     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 829       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 830     } else {
 831       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 832     }
 833   }
 834   $self->js
 835     ->run('kivi.Order.redisplay_items', \@to_sort)
 836     ->render;
 837 }
 838
 839 # show the popup to choose a price/discount source
 840 sub action_price_popup {
 841   my ($self) = @_;
 842
 843   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 844   my $item = $self->order->items_sorted->[$idx];
 845
 846   $self->render_price_dialog($item);
 847 }
 848
 849 # save the order in a session variable and redirect to the part controller
 850 sub action_create_part {
 851   my ($self) = @_;
 852
 853   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
 854
 855   my $callback     = $self->url_for(
 856     action       => 'return_from_create_part',
 857     type         => $self->type, # type is needed for check_auth on return
 858     previousform => $previousform,
 859   );
 860
 861   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
 862
 863   my @redirect_params = (
 864     controller => 'Part',
 865     action     => 'add',
 866     part_type  => $::form->{add_item}->{create_part_type},
 867     callback   => $callback,
 868     show_abort => 1,
 869   );
 870
 871   $self->redirect_to(@redirect_params);
 872 }
 873
 874 sub action_return_from_create_part {
 875   my ($self) = @_;
 876
 877   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
 878
 879   $::auth->restore_form_from_session(delete $::form->{previousform});
 880
 881   # set item ids to new fake id, to identify them as new items
 882   foreach my $item (@{$self->order->items_sorted}) {
 883     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 884   }
 885
 886   $self->get_unalterable_data();
 887   $self->pre_render();
 888
 889   # trigger rendering values for second row/longdescription as hidden,
 890   # because they are loaded only on demand. So we need to keep the values
 891   # from the source.
 892   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
 893   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 894
 895   $self->render(
 896     'order/form',
 897     title => $self->get_title_for('edit'),
 898     %{$self->{template_args}}
 899   );
 900
 901 }
 902
 903 # load the second row for one or more items
 904 #
 905 # This action gets the html code for all items second rows by rendering a template for
 906 # the second row and sets the html code via client js.
 907 sub action_load_second_rows {
 908   my ($self) = @_;
 909
 910   foreach my $item_id (@{ $::form->{item_ids} }) {
 911     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 912     my $item = $self->order->items_sorted->[$idx];
 913
 914     $self->js_load_second_row($item, $item_id, 0);
 915   }
 916
 917   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 918
 919   $self->js->render();
 920 }
 921
 922 # update description, notes and sellprice from master data
 923 sub action_update_row_from_master_data {
 924   my ($self) = @_;
 925
 926   foreach my $item_id (@{ $::form->{item_ids} }) {
 927     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 928     my $item  = $self->order->items_sorted->[$idx];
 929     my $texts = get_part_texts($item->part, $self->order->language_id);
 930
 931     $item->description($texts->{description});
 932     $item->longdescription($texts->{longdescription});
 933
 934     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 935
 936     my $price_src;
 937     if ($item->part->is_assortment) {
 938     # add assortment items with price 0, as the components carry the price
 939       $price_src = $price_source->price_from_source("");
 940       $price_src->price(0);
 941     } else {
 942       $price_src = $price_source->best_price
 943                  ? $price_source->best_price
 944                  : $price_source->price_from_source("");
 945       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
 946       $price_src->price(0) if !$price_source->best_price;
 947     }
 948
 949
 950     $item->sellprice($price_src->price);
 951     $item->active_price_source($price_src);
 952
 953     $self->js
 954       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
 955       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
 956       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
 957       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
 958
 959     if ($self->search_cvpartnumber) {
 960       $self->get_item_cvpartnumber($item);
 961       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
 962     }
 963   }
 964
 965   $self->js_redisplay_line_values;
 966
 967   $self->js->render();
 968 }
 969
 970 sub js_load_second_row {
 971   my ($self, $item, $item_id, $do_parse) = @_;
 972
 973   if ($do_parse) {
 974     # Parse values from form (they are formated while rendering (template)).
 975     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 976     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
 977     foreach my $var (@{ $item->cvars_by_config }) {
 978       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 979     }
 980     $item->parse_custom_variable_values;
 981   }
 982
 983   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
 984
 985   $self->js
 986     ->html('#second_row_' . $item_id, $row_as_html)
 987     ->data('#second_row_' . $item_id, 'loaded', 1);
 988 }
 989
 990 sub js_redisplay_line_values {
 991   my ($self) = @_;
 992
 993   my $is_sales = $self->order->is_sales;
 994
 995   # sales orders with margins
 996   my @data;
 997   if ($is_sales) {
 998     @data = map {
 999       [
1000        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1001        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1002        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1003       ]} @{ $self->order->items_sorted };
1004   } else {
1005     @data = map {
1006       [
1007        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1008       ]} @{ $self->order->items_sorted };
1009   }
1010
1011   $self->js
1012     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1013 }
1014
1015 sub js_redisplay_cvpartnumbers {
1016   my ($self) = @_;
1017
1018   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1019
1020   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1021
1022   $self->js
1023     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1024 }
1025
1026 sub js_reset_order_and_item_ids_after_save {
1027   my ($self) = @_;
1028
1029   $self->js
1030     ->val('#id', $self->order->id)
1031     ->val('#converted_from_oe_id', '')
1032     ->val('#order_' . $self->nr_key(), $self->order->number);
1033
1034   my $idx = 0;
1035   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1036     next if !$self->order->items_sorted->[$idx]->id;
1037     next if $form_item_id !~ m{^new};
1038     $self->js
1039       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1040       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1041       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1042   } continue {
1043     $idx++;
1044   }
1045   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1046 }
1047
1048 #
1049 # helpers
1050 #
1051
1052 sub init_valid_types {
1053   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1054 }
1055
1056 sub init_type {
1057   my ($self) = @_;
1058
1059   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1060     die "Not a valid type for order";
1061   }
1062
1063   $self->type($::form->{type});
1064 }
1065
1066 sub init_cv {
1067   my ($self) = @_;
1068
1069   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1070          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1071          : die "Not a valid type for order";
1072
1073   return $cv;
1074 }
1075
1076 sub init_search_cvpartnumber {
1077   my ($self) = @_;
1078
1079   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1080   my $search_cvpartnumber;
1081   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1082   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1083
1084   return $search_cvpartnumber;
1085 }
1086
1087 sub init_show_update_button {
1088   my ($self) = @_;
1089
1090   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1091 }
1092
1093 sub init_p {
1094   SL::Presenter->get;
1095 }
1096
1097 sub init_order {
1098   $_[0]->make_order;
1099 }
1100
1101 sub init_all_price_factors {
1102   SL::DB::Manager::PriceFactor->get_all;
1103 }
1104
1105 sub init_part_picker_classification_ids {
1106   my ($self)    = @_;
1107   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1108
1109   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1110 }
1111
1112 sub check_auth {
1113   my ($self) = @_;
1114
1115   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1116
1117   my $right   = $right_for->{ $self->type };
1118   $right    ||= 'DOES_NOT_EXIST';
1119
1120   $::auth->assert($right);
1121 }
1122
1123 # build the selection box for contacts
1124 #
1125 # Needed, if customer/vendor changed.
1126 sub build_contact_select {
1127   my ($self) = @_;
1128
1129   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1130     value_key  => 'cp_id',
1131     title_key  => 'full_name_dep',
1132     default    => $self->order->cp_id,
1133     with_empty => 1,
1134     style      => 'width: 300px',
1135   );
1136 }
1137
1138 # build the selection box for shiptos
1139 #
1140 # Needed, if customer/vendor changed.
1141 sub build_shipto_select {
1142   my ($self) = @_;
1143
1144   select_tag('order.shipto_id',
1145              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1146              value_key  => 'shipto_id',
1147              title_key  => 'displayable_id',
1148              default    => $self->order->shipto_id,
1149              with_empty => 0,
1150              style      => 'width: 300px',
1151   );
1152 }
1153
1154 # build the inputs for the cusom shipto dialog
1155 #
1156 # Needed, if customer/vendor changed.
1157 sub build_shipto_inputs {
1158   my ($self) = @_;
1159
1160   my $content = $self->p->render('common/_ship_to_dialog',
1161                                  vc_obj      => $self->order->customervendor,
1162                                  cs_obj      => $self->order->custom_shipto,
1163                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1164                                  id_selector => '#order_shipto_id');
1165
1166   div_tag($content, id => 'shipto_inputs');
1167 }
1168
1169 # render the info line for business
1170 #
1171 # Needed, if customer/vendor changed.
1172 sub build_business_info_row
1173 {
1174   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1175 }
1176
1177
1178 sub render_price_dialog {
1179   my ($self, $record_item) = @_;
1180
1181   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1182
1183   $self->js
1184     ->run(
1185       'kivi.io.price_chooser_dialog',
1186       t8('Available Prices'),
1187       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1188     )
1189     ->reinit_widgets;
1190
1191 #   if (@errors) {
1192 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1193 #     $self->js->show('#dialog_flash_error');
1194 #   }
1195
1196   $self->js->render;
1197 }
1198
1199 sub load_order {
1200   my ($self) = @_;
1201
1202   return if !$::form->{id};
1203
1204   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1205
1206   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1207   # You need a custom shipto object to call cvars_by_config to get the cvars.
1208   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1209
1210   return $self->order;
1211 }
1212
1213 # load or create a new order object
1214 #
1215 # And assign changes from the form to this object.
1216 # If the order is loaded from db, check if items are deleted in the form,
1217 # remove them form the object and collect them for removing from db on saving.
1218 # Then create/update items from form (via make_item) and add them.
1219 sub make_order {
1220   my ($self) = @_;
1221
1222   # add_items adds items to an order with no items for saving, but they cannot
1223   # be retrieved via items until the order is saved. Adding empty items to new
1224   # order here solves this problem.
1225   my $order;
1226   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1227   $order ||= SL::DB::Order->new(orderitems  => [],
1228                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1229                                 currency_id => $::instance_conf->get_currency_id(),);
1230
1231   my $cv_id_method = $self->cv . '_id';
1232   if (!$::form->{id} && $::form->{$cv_id_method}) {
1233     $order->$cv_id_method($::form->{$cv_id_method});
1234     setup_order_from_cv($order);
1235   }
1236
1237   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1238
1239   $order->assign_attributes(%{$::form->{order}});
1240
1241   $self->setup_custom_shipto_from_form($order, $::form);
1242
1243   # remove deleted items
1244   $self->item_ids_to_delete([]);
1245   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1246     my $item = $order->orderitems->[$idx];
1247     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1248       splice @{$order->orderitems}, $idx, 1;
1249       push @{$self->item_ids_to_delete}, $item->id;
1250     }
1251   }
1252
1253   my @items;
1254   my $pos = 1;
1255   foreach my $form_attr (@{$form_orderitems}) {
1256     my $item = make_item($order, $form_attr);
1257     $item->position($pos);
1258     push @items, $item;
1259     $pos++;
1260   }
1261   $order->add_items(grep {!$_->id} @items);
1262
1263   return $order;
1264 }
1265
1266 # create or update items from form
1267 #
1268 # Make item objects from form values. For items already existing read from db.
1269 # Create a new item else. And assign attributes.
1270 sub make_item {
1271   my ($record, $attr) = @_;
1272
1273   my $item;
1274   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1275
1276   my $is_new = !$item;
1277
1278   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1279   # they cannot be retrieved via custom_variables until the order/orderitem is
1280   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1281   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1282
1283   $item->assign_attributes(%$attr);
1284
1285   if ($is_new) {
1286     my $texts = get_part_texts($item->part, $record->language_id);
1287     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1288     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1289     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1290   }
1291
1292   return $item;
1293 }
1294
1295 # create a new item
1296 #
1297 # This is used to add one item
1298 sub new_item {
1299   my ($record, $attr) = @_;
1300
1301   my $item = SL::DB::OrderItem->new;
1302
1303   # Remove attributes where the user left or set the inputs empty.
1304   # So these attributes will be undefined and we can distinguish them
1305   # from zero later on.
1306   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1307     delete $attr->{$_} if $attr->{$_} eq '';
1308   }
1309
1310   $item->assign_attributes(%$attr);
1311
1312   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1313   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1314
1315   $item->unit($part->unit) if !$item->unit;
1316
1317   my $price_src;
1318   if ( $part->is_assortment ) {
1319     # add assortment items with price 0, as the components carry the price
1320     $price_src = $price_source->price_from_source("");
1321     $price_src->price(0);
1322   } elsif (defined $item->sellprice) {
1323     $price_src = $price_source->price_from_source("");
1324     $price_src->price($item->sellprice);
1325   } else {
1326     $price_src = $price_source->best_price
1327                ? $price_source->best_price
1328                : $price_source->price_from_source("");
1329     $price_src->price(0) if !$price_source->best_price;
1330   }
1331
1332   my $discount_src;
1333   if (defined $item->discount) {
1334     $discount_src = $price_source->discount_from_source("");
1335     $discount_src->discount($item->discount);
1336   } else {
1337     $discount_src = $price_source->best_discount
1338                   ? $price_source->best_discount
1339                   : $price_source->discount_from_source("");
1340     $discount_src->discount(0) if !$price_source->best_discount;
1341   }
1342
1343   my %new_attr;
1344   $new_attr{part}                   = $part;
1345   $new_attr{description}            = $part->description     if ! $item->description;
1346   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1347   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1348   $new_attr{sellprice}              = $price_src->price;
1349   $new_attr{discount}               = $discount_src->discount;
1350   $new_attr{active_price_source}    = $price_src;
1351   $new_attr{active_discount_source} = $discount_src;
1352   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1353   $new_attr{project_id}             = $record->globalproject_id;
1354   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1355
1356   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1357   # they cannot be retrieved via custom_variables until the order/orderitem is
1358   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1359   $new_attr{custom_variables} = [];
1360
1361   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1362
1363   $item->assign_attributes(%new_attr, %{ $texts });
1364
1365   return $item;
1366 }
1367
1368 sub setup_order_from_cv {
1369   my ($order) = @_;
1370
1371   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1372
1373   $order->intnotes($order->customervendor->notes);
1374
1375   if ($order->is_sales) {
1376     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1377     $order->taxincluded(defined($order->customer->taxincluded_checked)
1378                         ? $order->customer->taxincluded_checked
1379                         : $::myconfig{taxincluded_checked});
1380   }
1381
1382 }
1383
1384 # setup custom shipto from form
1385 #
1386 # The dialog returns form variables starting with 'shipto' and cvars starting
1387 # with 'shiptocvar_'.
1388 # Mark it to be deleted if a shipto from master data is selected
1389 # (i.e. order has a shipto).
1390 # Else, update or create a new custom shipto. If the fields are empty, it
1391 # will not be saved on save.
1392 sub setup_custom_shipto_from_form {
1393   my ($self, $order, $form) = @_;
1394
1395   if ($order->shipto) {
1396     $self->is_custom_shipto_to_delete(1);
1397   } else {
1398     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1399
1400     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1401     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1402
1403     $custom_shipto->assign_attributes(%$shipto_attrs);
1404     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1405   }
1406 }
1407
1408 # get data for saving, printing, ..., that is not changed in the form
1409 #
1410 # Only cvars for now.
1411 sub get_unalterable_data {
1412   my ($self) = @_;
1413
1414   foreach my $item (@{ $self->order->items }) {
1415     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1416     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1417     foreach my $var (@{ $item->cvars_by_config }) {
1418       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1419     }
1420     $item->parse_custom_variable_values;
1421   }
1422 }
1423
1424 # delete the order
1425 #
1426 # And remove related files in the spool directory
1427 sub delete {
1428   my ($self) = @_;
1429
1430   my $errors = [];
1431   my $db     = $self->order->db;
1432
1433   $db->with_transaction(
1434     sub {
1435       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1436       $self->order->delete;
1437       my $spool = $::lx_office_conf{paths}->{spool};
1438       unlink map { "$spool/$_" } @spoolfiles if $spool;
1439
1440       $self->save_history('DELETED');
1441
1442       1;
1443   }) || push(@{$errors}, $db->error);
1444
1445   return $errors;
1446 }
1447
1448 # save the order
1449 #
1450 # And delete items that are deleted in the form.
1451 sub save {
1452   my ($self) = @_;
1453
1454   my $errors = [];
1455   my $db     = $self->order->db;
1456
1457   $db->with_transaction(sub {
1458     # delete custom shipto if it is to be deleted or if it is empty
1459     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1460       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1461       $self->order->custom_shipto(undef);
1462     }
1463
1464     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1465     $self->order->save(cascade => 1);
1466
1467     # link records
1468     if ($::form->{converted_from_oe_id}) {
1469       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1470       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1471         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1472         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1473         $src->link_to_record($self->order);
1474       }
1475       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1476         my $idx = 0;
1477         foreach (@{ $self->order->items_sorted }) {
1478           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1479           next if !$from_id;
1480           SL::DB::RecordLink->new(from_table => 'orderitems',
1481                                   from_id    => $from_id,
1482                                   to_table   => 'orderitems',
1483                                   to_id      => $_->id
1484           )->save;
1485           $idx++;
1486         }
1487       }
1488     }
1489
1490     $self->save_history('SAVED');
1491
1492     1;
1493   }) || push(@{$errors}, $db->error);
1494
1495   return $errors;
1496 }
1497
1498 sub workflow_sales_or_request_for_quotation {
1499   my ($self) = @_;
1500
1501   # always save
1502   my $errors = $self->save();
1503
1504   if (scalar @{ $errors }) {
1505     $self->js->flash('error', $_) for @{ $errors };
1506     return $self->js->render();
1507   }
1508
1509   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1510
1511   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1512   $self->{converted_from_oe_id} = delete $::form->{id};
1513
1514   # set item ids to new fake id, to identify them as new items
1515   foreach my $item (@{$self->order->items_sorted}) {
1516     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1517   }
1518
1519   # change form type
1520   $::form->{type} = $destination_type;
1521   $self->type($self->init_type);
1522   $self->cv  ($self->init_cv);
1523   $self->check_auth;
1524
1525   $self->get_unalterable_data();
1526   $self->pre_render();
1527
1528   # trigger rendering values for second row as hidden, because they
1529   # are loaded only on demand. So we need to keep the values from the
1530   # source.
1531   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1532
1533   $self->render(
1534     'order/form',
1535     title => $self->get_title_for('edit'),
1536     %{$self->{template_args}}
1537   );
1538 }
1539
1540 sub workflow_sales_or_purchase_order {
1541   my ($self) = @_;
1542
1543   # always save
1544   my $errors = $self->save();
1545
1546   if (scalar @{ $errors }) {
1547     $self->js->flash('error', $_) foreach @{ $errors };
1548     return $self->js->render();
1549   }
1550
1551   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1552                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1553                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1554                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1555                        : '';
1556
1557   # check for direct delivery
1558   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1559   my $custom_shipto;
1560   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1561       && $::form->{use_shipto} && $self->order->shipto) {
1562     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1563   }
1564
1565   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1566   $self->{converted_from_oe_id} = delete $::form->{id};
1567
1568   # set item ids to new fake id, to identify them as new items
1569   foreach my $item (@{$self->order->items_sorted}) {
1570     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1571   }
1572
1573   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1574     if ($::form->{use_shipto}) {
1575       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1576     } else {
1577       # remove any custom shipto if not wanted
1578       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1579     }
1580   }
1581
1582   # change form type
1583   $::form->{type} = $destination_type;
1584   $self->type($self->init_type);
1585   $self->cv  ($self->init_cv);
1586   $self->check_auth;
1587
1588   $self->get_unalterable_data();
1589   $self->pre_render();
1590
1591   # trigger rendering values for second row as hidden, because they
1592   # are loaded only on demand. So we need to keep the values from the
1593   # source.
1594   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1595
1596   $self->render(
1597     'order/form',
1598     title => $self->get_title_for('edit'),
1599     %{$self->{template_args}}
1600   );
1601 }
1602
1603
1604 sub pre_render {
1605   my ($self) = @_;
1606
1607   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1608   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1609   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1610   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1611   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1612                                                                                               deleted => 0 ] ],
1613                                                                            sort_by => 'name');
1614   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1615                                                                                               deleted => 0 ] ],
1616                                                                            sort_by => 'name');
1617   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1618                                                                                                         obsolete => 0 ] ]);
1619   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1620   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1621   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1622   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1623
1624   my $print_form = Form->new('');
1625   $print_form->{type}        = $self->type;
1626   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1627   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1628     form => $print_form,
1629     options => {dialog_name_prefix => 'print_options.',
1630                 show_headers       => 1,
1631                 no_queue           => 1,
1632                 no_postscript      => 1,
1633                 no_opendocument    => 0,
1634                 no_html            => 1},
1635   );
1636
1637   foreach my $item (@{$self->order->orderitems}) {
1638     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1639     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1640     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1641   }
1642
1643   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1644     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1645     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1646     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1647     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1648   }
1649
1650   if ($self->order->number && $::instance_conf->get_webdav) {
1651     my $webdav = SL::Webdav->new(
1652       type     => $self->type,
1653       number   => $self->order->number,
1654     );
1655     my @all_objects = $webdav->get_all_objects;
1656     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1657                                                     type => t8('File'),
1658                                                     link => File::Spec->catfile($_->full_filedescriptor),
1659                                                 } } @all_objects;
1660   }
1661
1662   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1663
1664   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1665                                                          calculate_qty kivi.Validator follow_up show_history);
1666   $self->setup_edit_action_bar;
1667 }
1668
1669 sub setup_edit_action_bar {
1670   my ($self, %params) = @_;
1671
1672   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1673                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1674                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1675
1676   for my $bar ($::request->layout->get('actionbar')) {
1677     $bar->add(
1678       combobox => [
1679         action => [
1680           t8('Save'),
1681           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1682                                                     $::instance_conf->get_order_warn_no_deliverydate,
1683                                                                                                       ],
1684         ],
1685         action => [
1686           t8('Save as new'),
1687           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1688           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1689         ],
1690       ], # end of combobox "Save"
1691
1692       combobox => [
1693         action => [
1694           t8('Workflow'),
1695         ],
1696         action => [
1697           t8('Save and Quotation'),
1698           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1699           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1700         ],
1701         action => [
1702           t8('Save and RFQ'),
1703           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1704           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1705         ],
1706         action => [
1707           t8('Save and Sales Order'),
1708           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1709           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1710         ],
1711         action => [
1712           t8('Save and Purchase Order'),
1713           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1714           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1715         ],
1716         action => [
1717           t8('Save and Delivery Order'),
1718           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1719                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1720                                                                                                                         ],
1721           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1722         ],
1723         action => [
1724           t8('Save and Invoice'),
1725           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1726         ],
1727         action => [
1728           t8('Save and AP Transaction'),
1729           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1730           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1731         ],
1732
1733       ], # end of combobox "Workflow"
1734
1735       combobox => [
1736         action => [
1737           t8('Export'),
1738         ],
1739         action => [
1740           t8('Save and preview PDF'),
1741            call => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
1742                                                        $::instance_conf->get_order_warn_no_deliverydate,
1743                                                                                                          ],
1744         ],
1745         action => [
1746           t8('Save and print'),
1747           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
1748                                                      $::instance_conf->get_order_warn_no_deliverydate,
1749                                                                                                       ],
1750         ],
1751         action => [
1752           t8('Save and E-mail'),
1753           id   => 'save_and_email_action',
1754           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
1755                                                                      $::instance_conf->get_order_warn_no_deliverydate,
1756                   ],
1757           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1758         ],
1759         action => [
1760           t8('Download attachments of all parts'),
1761           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1762           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1763           only_if  => $::instance_conf->get_doc_storage,
1764         ],
1765       ], # end of combobox "Export"
1766
1767       action => [
1768         t8('Delete'),
1769         call     => [ 'kivi.Order.delete_order' ],
1770         confirm  => $::locale->text('Do you really want to delete this object?'),
1771         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1772         only_if  => $deletion_allowed,
1773       ],
1774
1775       combobox => [
1776         action => [
1777           t8('more')
1778         ],
1779         action => [
1780           t8('Follow-Up'),
1781           call     => [ 'kivi.Order.follow_up_window' ],
1782           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1783           only_if  => $::auth->assert('productivity', 1),
1784         ],
1785         action => [
1786           t8('History'),
1787           call     => [ 'set_history_window', $self->order->id, 'id' ],
1788           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
1789         ],
1790       ], # end of combobox "more"
1791     );
1792   }
1793 }
1794
1795 sub generate_pdf {
1796   my ($order, $pdf_ref, $params) = @_;
1797
1798   my @errors = ();
1799
1800   my $print_form = Form->new('');
1801   $print_form->{type}        = $order->type;
1802   $print_form->{formname}    = $params->{formname} || $order->type;
1803   $print_form->{format}      = $params->{format}   || 'pdf';
1804   $print_form->{media}       = $params->{media}    || 'file';
1805   $print_form->{groupitems}  = $params->{groupitems};
1806   $print_form->{printer_id}  = $params->{printer_id};
1807   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1808
1809   $order->language($params->{language});
1810   $order->flatten_to_form($print_form, format_amounts => 1);
1811
1812   my $template_ext;
1813   my $template_type;
1814   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1815     $template_ext  = 'odt';
1816     $template_type = 'OpenDocument';
1817   }
1818
1819   # search for the template
1820   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1821     name        => $print_form->{formname},
1822     extension   => $template_ext,
1823     email       => $print_form->{media} eq 'email',
1824     language    => $params->{language},
1825     printer_id  => $print_form->{printer_id},
1826   );
1827
1828   if (!defined $template_file) {
1829     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1830   }
1831
1832   return @errors if scalar @errors;
1833
1834   $print_form->throw_on_error(sub {
1835     eval {
1836       $print_form->prepare_for_printing;
1837
1838       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1839         format        => $print_form->{format},
1840         template_type => $template_type,
1841         template      => $template_file,
1842         variables     => $print_form,
1843         variable_content_types => {
1844           longdescription => 'html',
1845           partnotes       => 'html',
1846           notes           => 'html',
1847         },
1848       );
1849       1;
1850     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1851   });
1852
1853   return @errors;
1854 }
1855
1856 sub get_files_for_email_dialog {
1857   my ($self) = @_;
1858
1859   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1860
1861   return %files if !$::instance_conf->get_doc_storage;
1862
1863   if ($self->order->id) {
1864     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1865     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1866     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1867     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
1868   }
1869
1870   my @parts =
1871     uniq_by { $_->{id} }
1872     map {
1873       +{ id         => $_->part->id,
1874          partnumber => $_->part->partnumber }
1875     } @{$self->order->items_sorted};
1876
1877   foreach my $part (@parts) {
1878     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1879     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1880   }
1881
1882   foreach my $key (keys %files) {
1883     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1884   }
1885
1886   return %files;
1887 }
1888
1889 sub get_title_for {
1890   my ($self, $action) = @_;
1891
1892   return '' if none { lc($action)} qw(add edit);
1893
1894   # for locales:
1895   # $::locale->text("Add Sales Order");
1896   # $::locale->text("Add Purchase Order");
1897   # $::locale->text("Add Quotation");
1898   # $::locale->text("Add Request for Quotation");
1899   # $::locale->text("Edit Sales Order");
1900   # $::locale->text("Edit Purchase Order");
1901   # $::locale->text("Edit Quotation");
1902   # $::locale->text("Edit Request for Quotation");
1903
1904   $action = ucfirst(lc($action));
1905   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
1906        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
1907        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
1908        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
1909        : '';
1910 }
1911
1912 sub get_item_cvpartnumber {
1913   my ($self, $item) = @_;
1914
1915   return if !$self->search_cvpartnumber;
1916   return if !$self->order->customervendor;
1917
1918   if ($self->cv eq 'vendor') {
1919     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
1920     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
1921   } elsif ($self->cv eq 'customer') {
1922     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
1923     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
1924   }
1925 }
1926
1927 sub get_part_texts {
1928   my ($part_or_id, $language_or_id, %defaults) = @_;
1929
1930   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
1931   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
1932   my $texts       = {
1933     description     => $defaults{description}     // $part->description,
1934     longdescription => $defaults{longdescription} // $part->notes,
1935   };
1936
1937   return $texts unless $language_id;
1938
1939   my $translation = SL::DB::Manager::Translation->get_first(
1940     where => [
1941       parts_id    => $part->id,
1942       language_id => $language_id,
1943     ]);
1944
1945   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
1946   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
1947
1948   return $texts;
1949 }
1950
1951 sub sales_order_type {
1952   'sales_order';
1953 }
1954
1955 sub purchase_order_type {
1956   'purchase_order';
1957 }
1958
1959 sub sales_quotation_type {
1960   'sales_quotation';
1961 }
1962
1963 sub request_quotation_type {
1964   'request_quotation';
1965 }
1966
1967 sub nr_key {
1968   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
1969        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
1970        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
1971        : $_[0]->type eq request_quotation_type() ? 'quonumber'
1972        : '';
1973 }
1974
1975 sub save_and_redirect_to {
1976   my ($self, %params) = @_;
1977
1978   my $errors = $self->save();
1979
1980   if (scalar @{ $errors }) {
1981     $self->js->flash('error', $_) foreach @{ $errors };
1982     return $self->js->render();
1983   }
1984
1985   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
1986            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
1987            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
1988            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
1989            : '';
1990   flash_later('info', $text);
1991
1992   $self->redirect_to(%params, id => $self->order->id);
1993 }
1994
1995 sub save_history {
1996   my ($self, $addition) = @_;
1997
1998   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
1999   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2000
2001   SL::DB::History->new(
2002     trans_id    => $self->order->id,
2003     employee_id => SL::DB::Manager::Employee->current->id,
2004     what_done   => $self->order->type,
2005     snumbers    => $snumbers,
2006     addition    => $addition,
2007   )->save;
2008 }
2009
2010 sub store_pdf_to_webdav_and_filemanagement {
2011   my($order, $content, $filename) = @_;
2012
2013   my @errors;
2014
2015   # copy file to webdav folder
2016   if ($order->number && $::instance_conf->get_webdav_documents) {
2017     my $webdav = SL::Webdav->new(
2018       type     => $order->type,
2019       number   => $order->number,
2020     );
2021     my $webdav_file = SL::Webdav::File->new(
2022       webdav   => $webdav,
2023       filename => $filename,
2024     );
2025     eval {
2026       $webdav_file->store(data => \$content);
2027       1;
2028     } or do {
2029       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2030     };
2031   }
2032   if ($order->id && $::instance_conf->get_doc_storage) {
2033     eval {
2034       SL::File->save(object_id     => $order->id,
2035                      object_type   => $order->type,
2036                      mime_type     => 'application/pdf',
2037                      source        => 'created',
2038                      file_type     => 'document',
2039                      file_name     => $filename,
2040                      file_contents => $content);
2041       1;
2042     } or do {
2043       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2044     };
2045   }
2046
2047   return @errors;
2048 }
2049
2050 1;
2051
2052 __END__
2053
2054 =encoding utf-8
2055
2056 =head1 NAME
2057
2058 SL::Controller::Order - controller for orders
2059
2060 =head1 SYNOPSIS
2061
2062 This is a new form to enter orders, completely rewritten with the use
2063 of controller and java script techniques.
2064
2065 The aim is to provide the user a better experience and a faster workflow. Also
2066 the code should be more readable, more reliable and better to maintain.
2067
2068 =head2 Key Features
2069
2070 =over 4
2071
2072 =item *
2073
2074 One input row, so that input happens every time at the same place.
2075
2076 =item *
2077
2078 Use of pickers where possible.
2079
2080 =item *
2081
2082 Possibility to enter more than one item at once.
2083
2084 =item *
2085
2086 Item list in a scrollable area, so that the workflow buttons stay at
2087 the bottom.
2088
2089 =item *
2090
2091 Reordering item rows with drag and drop is possible. Sorting item rows is
2092 possible (by partnumber, description, qty, sellprice and discount for now).
2093
2094 =item *
2095
2096 No C<update> is necessary. All entries and calculations are managed
2097 with ajax-calls and the page only reloads on C<save>.
2098
2099 =item *
2100
2101 User can see changes immediately, because of the use of java script
2102 and ajax.
2103
2104 =back
2105
2106 =head1 CODE
2107
2108 =head2 Layout
2109
2110 =over 4
2111
2112 =item * C<SL/Controller/Order.pm>
2113
2114 the controller
2115
2116 =item * C<template/webpages/order/form.html>
2117
2118 main form
2119
2120 =item * C<template/webpages/order/tabs/basic_data.html>
2121
2122 Main tab for basic_data.
2123
2124 This is the only tab here for now. "linked records" and "webdav" tabs are
2125 reused from generic code.
2126
2127 =over 4
2128
2129 =item * C<template/webpages/order/tabs/_business_info_row.html>
2130
2131 For displaying information on business type
2132
2133 =item * C<template/webpages/order/tabs/_item_input.html>
2134
2135 The input line for items
2136
2137 =item * C<template/webpages/order/tabs/_row.html>
2138
2139 One row for already entered items
2140
2141 =item * C<template/webpages/order/tabs/_tax_row.html>
2142
2143 Displaying tax information
2144
2145 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2146
2147 Dialog for selecting price and discount sources
2148
2149 =back
2150
2151 =item * C<js/kivi.Order.js>
2152
2153 java script functions
2154
2155 =back
2156
2157 =head1 TODO
2158
2159 =over 4
2160
2161 =item * testing
2162
2163 =item * price sources: little symbols showing better price / better discount
2164
2165 =item * select units in input row?
2166
2167 =item * check for direct delivery (workflow sales order -> purchase order)
2168
2169 =item * access rights
2170
2171 =item * display weights
2172
2173 =item * mtime check
2174
2175 =item * optional client/user behaviour
2176
2177 (transactions has to be set - department has to be set -
2178  force project if enabled in client config - transport cost reminder)
2179
2180 =back
2181
2182 =head1 KNOWN BUGS AND CAVEATS
2183
2184 =over 4
2185
2186 =item *
2187
2188 Customer discount is not displayed as a valid discount in price source popup
2189 (this might be a bug in price sources)
2190
2191 (I cannot reproduce this (Bernd))
2192
2193 =item *
2194
2195 No indication that <shift>-up/down expands/collapses second row.
2196
2197 =item *
2198
2199 Inline creation of parts is not currently supported
2200
2201 =item *
2202
2203 Table header is not sticky in the scrolling area.
2204
2205 =item *
2206
2207 Sorting does not include C<position>, neither does reordering.
2208
2209 This behavior was implemented intentionally. But we can discuss, which behavior
2210 should be implemented.
2211
2212 =back
2213
2214 =head1 To discuss / Nice to have
2215
2216 =over 4
2217
2218 =item *
2219
2220 How to expand/collapse second row. Now it can be done clicking the icon or
2221 <shift>-up/down.
2222
2223 =item *
2224
2225 Possibility to select PriceSources in input row?
2226
2227 =item *
2228
2229 This controller uses a (changed) copy of the template for the PriceSource
2230 dialog. Maybe there could be used one code source.
2231
2232 =item *
2233
2234 Rounding-differences between this controller (PriceTaxCalculator) and the old
2235 form. This is not only a problem here, but also in all parts using the PTC.
2236 There exists a ticket and a patch. This patch should be testet.
2237
2238 =item *
2239
2240 An indicator, if the actual inputs are saved (like in an
2241 editor or on text processing application).
2242
2243 =item *
2244
2245 A warning when leaving the page without saveing unchanged inputs.
2246
2247
2248 =back
2249
2250 =head1 AUTHOR
2251
2252 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2253
2254 =cut