SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::Paginated;
  10 use SL::Controller::Helper::Sorted;
  11 use SL::Controller::Helper::ParseFilter;
  12 use SL::Controller::Helper::ReportGenerator;
  13
  14 use Rose::Object::MakeMethods::Generic (
  15   scalar => [ qw(db_args flat_filter) ],
  16 );
  17
  18 __PACKAGE__->run_before(sub { $::auth->assert('sales_order_edit'); });
  19
  20 __PACKAGE__->get_models_url_params('flat_filter');
  21 __PACKAGE__->make_paginated(
  22   MODEL         => 'OrderItem',
  23   PAGINATE_ARGS => 'db_args',
  24   ONLY          => [ qw(list) ],
  25 );
  26
  27 __PACKAGE__->make_sorted(
  28   MODEL       => 'OrderItem',
  29   ONLY        => [ qw(list) ],
  30
  31   DEFAULT_BY  => 'reqdate',
  32   DEFAULT_DIR => 1,
  33
  34   reqdate     => 'Reqdate',
  35   description => 'Description',
  36   partnumber  => 'Part Number',
  37   qty         => 'Qty',
  38   missing     => 'Missing qty',
  39   shipped_qty => 'shipped',
  40   ordnumber   => 'Order',
  41   customer    => 'Customer',
  42 );
  43
  44 sub action_list {
  45   my ($self) = @_;
  46   my %list_params = (
  47     filter   => $::form->{filter},
  48   );
  49
  50   $self->db_args($self->setup_for_list(%list_params));
  51   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  52   $self->make_filter_summary;
  53
  54   my $top    = $::form->parse_html_template('delivery_plan/report_top', { FORM => $::form, SELF => $self });
  55   my $bottom = $::form->parse_html_template('delivery_plan/report_bottom', { SELF => $self });
  56
  57   $self->prepare_report(
  58     report_generator_options => {
  59       raw_top_info_text    => $top,
  60       raw_bottom_info_text => $bottom,
  61       controller_class     => 'DeliveryPlan',
  62     },
  63     report_generator_export_options => [ qw(list filter sort_by sort_dir) ],
  64   );
  65
  66   $self->{orderitems} = $self->get_models(%{ $self->db_args });
  67
  68   $self->list_objects;
  69 }
  70
  71 # private functions
  72
  73 sub setup_for_list {
  74   my ($self, %params) = @_;
  75   $self->{filter} = {};
  76   my %args = (
  77     parse_filter(
  78       $self->_pre_parse_filter($::form->{filter}, $self->{filter}),
  79       with_objects => [ 'order', 'order.customer', 'part' ],
  80       launder_to => $self->{filter},
  81     ),
  82   );
  83
  84   $args{query} = [ @{ $args{query} || [] },
  85     (
  86       'order.customer_id' => { gt => 0 },
  87       'order.closed' => 0,
  88       or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
  89
  90       # filter by shipped_qty < qty, read from innermost to outermost
  91       'id' => [ \"
  92         -- 3. resolve the desired information about those
  93         SELECT oi.id FROM (
  94           -- 2. slice only part, orderitem and both quantities from it
  95           SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
  96             -- 1. join orderitems and deliverorder items via record_links.
  97             --    also add customer data to filter for sales_orders
  98             SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
  99             FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 100             WHERE
 101               oe.id = oi.trans_id AND
 102               oe.customer_id IS NOT NULL AND
 103               (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 104               NOT oe.closed AND
 105               rl.from_id = oe.id AND
 106               rl.from_id = oi.trans_id AND
 107               oe.id = oi.trans_id AND
 108               rl.from_table = 'oe' AND
 109               rl.to_table = 'delivery_orders' AND
 110               rl.to_id = doi.delivery_order_id AND
 111               oi.parts_id = doi.parts_id
 112           ) tuples GROUP BY parts_id, trans_id, qty
 113         ) partials
 114         LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 115         WHERE oi.qty > doi_qty
 116
 117         UNION ALL
 118
 119         -- 4. since the join over record_links fails for sales_orders wihtout any delivery order
 120         --    retrieve those without record_links at all
 121         SELECT oi.id FROM orderitems oi, oe
 122         WHERE
 123           oe.id = oi.trans_id AND
 124           oe.customer_id IS NOT NULL AND
 125           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 126           NOT oe.closed AND
 127           oi.trans_id NOT IN (
 128             SELECT from_id
 129             FROM record_links rl
 130             WHERE
 131               rl.from_table ='oe' AND
 132               rl.to_table = 'delivery_orders'
 133           )
 134       " ],
 135     )
 136   ];
 137
 138   return \%args;
 139 }
 140
 141 sub prepare_report {
 142   my ($self, %params) = @_;
 143
 144   my $objects  = $params{objects} || [];
 145   my $report = SL::ReportGenerator->new(\%::myconfig, $::form);
 146   $self->{report} = $report;
 147
 148   my @columns  = qw(reqdate customer ordnumber partnumber description qty shipped_qty);
 149   my @visible  = qw(reqdate partnumber description qty shipped_qty ordnumber customer);
 150   my @sortable = qw(reqdate partnumber description                 ordnumber customer);
 151
 152   my %column_defs = (
 153     reqdate                 => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date }},
 154     description             => {      sub => sub { $_[0]->description },
 155                                  obj_link => sub { $self->link_to($_[0]->part) }},
 156     partnumber              => {      sub => sub { $_[0]->part->partnumber },
 157                                  obj_link => sub { $self->link_to($_[0]->part) }},
 158     qty                     => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit }},
 159     missing                 => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit }},
 160     shipped_qty             => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit }},
 161     ordnumber               => {      sub => sub { $_[0]->order->ordnumber },
 162                                  obj_link => sub { $self->link_to($_[0]->order) }},
 163     customer                => {      sub => sub { $_[0]->order->customer->name },
 164                                  obj_link => sub { $self->link_to($_[0]->order->customer) }},
 165   );
 166
 167   map { $column_defs{$_}->{text} = $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 168
 169   my %current_sort_params = $self->get_current_sort_params;
 170
 171   for my $col (@sortable) {
 172     $column_defs{$col}{link} = $self->get_callback(
 173       # TODO: column header links from helper
 174       sort_by  => $col,
 175       sort_dir => ($current_sort_params{by} eq $col ? 1 - $current_sort_params{dir} : $current_sort_params{dir}),
 176     );
 177   }
 178
 179   map { $column_defs{$_}->{visible} = 1 } @visible;
 180
 181   $report->set_columns(%column_defs);
 182   $report->set_column_order(@columns);
 183   $report->set_options(allow_pdf_export => 1, allow_csv_export => 1);
 184   $report->set_sort_indicator($current_sort_params{by}, $current_sort_params{dir});
 185   $report->set_export_options(@{ $params{report_generator_export_options} || [] });
 186   $report->set_options(
 187     %{ $params{report_generator_options} || {} },
 188     output_format        => 'HTML',
 189     top_info_text        => $::locale->text('Delivery Plan for currently outstanding sales orders'),
 190     title                => $::locale->text('Delivery Plan'),
 191   );
 192   $report->set_options_from_form;
 193
 194   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 195
 196   $self->{report_data} = {
 197     column_defs => \%column_defs,
 198     columns     => \@columns,
 199     visible     => \@visible,
 200     sortable    => \@sortable,
 201   };
 202 }
 203
 204 sub list_objects {
 205   my ($self) = @_;
 206   my $column_defs = $self->{report_data}{column_defs};
 207   for my $obj (@{ $self->{orderitems} || [] }) {
 208     $self->{report}->add_data({
 209       map {
 210         $_ => {
 211           data => $column_defs->{$_}{sub} ? $column_defs->{$_}{sub}->($obj)
 212                 : $obj->can($_)           ? $obj->$_
 213                 :                           $obj->{$_},
 214           link => $column_defs->{$_}{obj_link} ? $column_defs->{$_}{obj_link}->($obj) : '',
 215         },
 216       } @{ $self->{report_data}{columns} || {} }
 217     });
 218   }
 219
 220   return $self->{report}->generate_with_headers;
 221 }
 222
 223 sub make_filter_summary {
 224   my ($self) = @_;
 225
 226   my $filter = $::form->{filter} || {};
 227   my @filter_strings;
 228
 229   my @filters = (
 230     [ $filter->{order}{"ordnumber:substr::ilike"}, $::locale->text('Number') ],
 231     [ $filter->{part}{"partnumber:substr::ilike"}, $::locale->text('Part Number') ],
 232     [ $filter->{"description:substr::ilike"}, $::locale->text('Part Description') ],
 233     [ $filter->{"reqdate:date::ge"}, $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 234     [ $filter->{"reqdate:date::le"}, $::locale->text('Delivery Date') . " " . $::locale->text('To Date') ],
 235     [ $filter->{"qty:number"}, $::locale->text('Quantity') ],
 236     [ $filter->{order}{customer}{"name:substr::ilike"}, $::locale->text('Customer') ],
 237     [ $filter->{order}{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number') ],
 238   );
 239
 240   my @flags = (
 241     [ $filter->{part}{type}{part}, $::locale->text('Parts') ],
 242     [ $filter->{part}{type}{service}, $::locale->text('Services') ],
 243     [ $filter->{part}{type}{assembly}, $::locale->text('Assemblies') ],
 244   );
 245
 246   for (@flags) {
 247     push @filter_strings, "$_->[1]" if $_->[0];
 248   }
 249   for (@filters) {
 250     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 251   }
 252
 253   $self->{filter_summary} = join ', ', @filter_strings;
 254 }
 255
 256 sub link_to {
 257   my ($self, $object, %params) = @_;
 258
 259   return unless $object;
 260   my $action = $params{action} || 'edit';
 261
 262   if ($object->isa('SL::DB::Order')) {
 263     my $type   = $object->type;
 264     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 265     my $id     = $object->id;
 266
 267     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 268   }
 269   if ($object->isa('SL::DB::Part')) {
 270     my $id     = $object->id;
 271     return "ic.pl?action=$action&id=$id";
 272   }
 273   if ($object->isa('SL::DB::Customer')) {
 274     my $id     = $object->id;
 275     return "ct.pl?action=$action&id=$id&db=customer";
 276   }
 277 }
 278
 279 # unfortunately ParseFilter can't handle compount filters.
 280 # so we clone the original filter (still need that for serializing)
 281 # rip out the options we know an replace them with the compound options.
 282 # ParseFilter will take care of the prefixing then.
 283 sub _pre_parse_filter {
 284   my ($self, $orig_filter, $launder_to) = @_;
 285
 286   return undef unless $orig_filter;
 287
 288   my $filter = clone($orig_filter);
 289   if ($filter->{part} && $filter->{part}{type}) {
 290     $launder_to->{part}{type} = delete $filter->{part}{type};
 291     my @part_filters = grep $_, map {
 292       $launder_to->{part}{type}{$_} ? SL::DB::Manager::Part->type_filter($_) : ()
 293     } qw(part service assembly);
 294
 295     push @{ $filter->{and} }, or => [ @part_filters ] if @part_filters;
 296   }
 297
 298   for my $op (qw(le ge)) {
 299     if ($filter->{"reqdate:date::$op"}) {
 300       $launder_to->{"reqdate_date__$op"} = delete $filter->{"reqdate:date::$op"};
 301       my $parsed_date = DateTime->from_lxoffice($launder_to->{"reqdate_date__$op"});
 302       push @{ $filter->{and} }, or => [
 303         'reqdate' => { $op => $parsed_date },
 304         and => [
 305           'reqdate' => undef,
 306           'order.reqdate' => { $op => $parsed_date },
 307         ]
 308       ] if $parsed_date;
 309     }
 310   }
 311
 312   if (my $style = delete $filter->{searchstyle}) {
 313     $self->{searchstyle}       = $style;
 314     $launder_to->{searchstyle} = $style;
 315   }
 316
 317   return $filter;
 318 }
 319
 320 1;