SL/Controller/DeliveryOrder.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::History;
  17 use SL::DB::Order;
  18 use SL::DB::Default;
  19 use SL::DB::Unit;
  20 use SL::DB::Part;
  21 use SL::DB::PartClassification;
  22 use SL::DB::PartsGroup;
  23 use SL::DB::Printer;
  24 use SL::DB::Language;
  25 use SL::DB::RecordLink;
  26 use SL::DB::Shipto;
  27 use SL::DB::Translation;
  28
  29 use SL::Helper::CreatePDF qw(:all);
  30 use SL::Helper::PrintOptions;
  31 use SL::Helper::ShippedQty;
  32 use SL::Helper::UserPreferences::PositionsScrollbar;
  33 use SL::Helper::UserPreferences::UpdatePositions;
  34
  35 use SL::Controller::Helper::GetModels;
  36
  37 use List::Util qw(first sum0);
  38 use List::UtilsBy qw(sort_by uniq_by);
  39 use List::MoreUtils qw(any none pairwise first_index);
  40 use English qw(-no_match_vars);
  41 use File::Spec;
  42 use Cwd;
  43 use Sort::Naturally;
  44
  45 use Rose::Object::MakeMethods::Generic
  46 (
  47  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  48  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  49 );
  50
  51
  52 # safety
  53 __PACKAGE__->run_before('check_auth');
  54
  55 __PACKAGE__->run_before('recalc',
  56                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  57                                      print send_email) ]);
  58
  59 __PACKAGE__->run_before('get_unalterable_data',
  60                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  61                                      print send_email) ]);
  62
  63 #
  64 # actions
  65 #
  66
  67 # add a new order
  68 sub action_add {
  69   my ($self) = @_;
  70
  71   $self->order->transdate(DateTime->now_local());
  72   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  73                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  74
  75   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  76       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  77       && (!$self->order->reqdate)) {
  78     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  79   }
  80
  81
  82   $self->pre_render();
  83   $self->render(
  84     'order/form',
  85     title => $self->get_title_for('add'),
  86     %{$self->{template_args}}
  87   );
  88 }
  89
  90 # edit an existing order
  91 sub action_edit {
  92   my ($self) = @_;
  93
  94   if ($::form->{id}) {
  95     $self->load_order;
  96
  97   } else {
  98     # this is to edit an order from an unsaved order object
  99
 100     # set item ids to new fake id, to identify them as new items
 101     foreach my $item (@{$self->order->items_sorted}) {
 102       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 103     }
 104     # trigger rendering values for second row as hidden, because they
 105     # are loaded only on demand. So we need to keep the values from
 106     # the source.
 107     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 108   }
 109
 110   $self->recalc();
 111   $self->pre_render();
 112   $self->render(
 113     'order/form',
 114     title => $self->get_title_for('edit'),
 115     %{$self->{template_args}}
 116   );
 117 }
 118
 119 # edit a collective order (consisting of one or more existing orders)
 120 sub action_edit_collective {
 121   my ($self) = @_;
 122
 123   # collect order ids
 124   my @multi_ids = map {
 125     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 126   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 127
 128   # fall back to add if no ids are given
 129   if (scalar @multi_ids == 0) {
 130     $self->action_add();
 131     return;
 132   }
 133
 134   # fall back to save as new if only one id is given
 135   if (scalar @multi_ids == 1) {
 136     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 137     $self->action_save_as_new();
 138     return;
 139   }
 140
 141   # make new order from given orders
 142   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 143   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 144   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 145
 146   $self->action_edit();
 147 }
 148
 149 # delete the order
 150 sub action_delete {
 151   my ($self) = @_;
 152
 153   my $errors = $self->delete();
 154
 155   if (scalar @{ $errors }) {
 156     $self->js->flash('error', $_) foreach @{ $errors };
 157     return $self->js->render();
 158   }
 159
 160   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 161            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 162            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 163            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 164            : '';
 165   flash_later('info', $text);
 166
 167   my @redirect_params = (
 168     action => 'add',
 169     type   => $self->type,
 170   );
 171
 172   $self->redirect_to(@redirect_params);
 173 }
 174
 175 # save the order
 176 sub action_save {
 177   my ($self) = @_;
 178
 179   my $errors = $self->save();
 180
 181   if (scalar @{ $errors }) {
 182     $self->js->flash('error', $_) foreach @{ $errors };
 183     return $self->js->render();
 184   }
 185
 186   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 187            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 188            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 189            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 190            : '';
 191   flash_later('info', $text);
 192
 193   my @redirect_params = (
 194     action => 'edit',
 195     type   => $self->type,
 196     id     => $self->order->id,
 197   );
 198
 199   $self->redirect_to(@redirect_params);
 200 }
 201
 202 # save the order as new document an open it for edit
 203 sub action_save_as_new {
 204   my ($self) = @_;
 205
 206   my $order = $self->order;
 207
 208   if (!$order->id) {
 209     $self->js->flash('error', t8('This object has not been saved yet.'));
 210     return $self->js->render();
 211   }
 212
 213   # load order from db to check if values changed
 214   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 215
 216   my %new_attrs;
 217   # Lets assign a new number if the user hasn't changed the previous one.
 218   # If it has been changed manually then use it as-is.
 219   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 220                         ? ''
 221                         : trim($order->number);
 222
 223   # Clear transdate unless changed
 224   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 225                         ? DateTime->today_local
 226                         : $order->transdate;
 227
 228   # Set new reqdate unless changed if it is enabled in client config
 229   if ($order->reqdate == $saved_order->reqdate) {
 230     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 231                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 232
 233     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 234         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 235       $new_attrs{reqdate} = '';
 236     } else {
 237       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 238     }
 239   } else {
 240     $new_attrs{reqdate} = $order->reqdate;
 241   }
 242
 243   # Update employee
 244   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 245
 246   # Create new record from current one
 247   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 248
 249   # no linked records on save as new
 250   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 251
 252   # save
 253   $self->action_save();
 254 }
 255
 256 # print the order
 257 #
 258 # This is called if "print" is pressed in the print dialog.
 259 # If PDF creation was requested and succeeded, the pdf is offered for download
 260 # via send_file (which uses ajax in this case).
 261 sub action_print {
 262   my ($self) = @_;
 263
 264   my $errors = $self->save();
 265
 266   if (scalar @{ $errors }) {
 267     $self->js->flash('error', $_) foreach @{ $errors };
 268     return $self->js->render();
 269   }
 270
 271   $self->js_reset_order_and_item_ids_after_save;
 272
 273   my $format      = $::form->{print_options}->{format};
 274   my $media       = $::form->{print_options}->{media};
 275   my $formname    = $::form->{print_options}->{formname};
 276   my $copies      = $::form->{print_options}->{copies};
 277   my $groupitems  = $::form->{print_options}->{groupitems};
 278   my $printer_id  = $::form->{print_options}->{printer_id};
 279
 280   # only pdf and opendocument by now
 281   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 282     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 283   }
 284
 285   # only screen or printer by now
 286   if (none { $media eq $_ } qw(screen printer)) {
 287     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 288   }
 289
 290   # create a form for generate_attachment_filename
 291   my $form   = Form->new;
 292   $form->{$self->nr_key()}  = $self->order->number;
 293   $form->{type}             = $self->type;
 294   $form->{format}           = $format;
 295   $form->{formname}         = $formname;
 296   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 297   my $pdf_filename          = $form->generate_attachment_filename();
 298
 299   my $pdf;
 300   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 301                                                    formname   => $formname,
 302                                                    language   => $self->order->language,
 303                                                    printer_id => $printer_id,
 304                                                    groupitems => $groupitems });
 305   if (scalar @errors) {
 306     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 307   }
 308
 309   if ($media eq 'screen') {
 310     # screen/download
 311     $self->js->flash('info', t8('The PDF has been created'));
 312     $self->send_file(
 313       \$pdf,
 314       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 315       name         => $pdf_filename,
 316       js_no_render => 1,
 317     );
 318
 319   } elsif ($media eq 'printer') {
 320     # printer
 321     my $printer_id = $::form->{print_options}->{printer_id};
 322     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 323       copies  => $copies,
 324       content => $pdf,
 325     );
 326
 327     $self->js->flash('info', t8('The PDF has been printed'));
 328   }
 329
 330   my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $pdf_filename);
 331   if (scalar @warnings) {
 332     $self->js->flash('warning', $_) for @warnings;
 333   }
 334
 335   $self->save_history('PRINTED');
 336
 337   $self->js
 338     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 339     ->render;
 340 }
 341 sub action_preview_pdf {
 342   my ($self) = @_;
 343
 344   my $errors = $self->save();
 345   if (scalar @{ $errors }) {
 346     $self->js->flash('error', $_) foreach @{ $errors };
 347     return $self->js->render();
 348   }
 349
 350   $self->js_reset_order_and_item_ids_after_save;
 351
 352   my $format      = 'pdf';
 353   my $media       = 'screen';
 354   my $formname    = $self->type;
 355
 356   # only pdf
 357   # create a form for generate_attachment_filename
 358   my $form   = Form->new;
 359   $form->{$self->nr_key()}  = $self->order->number;
 360   $form->{type}             = $self->type;
 361   $form->{format}           = $format;
 362   $form->{formname}         = $formname;
 363   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 364   my $pdf_filename          = $form->generate_attachment_filename();
 365
 366   my $pdf;
 367   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 368                                                    formname   => $formname,
 369                                                    language   => $self->order->language,
 370                                                  });
 371   if (scalar @errors) {
 372     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 373   }
 374   $self->save_history('PREVIEWED');
 375   $self->js->flash('info', t8('The PDF has been previewed'));
 376   # screen/download
 377   $self->send_file(
 378     \$pdf,
 379     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 380     name         => $pdf_filename,
 381     js_no_render => 0,
 382   );
 383 }
 384
 385 # open the email dialog
 386 sub action_save_and_show_email_dialog {
 387   my ($self) = @_;
 388
 389   my $errors = $self->save();
 390
 391   if (scalar @{ $errors }) {
 392     $self->js->flash('error', $_) foreach @{ $errors };
 393     return $self->js->render();
 394   }
 395
 396   my $cv_method = $self->cv;
 397
 398   if (!$self->order->$cv_method) {
 399     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 400                     ->render($self);
 401   }
 402
 403   my $email_form;
 404   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 405   $email_form->{to} ||= $self->order->$cv_method->email;
 406   $email_form->{cc}   = $self->order->$cv_method->cc;
 407   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 408   # Todo: get addresses from shipto, if any
 409
 410   my $form = Form->new;
 411   $form->{$self->nr_key()}  = $self->order->number;
 412   $form->{cusordnumber}     = $self->order->cusordnumber;
 413   $form->{formname}         = $self->type;
 414   $form->{type}             = $self->type;
 415   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 416   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 417   $form->{format}           = 'pdf';
 418   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 419
 420   $email_form->{subject}             = $form->generate_email_subject();
 421   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 422   $email_form->{message}             = $form->generate_email_body();
 423   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 424
 425   my %files = $self->get_files_for_email_dialog();
 426   $self->{all_employees} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 427   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 428                                   email_form  => $email_form,
 429                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 430                                   FILES       => \%files,
 431                                   is_customer => $self->cv eq 'customer',
 432                                   ALL_EMPLOYEES => $self->{all_employees},
 433   );
 434
 435   $self->js
 436       ->run('kivi.Order.show_email_dialog', $dialog_html)
 437       ->reinit_widgets
 438       ->render($self);
 439 }
 440
 441 # send email
 442 #
 443 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 444 sub action_send_email {
 445   my ($self) = @_;
 446
 447   my $errors = $self->save();
 448
 449   if (scalar @{ $errors }) {
 450     $self->js->run('kivi.Order.close_email_dialog');
 451     $self->js->flash('error', $_) foreach @{ $errors };
 452     return $self->js->render();
 453   }
 454
 455   $self->js_reset_order_and_item_ids_after_save;
 456
 457   my $email_form  = delete $::form->{email_form};
 458   my %field_names = (to => 'email');
 459
 460   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 461
 462   # for Form::cleanup which may be called in Form::send_email
 463   $::form->{cwd}    = getcwd();
 464   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 465
 466   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 467   $::form->{media}  = 'email';
 468
 469   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 470     my $pdf;
 471     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 472                                                     format     => $::form->{print_options}->{format},
 473                                                     formname   => $::form->{print_options}->{formname},
 474                                                     language   => $self->order->language,
 475                                                     printer_id => $::form->{print_options}->{printer_id},
 476                                                     groupitems => $::form->{print_options}->{groupitems}});
 477     if (scalar @errors) {
 478       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 479     }
 480
 481     my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $::form->{attachment_filename});
 482     if (scalar @warnings) {
 483       flash_later('warning', $_) for @warnings;
 484     }
 485
 486     my $sfile = SL::SessionFile::Random->new(mode => "w");
 487     $sfile->fh->print($pdf);
 488     $sfile->fh->close;
 489
 490     $::form->{tmpfile} = $sfile->file_name;
 491     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 492   }
 493
 494   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 495   $::form->send_email(\%::myconfig, 'pdf');
 496
 497   # internal notes
 498   my $intnotes = $self->order->intnotes;
 499   $intnotes   .= "\n\n" if $self->order->intnotes;
 500   $intnotes   .= t8('[email]')                                                                                        . "\n";
 501   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 502   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 503   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 504   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 505   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 506   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 507
 508   $self->order->update_attributes(intnotes => $intnotes);
 509
 510   $self->save_history('MAILED');
 511
 512   flash_later('info', t8('The email has been sent.'));
 513
 514   my @redirect_params = (
 515     action => 'edit',
 516     type   => $self->type,
 517     id     => $self->order->id,
 518   );
 519
 520   $self->redirect_to(@redirect_params);
 521 }
 522
 523 # save the order and redirect to the frontend subroutine for a new
 524 # delivery order
 525 sub action_save_and_delivery_order {
 526   my ($self) = @_;
 527
 528   $self->save_and_redirect_to(
 529     controller => 'oe.pl',
 530     action     => 'oe_delivery_order_from_order',
 531   );
 532 }
 533
 534 # save the order and redirect to the frontend subroutine for a new
 535 # invoice
 536 sub action_save_and_invoice {
 537   my ($self) = @_;
 538
 539   $self->save_and_redirect_to(
 540     controller => 'oe.pl',
 541     action     => 'oe_invoice_from_order',
 542   );
 543 }
 544
 545 # workflow from sales order to sales quotation
 546 sub action_sales_quotation {
 547   $_[0]->workflow_sales_or_request_for_quotation();
 548 }
 549
 550 # workflow from sales order to sales quotation
 551 sub action_request_for_quotation {
 552   $_[0]->workflow_sales_or_request_for_quotation();
 553 }
 554
 555 # workflow from sales quotation to sales order
 556 sub action_sales_order {
 557   $_[0]->workflow_sales_or_purchase_order();
 558 }
 559
 560 # workflow from rfq to purchase order
 561 sub action_purchase_order {
 562   $_[0]->workflow_sales_or_purchase_order();
 563 }
 564
 565 # workflow from purchase order to ap transaction
 566 sub action_save_and_ap_transaction {
 567   my ($self) = @_;
 568
 569   $self->save_and_redirect_to(
 570     controller => 'ap.pl',
 571     action     => 'add_from_purchase_order',
 572   );
 573 }
 574
 575 # set form elements in respect to a changed customer or vendor
 576 #
 577 # This action is called on an change of the customer/vendor picker.
 578 sub action_customer_vendor_changed {
 579   my ($self) = @_;
 580
 581   setup_order_from_cv($self->order);
 582   $self->recalc();
 583
 584   my $cv_method = $self->cv;
 585
 586   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 587     $self->js->show('#cp_row');
 588   } else {
 589     $self->js->hide('#cp_row');
 590   }
 591
 592   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 593     $self->js->show('#shipto_selection');
 594   } else {
 595     $self->js->hide('#shipto_selection');
 596   }
 597
 598   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 599
 600   $self->js
 601     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 602     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 603     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 604     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 605     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 606     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 607     ->val(        '#order_currency_id',      $self->order->currency_id)
 608     ->val(        '#order_payment_id',       $self->order->payment_id)
 609     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 610     ->val(        '#order_intnotes',         $self->order->intnotes)
 611     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 612     ->focus(      '#order_' . $self->cv . '_id')
 613     ->run('kivi.Order.update_exchangerate');
 614
 615   $self->js_redisplay_amounts_and_taxes;
 616   $self->js_redisplay_cvpartnumbers;
 617   $self->js->render();
 618 }
 619
 620 # open the dialog for customer/vendor details
 621 sub action_show_customer_vendor_details_dialog {
 622   my ($self) = @_;
 623
 624   my $is_customer = 'customer' eq $::form->{vc};
 625   my $cv;
 626   if ($is_customer) {
 627     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 628   } else {
 629     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 630   }
 631
 632   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 633   $details{discount_as_percent} = $cv->discount_as_percent;
 634   $details{creditlimt}          = $cv->creditlimit_as_number;
 635   $details{business}            = $cv->business->description      if $cv->business;
 636   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 637   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 638   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 639   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 640
 641   foreach my $entry (@{ $cv->shipto }) {
 642     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 643   }
 644   foreach my $entry (@{ $cv->contacts }) {
 645     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 646   }
 647
 648   $_[0]->render('common/show_vc_details', { layout => 0 },
 649                 is_customer => $is_customer,
 650                 %details);
 651
 652 }
 653
 654 # called if a unit in an existing item row is changed
 655 sub action_unit_changed {
 656   my ($self) = @_;
 657
 658   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 659   my $item = $self->order->items_sorted->[$idx];
 660
 661   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 662   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 663
 664   $self->recalc();
 665
 666   $self->js
 667     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 668   $self->js_redisplay_line_values;
 669   $self->js_redisplay_amounts_and_taxes;
 670   $self->js->render();
 671 }
 672
 673 # add an item row for a new item entered in the input row
 674 sub action_add_item {
 675   my ($self) = @_;
 676
 677   delete $::form->{add_item}->{create_part_type};
 678
 679   my $form_attr = $::form->{add_item};
 680
 681   return unless $form_attr->{parts_id};
 682
 683   my $item = new_item($self->order, $form_attr);
 684
 685   $self->order->add_items($item);
 686
 687   $self->recalc();
 688
 689   $self->get_item_cvpartnumber($item);
 690
 691   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 692   my $row_as_html = $self->p->render('order/tabs/_row',
 693                                      ITEM => $item,
 694                                      ID   => $item_id,
 695                                      SELF => $self,
 696   );
 697
 698   if ($::form->{insert_before_item_id}) {
 699     $self->js
 700       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 701   } else {
 702     $self->js
 703       ->append('#row_table_id', $row_as_html);
 704   }
 705
 706   if ( $item->part->is_assortment ) {
 707     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 708     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 709       my $attr = { parts_id => $assortment_item->parts_id,
 710                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 711                    unit     => $assortment_item->unit,
 712                    description => $assortment_item->part->description,
 713                  };
 714       my $item = new_item($self->order, $attr);
 715
 716       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 717       $item->discount(1) unless $assortment_item->charge;
 718
 719       $self->order->add_items( $item );
 720       $self->recalc();
 721       $self->get_item_cvpartnumber($item);
 722       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 723       my $row_as_html = $self->p->render('order/tabs/_row',
 724                                          ITEM => $item,
 725                                          ID   => $item_id,
 726                                          SELF => $self,
 727       );
 728       if ($::form->{insert_before_item_id}) {
 729         $self->js
 730           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 731       } else {
 732         $self->js
 733           ->append('#row_table_id', $row_as_html);
 734       }
 735     };
 736   };
 737
 738   $self->js
 739     ->val('.add_item_input', '')
 740     ->run('kivi.Order.init_row_handlers')
 741     ->run('kivi.Order.renumber_positions')
 742     ->focus('#add_item_parts_id_name');
 743
 744   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 745
 746   $self->js_redisplay_amounts_and_taxes;
 747   $self->js->render();
 748 }
 749
 750 # add item rows for multiple items at once
 751 sub action_add_multi_items {
 752   my ($self) = @_;
 753
 754   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 755   return $self->js->render() unless scalar @form_attr;
 756
 757   my @items;
 758   foreach my $attr (@form_attr) {
 759     my $item = new_item($self->order, $attr);
 760     push @items, $item;
 761     if ( $item->part->is_assortment ) {
 762       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 763         my $attr = { parts_id => $assortment_item->parts_id,
 764                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 765                      unit     => $assortment_item->unit,
 766                      description => $assortment_item->part->description,
 767                    };
 768         my $item = new_item($self->order, $attr);
 769
 770         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 771         $item->discount(1) unless $assortment_item->charge;
 772         push @items, $item;
 773       }
 774     }
 775   }
 776   $self->order->add_items(@items);
 777
 778   $self->recalc();
 779
 780   foreach my $item (@items) {
 781     $self->get_item_cvpartnumber($item);
 782     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 783     my $row_as_html = $self->p->render('order/tabs/_row',
 784                                        ITEM => $item,
 785                                        ID   => $item_id,
 786                                        SELF => $self,
 787     );
 788
 789     if ($::form->{insert_before_item_id}) {
 790       $self->js
 791         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 792     } else {
 793       $self->js
 794         ->append('#row_table_id', $row_as_html);
 795     }
 796   }
 797
 798   $self->js
 799     ->run('kivi.Part.close_picker_dialogs')
 800     ->run('kivi.Order.init_row_handlers')
 801     ->run('kivi.Order.renumber_positions')
 802     ->focus('#add_item_parts_id_name');
 803
 804   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 805
 806   $self->js_redisplay_amounts_and_taxes;
 807   $self->js->render();
 808 }
 809
 810 # recalculate all linetotals, amounts and taxes and redisplay them
 811 sub action_recalc_amounts_and_taxes {
 812   my ($self) = @_;
 813
 814   $self->recalc();
 815
 816   $self->js_redisplay_line_values;
 817   $self->js_redisplay_amounts_and_taxes;
 818   $self->js->render();
 819 }
 820
 821 sub action_update_exchangerate {
 822   my ($self) = @_;
 823
 824   my $data = {
 825     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 826     currency_name => $self->order->currency->name,
 827     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 828   };
 829
 830   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 831 }
 832
 833 # redisplay item rows if they are sorted by an attribute
 834 sub action_reorder_items {
 835   my ($self) = @_;
 836
 837   my %sort_keys = (
 838     partnumber   => sub { $_[0]->part->partnumber },
 839     description  => sub { $_[0]->description },
 840     qty          => sub { $_[0]->qty },
 841     sellprice    => sub { $_[0]->sellprice },
 842     discount     => sub { $_[0]->discount },
 843     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 844   );
 845
 846   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 847
 848   my $method = $sort_keys{$::form->{order_by}};
 849   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 850   if ($::form->{sort_dir}) {
 851     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 852       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 853     } else {
 854       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 855     }
 856   } else {
 857     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 858       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 859     } else {
 860       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 861     }
 862   }
 863   $self->js
 864     ->run('kivi.Order.redisplay_items', \@to_sort)
 865     ->render;
 866 }
 867
 868 # show the popup to choose a price/discount source
 869 sub action_price_popup {
 870   my ($self) = @_;
 871
 872   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 873   my $item = $self->order->items_sorted->[$idx];
 874
 875   $self->render_price_dialog($item);
 876 }
 877
 878 # save the order in a session variable and redirect to the part controller
 879 sub action_create_part {
 880   my ($self) = @_;
 881
 882   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
 883
 884   my $callback     = $self->url_for(
 885     action       => 'return_from_create_part',
 886     type         => $self->type, # type is needed for check_auth on return
 887     previousform => $previousform,
 888   );
 889
 890   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
 891
 892   my @redirect_params = (
 893     controller => 'Part',
 894     action     => 'add',
 895     part_type  => $::form->{add_item}->{create_part_type},
 896     callback   => $callback,
 897     show_abort => 1,
 898   );
 899
 900   $self->redirect_to(@redirect_params);
 901 }
 902
 903 sub action_return_from_create_part {
 904   my ($self) = @_;
 905
 906   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
 907
 908   $::auth->restore_form_from_session(delete $::form->{previousform});
 909
 910   # set item ids to new fake id, to identify them as new items
 911   foreach my $item (@{$self->order->items_sorted}) {
 912     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 913   }
 914
 915   $self->recalc();
 916   $self->get_unalterable_data();
 917   $self->pre_render();
 918
 919   # trigger rendering values for second row/longdescription as hidden,
 920   # because they are loaded only on demand. So we need to keep the values
 921   # from the source.
 922   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
 923   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 924
 925   $self->render(
 926     'order/form',
 927     title => $self->get_title_for('edit'),
 928     %{$self->{template_args}}
 929   );
 930
 931 }
 932
 933 # load the second row for one or more items
 934 #
 935 # This action gets the html code for all items second rows by rendering a template for
 936 # the second row and sets the html code via client js.
 937 sub action_load_second_rows {
 938   my ($self) = @_;
 939
 940   $self->recalc() if $self->order->is_sales; # for margin calculation
 941
 942   foreach my $item_id (@{ $::form->{item_ids} }) {
 943     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 944     my $item = $self->order->items_sorted->[$idx];
 945
 946     $self->js_load_second_row($item, $item_id, 0);
 947   }
 948
 949   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 950
 951   $self->js->render();
 952 }
 953
 954 # update description, notes and sellprice from master data
 955 sub action_update_row_from_master_data {
 956   my ($self) = @_;
 957
 958   foreach my $item_id (@{ $::form->{item_ids} }) {
 959     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 960     my $item  = $self->order->items_sorted->[$idx];
 961     my $texts = get_part_texts($item->part, $self->order->language_id);
 962
 963     $item->description($texts->{description});
 964     $item->longdescription($texts->{longdescription});
 965
 966     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 967
 968     my $price_src;
 969     if ($item->part->is_assortment) {
 970     # add assortment items with price 0, as the components carry the price
 971       $price_src = $price_source->price_from_source("");
 972       $price_src->price(0);
 973     } else {
 974       $price_src = $price_source->best_price
 975                  ? $price_source->best_price
 976                  : $price_source->price_from_source("");
 977       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
 978       $price_src->price(0) if !$price_source->best_price;
 979     }
 980
 981
 982     $item->sellprice($price_src->price);
 983     $item->active_price_source($price_src);
 984
 985     $self->js
 986       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
 987       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
 988       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
 989       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
 990
 991     if ($self->search_cvpartnumber) {
 992       $self->get_item_cvpartnumber($item);
 993       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
 994     }
 995   }
 996
 997   $self->recalc();
 998   $self->js_redisplay_line_values;
 999   $self->js_redisplay_amounts_and_taxes;
1000
1001   $self->js->render();
1002 }
1003
1004 sub js_load_second_row {
1005   my ($self, $item, $item_id, $do_parse) = @_;
1006
1007   if ($do_parse) {
1008     # Parse values from form (they are formated while rendering (template)).
1009     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1010     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1011     foreach my $var (@{ $item->cvars_by_config }) {
1012       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1013     }
1014     $item->parse_custom_variable_values;
1015   }
1016
1017   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1018
1019   $self->js
1020     ->html('#second_row_' . $item_id, $row_as_html)
1021     ->data('#second_row_' . $item_id, 'loaded', 1);
1022 }
1023
1024 sub js_redisplay_line_values {
1025   my ($self) = @_;
1026
1027   my $is_sales = $self->order->is_sales;
1028
1029   # sales orders with margins
1030   my @data;
1031   if ($is_sales) {
1032     @data = map {
1033       [
1034        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1035        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1036        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1037       ]} @{ $self->order->items_sorted };
1038   } else {
1039     @data = map {
1040       [
1041        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1042       ]} @{ $self->order->items_sorted };
1043   }
1044
1045   $self->js
1046     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1047 }
1048
1049 sub js_redisplay_amounts_and_taxes {
1050   my ($self) = @_;
1051
1052   if (scalar @{ $self->{taxes} }) {
1053     $self->js->show('#taxincluded_row_id');
1054   } else {
1055     $self->js->hide('#taxincluded_row_id');
1056   }
1057
1058   if ($self->order->taxincluded) {
1059     $self->js->hide('#subtotal_row_id');
1060   } else {
1061     $self->js->show('#subtotal_row_id');
1062   }
1063
1064   if ($self->order->is_sales) {
1065     my $is_neg = $self->order->marge_total < 0;
1066     $self->js
1067       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1068       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1069       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1070       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1071       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1072       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1073       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1074       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1075   }
1076
1077   $self->js
1078     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1079     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1080     ->remove('.tax_row')
1081     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1082 }
1083
1084 sub js_redisplay_cvpartnumbers {
1085   my ($self) = @_;
1086
1087   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1088
1089   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1090
1091   $self->js
1092     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1093 }
1094
1095 sub js_reset_order_and_item_ids_after_save {
1096   my ($self) = @_;
1097
1098   $self->js
1099     ->val('#id', $self->order->id)
1100     ->val('#converted_from_oe_id', '')
1101     ->val('#order_' . $self->nr_key(), $self->order->number);
1102
1103   my $idx = 0;
1104   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1105     next if !$self->order->items_sorted->[$idx]->id;
1106     next if $form_item_id !~ m{^new};
1107     $self->js
1108       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1109       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1110       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1111   } continue {
1112     $idx++;
1113   }
1114   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1115 }
1116
1117 #
1118 # helpers
1119 #
1120
1121 sub init_valid_types {
1122   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1123 }
1124
1125 sub init_type {
1126   my ($self) = @_;
1127
1128   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1129     die "Not a valid type for order";
1130   }
1131
1132   $self->type($::form->{type});
1133 }
1134
1135 sub init_cv {
1136   my ($self) = @_;
1137
1138   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1139          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1140          : die "Not a valid type for order";
1141
1142   return $cv;
1143 }
1144
1145 sub init_search_cvpartnumber {
1146   my ($self) = @_;
1147
1148   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1149   my $search_cvpartnumber;
1150   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1151   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1152
1153   return $search_cvpartnumber;
1154 }
1155
1156 sub init_show_update_button {
1157   my ($self) = @_;
1158
1159   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1160 }
1161
1162 sub init_p {
1163   SL::Presenter->get;
1164 }
1165
1166 sub init_order {
1167   $_[0]->make_order;
1168 }
1169
1170 sub init_all_price_factors {
1171   SL::DB::Manager::PriceFactor->get_all;
1172 }
1173
1174 sub init_part_picker_classification_ids {
1175   my ($self)    = @_;
1176   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1177
1178   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1179 }
1180
1181 sub check_auth {
1182   my ($self) = @_;
1183
1184   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1185
1186   my $right   = $right_for->{ $self->type };
1187   $right    ||= 'DOES_NOT_EXIST';
1188
1189   $::auth->assert($right);
1190 }
1191
1192 # build the selection box for contacts
1193 #
1194 # Needed, if customer/vendor changed.
1195 sub build_contact_select {
1196   my ($self) = @_;
1197
1198   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1199     value_key  => 'cp_id',
1200     title_key  => 'full_name_dep',
1201     default    => $self->order->cp_id,
1202     with_empty => 1,
1203     style      => 'width: 300px',
1204   );
1205 }
1206
1207 # build the selection box for shiptos
1208 #
1209 # Needed, if customer/vendor changed.
1210 sub build_shipto_select {
1211   my ($self) = @_;
1212
1213   select_tag('order.shipto_id',
1214              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1215              value_key  => 'shipto_id',
1216              title_key  => 'displayable_id',
1217              default    => $self->order->shipto_id,
1218              with_empty => 0,
1219              style      => 'width: 300px',
1220   );
1221 }
1222
1223 # build the inputs for the cusom shipto dialog
1224 #
1225 # Needed, if customer/vendor changed.
1226 sub build_shipto_inputs {
1227   my ($self) = @_;
1228
1229   my $content = $self->p->render('common/_ship_to_dialog',
1230                                  vc_obj      => $self->order->customervendor,
1231                                  cs_obj      => $self->order->custom_shipto,
1232                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1233                                  id_selector => '#order_shipto_id');
1234
1235   div_tag($content, id => 'shipto_inputs');
1236 }
1237
1238 # render the info line for business
1239 #
1240 # Needed, if customer/vendor changed.
1241 sub build_business_info_row
1242 {
1243   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1244 }
1245
1246 # build the rows for displaying taxes
1247 #
1248 # Called if amounts where recalculated and redisplayed.
1249 sub build_tax_rows {
1250   my ($self) = @_;
1251
1252   my $rows_as_html;
1253   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1254     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1255   }
1256   return $rows_as_html;
1257 }
1258
1259
1260 sub render_price_dialog {
1261   my ($self, $record_item) = @_;
1262
1263   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1264
1265   $self->js
1266     ->run(
1267       'kivi.io.price_chooser_dialog',
1268       t8('Available Prices'),
1269       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1270     )
1271     ->reinit_widgets;
1272
1273 #   if (@errors) {
1274 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1275 #     $self->js->show('#dialog_flash_error');
1276 #   }
1277
1278   $self->js->render;
1279 }
1280
1281 sub load_order {
1282   my ($self) = @_;
1283
1284   return if !$::form->{id};
1285
1286   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1287
1288   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1289   # You need a custom shipto object to call cvars_by_config to get the cvars.
1290   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1291
1292   return $self->order;
1293 }
1294
1295 # load or create a new order object
1296 #
1297 # And assign changes from the form to this object.
1298 # If the order is loaded from db, check if items are deleted in the form,
1299 # remove them form the object and collect them for removing from db on saving.
1300 # Then create/update items from form (via make_item) and add them.
1301 sub make_order {
1302   my ($self) = @_;
1303
1304   # add_items adds items to an order with no items for saving, but they cannot
1305   # be retrieved via items until the order is saved. Adding empty items to new
1306   # order here solves this problem.
1307   my $order;
1308   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1309   $order ||= SL::DB::Order->new(orderitems  => [],
1310                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1311                                 currency_id => $::instance_conf->get_currency_id(),);
1312
1313   my $cv_id_method = $self->cv . '_id';
1314   if (!$::form->{id} && $::form->{$cv_id_method}) {
1315     $order->$cv_id_method($::form->{$cv_id_method});
1316     setup_order_from_cv($order);
1317   }
1318
1319   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1320
1321   $order->assign_attributes(%{$::form->{order}});
1322
1323   $self->setup_custom_shipto_from_form($order, $::form);
1324
1325   # remove deleted items
1326   $self->item_ids_to_delete([]);
1327   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1328     my $item = $order->orderitems->[$idx];
1329     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1330       splice @{$order->orderitems}, $idx, 1;
1331       push @{$self->item_ids_to_delete}, $item->id;
1332     }
1333   }
1334
1335   my @items;
1336   my $pos = 1;
1337   foreach my $form_attr (@{$form_orderitems}) {
1338     my $item = make_item($order, $form_attr);
1339     $item->position($pos);
1340     push @items, $item;
1341     $pos++;
1342   }
1343   $order->add_items(grep {!$_->id} @items);
1344
1345   return $order;
1346 }
1347
1348 # create or update items from form
1349 #
1350 # Make item objects from form values. For items already existing read from db.
1351 # Create a new item else. And assign attributes.
1352 sub make_item {
1353   my ($record, $attr) = @_;
1354
1355   my $item;
1356   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1357
1358   my $is_new = !$item;
1359
1360   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1361   # they cannot be retrieved via custom_variables until the order/orderitem is
1362   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1363   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1364
1365   $item->assign_attributes(%$attr);
1366
1367   if ($is_new) {
1368     my $texts = get_part_texts($item->part, $record->language_id);
1369     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1370     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1371     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1372   }
1373
1374   return $item;
1375 }
1376
1377 # create a new item
1378 #
1379 # This is used to add one item
1380 sub new_item {
1381   my ($record, $attr) = @_;
1382
1383   my $item = SL::DB::OrderItem->new;
1384
1385   # Remove attributes where the user left or set the inputs empty.
1386   # So these attributes will be undefined and we can distinguish them
1387   # from zero later on.
1388   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1389     delete $attr->{$_} if $attr->{$_} eq '';
1390   }
1391
1392   $item->assign_attributes(%$attr);
1393
1394   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1395   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1396
1397   $item->unit($part->unit) if !$item->unit;
1398
1399   my $price_src;
1400   if ( $part->is_assortment ) {
1401     # add assortment items with price 0, as the components carry the price
1402     $price_src = $price_source->price_from_source("");
1403     $price_src->price(0);
1404   } elsif (defined $item->sellprice) {
1405     $price_src = $price_source->price_from_source("");
1406     $price_src->price($item->sellprice);
1407   } else {
1408     $price_src = $price_source->best_price
1409                ? $price_source->best_price
1410                : $price_source->price_from_source("");
1411     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1412     $price_src->price(0) if !$price_source->best_price;
1413   }
1414
1415   my $discount_src;
1416   if (defined $item->discount) {
1417     $discount_src = $price_source->discount_from_source("");
1418     $discount_src->discount($item->discount);
1419   } else {
1420     $discount_src = $price_source->best_discount
1421                   ? $price_source->best_discount
1422                   : $price_source->discount_from_source("");
1423     $discount_src->discount(0) if !$price_source->best_discount;
1424   }
1425
1426   my %new_attr;
1427   $new_attr{part}                   = $part;
1428   $new_attr{description}            = $part->description     if ! $item->description;
1429   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1430   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1431   $new_attr{sellprice}              = $price_src->price;
1432   $new_attr{discount}               = $discount_src->discount;
1433   $new_attr{active_price_source}    = $price_src;
1434   $new_attr{active_discount_source} = $discount_src;
1435   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1436   $new_attr{project_id}             = $record->globalproject_id;
1437   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1438
1439   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1440   # they cannot be retrieved via custom_variables until the order/orderitem is
1441   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1442   $new_attr{custom_variables} = [];
1443
1444   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1445
1446   $item->assign_attributes(%new_attr, %{ $texts });
1447
1448   return $item;
1449 }
1450
1451 sub setup_order_from_cv {
1452   my ($order) = @_;
1453
1454   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1455
1456   $order->intnotes($order->customervendor->notes);
1457
1458   if ($order->is_sales) {
1459     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1460     $order->taxincluded(defined($order->customer->taxincluded_checked)
1461                         ? $order->customer->taxincluded_checked
1462                         : $::myconfig{taxincluded_checked});
1463   }
1464
1465 }
1466
1467 # setup custom shipto from form
1468 #
1469 # The dialog returns form variables starting with 'shipto' and cvars starting
1470 # with 'shiptocvar_'.
1471 # Mark it to be deleted if a shipto from master data is selected
1472 # (i.e. order has a shipto).
1473 # Else, update or create a new custom shipto. If the fields are empty, it
1474 # will not be saved on save.
1475 sub setup_custom_shipto_from_form {
1476   my ($self, $order, $form) = @_;
1477
1478   if ($order->shipto) {
1479     $self->is_custom_shipto_to_delete(1);
1480   } else {
1481     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1482
1483     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1484     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1485
1486     $custom_shipto->assign_attributes(%$shipto_attrs);
1487     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1488   }
1489 }
1490
1491 # recalculate prices and taxes
1492 #
1493 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1494 sub recalc {
1495   my ($self) = @_;
1496
1497   my %pat = $self->order->calculate_prices_and_taxes();
1498
1499   $self->{taxes} = [];
1500   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1501     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1502
1503     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1504                                 netamount => $netamount,
1505                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1506   }
1507   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1508 }
1509
1510 # get data for saving, printing, ..., that is not changed in the form
1511 #
1512 # Only cvars for now.
1513 sub get_unalterable_data {
1514   my ($self) = @_;
1515
1516   foreach my $item (@{ $self->order->items }) {
1517     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1518     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1519     foreach my $var (@{ $item->cvars_by_config }) {
1520       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1521     }
1522     $item->parse_custom_variable_values;
1523   }
1524 }
1525
1526 # delete the order
1527 #
1528 # And remove related files in the spool directory
1529 sub delete {
1530   my ($self) = @_;
1531
1532   my $errors = [];
1533   my $db     = $self->order->db;
1534
1535   $db->with_transaction(
1536     sub {
1537       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1538       $self->order->delete;
1539       my $spool = $::lx_office_conf{paths}->{spool};
1540       unlink map { "$spool/$_" } @spoolfiles if $spool;
1541
1542       $self->save_history('DELETED');
1543
1544       1;
1545   }) || push(@{$errors}, $db->error);
1546
1547   return $errors;
1548 }
1549
1550 # save the order
1551 #
1552 # And delete items that are deleted in the form.
1553 sub save {
1554   my ($self) = @_;
1555
1556   my $errors = [];
1557   my $db     = $self->order->db;
1558
1559   $db->with_transaction(sub {
1560     # delete custom shipto if it is to be deleted or if it is empty
1561     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1562       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1563       $self->order->custom_shipto(undef);
1564     }
1565
1566     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1567     $self->order->save(cascade => 1);
1568
1569     # link records
1570     if ($::form->{converted_from_oe_id}) {
1571       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1572       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1573         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1574         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1575         $src->link_to_record($self->order);
1576       }
1577       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1578         my $idx = 0;
1579         foreach (@{ $self->order->items_sorted }) {
1580           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1581           next if !$from_id;
1582           SL::DB::RecordLink->new(from_table => 'orderitems',
1583                                   from_id    => $from_id,
1584                                   to_table   => 'orderitems',
1585                                   to_id      => $_->id
1586           )->save;
1587           $idx++;
1588         }
1589       }
1590     }
1591
1592     $self->save_history('SAVED');
1593
1594     1;
1595   }) || push(@{$errors}, $db->error);
1596
1597   return $errors;
1598 }
1599
1600 sub workflow_sales_or_request_for_quotation {
1601   my ($self) = @_;
1602
1603   # always save
1604   my $errors = $self->save();
1605
1606   if (scalar @{ $errors }) {
1607     $self->js->flash('error', $_) for @{ $errors };
1608     return $self->js->render();
1609   }
1610
1611   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1612
1613   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1614   $self->{converted_from_oe_id} = delete $::form->{id};
1615
1616   # set item ids to new fake id, to identify them as new items
1617   foreach my $item (@{$self->order->items_sorted}) {
1618     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1619   }
1620
1621   # change form type
1622   $::form->{type} = $destination_type;
1623   $self->type($self->init_type);
1624   $self->cv  ($self->init_cv);
1625   $self->check_auth;
1626
1627   $self->recalc();
1628   $self->get_unalterable_data();
1629   $self->pre_render();
1630
1631   # trigger rendering values for second row as hidden, because they
1632   # are loaded only on demand. So we need to keep the values from the
1633   # source.
1634   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1635
1636   $self->render(
1637     'order/form',
1638     title => $self->get_title_for('edit'),
1639     %{$self->{template_args}}
1640   );
1641 }
1642
1643 sub workflow_sales_or_purchase_order {
1644   my ($self) = @_;
1645
1646   # always save
1647   my $errors = $self->save();
1648
1649   if (scalar @{ $errors }) {
1650     $self->js->flash('error', $_) foreach @{ $errors };
1651     return $self->js->render();
1652   }
1653
1654   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1655                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1656                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1657                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1658                        : '';
1659
1660   # check for direct delivery
1661   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1662   my $custom_shipto;
1663   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1664       && $::form->{use_shipto} && $self->order->shipto) {
1665     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1666   }
1667
1668   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1669   $self->{converted_from_oe_id} = delete $::form->{id};
1670
1671   # set item ids to new fake id, to identify them as new items
1672   foreach my $item (@{$self->order->items_sorted}) {
1673     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1674   }
1675
1676   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1677     if ($::form->{use_shipto}) {
1678       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1679     } else {
1680       # remove any custom shipto if not wanted
1681       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1682     }
1683   }
1684
1685   # change form type
1686   $::form->{type} = $destination_type;
1687   $self->type($self->init_type);
1688   $self->cv  ($self->init_cv);
1689   $self->check_auth;
1690
1691   $self->recalc();
1692   $self->get_unalterable_data();
1693   $self->pre_render();
1694
1695   # trigger rendering values for second row as hidden, because they
1696   # are loaded only on demand. So we need to keep the values from the
1697   # source.
1698   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1699
1700   $self->render(
1701     'order/form',
1702     title => $self->get_title_for('edit'),
1703     %{$self->{template_args}}
1704   );
1705 }
1706
1707
1708 sub pre_render {
1709   my ($self) = @_;
1710
1711   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1712   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1713   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1714   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1715   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1716                                                                                               deleted => 0 ] ],
1717                                                                            sort_by => 'name');
1718   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1719                                                                                               deleted => 0 ] ],
1720                                                                            sort_by => 'name');
1721   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1722                                                                                                         obsolete => 0 ] ]);
1723   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1724   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1725   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1726   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1727
1728   my $print_form = Form->new('');
1729   $print_form->{type}        = $self->type;
1730   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1731   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1732     form => $print_form,
1733     options => {dialog_name_prefix => 'print_options.',
1734                 show_headers       => 1,
1735                 no_queue           => 1,
1736                 no_postscript      => 1,
1737                 no_opendocument    => 0,
1738                 no_html            => 1},
1739   );
1740
1741   foreach my $item (@{$self->order->orderitems}) {
1742     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1743     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1744     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1745   }
1746
1747   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1748     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1749     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1750     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1751     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1752   }
1753
1754   if ($self->order->number && $::instance_conf->get_webdav) {
1755     my $webdav = SL::Webdav->new(
1756       type     => $self->type,
1757       number   => $self->order->number,
1758     );
1759     my @all_objects = $webdav->get_all_objects;
1760     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1761                                                     type => t8('File'),
1762                                                     link => File::Spec->catfile($_->full_filedescriptor),
1763                                                 } } @all_objects;
1764   }
1765
1766   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1767
1768   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1769                                                          calculate_qty kivi.Validator follow_up show_history);
1770   $self->setup_edit_action_bar;
1771 }
1772
1773 sub setup_edit_action_bar {
1774   my ($self, %params) = @_;
1775
1776   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1777                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1778                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1779
1780   for my $bar ($::request->layout->get('actionbar')) {
1781     $bar->add(
1782       combobox => [
1783         action => [
1784           t8('Save'),
1785           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1786                                                     $::instance_conf->get_order_warn_no_deliverydate,
1787                                                                                                       ],
1788         ],
1789         action => [
1790           t8('Save as new'),
1791           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1792           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1793         ],
1794       ], # end of combobox "Save"
1795
1796       combobox => [
1797         action => [
1798           t8('Workflow'),
1799         ],
1800         action => [
1801           t8('Save and Quotation'),
1802           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1803           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1804         ],
1805         action => [
1806           t8('Save and RFQ'),
1807           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1808           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1809         ],
1810         action => [
1811           t8('Save and Sales Order'),
1812           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1813           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1814         ],
1815         action => [
1816           t8('Save and Purchase Order'),
1817           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1818           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1819         ],
1820         action => [
1821           t8('Save and Delivery Order'),
1822           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1823                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1824                                                                                                                         ],
1825           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1826         ],
1827         action => [
1828           t8('Save and Invoice'),
1829           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1830         ],
1831         action => [
1832           t8('Save and AP Transaction'),
1833           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1834           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1835         ],
1836
1837       ], # end of combobox "Workflow"
1838
1839       combobox => [
1840         action => [
1841           t8('Export'),
1842         ],
1843         action => [
1844           t8('Save and preview PDF'),
1845            call => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
1846                                                        $::instance_conf->get_order_warn_no_deliverydate,
1847                                                                                                          ],
1848         ],
1849         action => [
1850           t8('Save and print'),
1851           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
1852                                                      $::instance_conf->get_order_warn_no_deliverydate,
1853                                                                                                       ],
1854         ],
1855         action => [
1856           t8('Save and E-mail'),
1857           id   => 'save_and_email_action',
1858           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
1859                                                                      $::instance_conf->get_order_warn_no_deliverydate,
1860                   ],
1861           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1862         ],
1863         action => [
1864           t8('Download attachments of all parts'),
1865           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1866           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1867           only_if  => $::instance_conf->get_doc_storage,
1868         ],
1869       ], # end of combobox "Export"
1870
1871       action => [
1872         t8('Delete'),
1873         call     => [ 'kivi.Order.delete_order' ],
1874         confirm  => $::locale->text('Do you really want to delete this object?'),
1875         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1876         only_if  => $deletion_allowed,
1877       ],
1878
1879       combobox => [
1880         action => [
1881           t8('more')
1882         ],
1883         action => [
1884           t8('Follow-Up'),
1885           call     => [ 'kivi.Order.follow_up_window' ],
1886           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1887           only_if  => $::auth->assert('productivity', 1),
1888         ],
1889         action => [
1890           t8('History'),
1891           call     => [ 'set_history_window', $self->order->id, 'id' ],
1892           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
1893         ],
1894       ], # end of combobox "more"
1895     );
1896   }
1897 }
1898
1899 sub generate_pdf {
1900   my ($order, $pdf_ref, $params) = @_;
1901
1902   my @errors = ();
1903
1904   my $print_form = Form->new('');
1905   $print_form->{type}        = $order->type;
1906   $print_form->{formname}    = $params->{formname} || $order->type;
1907   $print_form->{format}      = $params->{format}   || 'pdf';
1908   $print_form->{media}       = $params->{media}    || 'file';
1909   $print_form->{groupitems}  = $params->{groupitems};
1910   $print_form->{printer_id}  = $params->{printer_id};
1911   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1912
1913   $order->language($params->{language});
1914   $order->flatten_to_form($print_form, format_amounts => 1);
1915
1916   my $template_ext;
1917   my $template_type;
1918   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1919     $template_ext  = 'odt';
1920     $template_type = 'OpenDocument';
1921   }
1922
1923   # search for the template
1924   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1925     name        => $print_form->{formname},
1926     extension   => $template_ext,
1927     email       => $print_form->{media} eq 'email',
1928     language    => $params->{language},
1929     printer_id  => $print_form->{printer_id},
1930   );
1931
1932   if (!defined $template_file) {
1933     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1934   }
1935
1936   return @errors if scalar @errors;
1937
1938   $print_form->throw_on_error(sub {
1939     eval {
1940       $print_form->prepare_for_printing;
1941
1942       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1943         format        => $print_form->{format},
1944         template_type => $template_type,
1945         template      => $template_file,
1946         variables     => $print_form,
1947         variable_content_types => {
1948           longdescription => 'html',
1949           partnotes       => 'html',
1950           notes           => 'html',
1951         },
1952       );
1953       1;
1954     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1955   });
1956
1957   return @errors;
1958 }
1959
1960 sub get_files_for_email_dialog {
1961   my ($self) = @_;
1962
1963   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1964
1965   return %files if !$::instance_conf->get_doc_storage;
1966
1967   if ($self->order->id) {
1968     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1969     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1970     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1971     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
1972   }
1973
1974   my @parts =
1975     uniq_by { $_->{id} }
1976     map {
1977       +{ id         => $_->part->id,
1978          partnumber => $_->part->partnumber }
1979     } @{$self->order->items_sorted};
1980
1981   foreach my $part (@parts) {
1982     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1983     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1984   }
1985
1986   foreach my $key (keys %files) {
1987     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1988   }
1989
1990   return %files;
1991 }
1992
1993 sub get_title_for {
1994   my ($self, $action) = @_;
1995
1996   return '' if none { lc($action)} qw(add edit);
1997
1998   # for locales:
1999   # $::locale->text("Add Sales Order");
2000   # $::locale->text("Add Purchase Order");
2001   # $::locale->text("Add Quotation");
2002   # $::locale->text("Add Request for Quotation");
2003   # $::locale->text("Edit Sales Order");
2004   # $::locale->text("Edit Purchase Order");
2005   # $::locale->text("Edit Quotation");
2006   # $::locale->text("Edit Request for Quotation");
2007
2008   $action = ucfirst(lc($action));
2009   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2010        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2011        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2012        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2013        : '';
2014 }
2015
2016 sub get_item_cvpartnumber {
2017   my ($self, $item) = @_;
2018
2019   return if !$self->search_cvpartnumber;
2020   return if !$self->order->customervendor;
2021
2022   if ($self->cv eq 'vendor') {
2023     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2024     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2025   } elsif ($self->cv eq 'customer') {
2026     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2027     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2028   }
2029 }
2030
2031 sub get_part_texts {
2032   my ($part_or_id, $language_or_id, %defaults) = @_;
2033
2034   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2035   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2036   my $texts       = {
2037     description     => $defaults{description}     // $part->description,
2038     longdescription => $defaults{longdescription} // $part->notes,
2039   };
2040
2041   return $texts unless $language_id;
2042
2043   my $translation = SL::DB::Manager::Translation->get_first(
2044     where => [
2045       parts_id    => $part->id,
2046       language_id => $language_id,
2047     ]);
2048
2049   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2050   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2051
2052   return $texts;
2053 }
2054
2055 sub sales_order_type {
2056   'sales_order';
2057 }
2058
2059 sub purchase_order_type {
2060   'purchase_order';
2061 }
2062
2063 sub sales_quotation_type {
2064   'sales_quotation';
2065 }
2066
2067 sub request_quotation_type {
2068   'request_quotation';
2069 }
2070
2071 sub nr_key {
2072   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2073        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2074        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2075        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2076        : '';
2077 }
2078
2079 sub save_and_redirect_to {
2080   my ($self, %params) = @_;
2081
2082   my $errors = $self->save();
2083
2084   if (scalar @{ $errors }) {
2085     $self->js->flash('error', $_) foreach @{ $errors };
2086     return $self->js->render();
2087   }
2088
2089   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2090            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2091            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2092            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2093            : '';
2094   flash_later('info', $text);
2095
2096   $self->redirect_to(%params, id => $self->order->id);
2097 }
2098
2099 sub save_history {
2100   my ($self, $addition) = @_;
2101
2102   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2103   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2104
2105   SL::DB::History->new(
2106     trans_id    => $self->order->id,
2107     employee_id => SL::DB::Manager::Employee->current->id,
2108     what_done   => $self->order->type,
2109     snumbers    => $snumbers,
2110     addition    => $addition,
2111   )->save;
2112 }
2113
2114 sub store_pdf_to_webdav_and_filemanagement {
2115   my($order, $content, $filename) = @_;
2116
2117   my @errors;
2118
2119   # copy file to webdav folder
2120   if ($order->number && $::instance_conf->get_webdav_documents) {
2121     my $webdav = SL::Webdav->new(
2122       type     => $order->type,
2123       number   => $order->number,
2124     );
2125     my $webdav_file = SL::Webdav::File->new(
2126       webdav   => $webdav,
2127       filename => $filename,
2128     );
2129     eval {
2130       $webdav_file->store(data => \$content);
2131       1;
2132     } or do {
2133       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2134     };
2135   }
2136   if ($order->id && $::instance_conf->get_doc_storage) {
2137     eval {
2138       SL::File->save(object_id     => $order->id,
2139                      object_type   => $order->type,
2140                      mime_type     => 'application/pdf',
2141                      source        => 'created',
2142                      file_type     => 'document',
2143                      file_name     => $filename,
2144                      file_contents => $content);
2145       1;
2146     } or do {
2147       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2148     };
2149   }
2150
2151   return @errors;
2152 }
2153
2154 1;
2155
2156 __END__
2157
2158 =encoding utf-8
2159
2160 =head1 NAME
2161
2162 SL::Controller::Order - controller for orders
2163
2164 =head1 SYNOPSIS
2165
2166 This is a new form to enter orders, completely rewritten with the use
2167 of controller and java script techniques.
2168
2169 The aim is to provide the user a better experience and a faster workflow. Also
2170 the code should be more readable, more reliable and better to maintain.
2171
2172 =head2 Key Features
2173
2174 =over 4
2175
2176 =item *
2177
2178 One input row, so that input happens every time at the same place.
2179
2180 =item *
2181
2182 Use of pickers where possible.
2183
2184 =item *
2185
2186 Possibility to enter more than one item at once.
2187
2188 =item *
2189
2190 Item list in a scrollable area, so that the workflow buttons stay at
2191 the bottom.
2192
2193 =item *
2194
2195 Reordering item rows with drag and drop is possible. Sorting item rows is
2196 possible (by partnumber, description, qty, sellprice and discount for now).
2197
2198 =item *
2199
2200 No C<update> is necessary. All entries and calculations are managed
2201 with ajax-calls and the page only reloads on C<save>.
2202
2203 =item *
2204
2205 User can see changes immediately, because of the use of java script
2206 and ajax.
2207
2208 =back
2209
2210 =head1 CODE
2211
2212 =head2 Layout
2213
2214 =over 4
2215
2216 =item * C<SL/Controller/Order.pm>
2217
2218 the controller
2219
2220 =item * C<template/webpages/order/form.html>
2221
2222 main form
2223
2224 =item * C<template/webpages/order/tabs/basic_data.html>
2225
2226 Main tab for basic_data.
2227
2228 This is the only tab here for now. "linked records" and "webdav" tabs are
2229 reused from generic code.
2230
2231 =over 4
2232
2233 =item * C<template/webpages/order/tabs/_business_info_row.html>
2234
2235 For displaying information on business type
2236
2237 =item * C<template/webpages/order/tabs/_item_input.html>
2238
2239 The input line for items
2240
2241 =item * C<template/webpages/order/tabs/_row.html>
2242
2243 One row for already entered items
2244
2245 =item * C<template/webpages/order/tabs/_tax_row.html>
2246
2247 Displaying tax information
2248
2249 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2250
2251 Dialog for selecting price and discount sources
2252
2253 =back
2254
2255 =item * C<js/kivi.Order.js>
2256
2257 java script functions
2258
2259 =back
2260
2261 =head1 TODO
2262
2263 =over 4
2264
2265 =item * testing
2266
2267 =item * price sources: little symbols showing better price / better discount
2268
2269 =item * select units in input row?
2270
2271 =item * check for direct delivery (workflow sales order -> purchase order)
2272
2273 =item * access rights
2274
2275 =item * display weights
2276
2277 =item * mtime check
2278
2279 =item * optional client/user behaviour
2280
2281 (transactions has to be set - department has to be set -
2282  force project if enabled in client config - transport cost reminder)
2283
2284 =back
2285
2286 =head1 KNOWN BUGS AND CAVEATS
2287
2288 =over 4
2289
2290 =item *
2291
2292 Customer discount is not displayed as a valid discount in price source popup
2293 (this might be a bug in price sources)
2294
2295 (I cannot reproduce this (Bernd))
2296
2297 =item *
2298
2299 No indication that <shift>-up/down expands/collapses second row.
2300
2301 =item *
2302
2303 Inline creation of parts is not currently supported
2304
2305 =item *
2306
2307 Table header is not sticky in the scrolling area.
2308
2309 =item *
2310
2311 Sorting does not include C<position>, neither does reordering.
2312
2313 This behavior was implemented intentionally. But we can discuss, which behavior
2314 should be implemented.
2315
2316 =back
2317
2318 =head1 To discuss / Nice to have
2319
2320 =over 4
2321
2322 =item *
2323
2324 How to expand/collapse second row. Now it can be done clicking the icon or
2325 <shift>-up/down.
2326
2327 =item *
2328
2329 Possibility to select PriceSources in input row?
2330
2331 =item *
2332
2333 This controller uses a (changed) copy of the template for the PriceSource
2334 dialog. Maybe there could be used one code source.
2335
2336 =item *
2337
2338 Rounding-differences between this controller (PriceTaxCalculator) and the old
2339 form. This is not only a problem here, but also in all parts using the PTC.
2340 There exists a ticket and a patch. This patch should be testet.
2341
2342 =item *
2343
2344 An indicator, if the actual inputs are saved (like in an
2345 editor or on text processing application).
2346
2347 =item *
2348
2349 A warning when leaving the page without saveing unchanged inputs.
2350
2351
2352 =back
2353
2354 =head1 AUTHOR
2355
2356 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2357
2358 =cut