SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::DB::Business;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::Locale::String;
  12 use SL::AM;
  13 use SL::DBUtils ();
  14 use Carp;
  15
  16 use Rose::Object::MakeMethods::Generic (
  17   scalar => [ qw(db_args flat_filter) ],
  18   'scalar --get_set_init' => [ qw(models all_edit_right mode vc all_employees all_businesses) ],
  19 );
  20
  21 __PACKAGE__->run_before(sub { $::auth->assert('delivery_plan'); });
  22
  23 my %sort_columns = (
  24   reqdate           => t8('Reqdate'),
  25   description       => t8('Description'),
  26   partnumber        => t8('Part Number'),
  27   qty               => t8('Qty'),
  28   unit              => t8('Unit'),
  29   shipped_qty       => t8('shipped'),
  30   delivered_qty     => t8('transferred in / out'),
  31   not_shipped_qty   => t8('not shipped'),
  32   ordnumber         => t8('Order'),
  33   customer          => t8('Customer'),
  34   vendor            => t8('Vendor'),
  35   value_of_goods    => t8('Value of transferred goods'),
  36 );
  37
  38
  39 sub action_list {
  40   my ($self) = @_;
  41   $self->make_filter_summary;
  42   $self->prepare_report;
  43
  44   my $orderitems = $self->models->get;
  45   $self->calc_qtys($orderitems);
  46   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
  47 }
  48
  49 # private functions
  50 #
  51 sub prepare_report {
  52   my ($self)      = @_;
  53
  54   my $vc          = $self->vc;
  55   my $mode        = $self->mode;
  56   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  57   my $csv_option  = $::form->{report_generator_output_format};
  58   $self->{report} = $report;
  59
  60   my @columns     = qw(reqdate customer vendor ordnumber partnumber description qty shipped_qty not_shipped_qty delivered_qty value_of_goods);
  61
  62   my @sortable    = qw(reqdate customer vendor ordnumber partnumber description);
  63   my $rp_csv_mod  = ($csv_option eq 'CSV' && $mode eq 'delivery_value_report') ? 1 : '';
  64
  65   my %column_defs = (
  66     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
  67     description       => {      sub => sub { $_[0]->description                                                              },
  68                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  69     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
  70                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  71     qty               => {      sub => sub { $_[0]->qty_as_number .
  72                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  73     unit              => {      sub => sub {  $_[0]->unit                                                                    },
  74                             visible => $rp_csv_mod                                                                           },
  75     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]{shipped_qty}, 2) .
  76                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  77     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]{shipped_qty}, 2) .
  78                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  79     delivered_qty     => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]{delivered_qty}, 2) .
  80                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  81     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
  82                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
  83     vendor            => {      sub => sub { $_[0]->order->vendor->name                                                      },
  84                             visible => $vc eq 'vendor',
  85                            obj_link => sub { $self->link_to($_[0]->order->vendor)                                            } },
  86     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
  87                             visible => $vc eq 'customer',
  88                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
  89     value_of_goods    => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->value_of_goods, 2) . ' ' . $_[0]->taxincluded },
  90                             visible => $::auth->assert('sales_order_edit', 1) && $mode eq 'delivery_value_report' &&   $::instance_conf->get_delivery_plan_show_value_of_goods, },
  91   );
  92
  93   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
  94
  95   $report->set_options(
  96     std_column_visibility => 1,
  97     controller_class      => 'DeliveryPlan',
  98     output_format         => 'HTML',
  99     top_info_text         => ($vc eq 'customer') ?  (($mode eq 'delivery_plan') ? $::locale->text('Delivery Plan for currently outstanding sales orders') :
 100                                                    $::locale->text('Delivery Value Report for currently open sales orders')) :
 101                                                    ($mode eq 'delivery_value_report') ? $::locale->text('Delivery Value Report for currently outstanding purchase orders') :
 102                                                    $::locale->text('Delivery Plan for currently outstanding purchase orders'),
 103     title                 => ($mode eq 'delivery_plan') ? $::locale->text('Delivery Plan') : $::locale->text('Delivery Value Report'),
 104     allow_pdf_export      => 1,
 105     allow_csv_export      => 1,
 106   );
 107   $report->set_columns(%column_defs);
 108   $report->set_column_order(@columns);
 109   $report->set_export_options(qw(list filter vc mode));
 110   $report->set_options_from_form;
 111   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 112   $self->models->finalize; # for filter laundering
 113   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 114   $report->set_options(
 115     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }),
 116     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
 117   );
 118 }
 119
 120 sub calc_qtys {
 121   my ($self, $orderitems) = @_;
 122   # using $orderitem->shipped_qty 40 times is far too slow. need to do it manually
 123   #
 124
 125   return unless scalar @$orderitems;
 126
 127   my %orderitems_by_id = map { $_->id => $_ } @$orderitems;
 128
 129   return unless @$orderitems;
 130
 131   my $query = <<SQL;
 132     SELECT oi.id, doi.qty, doi.qty, doi.unit, doe.delivered
 133     FROM record_links rl
 134     INNER JOIN delivery_order_items doi ON (doi.delivery_order_id = rl.to_id)
 135     INNER JOIN delivery_orders doe ON (doe.id = rl.to_id)
 136     INNER JOIN orderitems oi ON (oi.trans_id = rl.from_id)
 137     WHERE rl.from_table = 'oe'
 138       AND rl.to_table   = 'delivery_orders'
 139       AND oi.parts_id   = doi.parts_id
 140       AND oi.id IN (@{[ join ', ', ("?")x @$orderitems ]})
 141 SQL
 142
 143   my $result = SL::DBUtils::selectall_hashref_query($::form, $::form->get_standard_dbh, $query, map { $_->id } @$orderitems);
 144
 145   for my $row (@$result) {
 146     my $item = $orderitems_by_id{ $row->{id} };
 147     $item->{shipped_qty}   ||= 0;
 148     $item->{delivered_qty} ||= 0;
 149     $item->{shipped_qty}    += AM->convert_unit($row->{unit} => $item->unit) * $row->{qty};
 150     $item->{delivered_qty}  += AM->convert_unit($row->{unit} => $item->unit) * $row->{qty} if $row->{delivered};
 151   }
 152 }
 153
 154 sub make_filter_summary {
 155   my ($self) = @_;
 156   my $vc     = $self->vc;
 157   my $mode   = $self->mode;
 158   my ($business, $employee);
 159
 160   my $filter = $::form->{filter} || {};
 161   my @filter_strings;
 162
 163   $business = SL::DB::Business->new(id => $filter->{order}{customer}{"business_id"})->load->description if $filter->{order}{customer}{"business_id"};
 164   $employee = SL::DB::Employee->new(id => $filter->{order}{employee_id})->load->name if $filter->{order}{employee_id};
 165
 166   my @filters = (
 167     [ $filter->{order}{"ordnumber:substr::ilike"},                    $::locale->text('Number')                                             ],
 168     [ $filter->{order}{globalproject}{"projectnumber:substr::ilike"}, $::locale->text('Document Project Number')                            ],
 169     [ $filter->{part}{"partnumber:substr::ilike"},                    $::locale->text('Part Number')                                        ],
 170     [ $filter->{"description:substr::ilike"},                         $::locale->text('Part Description')                                   ],
 171     [ $filter->{"reqdate:date::ge"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 172     [ $filter->{"reqdate:date::le"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 173     [ $filter->{"qty:number"},                                        $::locale->text('Quantity')                                           ],
 174     [ $filter->{order}{vendor}{"name:substr::ilike"},                 $::locale->text('Vendor')                                             ],
 175     [ $filter->{order}{vendor}{"vendornumber:substr::ilike"},         $::locale->text('Vendor Number')                                      ],
 176     [ $filter->{order}{customer}{"name:substr::ilike"},               $::locale->text('Customer')                                           ],
 177     [ $filter->{order}{customer}{"customernumber:substr::ilike"},     $::locale->text('Customer Number')                                    ],
 178     [ $business,                                                      $::locale->text('Customer type')                                      ],
 179     [ $employee,                                                      $::locale->text('Employee')                                           ],
 180   );
 181
 182   my %flags = (
 183     part     => $::locale->text('Parts'),
 184     service  => $::locale->text('Services'),
 185     assembly => $::locale->text('Assemblies'),
 186   );
 187   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 188
 189   for (@flags) {
 190     push @filter_strings, $_ if $_;
 191   }
 192   for (@filters) {
 193     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 194   }
 195
 196   $self->{filter_summary} = join ', ', @filter_strings;
 197 }
 198
 199 sub delivery_plan_query {
 200   my ($self) = @_;
 201   my $vc     = $self->vc;
 202   my $mode   = $self->mode;
 203   my $employee_id = SL::DB::Manager::Employee->current->id;
 204   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 205   # check delivered state for delivery_orders (transferred out) if enabled
 206   # OR if we are delivery_value_report mode
 207   my $filter_delivered = ($::instance_conf->get_delivery_plan_calculate_transferred_do ||
 208                           $mode eq 'delivery_value_report' ) ?
 209                           "AND (SELECT delivered from delivery_orders where id = doi.delivery_order_id)" : '';
 210   # Show ALL open orders in delivery_value_report mode
 211   my $comment_show_all_open_orders = ($mode eq 'delivery_value_report' ) ? "-- " : "";
 212   [
 213   "order.${vc}_id" => { gt => 0 },
 214   'order.closed' => 0,
 215   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 216
 217   # filter by shipped_qty < qty, read from innermost to outermost
 218   'id' => [ \"
 219     -- 3. resolve the desired information about those
 220     SELECT oi.id FROM (
 221       -- 2. slice only part, orderitem and both quantities from it
 222       SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
 223         -- 1. join orderitems and deliverorder items via record_links.
 224         --    also add customer data to filter for sales_orders
 225         SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
 226         FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 227         WHERE
 228           oe.id = oi.trans_id AND
 229           oe.${vc}_id IS NOT NULL AND
 230           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 231           NOT oe.closed AND
 232           $oe_owner
 233           rl.from_id = oe.id AND
 234           rl.from_id = oi.trans_id AND
 235           oe.id = oi.trans_id AND
 236           rl.from_table = 'oe' AND
 237           rl.to_table = 'delivery_orders' AND
 238           rl.to_id = doi.delivery_order_id AND
 239           oi.parts_id = doi.parts_id
 240           $filter_delivered
 241       ) tuples GROUP BY parts_id, trans_id, qty
 242     ) partials
 243     LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 244     WHERE oi.qty > doi_qty
 245
 246     UNION ALL
 247
 248     -- 4. since the join over record_links fails for sales_orders without any delivery order
 249     --    retrieve those without record_links at all
 250     SELECT oi.id FROM orderitems oi, oe
 251     WHERE
 252       oe.id = oi.trans_id AND
 253       oe.${vc}_id IS NOT NULL AND
 254       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 255       NOT oe.closed AND
 256       $oe_owner
 257       oi.trans_id NOT IN (
 258         SELECT from_id
 259         FROM record_links rl
 260         WHERE
 261           rl.from_table ='oe' AND
 262           rl.to_table = 'delivery_orders'
 263       )
 264
 265     UNION ALL
 266
 267     -- 5. now for the really nasty cases.
 268     --    If someone partially delivered an order in several delivery orders,
 269     --    there will be lots of record_links (4 doesn't catch those) but those
 270     --    won't have matching part_ids in delivery_order_items, so 1-3 can't
 271     --    find anything
 272     --    In this case aggreg record_links - delivery_order - delivery_order_items
 273     --    slice only oe.id, parts_id and sum of of qty
 274     --    left join that onto orderitems to get matching qtys in doi while retaining
 275     --    entrys without matches and then throw out those without record_links
 276     --    TODO: join this and 1-3 into a general case
 277                   -- need debug info? uncomment these:
 278     SELECT oi.id  -- ,oi.trans_id, oi.parts_id, coalesce(sum, 0), agg.parts_id
 279     FROM orderitems oi LEFT JOIN (
 280       SELECT rl.from_id as oid, doi.parts_id, sum(doi.qty) FROM (
 281         SELECT from_id, to_id
 282         FROM record_links rl
 283         LEFT JOIN oe ON oe.id = from_id
 284         WHERE
 285           rl.from_table = 'oe' AND
 286           rl.to_table = 'delivery_orders' AND
 287
 288           oe.${vc}_id IS NOT NULL AND
 289           $oe_owner
 290           (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 291       ) rl
 292       LEFT JOIN delivery_order_items doi ON (rl.to_id = doi.delivery_order_id)
 293       WHERE 1 = 1
 294       $filter_delivered
 295       GROUP BY rl.from_id, doi.parts_id
 296     ) agg ON (agg.oid = oi.trans_id AND agg.parts_id = oi.parts_id)
 297     LEFT JOIN oe ON oe.id = oi.trans_id
 298     WHERE
 299       EXISTS (
 300         SELECT to_id
 301         FROM record_links rl
 302         WHERE oi.trans_id = rl.from_id AND rl.from_table = 'oe' AND rl.to_table = 'delivery_orders'
 303       ) AND
 304       $comment_show_all_open_orders coalesce(sum, 0) < oi.qty AND
 305       oe.${vc}_id IS NOT NULL AND
 306       $oe_owner
 307       (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 308   " ],
 309   ]
 310 }
 311
 312 sub init_models {
 313   my ($self) = @_;
 314   my $vc     = $self->vc;
 315   my $mode   = $self->mode;
 316   SL::Controller::Helper::GetModels->new(
 317     controller            => $self,
 318     model                 => 'OrderItem',
 319     sorted                => {
 320       _default              => {
 321         by                    => 'reqdate',
 322         dir                   => 1,
 323       },
 324       %sort_columns,
 325     },
 326     query                 => $self->delivery_plan_query,
 327     with_objects          => [ 'order', "order.$vc", 'part' ],
 328     additional_url_params => { vc => $vc, mode => $mode},
 329   );
 330 }
 331
 332 sub init_all_edit_right {
 333   $::auth->assert('sales_all_edit', 1)
 334 }
 335 sub init_vc {
 336   return $::form->{vc} if ($::form->{vc} eq 'customer' || $::form->{vc} eq 'vendor') || croak "self (DeliveryPlan) has no vc defined";
 337 }
 338 sub init_mode {
 339   return $::form->{mode} if ($::form->{mode} eq 'delivery_value_report' || $::form->{mode} eq 'delivery_plan') || croak "self (DeliveryPlan) has no mode defined";
 340 }
 341
 342 sub init_all_employees {
 343   return SL::DB::Manager::Employee->get_all_sorted;
 344 }
 345 sub init_all_businesses {
 346   return SL::DB::Manager::Business->get_all_sorted;
 347 }
 348 sub link_to {
 349   my ($self, $object, %params) = @_;
 350
 351   return unless $object;
 352   my $action = $params{action} || 'edit';
 353
 354   if ($object->isa('SL::DB::Order')) {
 355     my $type   = $object->type;
 356     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 357     my $id     = $object->id;
 358
 359     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 360   }
 361   if ($object->isa('SL::DB::Part')) {
 362     my $id     = $object->id;
 363     return "ic.pl?action=$action&id=$id";
 364   }
 365   if ($object->isa('SL::DB::Customer')) {
 366     my $id     = $object->id;
 367     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 368   }
 369 }
 370
 371 1;