SL/Controller/DeliveryOrder.pm

   1 package SL::Controller::DeliveryOrder;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Helper::Number qw(_format_number _parse_number);
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Presenter::DeliveryOrder qw(delivery_order_status_line);
  10 use SL::Locale::String qw(t8);
  11 use SL::SessionFile::Random;
  12 use SL::PriceSource;
  13 use SL::Webdav;
  14 use SL::File;
  15 use SL::MIME;
  16 use SL::Util qw(trim);
  17 use SL::YAML;
  18 use SL::DB::History;
  19 use SL::DB::Order;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22 use SL::DB::Order;
  23 use SL::DB::Part;
  24 use SL::DB::PartClassification;
  25 use SL::DB::PartsGroup;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28 use SL::DB::RecordLink;
  29 use SL::DB::Shipto;
  30 use SL::DB::Translation;
  31 use SL::DB::TransferType;
  32
  33 use SL::Helper::CreatePDF qw(:all);
  34 use SL::Helper::PrintOptions;
  35 use SL::Helper::ShippedQty;
  36 use SL::Helper::UserPreferences::PositionsScrollbar;
  37 use SL::Helper::UserPreferences::UpdatePositions;
  38
  39 use SL::Controller::Helper::GetModels;
  40 use SL::Controller::DeliveryOrder::TypeData qw(:types);
  41
  42 use List::Util qw(first sum0);
  43 use List::UtilsBy qw(sort_by uniq_by);
  44 use List::MoreUtils qw(any none pairwise first_index);
  45 use English qw(-no_match_vars);
  46 use File::Spec;
  47 use Cwd;
  48 use Sort::Naturally;
  49
  50 use Rose::Object::MakeMethods::Generic
  51 (
  52  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  53  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids type_data) ],
  54 );
  55
  56
  57 # safety
  58 __PACKAGE__->run_before('check_auth',
  59                         except => [ qw(update_stock_information) ]);
  60
  61 __PACKAGE__->run_before('get_unalterable_data',
  62                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  63                                      print send_email) ]);
  64
  65 #
  66 # actions
  67 #
  68
  69 # add a new order
  70 sub action_add {
  71   my ($self) = @_;
  72
  73   $self->order->transdate(DateTime->now_local());
  74   $self->type_data->set_reqdate_by_type;
  75
  76
  77   $self->pre_render();
  78   $self->render(
  79     'delivery_order/form',
  80     title => $self->get_title_for('add'),
  81     %{$self->{template_args}}
  82   );
  83 }
  84
  85 sub action_add_from_order {
  86   my ($self) = @_;
  87   # this interfers with init_order
  88   $self->{converted_from_oe_id} = delete $::form->{id};
  89
  90   $self->type_data->validate($::form->{type});
  91
  92   my $order = SL::DB::Order->new(id => $self->{converted_from_oe_id})->load;
  93
  94   $self->order(SL::DB::DeliveryOrder->new_from($order, type => $::form->{type}));
  95
  96   $self->action_add;
  97 }
  98
  99 # edit an existing order
 100 sub action_edit {
 101   my ($self) = @_;
 102
 103   if ($::form->{id}) {
 104     $self->load_order;
 105
 106   } else {
 107     # this is to edit an order from an unsaved order object
 108
 109     # set item ids to new fake id, to identify them as new items
 110     foreach my $item (@{$self->order->items_sorted}) {
 111       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 112     }
 113     # trigger rendering values for second row as hidden, because they
 114     # are loaded only on demand. So we need to keep the values from
 115     # the source.
 116     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 117   }
 118
 119   $self->pre_render();
 120   $self->render(
 121     'delivery_order/form',
 122     title => $self->get_title_for('edit'),
 123     %{$self->{template_args}}
 124   );
 125 }
 126
 127 # edit a collective order (consisting of one or more existing orders)
 128 sub action_edit_collective {
 129   my ($self) = @_;
 130
 131   # collect order ids
 132   my @multi_ids = map {
 133     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 134   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 135
 136   # fall back to add if no ids are given
 137   if (scalar @multi_ids == 0) {
 138     $self->action_add();
 139     return;
 140   }
 141
 142   # fall back to save as new if only one id is given
 143   if (scalar @multi_ids == 1) {
 144     $self->order(SL::DB::DeliveryOrder->new(id => $multi_ids[0])->load);
 145     $self->action_save_as_new();
 146     return;
 147   }
 148
 149   # make new order from given orders
 150   my @multi_orders = map { SL::DB::DeliveryOrder->new(id => $_)->load } @multi_ids;
 151   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 152   $self->order(SL::DB::DeliveryOrder->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 153
 154   $self->action_edit();
 155 }
 156
 157 # delete the order
 158 sub action_delete {
 159   my ($self) = @_;
 160
 161   my $errors = $self->delete();
 162
 163   if (scalar @{ $errors }) {
 164     $self->js->flash('error', $_) foreach @{ $errors };
 165     return $self->js->render();
 166   }
 167
 168   flash_later('info', $self->type_data->text("delete"));
 169
 170   my @redirect_params = (
 171     action => 'add',
 172     type   => $self->type,
 173   );
 174
 175   $self->redirect_to(@redirect_params);
 176 }
 177
 178 # save the order
 179 sub action_save {
 180   my ($self) = @_;
 181
 182   my $errors = $self->save();
 183
 184   if (scalar @{ $errors }) {
 185     $self->js->flash('error', $_) foreach @{ $errors };
 186     return $self->js->render();
 187   }
 188
 189   flash_later('info', $self->type_data->text("saved"));
 190
 191   my @redirect_params = (
 192     action => 'edit',
 193     type   => $self->type,
 194     id     => $self->order->id,
 195   );
 196
 197   $self->redirect_to(@redirect_params);
 198 }
 199
 200 # save the order as new document an open it for edit
 201 sub action_save_as_new {
 202   my ($self) = @_;
 203
 204   my $order = $self->order;
 205
 206   if (!$order->id) {
 207     $self->js->flash('error', t8('This object has not been saved yet.'));
 208     return $self->js->render();
 209   }
 210
 211   # load order from db to check if values changed
 212   my $saved_order = SL::DB::DeliveryOrder->new(id => $order->id)->load;
 213
 214   my %new_attrs;
 215   # Lets assign a new number if the user hasn't changed the previous one.
 216   # If it has been changed manually then use it as-is.
 217   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 218                         ? ''
 219                         : trim($order->number);
 220
 221   # Clear transdate unless changed
 222   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 223                         ? DateTime->today_local
 224                         : $order->transdate;
 225
 226   # Set new reqdate unless changed if it is enabled in client config
 227   $new_attrs{reqdate} = $self->type_data->get_reqdate_by_type($order->reqdate, $saved_order->reqdate);
 228
 229   # Update employee
 230   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 231
 232   # Create new record from current one
 233   $self->order(SL::DB::DeliveryOrder->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 234
 235   # no linked records on save as new
 236   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 237
 238   # save
 239   $self->action_save();
 240 }
 241
 242 # print the order
 243 #
 244 # This is called if "print" is pressed in the print dialog.
 245 # If PDF creation was requested and succeeded, the pdf is offered for download
 246 # via send_file (which uses ajax in this case).
 247 sub action_print {
 248   my ($self) = @_;
 249
 250   my $errors = $self->save();
 251
 252   if (scalar @{ $errors }) {
 253     $self->js->flash('error', $_) foreach @{ $errors };
 254     return $self->js->render();
 255   }
 256
 257   $self->js_reset_order_and_item_ids_after_save;
 258
 259   my $format      = $::form->{print_options}->{format};
 260   my $media       = $::form->{print_options}->{media};
 261   my $formname    = $::form->{print_options}->{formname};
 262   my $copies      = $::form->{print_options}->{copies};
 263   my $groupitems  = $::form->{print_options}->{groupitems};
 264   my $printer_id  = $::form->{print_options}->{printer_id};
 265
 266   # only pdf and opendocument by now
 267   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 268     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 269   }
 270
 271   # only screen or printer by now
 272   if (none { $media eq $_ } qw(screen printer)) {
 273     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 274   }
 275
 276   # create a form for generate_attachment_filename
 277   my $form   = Form->new;
 278   $form->{$self->nr_key()}  = $self->order->number;
 279   $form->{type}             = $self->type;
 280   $form->{format}           = $format;
 281   $form->{formname}         = $formname;
 282   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 283   my $pdf_filename          = $form->generate_attachment_filename();
 284
 285   my $pdf;
 286   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 287                                                    formname   => $formname,
 288                                                    language   => $self->order->language,
 289                                                    printer_id => $printer_id,
 290                                                    groupitems => $groupitems });
 291   if (scalar @errors) {
 292     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 293   }
 294
 295   if ($media eq 'screen') {
 296     # screen/download
 297     $self->js->flash('info', t8('The PDF has been created'));
 298     $self->send_file(
 299       \$pdf,
 300       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 301       name         => $pdf_filename,
 302       js_no_render => 1,
 303     );
 304
 305   } elsif ($media eq 'printer') {
 306     # printer
 307     my $printer_id = $::form->{print_options}->{printer_id};
 308     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 309       copies  => $copies,
 310       content => $pdf,
 311     );
 312
 313     $self->js->flash('info', t8('The PDF has been printed'));
 314   }
 315
 316   my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $pdf_filename);
 317   if (scalar @warnings) {
 318     $self->js->flash('warning', $_) for @warnings;
 319   }
 320
 321   $self->save_history('PRINTED');
 322
 323   $self->js
 324     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 325     ->render;
 326 }
 327 sub action_preview_pdf {
 328   my ($self) = @_;
 329
 330   my $errors = $self->save();
 331   if (scalar @{ $errors }) {
 332     $self->js->flash('error', $_) foreach @{ $errors };
 333     return $self->js->render();
 334   }
 335
 336   $self->js_reset_order_and_item_ids_after_save;
 337
 338   my $format      = 'pdf';
 339   my $media       = 'screen';
 340   my $formname    = $self->type;
 341
 342   # only pdf
 343   # create a form for generate_attachment_filename
 344   my $form   = Form->new;
 345   $form->{$self->nr_key()}  = $self->order->number;
 346   $form->{type}             = $self->type;
 347   $form->{format}           = $format;
 348   $form->{formname}         = $formname;
 349   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 350   my $pdf_filename          = $form->generate_attachment_filename();
 351
 352   my $pdf;
 353   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 354                                                    formname   => $formname,
 355                                                    language   => $self->order->language,
 356                                                  });
 357   if (scalar @errors) {
 358     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 359   }
 360   $self->save_history('PREVIEWED');
 361   $self->js->flash('info', t8('The PDF has been previewed'));
 362   # screen/download
 363   $self->send_file(
 364     \$pdf,
 365     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 366     name         => $pdf_filename,
 367     js_no_render => 0,
 368   );
 369 }
 370
 371 # open the email dialog
 372 sub action_save_and_show_email_dialog {
 373   my ($self) = @_;
 374
 375   my $errors = $self->save();
 376
 377   if (scalar @{ $errors }) {
 378     $self->js->flash('error', $_) foreach @{ $errors };
 379     return $self->js->render();
 380   }
 381
 382   my $cv_method = $self->cv;
 383
 384   if (!$self->order->$cv_method) {
 385     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 386                     ->render($self);
 387   }
 388
 389   my $email_form;
 390   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 391   $email_form->{to} ||= $self->order->$cv_method->email;
 392   $email_form->{cc}   = $self->order->$cv_method->cc;
 393   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 394   # Todo: get addresses from shipto, if any
 395
 396   my $form = Form->new;
 397   $form->{$self->nr_key()}  = $self->order->number;
 398   $form->{cusordnumber}     = $self->order->cusordnumber;
 399   $form->{formname}         = $self->type;
 400   $form->{type}             = $self->type;
 401   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 402   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 403   $form->{format}           = 'pdf';
 404   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 405
 406   $email_form->{subject}             = $form->generate_email_subject();
 407   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 408   $email_form->{message}             = $form->generate_email_body();
 409   $email_form->{js_send_function}    = 'kivi.DeliveryOrder.send_email()';
 410
 411   my %files = $self->get_files_for_email_dialog();
 412   $self->{all_employees} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 413   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 414                                   email_form  => $email_form,
 415                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 416                                   FILES       => \%files,
 417                                   is_customer => $self->type_data->is_customer,
 418                                   ALL_EMPLOYEES => $self->{all_employees},
 419   );
 420
 421   $self->js
 422       ->run('kivi.DeliveryOrder.show_email_dialog', $dialog_html)
 423       ->reinit_widgets
 424       ->render($self);
 425 }
 426
 427 # send email
 428 #
 429 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 430 sub action_send_email {
 431   my ($self) = @_;
 432
 433   my $errors = $self->save();
 434
 435   if (scalar @{ $errors }) {
 436     $self->js->run('kivi.DeliveryOrder.close_email_dialog');
 437     $self->js->flash('error', $_) foreach @{ $errors };
 438     return $self->js->render();
 439   }
 440
 441   $self->js_reset_order_and_item_ids_after_save;
 442
 443   my $email_form  = delete $::form->{email_form};
 444   my %field_names = (to => 'email');
 445
 446   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 447
 448   # for Form::cleanup which may be called in Form::send_email
 449   $::form->{cwd}    = getcwd();
 450   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 451
 452   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 453   $::form->{media}  = 'email';
 454
 455   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 456     my $pdf;
 457     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 458                                                     format     => $::form->{print_options}->{format},
 459                                                     formname   => $::form->{print_options}->{formname},
 460                                                     language   => $self->order->language,
 461                                                     printer_id => $::form->{print_options}->{printer_id},
 462                                                     groupitems => $::form->{print_options}->{groupitems}});
 463     if (scalar @errors) {
 464       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 465     }
 466
 467     my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $::form->{attachment_filename});
 468     if (scalar @warnings) {
 469       flash_later('warning', $_) for @warnings;
 470     }
 471
 472     my $sfile = SL::SessionFile::Random->new(mode => "w");
 473     $sfile->fh->print($pdf);
 474     $sfile->fh->close;
 475
 476     $::form->{tmpfile} = $sfile->file_name;
 477     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 478   }
 479
 480   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 481   $::form->send_email(\%::myconfig, 'pdf');
 482
 483   # internal notes
 484   my $intnotes = $self->order->intnotes;
 485   $intnotes   .= "\n\n" if $self->order->intnotes;
 486   $intnotes   .= t8('[email]')                                                                                        . "\n";
 487   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 488   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 489   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 490   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 491   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 492   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 493
 494   $self->order->update_attributes(intnotes => $intnotes);
 495
 496   $self->save_history('MAILED');
 497
 498   flash_later('info', t8('The email has been sent.'));
 499
 500   my @redirect_params = (
 501     action => 'edit',
 502     type   => $self->type,
 503     id     => $self->order->id,
 504   );
 505
 506   $self->redirect_to(@redirect_params);
 507 }
 508
 509 # save the order and redirect to the frontend subroutine for a new
 510 # delivery order
 511 sub action_save_and_delivery_order {
 512   my ($self) = @_;
 513
 514   $self->save_and_redirect_to(
 515     controller => 'oe.pl',
 516     action     => 'oe_delivery_order_from_order',
 517   );
 518 }
 519
 520 # save the order and redirect to the frontend subroutine for a new
 521 # invoice
 522 sub action_save_and_invoice {
 523   my ($self) = @_;
 524
 525   $self->save_and_redirect_to(
 526     controller => 'oe.pl',
 527     action     => 'oe_invoice_from_order',
 528   );
 529 }
 530
 531 # workflow from sales order to sales quotation
 532 sub action_sales_quotation {
 533   $_[0]->workflow_sales_or_request_for_quotation();
 534 }
 535
 536 # workflow from sales order to sales quotation
 537 sub action_request_for_quotation {
 538   $_[0]->workflow_sales_or_request_for_quotation();
 539 }
 540
 541 # workflow from sales quotation to sales order
 542 sub action_sales_order {
 543   $_[0]->workflow_sales_or_purchase_order();
 544 }
 545
 546 # workflow from rfq to purchase order
 547 sub action_purchase_order {
 548   $_[0]->workflow_sales_or_purchase_order();
 549 }
 550
 551 # workflow from purchase order to ap transaction
 552 sub action_save_and_ap_transaction {
 553   my ($self) = @_;
 554
 555   $self->save_and_redirect_to(
 556     controller => 'ap.pl',
 557     action     => 'add_from_purchase_order',
 558   );
 559 }
 560
 561 # set form elements in respect to a changed customer or vendor
 562 #
 563 # This action is called on an change of the customer/vendor picker.
 564 sub action_customer_vendor_changed {
 565   my ($self) = @_;
 566
 567   setup_order_from_cv($self->order);
 568
 569   my $cv_method = $self->cv;
 570
 571   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 572     $self->js->show('#cp_row');
 573   } else {
 574     $self->js->hide('#cp_row');
 575   }
 576
 577   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 578     $self->js->show('#shipto_selection');
 579   } else {
 580     $self->js->hide('#shipto_selection');
 581   }
 582
 583   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 584
 585   $self->js
 586     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 587     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 588     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 589     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 590     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 591     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 592     ->val(        '#order_currency_id',      $self->order->currency_id)
 593     ->val(        '#order_payment_id',       $self->order->payment_id)
 594     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 595     ->val(        '#order_intnotes',         $self->order->intnotes)
 596     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 597     ->focus(      '#order_' . $self->cv . '_id')
 598     ->run('kivi.DeliveryOrder.update_exchangerate');
 599
 600   $self->js_redisplay_cvpartnumbers;
 601   $self->js->render();
 602 }
 603
 604 # open the dialog for customer/vendor details
 605 sub action_show_customer_vendor_details_dialog {
 606   my ($self) = @_;
 607
 608   my $is_customer = 'customer' eq $::form->{vc};
 609   my $cv;
 610   if ($is_customer) {
 611     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 612   } else {
 613     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 614   }
 615
 616   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 617   $details{discount_as_percent} = $cv->discount_as_percent;
 618   $details{creditlimt}          = $cv->creditlimit_as_number;
 619   $details{business}            = $cv->business->description      if $cv->business;
 620   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 621   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 622   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 623   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 624
 625   foreach my $entry (@{ $cv->shipto }) {
 626     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 627   }
 628   foreach my $entry (@{ $cv->contacts }) {
 629     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 630   }
 631
 632   $_[0]->render('common/show_vc_details', { layout => 0 },
 633                 is_customer => $is_customer,
 634                 %details);
 635
 636 }
 637
 638 # called if a unit in an existing item row is changed
 639 sub action_unit_changed {
 640   my ($self) = @_;
 641
 642   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 643   my $item = $self->order->items_sorted->[$idx];
 644
 645   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 646   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 647
 648   $self->js
 649     ->run('kivi.DeliveryOrder.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 650   $self->js_redisplay_line_values;
 651   $self->js->render();
 652 }
 653
 654 # add an item row for a new item entered in the input row
 655 sub action_add_item {
 656   my ($self) = @_;
 657
 658   delete $::form->{add_item}->{create_part_type};
 659
 660   my $form_attr = $::form->{add_item};
 661
 662   return unless $form_attr->{parts_id};
 663
 664   my $item = new_item($self->order, $form_attr);
 665
 666   $self->order->add_items($item);
 667
 668   $self->get_item_cvpartnumber($item);
 669
 670   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 671   my $row_as_html = $self->p->render('delivery_order/tabs/_row',
 672                                      ITEM => $item,
 673                                      ID   => $item_id,
 674                                      SELF => $self,
 675                                      in_out => $self->type_data->transfer,
 676   );
 677
 678   if ($::form->{insert_before_item_id}) {
 679     $self->js
 680       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 681   } else {
 682     $self->js
 683       ->append('#row_table_id', $row_as_html);
 684   }
 685
 686   if ( $item->part->is_assortment ) {
 687     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 688     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 689       my $attr = { parts_id => $assortment_item->parts_id,
 690                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 691                    unit     => $assortment_item->unit,
 692                    description => $assortment_item->part->description,
 693                  };
 694       my $item = new_item($self->order, $attr);
 695
 696       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 697       $item->discount(1) unless $assortment_item->charge;
 698
 699       $self->order->add_items( $item );
 700       $self->get_item_cvpartnumber($item);
 701       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 702       my $row_as_html = $self->p->render('delivery_order/tabs/_row',
 703                                          ITEM => $item,
 704                                          ID   => $item_id,
 705                                          SELF => $self,
 706       );
 707       if ($::form->{insert_before_item_id}) {
 708         $self->js
 709           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 710       } else {
 711         $self->js
 712           ->append('#row_table_id', $row_as_html);
 713       }
 714     };
 715   };
 716
 717   $self->js
 718     ->val('.add_item_input', '')
 719     ->run('kivi.DeliveryOrder.init_row_handlers')
 720     ->run('kivi.DeliveryOrder.renumber_positions')
 721     ->focus('#add_item_parts_id_name');
 722
 723   $self->js->run('kivi.DeliveryOrder.row_table_scroll_down') if !$::form->{insert_before_item_id};
 724
 725   $self->js->render();
 726 }
 727
 728 # add item rows for multiple items at once
 729 sub action_add_multi_items {
 730   my ($self) = @_;
 731
 732   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 733   return $self->js->render() unless scalar @form_attr;
 734
 735   my @items;
 736   foreach my $attr (@form_attr) {
 737     my $item = new_item($self->order, $attr);
 738     push @items, $item;
 739     if ( $item->part->is_assortment ) {
 740       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 741         my $attr = { parts_id => $assortment_item->parts_id,
 742                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 743                      unit     => $assortment_item->unit,
 744                      description => $assortment_item->part->description,
 745                    };
 746         my $item = new_item($self->order, $attr);
 747
 748         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 749         $item->discount(1) unless $assortment_item->charge;
 750         push @items, $item;
 751       }
 752     }
 753   }
 754   $self->order->add_items(@items);
 755
 756   foreach my $item (@items) {
 757     $self->get_item_cvpartnumber($item);
 758     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 759     my $row_as_html = $self->p->render('delivery_order/tabs/_row',
 760                                        ITEM => $item,
 761                                        ID   => $item_id,
 762                                        SELF => $self,
 763                                        in_out => $self->type_data->transfer,
 764     );
 765
 766     if ($::form->{insert_before_item_id}) {
 767       $self->js
 768         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 769     } else {
 770       $self->js
 771         ->append('#row_table_id', $row_as_html);
 772     }
 773   }
 774
 775   $self->js
 776     ->run('kivi.Part.close_picker_dialogs')
 777     ->run('kivi.DeliveryOrder.init_row_handlers')
 778     ->run('kivi.DeliveryOrder.renumber_positions')
 779     ->focus('#add_item_parts_id_name');
 780
 781   $self->js->run('kivi.DeliveryOrder.row_table_scroll_down') if !$::form->{insert_before_item_id};
 782
 783   $self->js->render();
 784 }
 785
 786 sub action_update_exchangerate {
 787   my ($self) = @_;
 788
 789   my $data = {
 790     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 791     currency_name => $self->order->currency->name,
 792   };
 793
 794   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 795 }
 796
 797 # redisplay item rows if they are sorted by an attribute
 798 sub action_reorder_items {
 799   my ($self) = @_;
 800
 801   my %sort_keys = (
 802     partnumber   => sub { $_[0]->part->partnumber },
 803     description  => sub { $_[0]->description },
 804     qty          => sub { $_[0]->qty },
 805     sellprice    => sub { $_[0]->sellprice },
 806     discount     => sub { $_[0]->discount },
 807     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 808   );
 809
 810   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 811
 812   my $method = $sort_keys{$::form->{order_by}};
 813   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 814   if ($::form->{sort_dir}) {
 815     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 816       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 817     } else {
 818       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 819     }
 820   } else {
 821     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 822       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 823     } else {
 824       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 825     }
 826   }
 827   $self->js
 828     ->run('kivi.DeliveryOrder.redisplay_items', \@to_sort)
 829     ->render;
 830 }
 831
 832 # show the popup to choose a price/discount source
 833 sub action_price_popup {
 834   my ($self) = @_;
 835
 836   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 837   my $item = $self->order->items_sorted->[$idx];
 838
 839   $self->render_price_dialog($item);
 840 }
 841
 842 # save the order in a session variable and redirect to the part controller
 843 sub action_create_part {
 844   my ($self) = @_;
 845
 846   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
 847
 848   my $callback     = $self->url_for(
 849     action       => 'return_from_create_part',
 850     type         => $self->type, # type is needed for check_auth on return
 851     previousform => $previousform,
 852   );
 853
 854   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
 855
 856   my @redirect_params = (
 857     controller => 'Part',
 858     action     => 'add',
 859     part_type  => $::form->{add_item}->{create_part_type},
 860     callback   => $callback,
 861     show_abort => 1,
 862   );
 863
 864   $self->redirect_to(@redirect_params);
 865 }
 866
 867 sub action_return_from_create_part {
 868   my ($self) = @_;
 869
 870   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
 871
 872   $::auth->restore_form_from_session(delete $::form->{previousform});
 873
 874   # set item ids to new fake id, to identify them as new items
 875   foreach my $item (@{$self->order->items_sorted}) {
 876     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 877   }
 878
 879   $self->get_unalterable_data();
 880   $self->pre_render();
 881
 882   # trigger rendering values for second row/longdescription as hidden,
 883   # because they are loaded only on demand. So we need to keep the values
 884   # from the source.
 885   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
 886   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 887
 888   $self->render(
 889     'delivery_order/form',
 890     title => $self->get_title_for('edit'),
 891     %{$self->{template_args}}
 892   );
 893
 894 }
 895
 896 sub action_stock_in_out_dialog {
 897   my ($self) = @_;
 898
 899   my $part    = SL::DB::Part->load_cached($::form->{parts_id}) or die "need parts_id";
 900   my $unit    = SL::DB::Unit->load_cached($::form->{unit}) or die "need unit";
 901   my $stock   = $::form->{stock};
 902   my $row     = $::form->{row};
 903   my $item_id = $::form->{item_id};
 904   my $qty     = _parse_number($::form->{qty_as_number});
 905
 906   my $inout = $self->type_data->transfer;
 907
 908   my @contents   = DO->get_item_availability(parts_id => $part->id);
 909   my $stock_info = DO->unpack_stock_information(packed => $stock);
 910
 911   $self->merge_stock_data($stock_info, \@contents, $part, $unit);
 912
 913   $self->render("delivery_order/stock_dialog", { layout => 0 },
 914     WHCONTENTS => $self->order->delivered ? $stock_info : \@contents,
 915     part       => $part,
 916     do_qty     => $qty,
 917     do_unit    => $unit->unit,
 918     delivered  => $self->order->delivered,
 919     row        => $row,
 920     item_id    => $item_id,
 921   );
 922 }
 923
 924 sub action_update_stock_information {
 925   my ($self) = @_;
 926
 927   my $stock_info = $::form->{stock_info};
 928   my $unit = $::form->{unit};
 929   my $yaml = SL::YAML::Dump($stock_info);
 930   my $stock_qty = $self->calculate_stock_in_out_from_stock_info($unit, $stock_info);
 931
 932   my $response = {
 933     stock_info => $yaml,
 934     stock_qty => $stock_qty,
 935   };
 936
 937   $self->render(\ SL::JSON::to_json($response), { layout => 0, type => 'json', process => 0 });
 938 }
 939
 940 sub merge_stock_data {
 941   my ($self, $stock_info, $contents, $part, $unit) = @_;
 942   # TODO rewrite to mapping
 943
 944   if (!$self->order->delivered) {
 945     for my $row (@$contents) {
 946       # row here is in parts units. stock is in item units
 947       $row->{available_qty} = _format_number($part->unit_obj->convert_to($row->{qty}, $unit));
 948
 949       for my $sinfo (@{ $stock_info }) {
 950         next if $row->{bin_id}       != $sinfo->{bin_id} ||
 951                 $row->{warehouse_id} != $sinfo->{warehouse_id} ||
 952                 $row->{chargenumber} ne $sinfo->{chargenumber} ||
 953                 $row->{bestbefore}   ne $sinfo->{bestbefore};
 954
 955         $row->{"stock_$_"} = $sinfo->{$_}
 956           for qw(qty unit error delivery_order_items_stock_id);
 957       }
 958     }
 959
 960   } else {
 961     for my $sinfo (@{ $stock_info }) {
 962       my $bin = SL::DB::Bin->load_cached($sinfo->{bin_id});
 963       $sinfo->{warehousedescription} = $bin->warehouse->description;
 964       $sinfo->{bindescription}       = $bin->description;
 965       map { $sinfo->{"stock_$_"}      = $sinfo->{$_} } qw(qty unit);
 966     }
 967   }
 968 }
 969
 970 # load the second row for one or more items
 971 #
 972 # This action gets the html code for all items second rows by rendering a template for
 973 # the second row and sets the html code via client js.
 974 sub action_load_second_rows {
 975   my ($self) = @_;
 976
 977   foreach my $item_id (@{ $::form->{item_ids} }) {
 978     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 979     my $item = $self->order->items_sorted->[$idx];
 980
 981     $self->js_load_second_row($item, $item_id, 0);
 982   }
 983
 984   $self->js->run('kivi.DeliveryOrder.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 985
 986   $self->js->render();
 987 }
 988
 989 # update description, notes and sellprice from master data
 990 sub action_update_row_from_master_data {
 991   my ($self) = @_;
 992
 993   foreach my $item_id (@{ $::form->{item_ids} }) {
 994     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 995     my $item  = $self->order->items_sorted->[$idx];
 996     my $texts = get_part_texts($item->part, $self->order->language_id);
 997
 998     $item->description($texts->{description});
 999     $item->longdescription($texts->{longdescription});
1000
1001     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1002
1003     my $price_src;
1004     if ($item->part->is_assortment) {
1005     # add assortment items with price 0, as the components carry the price
1006       $price_src = $price_source->price_from_source("");
1007       $price_src->price(0);
1008     } else {
1009       $price_src = $price_source->best_price
1010                  ? $price_source->best_price
1011                  : $price_source->price_from_source("");
1012       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1013       $price_src->price(0) if !$price_source->best_price;
1014     }
1015
1016
1017     $item->sellprice($price_src->price);
1018     $item->active_price_source($price_src);
1019
1020     $self->js
1021       ->run('kivi.DeliveryOrder.update_sellprice', $item_id, $item->sellprice_as_number)
1022       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1023       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1024       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1025
1026     if ($self->search_cvpartnumber) {
1027       $self->get_item_cvpartnumber($item);
1028       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1029     }
1030   }
1031
1032   $self->js_redisplay_line_values;
1033
1034   $self->js->render();
1035 }
1036
1037 sub action_transfer_stock {
1038   my ($self) = @_;
1039
1040   if ($self->order->delivered) {
1041     return $self->js->flash("error", t8('The parts for this order have already been transferred'))->render;
1042   }
1043
1044   my $inout = $self->type_data->properties('transfer');
1045
1046   my $errors = $self->save;
1047
1048   if (@$errors) {
1049     $self->js->flash('error', $_) for @$errors;
1050     return $self->js->render;
1051   }
1052
1053   my $order = $self->order;
1054
1055   # TODO move to type data
1056   my $trans_type = $inout eq 'in'
1057     ? SL::DB::Manager::TransferType->find_by(direction => "id", description => "stock")
1058     : SL::DB::Manager::TransferType->find_by(direction => "out", description => "shipped");
1059
1060   my @transfer_requests;
1061
1062   for my $item (@{ $order->items_sorted }) {
1063     for my $stock (@{ $item->delivery_order_stock_entries }) {
1064       my $transfer = SL::DB::Inventory->new_from($stock);
1065       $transfer->trans_type($trans_type);
1066       $transfer->qty($transfer->qty * -1) if $inout eq 'out';
1067
1068       push @transfer_requests, $transfer if defined $transfer->qty && $transfer->qty != 0;
1069     };
1070   }
1071
1072   if (!@transfer_requests) {
1073     return $self->js->flash("error", t8("No stock to transfer"))->render;
1074   }
1075
1076   SL::DB->client->with_transaction(sub {
1077     $_->save for @transfer_requests;
1078     $self->order->update_attributes(delivered => 1);
1079   });
1080
1081   $self->js
1082     ->flash("info", t8("Stock transfered"))
1083     ->run('kivi.ActionBar.setDisabled', '#transfer_out_action', t8('The parts for this order have already been transferred'))
1084     ->run('kivi.ActionBar.setDisabled', '#transfer_in_action', t8('The parts for this order have already been transferred'))
1085     ->run('kivi.ActionBar.setDisabled', '#delete_action', t8('The parts for this order have already been transferred'))
1086     ->replaceWith('#data-status-line', delivery_order_status_line($self->order))
1087     ->render;
1088
1089 }
1090
1091 sub js_load_second_row {
1092   my ($self, $item, $item_id, $do_parse) = @_;
1093
1094   if ($do_parse) {
1095     # Parse values from form (they are formated while rendering (template)).
1096     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1097     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1098     foreach my $var (@{ $item->cvars_by_config }) {
1099       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1100     }
1101     $item->parse_custom_variable_values;
1102   }
1103
1104   my $row_as_html = $self->p->render('delivery_order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1105
1106   $self->js
1107     ->html('#second_row_' . $item_id, $row_as_html)
1108     ->data('#second_row_' . $item_id, 'loaded', 1);
1109 }
1110
1111 sub js_redisplay_line_values {
1112   my ($self) = @_;
1113
1114   my $is_sales = $self->order->is_sales;
1115
1116   # sales orders with margins
1117   my @data;
1118   if ($is_sales) {
1119     @data = map {
1120       [
1121        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1122        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1123        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1124       ]} @{ $self->order->items_sorted };
1125   } else {
1126     @data = map {
1127       [
1128        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1129       ]} @{ $self->order->items_sorted };
1130   }
1131
1132   $self->js
1133     ->run('kivi.DeliveryOrder.redisplay_line_values', $is_sales, \@data);
1134 }
1135
1136 sub js_redisplay_cvpartnumbers {
1137   my ($self) = @_;
1138
1139   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1140
1141   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1142
1143   $self->js
1144     ->run('kivi.DeliveryOrder.redisplay_cvpartnumbers', \@data);
1145 }
1146
1147 sub js_reset_order_and_item_ids_after_save {
1148   my ($self) = @_;
1149
1150   $self->js
1151     ->val('#id', $self->order->id)
1152     ->val('#converted_from_oe_id', '')
1153     ->val('#order_' . $self->nr_key(), $self->order->number);
1154
1155   my $idx = 0;
1156   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1157     next if !$self->order->items_sorted->[$idx]->id;
1158     next if $form_item_id !~ m{^new};
1159     $self->js
1160       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1161       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1162       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1163   } continue {
1164     $idx++;
1165   }
1166   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1167 }
1168
1169 #
1170 # helpers
1171 #
1172
1173 sub init_type {
1174   my ($self) = @_;
1175
1176   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1177     die "Not a valid type for delivery order";
1178   }
1179
1180   $self->type($::form->{type});
1181 }
1182
1183 sub init_cv {
1184   my ($self) = @_;
1185
1186   return $self->type_data->customervendor;
1187 }
1188
1189 sub init_search_cvpartnumber {
1190   my ($self) = @_;
1191
1192   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1193   my $search_cvpartnumber;
1194   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1195   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1196
1197   return $search_cvpartnumber;
1198 }
1199
1200 sub init_show_update_button {
1201   my ($self) = @_;
1202
1203   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1204 }
1205
1206 sub init_p {
1207   SL::Presenter->get;
1208 }
1209
1210 sub init_order {
1211   $_[0]->make_order;
1212 }
1213
1214 sub init_all_price_factors {
1215   SL::DB::Manager::PriceFactor->get_all;
1216 }
1217
1218 sub init_part_picker_classification_ids {
1219   my ($self)    = @_;
1220
1221   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => $self->type_data->part_classification_query) } ];
1222 }
1223
1224 sub check_auth {
1225   my ($self) = @_;
1226
1227   $::auth->assert($self->type_data->access || 'DOES_NOT_EXIST');
1228 }
1229
1230 # build the selection box for contacts
1231 #
1232 # Needed, if customer/vendor changed.
1233 sub build_contact_select {
1234   my ($self) = @_;
1235
1236   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1237     value_key  => 'cp_id',
1238     title_key  => 'full_name_dep',
1239     default    => $self->order->cp_id,
1240     with_empty => 1,
1241     style      => 'width: 300px',
1242   );
1243 }
1244
1245 # build the selection box for shiptos
1246 #
1247 # Needed, if customer/vendor changed.
1248 sub build_shipto_select {
1249   my ($self) = @_;
1250
1251   select_tag('order.shipto_id',
1252              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1253              value_key  => 'shipto_id',
1254              title_key  => 'displayable_id',
1255              default    => $self->order->shipto_id,
1256              with_empty => 0,
1257              style      => 'width: 300px',
1258   );
1259 }
1260
1261 # build the inputs for the cusom shipto dialog
1262 #
1263 # Needed, if customer/vendor changed.
1264 sub build_shipto_inputs {
1265   my ($self) = @_;
1266
1267   my $content = $self->p->render('common/_ship_to_dialog',
1268                                  vc_obj      => $self->order->customervendor,
1269                                  cs_obj      => $self->order->custom_shipto,
1270                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1271                                  id_selector => '#order_shipto_id');
1272
1273   div_tag($content, id => 'shipto_inputs');
1274 }
1275
1276 # render the info line for business
1277 #
1278 # Needed, if customer/vendor changed.
1279 sub build_business_info_row
1280 {
1281   $_[0]->p->render('delivery_order/tabs/_business_info_row', SELF => $_[0]);
1282 }
1283
1284
1285 sub load_order {
1286   my ($self) = @_;
1287
1288   return if !$::form->{id};
1289
1290   $self->order(SL::DB::DeliveryOrder->new(id => $::form->{id})->load);
1291
1292   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1293   # You need a custom shipto object to call cvars_by_config to get the cvars.
1294   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1295
1296   $self->prepare_stock_info($_) for $self->order->items;
1297
1298   return $self->order;
1299 }
1300
1301 # load or create a new order object
1302 #
1303 # And assign changes from the form to this object.
1304 # If the order is loaded from db, check if items are deleted in the form,
1305 # remove them form the object and collect them for removing from db on saving.
1306 # Then create/update items from form (via make_item) and add them.
1307 sub make_order {
1308   my ($self) = @_;
1309
1310   # add_items adds items to an order with no items for saving, but they cannot
1311   # be retrieved via items until the order is saved. Adding empty items to new
1312   # order here solves this problem.
1313   my $order;
1314   $order   = SL::DB::DeliveryOrder->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1315   $order ||= SL::DB::DeliveryOrder->new(orderitems  => [], currency_id => $::instance_conf->get_currency_id(), order_type => $self->type_data->validate($::form->{type}));
1316
1317   my $cv_id_method = $self->cv . '_id';
1318   if (!$::form->{id} && $::form->{$cv_id_method}) {
1319     $order->$cv_id_method($::form->{$cv_id_method});
1320     setup_order_from_cv($order);
1321   }
1322
1323   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1324
1325   $order->assign_attributes(%{$::form->{order}});
1326
1327   $self->setup_custom_shipto_from_form($order, $::form);
1328
1329   # remove deleted items
1330   $self->item_ids_to_delete([]);
1331   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1332     my $item = $order->orderitems->[$idx];
1333     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1334       splice @{$order->orderitems}, $idx, 1;
1335       push @{$self->item_ids_to_delete}, $item->id;
1336     }
1337   }
1338
1339   my @items;
1340   my $pos = 1;
1341   foreach my $form_attr (@{$form_orderitems}) {
1342     my $item = make_item($order, $form_attr);
1343     $item->position($pos);
1344     push @items, $item;
1345     $pos++;
1346   }
1347
1348   $self->prepare_stock_info($_) for $order->items, @items;
1349
1350   $order->add_items(grep {!$_->id} @items);
1351
1352   return $order;
1353 }
1354
1355 # create or update items from form
1356 #
1357 # Make item objects from form values. For items already existing read from db.
1358 # Create a new item else. And assign attributes.
1359 sub make_item {
1360   my ($record, $attr) = @_;
1361
1362   my $item;
1363   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1364
1365   my $is_new = !$item;
1366
1367   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1368   # they cannot be retrieved via custom_variables until the order/orderitem is
1369   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1370   $item ||= SL::DB::DeliveryOrderItem->new(custom_variables => []);
1371
1372   # handle stock info
1373   if (my $stock_info = delete $attr->{stock_info}) {
1374     my %existing = map { $_->id => $_ } $item->delivery_order_stock_entries;
1375     my @save;
1376
1377     for my $line (@{ DO->unpack_stock_information(packed => $stock_info) }) {
1378       # lookup existing or make new
1379       my $obj = delete $existing{$line->{delivery_order_items_stock_id}}
1380              // SL::DB::DeliveryOrderItemsStock->new;
1381
1382       # assign attributes
1383       $obj->$_($line->{$_}) for qw(bin_id warehouse_id chargenumber qty unit);
1384       $obj->bestbefore_as_date($line->{bestfbefore})
1385         if $line->{bestbefore} && $::instance_conf->get_show_bestbefore;
1386       push @save, $obj if $obj->qty;
1387     }
1388
1389     $item->delivery_order_stock_entries(@save);
1390   }
1391
1392   $item->assign_attributes(%$attr);
1393
1394   if ($is_new) {
1395     my $texts = get_part_texts($item->part, $record->language_id);
1396     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1397     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1398     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1399   }
1400
1401   return $item;
1402 }
1403
1404 # create a new item
1405 #
1406 # This is used to add one item
1407 sub new_item {
1408   my ($record, $attr) = @_;
1409
1410   my $item = SL::DB::DeliveryOrderItem->new;
1411
1412   # Remove attributes where the user left or set the inputs empty.
1413   # So these attributes will be undefined and we can distinguish them
1414   # from zero later on.
1415   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1416     delete $attr->{$_} if $attr->{$_} eq '';
1417   }
1418
1419   $item->assign_attributes(%$attr);
1420
1421   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1422   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1423
1424   $item->unit($part->unit) if !$item->unit;
1425
1426   my $price_src;
1427   if ( $part->is_assortment ) {
1428     # add assortment items with price 0, as the components carry the price
1429     $price_src = $price_source->price_from_source("");
1430     $price_src->price(0);
1431   } elsif (defined $item->sellprice) {
1432     $price_src = $price_source->price_from_source("");
1433     $price_src->price($item->sellprice);
1434   } else {
1435     $price_src = $price_source->best_price
1436                ? $price_source->best_price
1437                : $price_source->price_from_source("");
1438     $price_src->price(0) if !$price_source->best_price;
1439   }
1440
1441   my $discount_src;
1442   if (defined $item->discount) {
1443     $discount_src = $price_source->discount_from_source("");
1444     $discount_src->discount($item->discount);
1445   } else {
1446     $discount_src = $price_source->best_discount
1447                   ? $price_source->best_discount
1448                   : $price_source->discount_from_source("");
1449     $discount_src->discount(0) if !$price_source->best_discount;
1450   }
1451
1452   my %new_attr;
1453   $new_attr{part}                   = $part;
1454   $new_attr{description}            = $part->description     if ! $item->description;
1455   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1456   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1457   $new_attr{sellprice}              = $price_src->price;
1458   $new_attr{discount}               = $discount_src->discount;
1459   $new_attr{active_price_source}    = $price_src;
1460   $new_attr{active_discount_source} = $discount_src;
1461   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1462   $new_attr{project_id}             = $record->globalproject_id;
1463   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1464
1465   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1466   # they cannot be retrieved via custom_variables until the order/orderitem is
1467   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1468   $new_attr{custom_variables} = [];
1469
1470   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1471
1472   $item->assign_attributes(%new_attr, %{ $texts });
1473
1474   return $item;
1475 }
1476
1477 sub prepare_stock_info {
1478   my ($self, $item) = @_;
1479
1480   $item->{stock_info} = SL::YAML::Dump([
1481     map +{
1482       delivery_order_items_stock_id => $_->id,
1483       qty                           => $_->qty,
1484       warehouse_id                  => $_->warehouse_id,
1485       bin_id                        => $_->bin_id,
1486       chargenumber                  => $_->chargenumber,
1487       unit                          => $_->unit,
1488     }, $item->delivery_order_stock_entries
1489   ]);
1490 }
1491
1492 sub setup_order_from_cv {
1493   my ($order) = @_;
1494
1495   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1496
1497   $order->intnotes($order->customervendor->notes);
1498
1499   if ($order->is_sales) {
1500     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1501     $order->taxincluded(defined($order->customer->taxincluded_checked)
1502                         ? $order->customer->taxincluded_checked
1503                         : $::myconfig{taxincluded_checked});
1504   }
1505
1506 }
1507
1508 # setup custom shipto from form
1509 #
1510 # The dialog returns form variables starting with 'shipto' and cvars starting
1511 # with 'shiptocvar_'.
1512 # Mark it to be deleted if a shipto from master data is selected
1513 # (i.e. order has a shipto).
1514 # Else, update or create a new custom shipto. If the fields are empty, it
1515 # will not be saved on save.
1516 sub setup_custom_shipto_from_form {
1517   my ($self, $order, $form) = @_;
1518
1519   if ($order->shipto) {
1520     $self->is_custom_shipto_to_delete(1);
1521   } else {
1522     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1523
1524     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1525     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1526
1527     $custom_shipto->assign_attributes(%$shipto_attrs);
1528     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1529   }
1530 }
1531
1532 # get data for saving, printing, ..., that is not changed in the form
1533 #
1534 # Only cvars for now.
1535 sub get_unalterable_data {
1536   my ($self) = @_;
1537
1538   foreach my $item (@{ $self->order->items }) {
1539     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1540     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1541     foreach my $var (@{ $item->cvars_by_config }) {
1542       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1543     }
1544     $item->parse_custom_variable_values;
1545   }
1546 }
1547
1548 # delete the order
1549 #
1550 # And remove related files in the spool directory
1551 sub delete {
1552   my ($self) = @_;
1553
1554   my $errors = [];
1555   my $db     = $self->order->db;
1556
1557   $db->with_transaction(
1558     sub {
1559       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1560       $self->order->delete;
1561       my $spool = $::lx_office_conf{paths}->{spool};
1562       unlink map { "$spool/$_" } @spoolfiles if $spool;
1563
1564       $self->save_history('DELETED');
1565
1566       1;
1567   }) || push(@{$errors}, $db->error);
1568
1569   return $errors;
1570 }
1571
1572 # save the order
1573 #
1574 # And delete items that are deleted in the form.
1575 sub save {
1576   my ($self) = @_;
1577
1578   my $errors = [];
1579   my $db     = $self->order->db;
1580
1581   $db->with_transaction(sub {
1582     # delete custom shipto if it is to be deleted or if it is empty
1583     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1584       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1585       $self->order->custom_shipto(undef);
1586     }
1587
1588     SL::DB::DeliveryOrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1589     $self->order->save(cascade => 1);
1590
1591     # link records
1592     if ($::form->{converted_from_oe_id}) {
1593       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1594       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1595         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1596         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/ && $self->order->is_type(PURCHASE_DELIVERY_ORDER_TYPE);
1597         $src->link_to_record($self->order);
1598       }
1599       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1600         my $idx = 0;
1601         foreach (@{ $self->order->items_sorted }) {
1602           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1603           next if !$from_id;
1604           SL::DB::RecordLink->new(from_table => 'orderitems',
1605                                   from_id    => $from_id,
1606                                   to_table   => 'orderitems',
1607                                   to_id      => $_->id
1608           )->save;
1609           $idx++;
1610         }
1611       }
1612     }
1613
1614     $self->save_history('SAVED');
1615
1616     1;
1617   }) || push(@{$errors}, $db->error);
1618
1619   return $errors;
1620 }
1621
1622 sub workflow_sales_or_request_for_quotation {
1623   my ($self) = @_;
1624
1625   # always save
1626   my $errors = $self->save();
1627
1628   if (scalar @{ $errors }) {
1629     $self->js->flash('error', $_) for @{ $errors };
1630     return $self->js->render();
1631   }
1632
1633   my $destination_type = $self->type_data->workflow("to_quotation_type");
1634
1635   $self->order(SL::DB::DeliveryOrder->new_from($self->order, destination_type => $destination_type));
1636   $self->{converted_from_oe_id} = delete $::form->{id};
1637
1638   # set item ids to new fake id, to identify them as new items
1639   foreach my $item (@{$self->order->items_sorted}) {
1640     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1641   }
1642
1643   # change form type
1644   $::form->{type} = $destination_type;
1645   $self->type($self->init_type);
1646   $self->cv  ($self->init_cv);
1647   $self->check_auth;
1648
1649   $self->get_unalterable_data();
1650   $self->pre_render();
1651
1652   # trigger rendering values for second row as hidden, because they
1653   # are loaded only on demand. So we need to keep the values from the
1654   # source.
1655   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1656
1657   $self->render(
1658     'delivery_order/form',
1659     title => $self->get_title_for('edit'),
1660     %{$self->{template_args}}
1661   );
1662 }
1663
1664 sub workflow_sales_or_purchase_order {
1665   my ($self) = @_;
1666
1667   # always save
1668   my $errors = $self->save();
1669
1670   if (scalar @{ $errors }) {
1671     $self->js->flash('error', $_) foreach @{ $errors };
1672     return $self->js->render();
1673   }
1674
1675   my $destination_type = $self->type_data->workflow("to_order_type");
1676
1677   # check for direct delivery
1678   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1679   my $custom_shipto;
1680   if ($self->type_data->workflow("to_order_copy_shipto") && $::form->{use_shipto} && $self->order->shipto) {
1681     $custom_shipto = $self->order->shipto->clone('SL::DB::DeliveryOrder');
1682   }
1683
1684   $self->order(SL::DB::DeliveryOrder->new_from($self->order, destination_type => $destination_type));
1685   $self->{converted_from_oe_id} = delete $::form->{id};
1686
1687   # set item ids to new fake id, to identify them as new items
1688   foreach my $item (@{$self->order->items_sorted}) {
1689     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1690   }
1691
1692   if ($self->type_data->workflow("to_order_copy_shipto")) {
1693     if ($::form->{use_shipto}) {
1694       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1695     } else {
1696       # remove any custom shipto if not wanted
1697       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1698     }
1699   }
1700
1701   # change form type
1702   $::form->{type} = $destination_type;
1703   $self->type($self->init_type);
1704   $self->cv  ($self->init_cv);
1705   $self->check_auth;
1706
1707   $self->get_unalterable_data();
1708   $self->pre_render();
1709
1710   # trigger rendering values for second row as hidden, because they
1711   # are loaded only on demand. So we need to keep the values from the
1712   # source.
1713   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1714
1715   $self->render(
1716     'delivery_order/form',
1717     title => $self->get_title_for('edit'),
1718     %{$self->{template_args}}
1719   );
1720 }
1721
1722 sub pre_render {
1723   my ($self) = @_;
1724
1725   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1726   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1727   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1728   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1729   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1730                                                                                               deleted => 0 ] ],
1731                                                                            sort_by => 'name');
1732   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1733                                                                                               deleted => 0 ] ],
1734                                                                            sort_by => 'name');
1735   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1736                                                                                                         obsolete => 0 ] ]);
1737   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1738   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1739   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1740   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1741
1742   my $print_form = Form->new('');
1743   $print_form->{type}        = $self->type;
1744   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1745   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1746     form => $print_form,
1747     options => {dialog_name_prefix => 'print_options.',
1748                 show_headers       => 1,
1749                 no_queue           => 1,
1750                 no_postscript      => 1,
1751                 no_opendocument    => 0,
1752                 no_html            => 1},
1753   );
1754
1755   foreach my $item (@{$self->order->orderitems}) {
1756     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1757     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1758     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1759   }
1760
1761   if ($self->order->${\ $self->type_data->nr_key } && $::instance_conf->get_webdav) {
1762     my $webdav = SL::Webdav->new(
1763       type     => $self->type,
1764       number   => $self->order->number,
1765     );
1766     my @all_objects = $webdav->get_all_objects;
1767     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1768                                                     type => t8('File'),
1769                                                     link => File::Spec->catfile($_->full_filedescriptor),
1770                                                 } } @all_objects;
1771   }
1772
1773   $self->{template_args}{in_out} = $self->type_data->transfer;
1774
1775   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1776
1777   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.DeliveryOrder kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1778                                                          calculate_qty kivi.Validator follow_up show_history);
1779   $self->setup_edit_action_bar;
1780 }
1781
1782 sub setup_edit_action_bar {
1783   my ($self, %params) = @_;
1784
1785   my $deletion_allowed = $self->type_data->show_menu("delete");
1786
1787   for my $bar ($::request->layout->get('actionbar')) {
1788     $bar->add(
1789       combobox => [
1790         action => [
1791           t8('Save'),
1792           call      => [ 'kivi.DeliveryOrder.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1793                                                     $::instance_conf->get_order_warn_no_deliverydate,
1794                                                                                                       ],
1795         ],
1796         action => [
1797           t8('Save as new'),
1798           call      => [ 'kivi.DeliveryOrder.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1799           disabled  =>   $self->type eq 'supplier_delivery_order' ? t8('Need a workflow for Supplier Delivery Order')
1800                        : !$self->order->id                        ? t8('This object has not been saved yet.')
1801                        : undef,
1802         ],
1803       ], # end of combobox "Save"
1804
1805       combobox => [
1806         action => [
1807           t8('Workflow'),
1808         ],
1809         action => [
1810           t8('Save and Quotation'),
1811           submit   => [ '#order_form', { action => "DeliveryOrder/sales_quotation" } ],
1812           only_if  => $self->type_data->show_menu("save_and_quotation"),
1813         ],
1814         action => [
1815           t8('Save and RFQ'),
1816           submit   => [ '#order_form', { action => "DeliveryOrder/request_for_quotation" } ],
1817           only_if  => $self->type_data->show_menu("save_and_rfq"),
1818         ],
1819         action => [
1820           t8('Save and Sales Order'),
1821           submit   => [ '#order_form', { action => "DeliveryOrder/sales_order" } ],
1822           only_if  => $self->type_data->show_menu("save_and_sales_order"),
1823         ],
1824         action => [
1825           t8('Save and Purchase Order'),
1826           call      => [ 'kivi.DeliveryOrder.purchase_order_check_for_direct_delivery' ],
1827           only_if  => $self->type_data->show_menu("save_and_purchase_order"),
1828         ],
1829         action => [
1830           t8('Save and Delivery Order'),
1831           call      => [ 'kivi.DeliveryOrder.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1832                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1833                                                                                                                         ],
1834           only_if  => $self->type_data->show_menu("save_and_delivery_order"),
1835         ],
1836         action => [
1837           t8('Save and Invoice'),
1838           call      => [ 'kivi.DeliveryOrder.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1839           only_if  => $self->type_data->show_menu("save_and_invoice"),
1840         ],
1841         action => [
1842           t8('Save and AP Transaction'),
1843           call      => [ 'kivi.DeliveryOrder.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1844           only_if  => $self->type_data->show_menu("save_and_ap_transaction"),
1845         ],
1846
1847       ], # end of combobox "Workflow"
1848
1849       combobox => [
1850         action => [
1851           t8('Export'),
1852         ],
1853         action => [
1854           t8('Save and preview PDF'),
1855            call => [ 'kivi.DeliveryOrder.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
1856                                                        $::instance_conf->get_order_warn_no_deliverydate,
1857                                                                                                          ],
1858         ],
1859         action => [
1860           t8('Save and print'),
1861           call => [ 'kivi.DeliveryOrder.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
1862                                                      $::instance_conf->get_order_warn_no_deliverydate,
1863                                                                                                       ],
1864         ],
1865         action => [
1866           t8('Save and E-mail'),
1867           id   => 'save_and_email_action',
1868           call => [ 'kivi.DeliveryOrder.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
1869                                                                      $::instance_conf->get_order_warn_no_deliverydate,
1870                   ],
1871           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1872         ],
1873         action => [
1874           t8('Download attachments of all parts'),
1875           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1876           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1877           only_if  => $::instance_conf->get_doc_storage,
1878         ],
1879       ], # end of combobox "Export"
1880
1881       action => [
1882         t8('Delete'),
1883         id       => 'delete_action',
1884         call     => [ 'kivi.DeliveryOrder.delete_order' ],
1885         confirm  => $::locale->text('Do you really want to delete this object?'),
1886         disabled => !$self->order->id       ? t8('This object has not been saved yet.') :
1887                     $self->order->delivered ? t8('The parts for this order have already been transferred') : undef,
1888         only_if  => $self->type_data->show_menu("delete"),
1889       ],
1890
1891       combobox => [
1892         action => [
1893           t8('Transfer out'),
1894           id   => 'transfer_out_action',
1895           call   => [ 'kivi.DeliveryOrder.save', 'transfer_stock' ],
1896           disabled => !$self->order->id ? t8('This object has not been saved yet.') :
1897                       $self->order->delivered ? t8('The parts for this order have already been transferred') : undef,
1898           only_if => $self->type_data->properties('transfer') eq 'out',
1899           confirm  => t8('Do you really want to transfer the stock and set this order to delivered?'),
1900         ],
1901         action => [
1902           t8('Transfer in'),
1903           id   => 'transfer_in_action',
1904           call   => [ 'kivi.DeliveryOrder.save', 'transfer_stock' ],
1905           disabled => !$self->order->id ? t8('This object has not been saved yet.') :
1906                       $self->order->delivered ? t8('The parts for this order have already been transferred') : undef,
1907           only_if => $self->type_data->properties('transfer') eq 'in',
1908           confirm  => t8('Do you really want to transfer the stock and set this order to delivered?'),
1909         ],
1910       ],
1911
1912       combobox => [
1913         action => [
1914           t8('more')
1915         ],
1916         action => [
1917           t8('Follow-Up'),
1918           call     => [ 'kivi.DeliveryOrder.follow_up_window' ],
1919           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1920           only_if  => $::auth->assert('productivity', 1),
1921         ],
1922         action => [
1923           t8('History'),
1924           call     => [ 'set_history_window', $self->order->id, 'id' ],
1925           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
1926         ],
1927       ], # end of combobox "more"
1928     );
1929   }
1930 }
1931
1932 sub generate_pdf {
1933   my ($order, $pdf_ref, $params) = @_;
1934
1935   my @errors = ();
1936
1937   my $print_form = Form->new('');
1938   $print_form->{type}        = $order->type;
1939   $print_form->{formname}    = $params->{formname} || $order->type;
1940   $print_form->{format}      = $params->{format}   || 'pdf';
1941   $print_form->{media}       = $params->{media}    || 'file';
1942   $print_form->{groupitems}  = $params->{groupitems};
1943   $print_form->{printer_id}  = $params->{printer_id};
1944   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1945
1946   $order->language($params->{language});
1947   $order->flatten_to_form($print_form, format_amounts => 1);
1948
1949   my $template_ext;
1950   my $template_type;
1951   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1952     $template_ext  = 'odt';
1953     $template_type = 'OpenDocument';
1954   }
1955
1956   # search for the template
1957   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1958     name        => $print_form->{formname},
1959     extension   => $template_ext,
1960     email       => $print_form->{media} eq 'email',
1961     language    => $params->{language},
1962     printer_id  => $print_form->{printer_id},
1963   );
1964
1965   if (!defined $template_file) {
1966     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1967   }
1968
1969   return @errors if scalar @errors;
1970
1971   $print_form->throw_on_error(sub {
1972     eval {
1973       $print_form->prepare_for_printing;
1974
1975       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1976         format        => $print_form->{format},
1977         template_type => $template_type,
1978         template      => $template_file,
1979         variables     => $print_form,
1980         variable_content_types => {
1981           longdescription => 'html',
1982           partnotes       => 'html',
1983           notes           => 'html',
1984         },
1985       );
1986       1;
1987     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1988   });
1989
1990   return @errors;
1991 }
1992
1993 sub get_files_for_email_dialog {
1994   my ($self) = @_;
1995
1996   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1997
1998   return %files if !$::instance_conf->get_doc_storage;
1999
2000   if ($self->order->id) {
2001     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2002     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2003     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2004     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2005   }
2006
2007   my @parts =
2008     uniq_by { $_->{id} }
2009     map {
2010       +{ id         => $_->part->id,
2011          partnumber => $_->part->partnumber }
2012     } @{$self->order->items_sorted};
2013
2014   foreach my $part (@parts) {
2015     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2016     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2017   }
2018
2019   foreach my $key (keys %files) {
2020     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2021   }
2022
2023   return %files;
2024 }
2025
2026 sub get_title_for {
2027   my ($self, $action) = @_;
2028
2029   return '' if none { lc($action)} qw(add edit);
2030   return $self->type_data->text($action);
2031 }
2032
2033 sub get_item_cvpartnumber {
2034   my ($self, $item) = @_;
2035
2036   return if !$self->search_cvpartnumber;
2037   return if !$self->order->customervendor;
2038
2039   if ($self->cv eq 'vendor') {
2040     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2041     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2042   } elsif ($self->cv eq 'customer') {
2043     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2044     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2045   }
2046 }
2047
2048 sub get_part_texts {
2049   my ($part_or_id, $language_or_id, %defaults) = @_;
2050
2051   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2052   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2053   my $texts       = {
2054     description     => $defaults{description}     // $part->description,
2055     longdescription => $defaults{longdescription} // $part->notes,
2056   };
2057
2058   return $texts unless $language_id;
2059
2060   my $translation = SL::DB::Manager::Translation->get_first(
2061     where => [
2062       parts_id    => $part->id,
2063       language_id => $language_id,
2064     ]);
2065
2066   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2067   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2068
2069   return $texts;
2070 }
2071
2072 sub nr_key {
2073   return $_[0]->type_data->nr_key;
2074 }
2075
2076 sub save_and_redirect_to {
2077   my ($self, %params) = @_;
2078
2079   my $errors = $self->save();
2080
2081   if (scalar @{ $errors }) {
2082     $self->js->flash('error', $_) foreach @{ $errors };
2083     return $self->js->render();
2084   }
2085
2086   flash_later('info', $self->type_data->text("saved"));
2087
2088   $self->redirect_to(%params, id => $self->order->id);
2089 }
2090
2091 sub save_history {
2092   my ($self, $addition) = @_;
2093
2094   my $number_type = $self->nr_key;
2095   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2096
2097   SL::DB::History->new(
2098     trans_id    => $self->order->id,
2099     employee_id => SL::DB::Manager::Employee->current->id,
2100     what_done   => $self->order->type,
2101     snumbers    => $snumbers,
2102     addition    => $addition,
2103   )->save;
2104 }
2105
2106 sub store_pdf_to_webdav_and_filemanagement {
2107   my($order, $content, $filename) = @_;
2108
2109   my @errors;
2110
2111   # copy file to webdav folder
2112   if ($order->number && $::instance_conf->get_webdav_documents) {
2113     my $webdav = SL::Webdav->new(
2114       type     => $order->type,
2115       number   => $order->number,
2116     );
2117     my $webdav_file = SL::Webdav::File->new(
2118       webdav   => $webdav,
2119       filename => $filename,
2120     );
2121     eval {
2122       $webdav_file->store(data => \$content);
2123       1;
2124     } or do {
2125       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2126     };
2127   }
2128   if ($order->id && $::instance_conf->get_doc_storage) {
2129     eval {
2130       SL::File->save(object_id     => $order->id,
2131                      object_type   => $order->type,
2132                      mime_type     => 'application/pdf',
2133                      source        => 'created',
2134                      file_type     => 'document',
2135                      file_name     => $filename,
2136                      file_contents => $content);
2137       1;
2138     } or do {
2139       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2140     };
2141   }
2142
2143   return @errors;
2144 }
2145
2146 sub calculate_stock_in_out_from_stock_info {
2147   my ($self, $unit, $stock_info) = @_;
2148
2149   return "" if !$unit;
2150
2151   my %units_by_name = map { $_->name => $_ } @{ SL::DB::Manager::Unit->get_all };
2152
2153   my $sum      = sum0 map {
2154     $units_by_name{$_->{unit}}->convert_to($_->{qty}, $units_by_name{$unit})
2155   } @$stock_info;
2156
2157   my $content  = _format_number($sum, 2);
2158
2159   return $content;
2160 }
2161
2162 sub calculate_stock_in_out {
2163   my ($self, $item, $stock_info) = @_;
2164
2165   return "" if !$item->part || !$item->part->unit || !$item->unit;
2166
2167   my $sum      = sum0 map {
2168     $_->unit_obj->convert_to($_->qty, $item->unit_obj)
2169   } $item->delivery_order_stock_entries;
2170
2171   my $content  = _format_number($sum, 2);
2172
2173   return $content;
2174 }
2175
2176 sub init_type_data {
2177   SL::Controller::DeliveryOrder::TypeData->new($_[0]);
2178 }
2179
2180 sub init_valid_types {
2181   $_[0]->type_data->valid_types;
2182 }
2183
2184 1;
2185
2186 __END__
2187
2188 =encoding utf-8
2189
2190 =head1 NAME
2191
2192 SL::Controller::Order - controller for orders
2193
2194 =head1 SYNOPSIS
2195
2196 This is a new form to enter orders, completely rewritten with the use
2197 of controller and java script techniques.
2198
2199 The aim is to provide the user a better experience and a faster workflow. Also
2200 the code should be more readable, more reliable and better to maintain.
2201
2202 =head2 Key Features
2203
2204 =over 4
2205
2206 =item *
2207
2208 One input row, so that input happens every time at the same place.
2209
2210 =item *
2211
2212 Use of pickers where possible.
2213
2214 =item *
2215
2216 Possibility to enter more than one item at once.
2217
2218 =item *
2219
2220 Item list in a scrollable area, so that the workflow buttons stay at
2221 the bottom.
2222
2223 =item *
2224
2225 Reordering item rows with drag and drop is possible. Sorting item rows is
2226 possible (by partnumber, description, qty, sellprice and discount for now).
2227
2228 =item *
2229
2230 No C<update> is necessary. All entries and calculations are managed
2231 with ajax-calls and the page only reloads on C<save>.
2232
2233 =item *
2234
2235 User can see changes immediately, because of the use of java script
2236 and ajax.
2237
2238 =back
2239
2240 =head1 CODE
2241
2242 =head2 Layout
2243
2244 =over 4
2245
2246 =item * C<SL/Controller/Order.pm>
2247
2248 the controller
2249
2250 =item * C<template/webpages/delivery_order/form.html>
2251
2252 main form
2253
2254 =item * C<template/webpages/delivery_order/tabs/basic_data.html>
2255
2256 Main tab for basic_data.
2257
2258 This is the only tab here for now. "linked records" and "webdav" tabs are
2259 reused from generic code.
2260
2261 =over 4
2262
2263 =item * C<template/webpages/delivery_order/tabs/_business_info_row.html>
2264
2265 For displaying information on business type
2266
2267 =item * C<template/webpages/delivery_order/tabs/_item_input.html>
2268
2269 The input line for items
2270
2271 =item * C<template/webpages/delivery_order/tabs/_row.html>
2272
2273 One row for already entered items
2274
2275 =item * C<template/webpages/delivery_order/tabs/_tax_row.html>
2276
2277 Displaying tax information
2278
2279 =back
2280
2281 =item * C<js/kivi.DeliveryOrder.js>
2282
2283 java script functions
2284
2285 =back
2286
2287 =head1 TODO
2288
2289 =over 4
2290
2291 =item * testing
2292
2293 =item * price sources: little symbols showing better price / better discount
2294
2295 =item * select units in input row?
2296
2297 =item * check for direct delivery (workflow sales order -> purchase order)
2298
2299 =item * access rights
2300
2301 =item * display weights
2302
2303 =item * mtime check
2304
2305 =item * optional client/user behaviour
2306
2307 (transactions has to be set - department has to be set -
2308  force project if enabled in client config - transport cost reminder)
2309
2310 =back
2311
2312 =head1 KNOWN BUGS AND CAVEATS
2313
2314 =over 4
2315
2316 =item *
2317
2318 Customer discount is not displayed as a valid discount in price source popup
2319 (this might be a bug in price sources)
2320
2321 (I cannot reproduce this (Bernd))
2322
2323 =item *
2324
2325 No indication that <shift>-up/down expands/collapses second row.
2326
2327 =item *
2328
2329 Inline creation of parts is not currently supported
2330
2331 =item *
2332
2333 Table header is not sticky in the scrolling area.
2334
2335 =item *
2336
2337 Sorting does not include C<position>, neither does reordering.
2338
2339 This behavior was implemented intentionally. But we can discuss, which behavior
2340 should be implemented.
2341
2342 =back
2343
2344 =head1 To discuss / Nice to have
2345
2346 =over 4
2347
2348 =item *
2349
2350 How to expand/collapse second row. Now it can be done clicking the icon or
2351 <shift>-up/down.
2352
2353 =item *
2354
2355 Possibility to select PriceSources in input row?
2356
2357 =item *
2358
2359 This controller uses a (changed) copy of the template for the PriceSource
2360 dialog. Maybe there could be used one code source.
2361
2362 =item *
2363
2364 Rounding-differences between this controller (PriceTaxCalculator) and the old
2365 form. This is not only a problem here, but also in all parts using the PTC.
2366 There exists a ticket and a patch. This patch should be testet.
2367
2368 =item *
2369
2370 An indicator, if the actual inputs are saved (like in an
2371 editor or on text processing application).
2372
2373 =item *
2374
2375 A warning when leaving the page without saveing unchanged inputs.
2376
2377
2378 =back
2379
2380 =head1 AUTHOR
2381
2382 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2383
2384 =cut