SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::DB::Business;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::Locale::String;
  12 use Carp;
  13
  14 use Rose::Object::MakeMethods::Generic (
  15   scalar => [ qw(db_args flat_filter) ],
  16   'scalar --get_set_init' => [ qw(models all_edit_right mode vc all_employees all_businesses) ],
  17 );
  18
  19 __PACKAGE__->run_before(sub { $::auth->assert('delivery_plan'); });
  20
  21 my %sort_columns = (
  22   reqdate           => t8('Reqdate'),
  23   description       => t8('Description'),
  24   partnumber        => t8('Part Number'),
  25   qty               => t8('Qty'),
  26   unit              => t8('Unit'),
  27   shipped_qty       => t8('shipped'),
  28   delivered_qty     => t8('transferred in / out'),
  29   not_shipped_qty   => t8('not shipped'),
  30   ordnumber         => t8('Order'),
  31   customer          => t8('Customer'),
  32   vendor            => t8('Vendor'),
  33   value_of_goods    => t8('Value of transferred goods'),
  34 );
  35
  36
  37 sub action_list {
  38   my ($self) = @_;
  39   $self->make_filter_summary;
  40   $self->prepare_report;
  41
  42   my $orderitems = $self->models->get;
  43
  44   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
  45 }
  46
  47 # private functions
  48 #
  49 sub prepare_report {
  50   my ($self)      = @_;
  51
  52   my $vc          = $self->vc;
  53   my $mode        = $self->mode;
  54   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  55   my $csv_option  = $::form->{report_generator_output_format};
  56   $self->{report} = $report;
  57
  58   my @columns     = qw(reqdate customer vendor ordnumber partnumber description qty shipped_qty not_shipped_qty delivered_qty value_of_goods);
  59
  60   my @sortable    = qw(reqdate customer vendor ordnumber partnumber description);
  61   my $rp_csv_mod  = ($csv_option eq 'CSV' && $mode eq 'delivery_value_report') ? 1 : '';
  62
  63   my %column_defs = (
  64     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
  65     description       => {      sub => sub { $_[0]->description                                                              },
  66                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  67     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
  68                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  69     qty               => {      sub => sub { $_[0]->qty_as_number .
  70                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  71     unit              => {      sub => sub {  $_[0]->unit                                                                    },
  72                             visible => $rp_csv_mod                                                                           },
  73     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty, 2) .
  74                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  75     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]->shipped_qty, 2) .
  76                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  77     delivered_qty     => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->delivered_qty, 2) .
  78                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  79     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
  80                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
  81     vendor            => {      sub => sub { $_[0]->order->vendor->name                                                      },
  82                             visible => $vc eq 'vendor',
  83                            obj_link => sub { $self->link_to($_[0]->order->vendor)                                            } },
  84     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
  85                             visible => $vc eq 'customer',
  86                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
  87     value_of_goods    => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->value_of_goods, 2) . ' ' . $_[0]->taxincluded },
  88                             visible => $::auth->assert('sales_order_edit', 1) && $mode eq 'delivery_value_report' &&   $::instance_conf->get_delivery_plan_show_value_of_goods, },
  89   );
  90
  91   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
  92
  93   $report->set_options(
  94     std_column_visibility => 1,
  95     controller_class      => 'DeliveryPlan',
  96     output_format         => 'HTML',
  97     top_info_text         => ($vc eq 'customer') ?  (($mode eq 'delivery_plan') ? $::locale->text('Delivery Plan for currently outstanding sales orders') :
  98                                                    $::locale->text('Delivery Value Report for currently open sales orders')) :
  99                                                    ($mode eq 'delivery_value_report') ? $::locale->text('Delivery Value Report for currently outstanding purchase orders') :
 100                                                    $::locale->text('Delivery Plan for currently outstanding purchase orders'),
 101     title                 => ($mode eq 'delivery_plan') ? $::locale->text('Delivery Plan') : $::locale->text('Delivery Value Report'),
 102     allow_pdf_export      => 1,
 103     allow_csv_export      => 1,
 104   );
 105   $report->set_columns(%column_defs);
 106   $report->set_column_order(@columns);
 107   $report->set_export_options(qw(list filter vc mode));
 108   $report->set_options_from_form;
 109   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 110   $self->models->finalize; # for filter laundering
 111   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 112   $report->set_options(
 113     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }),
 114     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
 115   );
 116 }
 117
 118 sub make_filter_summary {
 119   my ($self) = @_;
 120   my $vc     = $self->vc;
 121   my $mode   = $self->mode;
 122
 123   my $filter = $::form->{filter} || {};
 124   my @filter_strings;
 125
 126   my $business = SL::DB::Business->new(id => $filter->{order}{customer}{"business_id"})->load->description if $filter->{order}{customer}{"business_id"};
 127   my $employee = SL::DB::Employee->new(id => $filter->{order}{employee_id})->load->name if $filter->{order}{employee_id};
 128
 129   my @filters = (
 130     [ $filter->{order}{"ordnumber:substr::ilike"},                    $::locale->text('Number')                                             ],
 131     [ $filter->{order}{globalproject}{"projectnumber:substr::ilike"}, $::locale->text('Document Project Number')                            ],
 132     [ $filter->{part}{"partnumber:substr::ilike"},                    $::locale->text('Part Number')                                        ],
 133     [ $filter->{"description:substr::ilike"},                         $::locale->text('Part Description')                                   ],
 134     [ $filter->{"reqdate:date::ge"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 135     [ $filter->{"reqdate:date::le"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 136     [ $filter->{"qty:number"},                                        $::locale->text('Quantity')                                           ],
 137     [ $filter->{order}{vendor}{"name:substr::ilike"},                 $::locale->text('Vendor')                                             ],
 138     [ $filter->{order}{vendor}{"vendornumber:substr::ilike"},         $::locale->text('Vendor Number')                                      ],
 139     [ $filter->{order}{customer}{"name:substr::ilike"},               $::locale->text('Customer')                                           ],
 140     [ $filter->{order}{customer}{"customernumber:substr::ilike"},     $::locale->text('Customer Number')                                    ],
 141     [ $business,                                                      $::locale->text('Customer type')                                      ],
 142     [ $employee,                                                      $::locale->text('Employee')                                           ],
 143   );
 144
 145   my %flags = (
 146     part     => $::locale->text('Parts'),
 147     service  => $::locale->text('Services'),
 148     assembly => $::locale->text('Assemblies'),
 149   );
 150   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 151
 152   for (@flags) {
 153     push @filter_strings, $_ if $_;
 154   }
 155   for (@filters) {
 156     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 157   }
 158
 159   $self->{filter_summary} = join ', ', @filter_strings;
 160 }
 161
 162 sub delivery_plan_query {
 163   my ($self) = @_;
 164   my $vc     = $self->vc;
 165   my $mode   = $self->mode;
 166   my $employee_id = SL::DB::Manager::Employee->current->id;
 167   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 168   # check delivered state for delivery_orders (transferred out) if enabled
 169   # OR if we are delivery_value_report mode
 170   my $filter_delivered = ($::instance_conf->get_delivery_plan_calculate_transferred_do ||
 171                           $mode eq 'delivery_value_report' ) ?
 172                           "AND (SELECT delivered from delivery_orders where id = doi.delivery_order_id)" : '';
 173   # Show ALL open orders in delivery_value_report mode
 174   my $comment_show_all_open_orders = ($mode eq 'delivery_value_report' ) ? "-- " : "";
 175   [
 176   "order.${vc}_id" => { gt => 0 },
 177   'order.closed' => 0,
 178   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 179
 180   # filter by shipped_qty < qty, read from innermost to outermost
 181   'id' => [ \"
 182     -- 3. resolve the desired information about those
 183     SELECT oi.id FROM (
 184       -- 2. slice only part, orderitem and both quantities from it
 185       SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
 186         -- 1. join orderitems and deliverorder items via record_links.
 187         --    also add customer data to filter for sales_orders
 188         SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
 189         FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 190         WHERE
 191           oe.id = oi.trans_id AND
 192           oe.${vc}_id IS NOT NULL AND
 193           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 194           NOT oe.closed AND
 195           $oe_owner
 196           rl.from_id = oe.id AND
 197           rl.from_id = oi.trans_id AND
 198           oe.id = oi.trans_id AND
 199           rl.from_table = 'oe' AND
 200           rl.to_table = 'delivery_orders' AND
 201           rl.to_id = doi.delivery_order_id AND
 202           oi.parts_id = doi.parts_id
 203           $filter_delivered
 204       ) tuples GROUP BY parts_id, trans_id, qty
 205     ) partials
 206     LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 207     WHERE oi.qty > doi_qty
 208
 209     UNION ALL
 210
 211     -- 4. since the join over record_links fails for sales_orders without any delivery order
 212     --    retrieve those without record_links at all
 213     SELECT oi.id FROM orderitems oi, oe
 214     WHERE
 215       oe.id = oi.trans_id AND
 216       oe.${vc}_id IS NOT NULL AND
 217       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 218       NOT oe.closed AND
 219       $oe_owner
 220       oi.trans_id NOT IN (
 221         SELECT from_id
 222         FROM record_links rl
 223         WHERE
 224           rl.from_table ='oe' AND
 225           rl.to_table = 'delivery_orders'
 226       )
 227
 228     UNION ALL
 229
 230     -- 5. now for the really nasty cases.
 231     --    If someone partially delivered an order in several delivery orders,
 232     --    there will be lots of record_links (4 doesn't catch those) but those
 233     --    won't have matching part_ids in delivery_order_items, so 1-3 can't
 234     --    find anything
 235     --    In this case aggreg record_links - delivery_order - delivery_order_items
 236     --    slice only oe.id, parts_id and sum of of qty
 237     --    left join that onto orderitems to get matching qtys in doi while retaining
 238     --    entrys without matches and then throw out those without record_links
 239     --    TODO: join this and 1-3 into a general case
 240                   -- need debug info? uncomment these:
 241     SELECT oi.id  -- ,oi.trans_id, oi.parts_id, coalesce(sum, 0), agg.parts_id
 242     FROM orderitems oi LEFT JOIN (
 243       SELECT rl.from_id as oid, doi.parts_id, sum(doi.qty) FROM (
 244         SELECT from_id, to_id
 245         FROM record_links rl
 246         LEFT JOIN oe ON oe.id = from_id
 247         WHERE
 248           rl.from_table = 'oe' AND
 249           rl.to_table = 'delivery_orders' AND
 250
 251           oe.${vc}_id IS NOT NULL AND
 252           $oe_owner
 253           (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 254       ) rl
 255       LEFT JOIN delivery_order_items doi ON (rl.to_id = doi.delivery_order_id)
 256       WHERE 1 = 1
 257       $filter_delivered
 258       GROUP BY rl.from_id, doi.parts_id
 259     ) agg ON (agg.oid = oi.trans_id AND agg.parts_id = oi.parts_id)
 260     LEFT JOIN oe ON oe.id = oi.trans_id
 261     WHERE
 262       EXISTS (
 263         SELECT to_id
 264         FROM record_links rl
 265         WHERE oi.trans_id = rl.from_id AND rl.from_table = 'oe' AND rl.to_table = 'delivery_orders'
 266       ) AND
 267       $comment_show_all_open_orders coalesce(sum, 0) < oi.qty AND
 268       oe.${vc}_id IS NOT NULL AND
 269       $oe_owner
 270       (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 271   " ],
 272   ]
 273 }
 274
 275 sub init_models {
 276   my ($self) = @_;
 277   my $vc     = $self->vc;
 278   my $mode   = $self->mode;
 279   SL::Controller::Helper::GetModels->new(
 280     controller            => $self,
 281     model                 => 'OrderItem',
 282     sorted                => {
 283       _default              => {
 284         by                    => 'reqdate',
 285         dir                   => 1,
 286       },
 287       %sort_columns,
 288     },
 289     query                 => $self->delivery_plan_query,
 290     with_objects          => [ 'order', "order.$vc", 'part' ],
 291     additional_url_params => { vc => $vc, mode => $mode},
 292   );
 293 }
 294
 295 sub init_all_edit_right {
 296   $::auth->assert('sales_all_edit', 1)
 297 }
 298 sub init_vc {
 299   return $::form->{vc} if ($::form->{vc} eq 'customer' || $::form->{vc} eq 'vendor') || croak "self (DeliveryPlan) has no vc defined";
 300 }
 301 sub init_mode {
 302   return $::form->{mode} if ($::form->{mode} eq 'delivery_value_report' || $::form->{mode} eq 'delivery_plan') || croak "self (DeliveryPlan) has no mode defined";
 303 }
 304
 305 sub init_all_employees {
 306   return SL::DB::Manager::Employee->get_all_sorted;
 307 }
 308 sub init_all_businesses {
 309   return SL::DB::Manager::Business->get_all_sorted;
 310 }
 311 sub link_to {
 312   my ($self, $object, %params) = @_;
 313
 314   return unless $object;
 315   my $action = $params{action} || 'edit';
 316
 317   if ($object->isa('SL::DB::Order')) {
 318     my $type   = $object->type;
 319     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 320     my $id     = $object->id;
 321
 322     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 323   }
 324   if ($object->isa('SL::DB::Part')) {
 325     my $id     = $object->id;
 326     return "ic.pl?action=$action&id=$id";
 327   }
 328   if ($object->isa('SL::DB::Customer')) {
 329     my $id     = $object->id;
 330     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 331   }
 332 }
 333
 334 1;