SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::Paginated;
  10 use SL::Controller::Helper::Sorted;
  11 use SL::Controller::Helper::ParseFilter;
  12 use SL::Controller::Helper::ReportGenerator;
  13 use SL::Locale::String;
  14
  15 use Rose::Object::MakeMethods::Generic (
  16   scalar => [ qw(db_args flat_filter) ],
  17 );
  18
  19 __PACKAGE__->run_before(sub { $::auth->assert('sales_order_edit'); });
  20
  21 __PACKAGE__->get_models_url_params('flat_filter');
  22 __PACKAGE__->make_paginated(
  23   MODEL         => 'OrderItem',
  24   PAGINATE_ARGS => 'db_args',
  25   ONLY          => [ qw(list) ],
  26 );
  27
  28 __PACKAGE__->make_sorted(
  29   MODEL       => 'OrderItem',
  30   ONLY        => [ qw(list) ],
  31
  32   DEFAULT_BY  => 'reqdate',
  33   DEFAULT_DIR => 1,
  34
  35   reqdate     => t8('Reqdate'),
  36   description => t8('Description'),
  37   partnumber  => t8('Part Number'),
  38   qty         => t8('Qty'),
  39   shipped_qty => t8('shipped'),
  40   ordnumber   => t8('Order'),
  41   customer    => t8('Customer'),
  42 );
  43
  44 sub action_list {
  45   my ($self) = @_;
  46
  47   $self->db_args($self->setup_for_list(filter => $::form->{filter}));
  48   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  49   $self->make_filter_summary;
  50
  51   $self->prepare_report;
  52
  53   $self->{orderitems} = $self->get_models(%{ $self->db_args });
  54
  55   $self->list_objects;
  56 }
  57
  58 # private functions
  59
  60 sub setup_for_list {
  61   my ($self, %params) = @_;
  62   $self->{filter} = {};
  63   my %args = (
  64     parse_filter(
  65       $self->_pre_parse_filter($::form->{filter}, $self->{filter}),
  66       with_objects => [ 'order', 'order.customer', 'part' ],
  67       launder_to => $self->{filter},
  68     ),
  69   );
  70
  71   $args{query} = [ @{ $args{query} || [] },
  72     (
  73       'order.customer_id' => { gt => 0 },
  74       'order.closed' => 0,
  75       or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
  76
  77       # filter by shipped_qty < qty, read from innermost to outermost
  78       'id' => [ \"
  79         -- 3. resolve the desired information about those
  80         SELECT oi.id FROM (
  81           -- 2. slice only part, orderitem and both quantities from it
  82           SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
  83             -- 1. join orderitems and deliverorder items via record_links.
  84             --    also add customer data to filter for sales_orders
  85             SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
  86             FROM orderitems oi, oe, record_links rl, delivery_order_items doi
  87             WHERE
  88               oe.id = oi.trans_id AND
  89               oe.customer_id IS NOT NULL AND
  90               (oe.quotation = 'f' OR oe.quotation IS NULL) AND
  91               NOT oe.closed AND
  92               rl.from_id = oe.id AND
  93               rl.from_id = oi.trans_id AND
  94               oe.id = oi.trans_id AND
  95               rl.from_table = 'oe' AND
  96               rl.to_table = 'delivery_orders' AND
  97               rl.to_id = doi.delivery_order_id AND
  98               oi.parts_id = doi.parts_id
  99           ) tuples GROUP BY parts_id, trans_id, qty
 100         ) partials
 101         LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 102         WHERE oi.qty > doi_qty
 103
 104         UNION ALL
 105
 106         -- 4. since the join over record_links fails for sales_orders wihtout any delivery order
 107         --    retrieve those without record_links at all
 108         SELECT oi.id FROM orderitems oi, oe
 109         WHERE
 110           oe.id = oi.trans_id AND
 111           oe.customer_id IS NOT NULL AND
 112           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 113           NOT oe.closed AND
 114           oi.trans_id NOT IN (
 115             SELECT from_id
 116             FROM record_links rl
 117             WHERE
 118               rl.from_table ='oe' AND
 119               rl.to_table = 'delivery_orders'
 120           )
 121       " ],
 122     )
 123   ];
 124
 125   return \%args;
 126 }
 127
 128 sub prepare_report {
 129   my ($self)      = @_;
 130
 131   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 132   $self->{report} = $report;
 133
 134   my @columns     = qw(reqdate customer ordnumber partnumber description qty shipped_qty);
 135   my @sortable    = qw(reqdate customer ordnumber partnumber description                );
 136
 137   my %column_defs = (
 138     reqdate       => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
 139     description   => {      sub => sub { $_[0]->description                                                              },
 140                        obj_link => sub { $self->link_to($_[0]->part)                                                     } },
 141     partnumber    => {      sub => sub { $_[0]->part->partnumber                                                         },
 142                        obj_link => sub { $self->link_to($_[0]->part)                                                     } },
 143     qty           => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit                                        } },
 144     shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit } },
 145     ordnumber     => {      sub => sub { $_[0]->order->ordnumber                                                         },
 146                        obj_link => sub { $self->link_to($_[0]->order)                                                    } },
 147     customer      => {      sub => sub { $_[0]->order->customer->name                                                    },
 148                        obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
 149   );
 150
 151   map { $column_defs{$_}->{text} = $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 152
 153   $report->set_options(
 154     std_column_visibility => 1,
 155     controller_class      => 'DeliveryPlan',
 156     output_format         => 'HTML',
 157     top_info_text         => $::locale->text('Delivery Plan for currently outstanding sales orders'),
 158     raw_top_info_text     => $self->render('delivery_plan/report_top',    { no_output => 1, partial => 1 }),
 159     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { no_output => 1, partial => 1 }),
 160     title                 => $::locale->text('Delivery Plan'),
 161     allow_pdf_export      => 1,
 162     allow_csv_export      => 1,
 163   );
 164   $report->set_columns(%column_defs);
 165   $report->set_column_order(@columns);
 166   $report->set_export_options(qw(list filter));
 167   $report->set_options_from_form;
 168   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 169
 170   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 171
 172   $self->{report_data} = {
 173     column_defs        => \%column_defs,
 174     columns            => \@columns,
 175   };
 176 }
 177
 178 sub list_objects {
 179   my ($self) = @_;
 180   my $column_defs = $self->{report_data}{column_defs};
 181   for my $obj (@{ $self->{orderitems} || [] }) {
 182     $self->{report}->add_data({
 183       map {
 184         $_ => {
 185           data => $column_defs->{$_}{sub} ? $column_defs->{$_}{sub}->($obj)
 186                 : $obj->can($_)           ? $obj->$_
 187                 :                           $obj->{$_},
 188           link => $column_defs->{$_}{obj_link} ? $column_defs->{$_}{obj_link}->($obj) : '',
 189         },
 190       } @{ $self->{report_data}{columns} || {} }
 191     });
 192   }
 193
 194   return $self->{report}->generate_with_headers;
 195 }
 196
 197 sub make_filter_summary {
 198   my ($self) = @_;
 199
 200   my $filter = $::form->{filter} || {};
 201   my @filter_strings;
 202
 203   my @filters = (
 204     [ $filter->{order}{"ordnumber:substr::ilike"},                $::locale->text('Number')                                             ],
 205     [ $filter->{part}{"partnumber:substr::ilike"},                $::locale->text('Part Number')                                        ],
 206     [ $filter->{"description:substr::ilike"},                     $::locale->text('Part Description')                                   ],
 207     [ $filter->{"reqdate:date::ge"},                              $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 208     [ $filter->{"reqdate:date::le"},                              $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 209     [ $filter->{"qty:number"},                                    $::locale->text('Quantity')                                           ],
 210     [ $filter->{order}{customer}{"name:substr::ilike"},           $::locale->text('Customer')                                           ],
 211     [ $filter->{order}{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number')                                    ],
 212   );
 213
 214   my @flags = (
 215     [ $filter->{part}{type}{part},     $::locale->text('Parts')      ],
 216     [ $filter->{part}{type}{service},  $::locale->text('Services')   ],
 217     [ $filter->{part}{type}{assembly}, $::locale->text('Assemblies') ],
 218   );
 219
 220   for (@flags) {
 221     push @filter_strings, "$_->[1]" if $_->[0];
 222   }
 223   for (@filters) {
 224     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 225   }
 226
 227   $self->{filter_summary} = join ', ', @filter_strings;
 228 }
 229
 230 sub link_to {
 231   my ($self, $object, %params) = @_;
 232
 233   return unless $object;
 234   my $action = $params{action} || 'edit';
 235
 236   if ($object->isa('SL::DB::Order')) {
 237     my $type   = $object->type;
 238     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 239     my $id     = $object->id;
 240
 241     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 242   }
 243   if ($object->isa('SL::DB::Part')) {
 244     my $id     = $object->id;
 245     return "ic.pl?action=$action&id=$id";
 246   }
 247   if ($object->isa('SL::DB::Customer')) {
 248     my $id     = $object->id;
 249     return "ct.pl?action=$action&id=$id&db=customer";
 250   }
 251 }
 252
 253 # unfortunately ParseFilter can't handle compount filters.
 254 # so we clone the original filter (still need that for serializing)
 255 # rip out the options we know an replace them with the compound options.
 256 # ParseFilter will take care of the prefixing then.
 257 sub _pre_parse_filter {
 258   my ($self, $orig_filter, $launder_to) = @_;
 259
 260   return undef unless $orig_filter;
 261
 262   my $filter = clone($orig_filter);
 263   if ($filter->{part} && $filter->{part}{type}) {
 264     $launder_to->{part}{type} = delete $filter->{part}{type};
 265     my @part_filters = grep $_, map {
 266       $launder_to->{part}{type}{$_} ? SL::DB::Manager::Part->type_filter($_) : ()
 267     } qw(part service assembly);
 268
 269     push @{ $filter->{and} }, or => [ @part_filters ] if @part_filters;
 270   }
 271
 272   for my $op (qw(le ge)) {
 273     if ($filter->{"reqdate:date::$op"}) {
 274       $launder_to->{"reqdate_date__$op"} = delete $filter->{"reqdate:date::$op"};
 275       my $parsed_date = DateTime->from_lxoffice($launder_to->{"reqdate_date__$op"});
 276       push @{ $filter->{and} }, or => [
 277         'reqdate' => { $op => $parsed_date },
 278         and => [
 279           'reqdate' => undef,
 280           'order.reqdate' => { $op => $parsed_date },
 281         ]
 282       ] if $parsed_date;
 283     }
 284   }
 285
 286   if (my $style = delete $filter->{searchstyle}) {
 287     $self->{searchstyle}       = $style;
 288     $launder_to->{searchstyle} = $style;
 289   }
 290
 291   return $filter;
 292 }
 293
 294 1;