SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::ReportGenerator;
  10 use SL::Locale::String;
  11
  12 use Rose::Object::MakeMethods::Generic (
  13   scalar => [ qw(db_args flat_filter) ],
  14   'scalar --get_set_init' => [ qw(models all_edit_right) ],
  15 );
  16
  17 __PACKAGE__->run_before(sub { $::auth->assert('delivery_plan'); });
  18
  19 my %sort_columns = (
  20   reqdate           => t8('Reqdate'),
  21   description       => t8('Description'),
  22   partnumber        => t8('Part Number'),
  23   qty               => t8('Qty'),
  24   shipped_qty       => t8('shipped'),
  25   not_shipped_qty   => t8('not shipped'),
  26   ordnumber         => t8('Order'),
  27   customer          => t8('Customer'),
  28 );
  29
  30 sub action_list {
  31   my ($self) = @_;
  32
  33   $self->make_filter_summary;
  34   $self->prepare_report;
  35
  36   my $orderitems = $self->models->get;
  37
  38   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
  39 }
  40
  41 # private functions
  42 #
  43 sub prepare_report {
  44   my ($self)      = @_;
  45
  46   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  47   $self->{report} = $report;
  48
  49   my @columns     = qw(reqdate customer ordnumber partnumber description qty shipped_qty not_shipped_qty);
  50   my @sortable    = qw(reqdate customer ordnumber partnumber description);
  51
  52   my %column_defs = (
  53     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
  54     description       => {      sub => sub { $_[0]->description                                                              },
  55                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  56     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
  57                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  58     qty               => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit                                        } },
  59     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit } },
  60     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit } },
  61     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
  62                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
  63     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
  64                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
  65   );
  66
  67   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
  68
  69   $report->set_options(
  70     std_column_visibility => 1,
  71     controller_class      => 'DeliveryPlan',
  72     output_format         => 'HTML',
  73     top_info_text         => $::locale->text('Delivery Plan for currently outstanding sales orders'),
  74     title                 => $::locale->text('Delivery Plan'),
  75     allow_pdf_export      => 1,
  76     allow_csv_export      => 1,
  77   );
  78   $report->set_columns(%column_defs);
  79   $report->set_column_order(@columns);
  80   $report->set_export_options(qw(list filter));
  81   $report->set_options_from_form;
  82   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
  83   $self->models->finalize; # for filter laundering
  84   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
  85   $report->set_options(
  86     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }),
  87     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
  88   );
  89 }
  90
  91 sub make_filter_summary {
  92   my ($self) = @_;
  93
  94   my $filter = $::form->{filter} || {};
  95   my @filter_strings;
  96
  97   my @filters = (
  98     [ $filter->{order}{"ordnumber:substr::ilike"},                $::locale->text('Number')                                             ],
  99     [ $filter->{part}{"partnumber:substr::ilike"},                $::locale->text('Part Number')                                        ],
 100     [ $filter->{"description:substr::ilike"},                     $::locale->text('Part Description')                                   ],
 101     [ $filter->{"reqdate:date::ge"},                              $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 102     [ $filter->{"reqdate:date::le"},                              $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 103     [ $filter->{"qty:number"},                                    $::locale->text('Quantity')                                           ],
 104     [ $filter->{order}{customer}{"name:substr::ilike"},           $::locale->text('Customer')                                           ],
 105     [ $filter->{order}{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number')                                    ],
 106   );
 107
 108   my %flags = (
 109     part     => $::locale->text('Parts'),
 110     service  => $::locale->text('Services'),
 111     assembly => $::locale->text('Assemblies'),
 112   );
 113   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 114
 115   for (@flags) {
 116     push @filter_strings, $_ if $_;
 117   }
 118   for (@filters) {
 119     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 120   }
 121
 122   $self->{filter_summary} = join ', ', @filter_strings;
 123 }
 124
 125 sub delivery_plan_query {
 126   my $employee_id = SL::DB::Manager::Employee->current->id;
 127   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.eployee_id = $employee_id AND";
 128   [
 129   'order.customer_id' => { gt => 0 },
 130   'order.closed' => 0,
 131   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 132
 133   # filter by shipped_qty < qty, read from innermost to outermost
 134   'id' => [ \"
 135     -- 3. resolve the desired information about those
 136     SELECT oi.id FROM (
 137       -- 2. slice only part, orderitem and both quantities from it
 138       SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
 139         -- 1. join orderitems and deliverorder items via record_links.
 140         --    also add customer data to filter for sales_orders
 141         SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
 142         FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 143         WHERE
 144           oe.id = oi.trans_id AND
 145           oe.customer_id IS NOT NULL AND
 146           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 147           NOT oe.closed AND
 148           $oe_owner
 149           rl.from_id = oe.id AND
 150           rl.from_id = oi.trans_id AND
 151           oe.id = oi.trans_id AND
 152           rl.from_table = 'oe' AND
 153           rl.to_table = 'delivery_orders' AND
 154           rl.to_id = doi.delivery_order_id AND
 155           oi.parts_id = doi.parts_id
 156       ) tuples GROUP BY parts_id, trans_id, qty
 157     ) partials
 158     LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 159     WHERE oi.qty > doi_qty
 160
 161     UNION ALL
 162
 163     -- 4. since the join over record_links fails for sales_orders wihtout any delivery order
 164     --    retrieve those without record_links at all
 165     SELECT oi.id FROM orderitems oi, oe
 166     WHERE
 167       oe.id = oi.trans_id AND
 168       oe.customer_id IS NOT NULL AND
 169       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 170       NOT oe.closed AND
 171       $oe_owner
 172       oi.trans_id NOT IN (
 173         SELECT from_id
 174         FROM record_links rl
 175         WHERE
 176           rl.from_table ='oe' AND
 177           rl.to_table = 'delivery_orders'
 178       )
 179
 180     UNION ALL
 181
 182     -- 5. In case someone deleted a line of the delivery_order there will be a record_link (4 fails)
 183     --    but there won't be a delivery_order_items to find (3 fails too). Search for orphaned orderitems this way
 184     SELECT oi.id FROM orderitems AS oi, oe, record_links AS rl
 185     WHERE
 186       rl.from_table = 'oe' AND
 187       rl.to_table = 'delivery_orders' AND
 188
 189       oi.trans_id = rl.from_id AND
 190       oi.parts_id NOT IN (
 191         SELECT doi.parts_id FROM delivery_order_items AS doi WHERE doi.delivery_order_id = rl.to_id
 192       ) AND
 193
 194       oe.id = oi.trans_id AND
 195
 196       oe.customer_id IS NOT NULL AND
 197       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 198       $oe_owner
 199       NOT oe.closed
 200   " ],
 201   ]
 202 }
 203
 204 sub init_models {
 205   my ($self) = @_;
 206
 207   SL::Controller::Helper::GetModels->new(
 208     controller   => $self,
 209     model        => 'OrderItem',
 210     sorted       => {
 211       _default     => {
 212         by           => 'reqdate',
 213         dir          => 1,
 214       },
 215       %sort_columns,
 216     },
 217     query        => $self->delivery_plan_query,
 218     with_objects => [ 'order', 'order.customer', 'part' ],
 219   );
 220 }
 221
 222 sub init_all_edit_right {
 223   $::auth->assert('sales_all_edit', 1)
 224 }
 225
 226 sub link_to {
 227   my ($self, $object, %params) = @_;
 228
 229   return unless $object;
 230   my $action = $params{action} || 'edit';
 231
 232   if ($object->isa('SL::DB::Order')) {
 233     my $type   = $object->type;
 234     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 235     my $id     = $object->id;
 236
 237     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 238   }
 239   if ($object->isa('SL::DB::Part')) {
 240     my $id     = $object->id;
 241     return "ic.pl?action=$action&id=$id";
 242   }
 243   if ($object->isa('SL::DB::Customer')) {
 244     my $id     = $object->id;
 245     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 246   }
 247 }
 248
 249 1;