SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::DB::Business;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::Locale::String;
  12 use SL::AM;
  13 use SL::DBUtils ();
  14 use Carp;
  15
  16 use Rose::Object::MakeMethods::Generic (
  17   scalar => [ qw(db_args flat_filter) ],
  18   'scalar --get_set_init' => [ qw(models all_edit_right vc use_linked_items all_employees all_businesses) ],
  19 );
  20
  21 __PACKAGE__->run_before(sub { $::auth->assert('delivery_plan'); });
  22
  23 my %sort_columns = (
  24   reqdate           => t8('Reqdate'),
  25   description       => t8('Description'),
  26   partnumber        => t8('Part Number'),
  27   qty               => t8('Qty'),
  28   shipped_qty       => t8('shipped'),
  29   delivered_qty     => t8('transferred in / out'),
  30   not_shipped_qty   => t8('not shipped'),
  31   ordnumber         => t8('Order'),
  32   customer          => t8('Customer'),
  33   vendor            => t8('Vendor'),
  34 );
  35
  36
  37 sub action_list {
  38   my ($self) = @_;
  39   $self->make_filter_summary;
  40   $self->prepare_report;
  41
  42   my $orderitems = $self->models->get;
  43   $self->calc_qtys($orderitems);
  44   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
  45 }
  46
  47 # private functions
  48 #
  49 sub prepare_report {
  50   my ($self)      = @_;
  51
  52   my $vc          = $self->vc;
  53   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  54   $self->{report} = $report;
  55
  56   my @columns     = qw(reqdate customer vendor ordnumber partnumber description qty shipped_qty not_shipped_qty delivered_qty);
  57
  58   my @sortable    = qw(reqdate customer vendor ordnumber partnumber description);
  59
  60   my %column_defs = (
  61     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
  62     description       => {      sub => sub { $_[0]->description                                                              },
  63                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  64     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
  65                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  66     qty               => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit                                        } },
  67     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]{shipped_qty}, 2) . ' ' . $_[0]->unit } },
  68     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]{shipped_qty}, 2) . ' ' . $_[0]->unit } },
  69     delivered_qty     => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]{delivered_qty}, 2) .' ' . $_[0]->unit } },
  70     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
  71                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
  72     vendor            => {      sub => sub { $_[0]->order->vendor->name                                                      },
  73                             visible => $vc eq 'vendor',
  74                            obj_link => sub { $self->link_to($_[0]->order->vendor)                                            } },
  75     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
  76                             visible => $vc eq 'customer',
  77                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
  78   );
  79
  80   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
  81
  82   $report->set_options(
  83     std_column_visibility => 1,
  84     controller_class      => 'DeliveryPlan',
  85     output_format         => 'HTML',
  86     top_info_text         => ($vc eq 'customer') ? $::locale->text('Delivery Plan for currently outstanding sales orders') :
  87                                                    $::locale->text('Delivery Plan for currently outstanding purchase orders'),
  88     title                 => $::locale->text('Delivery Plan'),
  89     allow_pdf_export      => 1,
  90     allow_csv_export      => 1,
  91   );
  92   $report->set_columns(%column_defs);
  93   $report->set_column_order(@columns);
  94   $report->set_export_options(qw(list filter vc use_linked_items));
  95   $report->set_options_from_form;
  96   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
  97   $self->models->finalize; # for filter laundering
  98   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
  99   $report->set_options(
 100     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }),
 101     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
 102   );
 103 }
 104
 105 sub calc_qtys {
 106   my ($self, $orderitems) = @_;
 107   # using $orderitem->shipped_qty 40 times is far too slow. need to do it manually
 108   #
 109
 110   return unless scalar @$orderitems;
 111
 112   my %orderitems_by_id = map { $_->id => $_ } @$orderitems;
 113
 114   my $query = $self->use_linked_items ? _calc_qtys_query_linked_items(scalar @$orderitems)
 115             :                           _calc_qtys_query_match_parts(scalar @$orderitems);
 116
 117   my $result = SL::DBUtils::selectall_hashref_query($::form, $::form->get_standard_dbh, $query, map { $_->id } @$orderitems);
 118
 119   for my $row (@$result) {
 120     my $item = $orderitems_by_id{ $row->{id} };
 121     $item->{shipped_qty}   ||= 0;
 122     $item->{delivered_qty} ||= 0;
 123     $item->{shipped_qty}    += AM->convert_unit($row->{unit} => $item->unit) * $row->{qty};
 124     $item->{delivered_qty}  += AM->convert_unit($row->{unit} => $item->unit) * $row->{qty} if $row->{delivered};
 125   }
 126 }
 127
 128 sub _calc_qtys_query_match_parts {
 129   my ($num_items) = @_;
 130
 131   my $query = <<SQL;
 132     SELECT oi.id, doi.qty, doi.unit, doe.delivered
 133     FROM record_links rl
 134     INNER JOIN delivery_order_items doi ON (doi.delivery_order_id = rl.to_id)
 135     INNER JOIN delivery_orders doe ON (doe.id = rl.to_id)
 136     INNER JOIN orderitems oi ON (oi.trans_id = rl.from_id)
 137     WHERE rl.from_table = 'oe'
 138       AND rl.to_table   = 'delivery_orders'
 139       AND oi.parts_id   = doi.parts_id
 140       AND oi.id IN (@{[ join ', ', ("?")x $num_items ]})
 141 SQL
 142
 143   return $query;
 144 }
 145
 146 sub _calc_qtys_query_linked_items {
 147   my ($num_items) = @_;
 148
 149   my $query = <<SQL;
 150     SELECT rl.from_id as id, doi.qty, doi.unit, doe.delivered
 151     FROM record_links rl
 152     INNER JOIN delivery_order_items doi ON (doi.id = rl.to_id)
 153     INNER JOIN delivery_orders doe ON (doe.id = doi.delivery_order_id)
 154     WHERE rl.from_table LIKE 'orderitems'
 155       AND rl.to_table   LIKE 'delivery_order_items'
 156       AND rl.from_id IN (@{[ join ', ', ("?")x $num_items ]})
 157 SQL
 158
 159   return $query;
 160 }
 161
 162 sub make_filter_summary {
 163   my ($self) = @_;
 164   my $vc     = $self->vc;
 165   my ($business, $employee);
 166
 167   my $filter = $::form->{filter} || {};
 168   my @filter_strings;
 169
 170   $business = SL::DB::Business->new(id => $filter->{order}{customer}{"business_id"})->load->description if $filter->{order}{customer}{"business_id"};
 171   $employee = SL::DB::Employee->new(id => $filter->{order}{employee_id})->load->name if $filter->{order}{employee_id};
 172
 173   my @filters = (
 174     [ $filter->{order}{"ordnumber:substr::ilike"},                    $::locale->text('Number')                                             ],
 175     [ $filter->{order}{globalproject}{"projectnumber:substr::ilike"}, $::locale->text('Document Project Number')                            ],
 176     [ $filter->{part}{"partnumber:substr::ilike"},                    $::locale->text('Part Number')                                        ],
 177     [ $filter->{"description:substr::ilike"},                         $::locale->text('Part Description')                                   ],
 178     [ $filter->{"reqdate:date::ge"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 179     [ $filter->{"reqdate:date::le"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 180     [ $filter->{"qty:number"},                                        $::locale->text('Quantity')                                           ],
 181     [ $filter->{order}{vendor}{"name:substr::ilike"},                 $::locale->text('Vendor')                                             ],
 182     [ $filter->{order}{vendor}{"vendornumber:substr::ilike"},         $::locale->text('Vendor Number')                                      ],
 183     [ $filter->{order}{customer}{"name:substr::ilike"},               $::locale->text('Customer')                                           ],
 184     [ $filter->{order}{customer}{"customernumber:substr::ilike"},     $::locale->text('Customer Number')                                    ],
 185     [ $business,                                                      $::locale->text('Customer type')                                      ],
 186     [ $employee,                                                      $::locale->text('Employee')                                           ],
 187   );
 188
 189   my %flags = (
 190     part     => $::locale->text('Parts'),
 191     service  => $::locale->text('Services'),
 192     assembly => $::locale->text('Assemblies'),
 193   );
 194   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 195
 196   for (@flags) {
 197     push @filter_strings, $_ if $_;
 198   }
 199   for (@filters) {
 200     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 201   }
 202
 203   $self->{filter_summary} = join ', ', @filter_strings;
 204 }
 205
 206 sub delivery_plan_query {
 207   my ($self) = @_;
 208   my $vc     = $self->vc;
 209   my $employee_id = SL::DB::Manager::Employee->current->id;
 210   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 211   # check delivered state for delivery_orders (transferred out) if enabled
 212   my $filter_delivered = ($::instance_conf->get_delivery_plan_calculate_transferred_do) ?
 213       "AND (SELECT delivered from delivery_orders where id = doi.delivery_order_id)" : '';
 214   [
 215   "order.${vc}_id" => { gt => 0 },
 216   'order.closed' => 0,
 217   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 218
 219   # filter by shipped_qty < qty, read from innermost to outermost
 220   'id' => [ \"
 221     -- 3. resolve the desired information about those
 222     SELECT oi.id FROM (
 223       -- 2. slice only part, orderitem and both quantities from it
 224       SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
 225         -- 1. join orderitems and deliverorder items via record_links.
 226         --    also add customer data to filter for sales_orders
 227         SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
 228         FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 229         WHERE
 230           oe.id = oi.trans_id AND
 231           oe.${vc}_id IS NOT NULL AND
 232           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 233           NOT oe.closed AND
 234           $oe_owner
 235           rl.from_id = oe.id AND
 236           rl.from_id = oi.trans_id AND
 237           oe.id = oi.trans_id AND
 238           rl.from_table = 'oe' AND
 239           rl.to_table = 'delivery_orders' AND
 240           rl.to_id = doi.delivery_order_id AND
 241           oi.parts_id = doi.parts_id
 242           $filter_delivered
 243       ) tuples GROUP BY parts_id, trans_id, qty
 244     ) partials
 245     LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 246     WHERE oi.qty > doi_qty
 247
 248     UNION ALL
 249
 250     -- 4. since the join over record_links fails for sales_orders without any delivery order
 251     --    retrieve those without record_links at all
 252     SELECT oi.id FROM orderitems oi, oe
 253     WHERE
 254       oe.id = oi.trans_id AND
 255       oe.${vc}_id IS NOT NULL AND
 256       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 257       NOT oe.closed AND
 258       $oe_owner
 259       oi.trans_id NOT IN (
 260         SELECT from_id
 261         FROM record_links rl
 262         WHERE
 263           rl.from_table ='oe' AND
 264           rl.to_table = 'delivery_orders'
 265       )
 266
 267     UNION ALL
 268
 269     -- 5. now for the really nasty cases.
 270     --    If someone partially delivered an order in several delivery orders,
 271     --    there will be lots of record_links (4 doesn't catch those) but those
 272     --    won't have matching part_ids in delivery_order_items, so 1-3 can't
 273     --    find anything
 274     --    In this case aggreg record_links - delivery_order - delivery_order_items
 275     --    slice only oe.id, parts_id and sum of of qty
 276     --    left join that onto orderitems to get matching qtys in doi while retaining
 277     --    entrys without matches and then throw out those without record_links
 278     --    TODO: join this and 1-3 into a general case
 279                   -- need debug info? uncomment these:
 280     SELECT oi.id  -- ,oi.trans_id, oi.parts_id, coalesce(sum, 0), agg.parts_id
 281     FROM orderitems oi LEFT JOIN (
 282       SELECT rl.from_id as oid, doi.parts_id, sum(doi.qty) FROM (
 283         SELECT from_id, to_id
 284         FROM record_links rl
 285         LEFT JOIN oe ON oe.id = from_id
 286         WHERE
 287           rl.from_table = 'oe' AND
 288           rl.to_table = 'delivery_orders' AND
 289
 290           oe.${vc}_id IS NOT NULL AND
 291           $oe_owner
 292           (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 293       ) rl
 294       LEFT JOIN delivery_order_items doi ON (rl.to_id = doi.delivery_order_id)
 295       WHERE 1 = 1
 296       $filter_delivered
 297       GROUP BY rl.from_id, doi.parts_id
 298     ) agg ON (agg.oid = oi.trans_id AND agg.parts_id = oi.parts_id)
 299     LEFT JOIN oe ON oe.id = oi.trans_id
 300     WHERE
 301       EXISTS (
 302         SELECT to_id
 303         FROM record_links rl
 304         WHERE oi.trans_id = rl.from_id AND rl.from_table = 'oe' AND rl.to_table = 'delivery_orders'
 305       ) AND
 306       coalesce(sum, 0) < oi.qty AND
 307       oe.${vc}_id IS NOT NULL AND
 308       $oe_owner
 309       (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 310   " ], # make emacs happy again: '
 311   ]
 312 }
 313
 314 sub delivery_plan_query_linked_items {
 315   my ($self) = @_;
 316   my $vc     = $self->vc;
 317   my $employee_id = SL::DB::Manager::Employee->current->id;
 318   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 319   # check delivered state for delivery_orders (transferred out) if enabled
 320   my $filter_delivered = ($::instance_conf->get_delivery_plan_calculate_transferred_do) ?
 321       "AND (SELECT delivered from delivery_orders where id = doi.delivery_order_id)" : '';
 322
 323   [
 324   "order.${vc}_id" => { gt => 0 },
 325   'order.closed' => 0,
 326   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 327
 328   # filter by shipped_qty < qty, read from innermost to outermost
 329   'id' => [ \"
 330     SELECT id FROM (
 331       SELECT oi.qty, oi.id, SUM(doi.qty) AS doi_qty
 332       FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 333       WHERE
 334         oe.id = oi.trans_id AND
 335         oe.${vc}_id IS NOT NULL AND
 336         (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 337         NOT oe.closed AND
 338         $oe_owner
 339         doi.id = rl.to_id AND
 340         rl.from_table = 'orderitems'AND
 341         rl.to_table   = 'delivery_order_items' AND
 342         rl.from_id = oi.id
 343         $filter_delivered
 344       GROUP BY oi.id
 345     ) linked
 346     WHERE qty > doi_qty
 347
 348     UNION ALL
 349
 350     -- 2. since the join over record_links fails for items not in any delivery order
 351     --    retrieve those without record_links at all
 352     SELECT oi.id FROM orderitems oi, oe
 353     WHERE
 354       oe.id = oi.trans_id AND
 355       oe.${vc}_id IS NOT NULL AND
 356       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 357       NOT oe.closed AND
 358       $oe_owner
 359       oi.id NOT IN (
 360         SELECT from_id
 361         FROM record_links rl
 362         WHERE
 363           rl.from_table ='orderitems' AND
 364           rl.to_table = 'delivery_order_items'
 365       )
 366
 367   " ], # make emacs happy again: " ]
 368   ]
 369 }
 370
 371 sub init_models {
 372   my ($self) = @_;
 373   my $vc     = $self->vc;
 374
 375   my $query = $self->use_linked_items ? $self->delivery_plan_query_linked_items
 376             :                           $self->delivery_plan_query;
 377
 378   SL::Controller::Helper::GetModels->new(
 379     controller   => $self,
 380     model        => 'OrderItem',
 381     sorted       => {
 382       _default     => {
 383         by           => 'reqdate',
 384         dir          => 1,
 385       },
 386       %sort_columns,
 387     },
 388     query        => $query,
 389     with_objects => [ 'order', "order.$vc", 'part' ],
 390     additional_url_params => { vc => $vc, use_linked_items => $self->use_linked_items },
 391   );
 392 }
 393
 394 sub init_all_edit_right {
 395   $::auth->assert('sales_all_edit', 1)
 396 }
 397 sub init_vc {
 398   return $::form->{vc} if ($::form->{vc} eq 'customer' || $::form->{vc} eq 'vendor') || croak "self (DeliveryPlan) has no vc defined";
 399 }
 400
 401 sub init_use_linked_items {
 402   !!$::form->{use_linked_items};
 403 }
 404
 405 sub init_all_employees {
 406   return SL::DB::Manager::Employee->get_all_sorted;
 407 }
 408 sub init_all_businesses {
 409   return SL::DB::Manager::Business->get_all_sorted;
 410 }
 411 sub link_to {
 412   my ($self, $object, %params) = @_;
 413
 414   return unless $object;
 415   my $action = $params{action} || 'edit';
 416
 417   if ($object->isa('SL::DB::Order')) {
 418     my $type   = $object->type;
 419     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 420     my $id     = $object->id;
 421
 422     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 423   }
 424   if ($object->isa('SL::DB::Part')) {
 425     my $id     = $object->id;
 426     return "ic.pl?action=$action&id=$id";
 427   }
 428   if ($object->isa('SL::DB::Customer')) {
 429     my $id     = $object->id;
 430     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 431   }
 432 }
 433
 434 1;