SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::DB::Business;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::Locale::String;
  12 use SL::Helper::ShippedQty;
  13 use SL::AM;
  14 use SL::DBUtils ();
  15 use Carp;
  16
  17 use Rose::Object::MakeMethods::Generic (
  18   scalar => [ qw(db_args flat_filter) ],
  19   'scalar --get_set_init' => [ qw(models all_edit_right vc use_linked_items all_employees all_businesses all_departments) ],
  20 );
  21
  22 __PACKAGE__->run_before(sub { $::auth->assert('delivery_plan'); });
  23
  24 my %sort_columns = (
  25   reqdate           => t8('Reqdate'),
  26   description       => t8('Description'),
  27   partnumber        => t8('Part Number'),
  28   qty               => t8('Qty'),
  29   shipped_qty       => t8('shipped'),
  30   not_shipped_qty   => t8('not shipped'),
  31   ordnumber         => t8('Order'),
  32   customer          => t8('Customer'),
  33   vendor            => t8('Vendor'),
  34 );
  35
  36
  37 sub action_list {
  38   my ($self) = @_;
  39   $self->make_filter_summary;
  40   $self->prepare_report;
  41
  42   my $orderitems = $self->models->get;
  43   $self->calc_qtys($orderitems);
  44   $self->setup_list_action_bar;
  45   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
  46 }
  47
  48 # private functions
  49 #
  50 sub prepare_report {
  51   my ($self)      = @_;
  52
  53   my $vc          = $self->vc;
  54   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  55   $self->{report} = $report;
  56
  57   my @columns     = qw(reqdate customer vendor ordnumber partnumber description qty shipped_qty not_shipped_qty);
  58
  59   my @sortable    = qw(reqdate customer vendor ordnumber partnumber description);
  60
  61   my %column_defs = (
  62     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
  63     description       => {      sub => sub { $_[0]->description                                                              },
  64                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  65     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
  66                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  67     qty               => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit                                        } },
  68     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]{shipped_qty}, 2) . ' ' . $_[0]->unit } },
  69     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]{shipped_qty}, 2) . ' ' . $_[0]->unit } },
  70     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
  71                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
  72     vendor            => {      sub => sub { $_[0]->order->vendor->name                                                      },
  73                             visible => $vc eq 'vendor',
  74                            obj_link => sub { $self->link_to($_[0]->order->vendor)                                            } },
  75     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
  76                             visible => $vc eq 'customer',
  77                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
  78   );
  79
  80   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
  81
  82   $report->set_options(
  83     std_column_visibility => 1,
  84     controller_class      => 'DeliveryPlan',
  85     output_format         => 'HTML',
  86     top_info_text         => ($vc eq 'customer') ? $::locale->text('Delivery Plan for currently outstanding sales orders') :
  87                                                    $::locale->text('Delivery Plan for currently outstanding purchase orders'),
  88     title                 => $::locale->text('Delivery Plan'),
  89     allow_pdf_export      => 1,
  90     allow_csv_export      => 1,
  91   );
  92   $report->set_columns(%column_defs);
  93   $report->set_column_order(@columns);
  94   $report->set_export_options(qw(list filter vc use_linked_items));
  95   $report->set_options_from_form;
  96   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
  97   $self->models->finalize; # for filter laundering
  98   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
  99   $report->set_options(
 100     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }),
 101     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
 102   );
 103 }
 104
 105 sub calc_qtys {
 106   my ($self, $orderitems) = @_;
 107
 108   return unless scalar @$orderitems;
 109
 110   SL::Helper::ShippedQty
 111     ->new(fill_up => !$self->use_linked_items)
 112     ->calculate($orderitems)
 113     ->write_to_objects;
 114 }
 115
 116 sub make_filter_summary {
 117   my ($self) = @_;
 118   my $vc     = $self->vc;
 119   my ($business, $employee, $department);
 120
 121   my $filter = $::form->{filter} || {};
 122   my @filter_strings;
 123
 124   $business = SL::DB::Business->new(id => $filter->{order}{customer}{"business_id"})->load->description if $filter->{order}{customer}{"business_id"};
 125   $employee = SL::DB::Employee->new(id => $filter->{order}{employee_id})->load->name if $filter->{order}{employee_id};
 126   $department = SL::DB::Department->new(id => $filter->{order}{department_id})->load->description if $filter->{order}{department_id};
 127
 128   my @filters = (
 129     [ $filter->{order}{"ordnumber:substr::ilike"},                    $::locale->text('Number')                                             ],
 130     [ $filter->{order}{globalproject}{"projectnumber:substr::ilike"}, $::locale->text('Document Project Number')                            ],
 131     [ $filter->{part}{"partnumber:substr::ilike"},                    $::locale->text('Part Number')                                        ],
 132     [ $filter->{"description:substr::ilike"},                         $::locale->text('Part Description')                                   ],
 133     [ $filter->{"reqdate:date::ge"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 134     [ $filter->{"reqdate:date::le"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 135     [ $filter->{"qty:number"},                                        $::locale->text('Quantity')                                           ],
 136     [ $filter->{order}{vendor}{"name:substr::ilike"},                 $::locale->text('Vendor')                                             ],
 137     [ $filter->{order}{vendor}{"vendornumber:substr::ilike"},         $::locale->text('Vendor Number')                                      ],
 138     [ $filter->{order}{customer}{"name:substr::ilike"},               $::locale->text('Customer')                                           ],
 139     [ $filter->{order}{customer}{"customernumber:substr::ilike"},     $::locale->text('Customer Number')                                    ],
 140     [ $business,                                                      $::locale->text('Customer type')                                      ],
 141     [ $department,                                                    $::locale->text('Department')                                         ],
 142     [ $employee,                                                      $::locale->text('Employee')                                           ],
 143   );
 144
 145   my %flags = (
 146     part     => $::locale->text('Parts'),
 147     service  => $::locale->text('Services'),
 148     assembly => $::locale->text('Assemblies'),
 149   );
 150   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 151
 152   for (@flags) {
 153     push @filter_strings, $_ if $_;
 154   }
 155   for (@filters) {
 156     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 157   }
 158
 159   $self->{filter_summary} = join ', ', @filter_strings;
 160 }
 161
 162 sub delivery_plan_query {
 163   my ($self) = @_;
 164   my $vc     = $self->vc;
 165   my $employee_id = SL::DB::Manager::Employee->current->id;
 166   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 167
 168   [
 169   "order.${vc}_id" => { gt => 0 },
 170   'order.closed' => 0,
 171   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 172
 173   # filter by shipped_qty < qty, read from innermost to outermost
 174   'id' => [ \"
 175     -- 3. resolve the desired information about those
 176     SELECT oi.id FROM (
 177       -- 2. slice only part, orderitem and both quantities from it
 178       SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
 179         -- 1. join orderitems and deliverorder items via record_links.
 180         --    also add customer data to filter for sales_orders
 181         SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
 182         FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 183         WHERE
 184           oe.id = oi.trans_id AND
 185           oe.${vc}_id IS NOT NULL AND
 186           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 187           NOT oe.closed AND
 188           $oe_owner
 189           rl.from_id = oe.id AND
 190           rl.from_id = oi.trans_id AND
 191           oe.id = oi.trans_id AND
 192           rl.from_table = 'oe' AND
 193           rl.to_table = 'delivery_orders' AND
 194           rl.to_id = doi.delivery_order_id AND
 195           oi.parts_id = doi.parts_id
 196       ) tuples GROUP BY parts_id, trans_id, qty
 197     ) partials
 198     LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 199     WHERE oi.qty > doi_qty
 200
 201     UNION ALL
 202
 203     -- 4. since the join over record_links fails for sales_orders without any delivery order
 204     --    retrieve those without record_links at all
 205     SELECT oi.id FROM orderitems oi, oe
 206     WHERE
 207       oe.id = oi.trans_id AND
 208       oe.${vc}_id IS NOT NULL AND
 209       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 210       NOT oe.closed AND
 211       $oe_owner
 212       oi.trans_id NOT IN (
 213         SELECT from_id
 214         FROM record_links rl
 215         WHERE
 216           rl.from_table ='oe' AND
 217           rl.to_table = 'delivery_orders'
 218       )
 219
 220     UNION ALL
 221
 222     -- 5. now for the really nasty cases.
 223     --    If someone partially delivered an order in several delivery orders,
 224     --    there will be lots of record_links (4 doesn't catch those) but those
 225     --    won't have matching part_ids in delivery_order_items, so 1-3 can't
 226     --    find anything
 227     --    In this case aggreg record_links - delivery_order - delivery_order_items
 228     --    slice only oe.id, parts_id and sum of of qty
 229     --    left join that onto orderitems to get matching qtys in doi while retaining
 230     --    entrys without matches and then throw out those without record_links
 231     --    TODO: join this and 1-3 into a general case
 232                   -- need debug info? uncomment these:
 233     SELECT oi.id  -- ,oi.trans_id, oi.parts_id, coalesce(sum, 0), agg.parts_id
 234     FROM orderitems oi LEFT JOIN (
 235       SELECT rl.from_id as oid, doi.parts_id, sum(doi.qty) FROM (
 236         SELECT from_id, to_id
 237         FROM record_links rl
 238         LEFT JOIN oe ON oe.id = from_id
 239         WHERE
 240           rl.from_table = 'oe' AND
 241           rl.to_table = 'delivery_orders' AND
 242
 243           oe.${vc}_id IS NOT NULL AND
 244           $oe_owner
 245           (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 246       ) rl
 247       LEFT JOIN delivery_order_items doi ON (rl.to_id = doi.delivery_order_id)
 248       GROUP BY rl.from_id, doi.parts_id
 249     ) agg ON (agg.oid = oi.trans_id AND agg.parts_id = oi.parts_id)
 250     LEFT JOIN oe ON oe.id = oi.trans_id
 251     WHERE
 252       EXISTS (
 253         SELECT to_id
 254         FROM record_links rl
 255         WHERE oi.trans_id = rl.from_id AND rl.from_table = 'oe' AND rl.to_table = 'delivery_orders'
 256       ) AND
 257       coalesce(sum, 0) < oi.qty AND
 258       oe.${vc}_id IS NOT NULL AND
 259       $oe_owner
 260       (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 261   " ], # make emacs happy again: '
 262   ]
 263 }
 264
 265 sub delivery_plan_query_linked_items {
 266   my ($self) = @_;
 267   my $vc     = $self->vc;
 268   my $employee_id = SL::DB::Manager::Employee->current->id;
 269   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 270
 271   [
 272   "order.${vc}_id" => { gt => 0 },
 273   'order.closed' => 0,
 274   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 275
 276   # filter by shipped_qty < qty, read from innermost to outermost
 277   'id' => [ \"
 278     SELECT id FROM (
 279       SELECT oi.qty, oi.id, SUM(doi.qty) AS doi_qty
 280       FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 281       WHERE
 282         oe.id = oi.trans_id AND
 283         oe.${vc}_id IS NOT NULL AND
 284         (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 285         NOT oe.closed AND
 286         $oe_owner
 287         doi.id = rl.to_id AND
 288         rl.from_table = 'orderitems'AND
 289         rl.to_table   = 'delivery_order_items' AND
 290         rl.from_id = oi.id
 291       GROUP BY oi.id
 292     ) linked
 293     WHERE qty > doi_qty
 294
 295     UNION ALL
 296
 297     -- 2. since the join over record_links fails for items not in any delivery order
 298     --    retrieve those without record_links at all
 299     SELECT oi.id FROM orderitems oi, oe
 300     WHERE
 301       oe.id = oi.trans_id AND
 302       oe.${vc}_id IS NOT NULL AND
 303       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 304       NOT oe.closed AND
 305       $oe_owner
 306       oi.id NOT IN (
 307         SELECT from_id
 308         FROM record_links rl
 309         WHERE
 310           rl.from_table ='orderitems' AND
 311           rl.to_table = 'delivery_order_items'
 312       )
 313
 314   " ], # make emacs happy again: " ]
 315   ]
 316 }
 317
 318 sub init_models {
 319   my ($self) = @_;
 320   my $vc     = $self->vc;
 321
 322   my $query = $self->use_linked_items ? $self->delivery_plan_query_linked_items
 323             :                           $self->delivery_plan_query;
 324
 325   SL::Controller::Helper::GetModels->new(
 326     controller   => $self,
 327     model        => 'OrderItem',
 328     sorted       => {
 329       _default     => {
 330         by           => 'reqdate',
 331         dir          => 1,
 332       },
 333       %sort_columns,
 334     },
 335     query        => $query,
 336     with_objects => [ 'order', "order.$vc", 'part' ],
 337     additional_url_params => { vc => $vc, use_linked_items => $self->use_linked_items },
 338   );
 339 }
 340
 341 sub init_all_edit_right {
 342   $::auth->assert('sales_all_edit', 1)
 343 }
 344 sub init_vc {
 345   return $::form->{vc} if ($::form->{vc} eq 'customer' || $::form->{vc} eq 'vendor') || croak "self (DeliveryPlan) has no vc defined";
 346 }
 347
 348 sub init_use_linked_items {
 349   !!$::form->{use_linked_items};
 350 }
 351
 352 sub init_all_employees {
 353   return SL::DB::Manager::Employee->get_all_sorted;
 354 }
 355 sub init_all_businesses {
 356   return SL::DB::Manager::Business->get_all_sorted;
 357 }
 358 sub init_all_departments {
 359   return SL::DB::Manager::Department->get_all_sorted;
 360 }
 361 sub link_to {
 362   my ($self, $object, %params) = @_;
 363
 364   return unless $object;
 365   my $action = $params{action} || 'edit';
 366
 367   if ($object->isa('SL::DB::Order')) {
 368     my $type   = $object->type;
 369     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 370     my $id     = $object->id;
 371
 372     if ($::instance_conf->get_feature_experimental_order) {
 373       return "controller.pl?action=Order/$action&type=$type&id=$id";
 374     } else {
 375       return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 376     }
 377   }
 378   if ($object->isa('SL::DB::Part')) {
 379     my $id     = $object->id;
 380     return "controller.pl?action=Part/$action&part.id=$id";
 381   }
 382   if ($object->isa('SL::DB::Customer')) {
 383     my $id     = $object->id;
 384     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 385   }
 386 }
 387
 388 sub setup_list_action_bar {
 389   my ($self, %params) = @_;
 390
 391   for my $bar ($::request->layout->get('actionbar')) {
 392     $bar->add(
 393       action => [
 394         t8('Update'),
 395         submit    => [ '#filter_form', { action => 'DeliveryPlan/list' } ],
 396         accesskey => 'enter',
 397       ],
 398     );
 399   }
 400 }
 401
 402 1;