SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::DB::Business;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::Locale::String;
  12 use SL::AM;
  13 use SL::DBUtils ();
  14 use Carp;
  15
  16 use Rose::Object::MakeMethods::Generic (
  17   scalar => [ qw(db_args flat_filter) ],
  18   'scalar --get_set_init' => [ qw(models all_edit_right vc use_linked_items all_employees all_businesses) ],
  19 );
  20
  21 __PACKAGE__->run_before(sub { $::auth->assert('delivery_plan'); });
  22
  23 my %sort_columns = (
  24   reqdate           => t8('Reqdate'),
  25   description       => t8('Description'),
  26   partnumber        => t8('Part Number'),
  27   qty               => t8('Qty'),
  28   shipped_qty       => t8('shipped'),
  29   delivered_qty     => t8('transferred in / out'),
  30   not_shipped_qty   => t8('not shipped'),
  31   ordnumber         => t8('Order'),
  32   customer          => t8('Customer'),
  33   vendor            => t8('Vendor'),
  34 );
  35
  36
  37 sub action_list {
  38   my ($self) = @_;
  39   $self->make_filter_summary;
  40   $self->prepare_report;
  41
  42   my $orderitems = $self->models->get;
  43   $self->calc_qtys($orderitems);
  44   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
  45 }
  46
  47 # private functions
  48 #
  49 sub prepare_report {
  50   my ($self)      = @_;
  51
  52   my $vc          = $self->vc;
  53   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  54   $self->{report} = $report;
  55
  56   my @columns     = qw(reqdate customer vendor ordnumber partnumber description qty shipped_qty not_shipped_qty delivered_qty);
  57
  58   my @sortable    = qw(reqdate customer vendor ordnumber partnumber description);
  59
  60   my %column_defs = (
  61     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
  62     description       => {      sub => sub { $_[0]->description                                                              },
  63                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  64     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
  65                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  66     qty               => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit                                        } },
  67     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]{shipped_qty}, 2) . ' ' . $_[0]->unit } },
  68     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]{shipped_qty}, 2) . ' ' . $_[0]->unit } },
  69     delivered_qty     => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]{delivered_qty}, 2) .' ' . $_[0]->unit } },
  70     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
  71                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
  72     vendor            => {      sub => sub { $_[0]->order->vendor->name                                                      },
  73                             visible => $vc eq 'vendor',
  74                            obj_link => sub { $self->link_to($_[0]->order->vendor)                                            } },
  75     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
  76                             visible => $vc eq 'customer',
  77                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
  78   );
  79
  80   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
  81
  82   $report->set_options(
  83     std_column_visibility => 1,
  84     controller_class      => 'DeliveryPlan',
  85     output_format         => 'HTML',
  86     top_info_text         => ($vc eq 'customer') ? $::locale->text('Delivery Plan for currently outstanding sales orders') :
  87                                                    $::locale->text('Delivery Plan for currently outstanding purchase orders'),
  88     title                 => $::locale->text('Delivery Plan'),
  89     allow_pdf_export      => 1,
  90     allow_csv_export      => 1,
  91   );
  92   $report->set_columns(%column_defs);
  93   $report->set_column_order(@columns);
  94   $report->set_export_options(qw(list filter vc use_linked_items));
  95   $report->set_options_from_form;
  96   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
  97   $self->models->finalize; # for filter laundering
  98   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
  99   $report->set_options(
 100     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }),
 101     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
 102   );
 103 }
 104
 105 sub calc_qtys {
 106   my ($self, $orderitems) = @_;
 107   # using $orderitem->shipped_qty 40 times is far too slow. need to do it manually
 108   #
 109
 110   return unless scalar @$orderitems;
 111
 112   my %orderitems_by_id = map { $_->id => $_ } @$orderitems;
 113
 114   my $query = $self->use_linked_items ? _calc_qtys_query_linked_items(scalar @$orderitems)
 115             :                           _calc_qtys_query_match_parts(scalar @$orderitems);
 116
 117   my $result = SL::DBUtils::selectall_hashref_query($::form, $::form->get_standard_dbh, $query, map { $_->id } @$orderitems);
 118
 119   for my $row (@$result) {
 120     my $item = $orderitems_by_id{ $row->{id} };
 121     $item->{shipped_qty}   ||= 0;
 122     $item->{delivered_qty} ||= 0;
 123     $item->{shipped_qty}    += AM->convert_unit($row->{unit} => $item->unit) * $row->{qty};
 124     $item->{delivered_qty}  += AM->convert_unit($row->{unit} => $item->unit) * $row->{qty} if $row->{delivered};
 125   }
 126 }
 127
 128 sub _calc_qtys_query_match_parts {
 129   my ($num_items) = @_;
 130
 131   my $query = <<SQL;
 132     SELECT oi.id, doi.qty, doi.unit, doe.delivered
 133     FROM record_links rl
 134     INNER JOIN delivery_order_items doi ON (doi.delivery_order_id = rl.to_id)
 135     INNER JOIN delivery_orders doe ON (doe.id = rl.to_id)
 136     INNER JOIN orderitems oi ON (oi.trans_id = rl.from_id)
 137     WHERE rl.from_table = 'oe'
 138       AND rl.to_table   = 'delivery_orders'
 139       AND oi.parts_id   = doi.parts_id
 140       AND oi.id IN (@{[ join ', ', ("?")x $num_items ]})
 141 SQL
 142
 143   return $query;
 144 }
 145
 146 sub _calc_qtys_query_linked_items {
 147   my ($num_items) = @_;
 148
 149   my $query = <<SQL;
 150     SELECT rl.from_id as id, doi.qty, doi.unit, doe.delivered
 151     FROM record_links rl
 152     INNER JOIN delivery_order_items doi ON (doi.id = rl.to_id)
 153     INNER JOIN delivery_orders doe ON (doe.id = doi.delivery_order_id)
 154     WHERE rl.from_table LIKE 'orderitems'
 155       AND rl.to_table   LIKE 'delivery_order_items'
 156       AND rl.from_id IN (@{[ join ', ', ("?")x $num_items ]})
 157 SQL
 158
 159   return $query;
 160 }
 161
 162 sub make_filter_summary {
 163   my ($self) = @_;
 164   my $vc     = $self->vc;
 165   my ($business, $employee);
 166
 167   my $filter = $::form->{filter} || {};
 168   my @filter_strings;
 169
 170   $business = SL::DB::Business->new(id => $filter->{order}{customer}{"business_id"})->load->description if $filter->{order}{customer}{"business_id"};
 171   $employee = SL::DB::Employee->new(id => $filter->{order}{employee_id})->load->name if $filter->{order}{employee_id};
 172
 173   my @filters = (
 174     [ $filter->{order}{"ordnumber:substr::ilike"},                    $::locale->text('Number')                                             ],
 175     [ $filter->{order}{globalproject}{"projectnumber:substr::ilike"}, $::locale->text('Document Project Number')                            ],
 176     [ $filter->{part}{"partnumber:substr::ilike"},                    $::locale->text('Part Number')                                        ],
 177     [ $filter->{"description:substr::ilike"},                         $::locale->text('Part Description')                                   ],
 178     [ $filter->{"reqdate:date::ge"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 179     [ $filter->{"reqdate:date::le"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 180     [ $filter->{"qty:number"},                                        $::locale->text('Quantity')                                           ],
 181     [ $filter->{order}{vendor}{"name:substr::ilike"},                 $::locale->text('Vendor')                                             ],
 182     [ $filter->{order}{vendor}{"vendornumber:substr::ilike"},         $::locale->text('Vendor Number')                                      ],
 183     [ $filter->{order}{customer}{"name:substr::ilike"},               $::locale->text('Customer')                                           ],
 184     [ $filter->{order}{customer}{"customernumber:substr::ilike"},     $::locale->text('Customer Number')                                    ],
 185     [ $business,                                                      $::locale->text('Customer type')                                      ],
 186     [ $employee,                                                      $::locale->text('Employee')                                           ],
 187   );
 188
 189   my %flags = (
 190     part     => $::locale->text('Parts'),
 191     service  => $::locale->text('Services'),
 192     assembly => $::locale->text('Assemblies'),
 193   );
 194   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 195
 196   for (@flags) {
 197     push @filter_strings, $_ if $_;
 198   }
 199   for (@filters) {
 200     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 201   }
 202
 203   $self->{filter_summary} = join ', ', @filter_strings;
 204 }
 205
 206 sub delivery_plan_query {
 207   my ($self) = @_;
 208   my $vc     = $self->vc;
 209   my $employee_id = SL::DB::Manager::Employee->current->id;
 210   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 211
 212   [
 213   "order.${vc}_id" => { gt => 0 },
 214   'order.closed' => 0,
 215   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 216
 217   # filter by shipped_qty < qty, read from innermost to outermost
 218   'id' => [ \"
 219     -- 3. resolve the desired information about those
 220     SELECT oi.id FROM (
 221       -- 2. slice only part, orderitem and both quantities from it
 222       SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
 223         -- 1. join orderitems and deliverorder items via record_links.
 224         --    also add customer data to filter for sales_orders
 225         SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
 226         FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 227         WHERE
 228           oe.id = oi.trans_id AND
 229           oe.${vc}_id IS NOT NULL AND
 230           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 231           NOT oe.closed AND
 232           $oe_owner
 233           rl.from_id = oe.id AND
 234           rl.from_id = oi.trans_id AND
 235           oe.id = oi.trans_id AND
 236           rl.from_table = 'oe' AND
 237           rl.to_table = 'delivery_orders' AND
 238           rl.to_id = doi.delivery_order_id AND
 239           oi.parts_id = doi.parts_id
 240       ) tuples GROUP BY parts_id, trans_id, qty
 241     ) partials
 242     LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 243     WHERE oi.qty > doi_qty
 244
 245     UNION ALL
 246
 247     -- 4. since the join over record_links fails for sales_orders without any delivery order
 248     --    retrieve those without record_links at all
 249     SELECT oi.id FROM orderitems oi, oe
 250     WHERE
 251       oe.id = oi.trans_id AND
 252       oe.${vc}_id IS NOT NULL AND
 253       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 254       NOT oe.closed AND
 255       $oe_owner
 256       oi.trans_id NOT IN (
 257         SELECT from_id
 258         FROM record_links rl
 259         WHERE
 260           rl.from_table ='oe' AND
 261           rl.to_table = 'delivery_orders'
 262       )
 263
 264     UNION ALL
 265
 266     -- 5. now for the really nasty cases.
 267     --    If someone partially delivered an order in several delivery orders,
 268     --    there will be lots of record_links (4 doesn't catch those) but those
 269     --    won't have matching part_ids in delivery_order_items, so 1-3 can't
 270     --    find anything
 271     --    In this case aggreg record_links - delivery_order - delivery_order_items
 272     --    slice only oe.id, parts_id and sum of of qty
 273     --    left join that onto orderitems to get matching qtys in doi while retaining
 274     --    entrys without matches and then throw out those without record_links
 275     --    TODO: join this and 1-3 into a general case
 276                   -- need debug info? uncomment these:
 277     SELECT oi.id  -- ,oi.trans_id, oi.parts_id, coalesce(sum, 0), agg.parts_id
 278     FROM orderitems oi LEFT JOIN (
 279       SELECT rl.from_id as oid, doi.parts_id, sum(doi.qty) FROM (
 280         SELECT from_id, to_id
 281         FROM record_links rl
 282         LEFT JOIN oe ON oe.id = from_id
 283         WHERE
 284           rl.from_table = 'oe' AND
 285           rl.to_table = 'delivery_orders' AND
 286
 287           oe.${vc}_id IS NOT NULL AND
 288           $oe_owner
 289           (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 290       ) rl
 291       LEFT JOIN delivery_order_items doi ON (rl.to_id = doi.delivery_order_id)
 292       GROUP BY rl.from_id, doi.parts_id
 293     ) agg ON (agg.oid = oi.trans_id AND agg.parts_id = oi.parts_id)
 294     LEFT JOIN oe ON oe.id = oi.trans_id
 295     WHERE
 296       EXISTS (
 297         SELECT to_id
 298         FROM record_links rl
 299         WHERE oi.trans_id = rl.from_id AND rl.from_table = 'oe' AND rl.to_table = 'delivery_orders'
 300       ) AND
 301       coalesce(sum, 0) < oi.qty AND
 302       oe.${vc}_id IS NOT NULL AND
 303       $oe_owner
 304       (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 305   " ], # make emacs happy again: '
 306   ]
 307 }
 308
 309 sub delivery_plan_query_linked_items {
 310   my ($self) = @_;
 311   my $vc     = $self->vc;
 312   my $employee_id = SL::DB::Manager::Employee->current->id;
 313   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 314
 315   [
 316   "order.${vc}_id" => { gt => 0 },
 317   'order.closed' => 0,
 318   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 319
 320   # filter by shipped_qty < qty, read from innermost to outermost
 321   'id' => [ \"
 322     SELECT id FROM (
 323       SELECT oi.qty, oi.id, SUM(doi.qty) AS doi_qty
 324       FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 325       WHERE
 326         oe.id = oi.trans_id AND
 327         oe.${vc}_id IS NOT NULL AND
 328         (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 329         NOT oe.closed AND
 330         $oe_owner
 331         doi.id = rl.to_id AND
 332         rl.from_table = 'orderitems'AND
 333         rl.to_table   = 'delivery_order_items' AND
 334         rl.from_id = oi.id
 335       GROUP BY oi.id
 336     ) linked
 337     WHERE qty > doi_qty
 338
 339     UNION ALL
 340
 341     -- 2. since the join over record_links fails for items not in any delivery order
 342     --    retrieve those without record_links at all
 343     SELECT oi.id FROM orderitems oi, oe
 344     WHERE
 345       oe.id = oi.trans_id AND
 346       oe.${vc}_id IS NOT NULL AND
 347       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 348       NOT oe.closed AND
 349       $oe_owner
 350       oi.id NOT IN (
 351         SELECT from_id
 352         FROM record_links rl
 353         WHERE
 354           rl.from_table ='orderitems' AND
 355           rl.to_table = 'delivery_order_items'
 356       )
 357
 358   " ], # make emacs happy again: " ]
 359   ]
 360 }
 361
 362 sub init_models {
 363   my ($self) = @_;
 364   my $vc     = $self->vc;
 365
 366   my $query = $self->use_linked_items ? $self->delivery_plan_query_linked_items
 367             :                           $self->delivery_plan_query;
 368
 369   SL::Controller::Helper::GetModels->new(
 370     controller   => $self,
 371     model        => 'OrderItem',
 372     sorted       => {
 373       _default     => {
 374         by           => 'reqdate',
 375         dir          => 1,
 376       },
 377       %sort_columns,
 378     },
 379     query        => $query,
 380     with_objects => [ 'order', "order.$vc", 'part' ],
 381     additional_url_params => { vc => $vc, use_linked_items => $self->use_linked_items },
 382   );
 383 }
 384
 385 sub init_all_edit_right {
 386   $::auth->assert('sales_all_edit', 1)
 387 }
 388 sub init_vc {
 389   return $::form->{vc} if ($::form->{vc} eq 'customer' || $::form->{vc} eq 'vendor') || croak "self (DeliveryPlan) has no vc defined";
 390 }
 391
 392 sub init_use_linked_items {
 393   !!$::form->{use_linked_items};
 394 }
 395
 396 sub init_all_employees {
 397   return SL::DB::Manager::Employee->get_all_sorted;
 398 }
 399 sub init_all_businesses {
 400   return SL::DB::Manager::Business->get_all_sorted;
 401 }
 402 sub link_to {
 403   my ($self, $object, %params) = @_;
 404
 405   return unless $object;
 406   my $action = $params{action} || 'edit';
 407
 408   if ($object->isa('SL::DB::Order')) {
 409     my $type   = $object->type;
 410     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 411     my $id     = $object->id;
 412
 413     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 414   }
 415   if ($object->isa('SL::DB::Part')) {
 416     my $id     = $object->id;
 417     return "ic.pl?action=$action&id=$id";
 418   }
 419   if ($object->isa('SL::DB::Customer')) {
 420     my $id     = $object->id;
 421     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 422   }
 423 }
 424
 425 1;