SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::ReportGenerator;
  10 use SL::Locale::String;
  11
  12 use Rose::Object::MakeMethods::Generic (
  13   scalar => [ qw(db_args flat_filter) ],
  14   'scalar --get_set_init' => [ qw(models all_edit_right) ],
  15 );
  16
  17 __PACKAGE__->run_before(sub { $::auth->assert('delivery_plan'); });
  18
  19 my %sort_columns = (
  20   reqdate           => t8('Reqdate'),
  21   description       => t8('Description'),
  22   partnumber        => t8('Part Number'),
  23   qty               => t8('Qty'),
  24   shipped_qty       => t8('shipped'),
  25   delivered_qty     => t8('transferred out'),
  26   not_shipped_qty   => t8('not shipped'),
  27   ordnumber         => t8('Order'),
  28   customer          => t8('Customer'),
  29   value_of_goods    => t8('Value of goods'),
  30 );
  31
  32 sub action_list {
  33   my ($self) = @_;
  34
  35   $self->make_filter_summary;
  36   $self->prepare_report;
  37
  38   my $orderitems = $self->models->get;
  39
  40   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
  41 }
  42
  43 # private functions
  44 #
  45 sub prepare_report {
  46   my ($self)      = @_;
  47
  48   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  49   $self->{report} = $report;
  50
  51   my @columns     = qw(reqdate customer ordnumber partnumber description qty shipped_qty not_shipped_qty delivered_qty value_of_goods);
  52   my @sortable    = qw(reqdate customer ordnumber partnumber description);
  53
  54   my %column_defs = (
  55     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
  56     description       => {      sub => sub { $_[0]->description                                                              },
  57                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  58     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
  59                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  60     qty               => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit                                        } },
  61     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit } },
  62     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit } },
  63     delivered_qty     => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->delivered_qty, 2) . ' ' . $_[0]->unit } },
  64     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
  65                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
  66     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
  67                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
  68   );
  69
  70   # add value of goods in report
  71   if ($main::auth->assert('sales_order_edit') && $::instance_conf->get_delivery_plan_show_value_of_goods) {
  72     $column_defs{value_of_goods} = { sub =>  sub { $::form->format_amount(\%::myconfig, $_[0]->value_of_goods, 2) . ' ' . $_[0]->taxincluded } };
  73   }
  74   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
  75
  76   $report->set_options(
  77     std_column_visibility => 1,
  78     controller_class      => 'DeliveryPlan',
  79     output_format         => 'HTML',
  80     top_info_text         => $::locale->text('Delivery Plan for currently outstanding sales orders'),
  81     title                 => $::locale->text('Delivery Plan'),
  82     allow_pdf_export      => 1,
  83     allow_csv_export      => 1,
  84   );
  85   $report->set_columns(%column_defs);
  86   $report->set_column_order(@columns);
  87   $report->set_export_options(qw(list filter));
  88   $report->set_options_from_form;
  89   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
  90   $self->models->finalize; # for filter laundering
  91   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
  92   $report->set_options(
  93     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }),
  94     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
  95   );
  96 }
  97
  98 sub make_filter_summary {
  99   my ($self) = @_;
 100
 101   my $filter = $::form->{filter} || {};
 102   my @filter_strings;
 103
 104   my @filters = (
 105     [ $filter->{order}{"ordnumber:substr::ilike"},                $::locale->text('Number')                                             ],
 106     [ $filter->{part}{"partnumber:substr::ilike"},                $::locale->text('Part Number')                                        ],
 107     [ $filter->{"description:substr::ilike"},                     $::locale->text('Part Description')                                   ],
 108     [ $filter->{"reqdate:date::ge"},                              $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 109     [ $filter->{"reqdate:date::le"},                              $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 110     [ $filter->{"qty:number"},                                    $::locale->text('Quantity')                                           ],
 111     [ $filter->{order}{customer}{"name:substr::ilike"},           $::locale->text('Customer')                                           ],
 112     [ $filter->{order}{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number')                                    ],
 113   );
 114
 115   my %flags = (
 116     part     => $::locale->text('Parts'),
 117     service  => $::locale->text('Services'),
 118     assembly => $::locale->text('Assemblies'),
 119   );
 120   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 121
 122   for (@flags) {
 123     push @filter_strings, $_ if $_;
 124   }
 125   for (@filters) {
 126     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 127   }
 128
 129   $self->{filter_summary} = join ', ', @filter_strings;
 130 }
 131
 132 sub delivery_plan_query {
 133   my $employee_id = SL::DB::Manager::Employee->current->id;
 134   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.eployee_id = $employee_id AND";
 135   # check delivered state for delivery_orders (transferred out) if enabled
 136   my $filter_delivered = $::instance_conf->get_delivery_plan_calculate_transferred_do  ?
 137       "AND (SELECT delivered from delivery_orders where id = doi.delivery_order_id)" : '';
 138   [
 139   'order.customer_id' => { gt => 0 },
 140   'order.closed' => 0,
 141   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 142
 143   # filter by shipped_qty < qty, read from innermost to outermost
 144   'id' => [ \"
 145     -- 3. resolve the desired information about those
 146     SELECT oi.id FROM (
 147       -- 2. slice only part, orderitem and both quantities from it
 148       SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
 149         -- 1. join orderitems and deliverorder items via record_links.
 150         --    also add customer data to filter for sales_orders
 151         SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
 152         FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 153         WHERE
 154           oe.id = oi.trans_id AND
 155           oe.customer_id IS NOT NULL AND
 156           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 157           NOT oe.closed AND
 158           $oe_owner
 159           rl.from_id = oe.id AND
 160           rl.from_id = oi.trans_id AND
 161           oe.id = oi.trans_id AND
 162           rl.from_table = 'oe' AND
 163           rl.to_table = 'delivery_orders' AND
 164           rl.to_id = doi.delivery_order_id AND
 165           oi.parts_id = doi.parts_id
 166           $filter_delivered
 167       ) tuples GROUP BY parts_id, trans_id, qty
 168     ) partials
 169     LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 170     WHERE oi.qty > doi_qty
 171
 172     UNION ALL
 173
 174     -- 4. since the join over record_links fails for sales_orders without any delivery order
 175     --    retrieve those without record_links at all
 176     SELECT oi.id FROM orderitems oi, oe
 177     WHERE
 178       oe.id = oi.trans_id AND
 179       oe.customer_id IS NOT NULL AND
 180       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 181       NOT oe.closed AND
 182       $oe_owner
 183       oi.trans_id NOT IN (
 184         SELECT from_id
 185         FROM record_links rl
 186         WHERE
 187           rl.from_table ='oe' AND
 188           rl.to_table = 'delivery_orders'
 189       )
 190
 191     UNION ALL
 192
 193     -- 5. now for the really nasty cases.
 194     --    If someone partially delivered an order in several delivery orders,
 195     --    there will be lots of record_links (4 doesn't catch those) but those
 196     --    won't have matching part_ids in delivery_order_items, so 1-3 can't
 197     --    find anything
 198     --    In this case aggreg record_links - delivery_order - delivery_order_items
 199     --    slice only oe.id, parts_id and sum of of qty
 200     --    left join that onto orderitems to get matching qtys in doi while retaining
 201     --    entrys without matches and then throw out those without record_links
 202     --    TODO: join this and 1-3 into a general case
 203                   -- need debug info? uncomment these:
 204     SELECT oi.id  -- ,oi.trans_id, oi.parts_id, coalesce(sum, 0), agg.parts_id
 205     FROM orderitems oi LEFT JOIN (
 206       SELECT rl.from_id as oid, doi.parts_id, sum(doi.qty) FROM (
 207         SELECT from_id, to_id
 208         FROM record_links rl
 209         LEFT JOIN oe ON oe.id = from_id
 210         WHERE
 211           rl.from_table = 'oe' AND
 212           rl.to_table = 'delivery_orders' AND
 213
 214           oe.customer_id IS NOT NULL AND
 215           $oe_owner
 216           (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 217       ) rl
 218       LEFT JOIN delivery_order_items doi ON (rl.to_id = doi.delivery_order_id)
 219       WHERE 1 = 1
 220       $filter_delivered
 221       GROUP BY rl.from_id, doi.parts_id
 222     ) agg ON (agg.oid = oi.trans_id AND agg.parts_id = oi.parts_id)
 223     LEFT JOIN oe ON oe.id = oi.trans_id
 224     WHERE
 225       EXISTS (
 226         SELECT to_id
 227         FROM record_links rl
 228         WHERE oi.trans_id = rl.from_id AND rl.from_table = 'oe' AND rl.to_table = 'delivery_orders'
 229       ) AND
 230       coalesce(sum, 0) < oi.qty AND
 231       oe.customer_id IS NOT NULL AND
 232       $oe_owner
 233       (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 234   " ],
 235   ]
 236 }
 237
 238 sub init_models {
 239   my ($self) = @_;
 240
 241   SL::Controller::Helper::GetModels->new(
 242     controller   => $self,
 243     model        => 'OrderItem',
 244     sorted       => {
 245       _default     => {
 246         by           => 'reqdate',
 247         dir          => 1,
 248       },
 249       %sort_columns,
 250     },
 251     query        => $self->delivery_plan_query,
 252     with_objects => [ 'order', 'order.customer', 'part' ],
 253   );
 254 }
 255
 256 sub init_all_edit_right {
 257   $::auth->assert('sales_all_edit', 1)
 258 }
 259
 260 sub link_to {
 261   my ($self, $object, %params) = @_;
 262
 263   return unless $object;
 264   my $action = $params{action} || 'edit';
 265
 266   if ($object->isa('SL::DB::Order')) {
 267     my $type   = $object->type;
 268     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 269     my $id     = $object->id;
 270
 271     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 272   }
 273   if ($object->isa('SL::DB::Part')) {
 274     my $id     = $object->id;
 275     return "ic.pl?action=$action&id=$id";
 276   }
 277   if ($object->isa('SL::DB::Customer')) {
 278     my $id     = $object->id;
 279     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 280   }
 281 }
 282
 283 1;