SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::Paginated;
  10 use SL::Controller::Helper::ParseFilter;
  11 use SL::Controller::Helper::ReportGenerator;
  12
  13 use Rose::Object::MakeMethods::Generic
  14 (
  15   scalar => [ qw(db_args) ],
  16 );
  17
  18 __PACKAGE__->run_before(sub { $::auth->assert('sales_order_edit'); });
  19
  20 __PACKAGE__->get_models_url_params(sub {
  21   my ($self) = @_;
  22   return (
  23     %{ $self->{flat_filter} || {} },
  24     sort_dir => $self->{sort_dir},
  25     sort_by  => $self->{sort_by},
  26   );
  27 });
  28 __PACKAGE__->make_paginated(
  29   MODEL         => 'OrderItem',
  30   PAGINATE_ARGS => 'db_args',
  31   ONLY          => [ qw(list) ],
  32 );
  33
  34 sub action_list {
  35   my ($self) = @_;
  36   my %list_params = (
  37     sort_by  => $::form->{sort_by} || 'reqdate',
  38     sort_dir => $::form->{sort_dir},
  39     filter   => $::form->{filter},
  40   );
  41
  42   $self->db_args($self->setup_for_list(%list_params));
  43   $self->{flat_filter} = { map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') };
  44   $self->make_filter_summary;
  45
  46   my $top    = $::form->parse_html_template('delivery_plan/report_top', { FORM => $::form, SELF => $self });
  47   my $bottom = $::form->parse_html_template('delivery_plan/report_bottom', { SELF => $self });
  48
  49   $self->prepare_report(
  50     report_generator_options => {
  51       raw_top_info_text    => $top,
  52       raw_bottom_info_text => $bottom,
  53       controller_class     => 'DeliveryPlan',
  54     },
  55     report_generator_export_options => [
  56       'list', qw(filter sort_by sort_dir),
  57     ],
  58   );
  59
  60   $self->{orderitems} = $self->get_models(%{ $self->db_args });
  61
  62   $self->list_objects;
  63 }
  64
  65 # private functions
  66
  67 sub setup_for_list {
  68   my ($self, %params) = @_;
  69   $self->{filter} = {};
  70   my %args = (
  71     parse_filter(
  72       $self->_pre_parse_filter($::form->{filter}, $self->{filter}),
  73       with_objects => [ 'order', 'order.customer', 'part' ],
  74       launder_to => $self->{filter},
  75     ),
  76     sort_by => $self->set_sort_params(%params),
  77   );
  78
  79   $args{query} = [ @{ $args{query} || [] },
  80     (
  81       'order.customer_id' => { gt => 0 },
  82       'order.closed' => 0,
  83       or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
  84
  85       # filter by shipped_qty < qty, read from innermost to outermost
  86       'id' => [ \"
  87         -- 3. resolve the desired information about those
  88         SELECT oi.id FROM (
  89           -- 2. slice only part, orderitem and both quantities from it
  90           SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
  91             -- 1. join orderitems and deliverorder items via record_links.
  92             --    also add customer data to filter for sales_orders
  93             SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
  94             FROM orderitems oi, oe, record_links rl, delivery_order_items doi
  95             WHERE
  96               oe.id = oi.trans_id AND
  97               oe.customer_id IS NOT NULL AND
  98               (oe.quotation = 'f' OR oe.quotation IS NULL) AND
  99               NOT oe.closed AND
 100               rl.from_id = oe.id AND
 101               rl.from_id = oi.trans_id AND
 102               oe.id = oi.trans_id AND
 103               rl.from_table = 'oe' AND
 104               rl.to_table = 'delivery_orders' AND
 105               rl.to_id = doi.delivery_order_id AND
 106               oi.parts_id = doi.parts_id
 107           ) tuples GROUP BY parts_id, trans_id, qty
 108         ) partials
 109         LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 110         WHERE oi.qty > doi_qty
 111
 112         UNION ALL
 113
 114         -- 4. since the join over record_links fails for sales_orders wihtout any delivery order
 115         --    retrieve those without record_links at all
 116         SELECT oi.id FROM orderitems oi, oe
 117         WHERE
 118           oe.id = oi.trans_id AND
 119           oe.customer_id IS NOT NULL AND
 120           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 121           NOT oe.closed AND
 122           oi.trans_id NOT IN (
 123             SELECT from_id
 124             FROM record_links rl
 125             WHERE
 126               rl.from_table ='oe' AND
 127               rl.to_table = 'delivery_orders'
 128           )
 129       " ],
 130     )
 131   ];
 132
 133   return \%args;
 134 }
 135
 136 sub set_sort_params {
 137   my ($self, %params) = @_;
 138   my $sort_str;
 139   ($self->{sort_by}, $self->{sort_dir}, $sort_str) =
 140     SL::DB::Manager::OrderItem->make_sort_string(%params);
 141   return $sort_str;
 142 }
 143
 144 sub prepare_report {
 145   my ($self, %params) = @_;
 146
 147   my $objects  = $params{objects} || [];
 148   my $report = SL::ReportGenerator->new(\%::myconfig, $::form);
 149   $self->{report} = $report;
 150
 151   my @columns  = qw(reqdate customer ordnumber partnumber description qty shipped_qty);
 152   my @visible  = qw(reqdate partnumber description qty shipped_qty ordnumber customer);
 153   my @sortable = qw(reqdate partnumber description                 ordnumber customer);
 154
 155   my %column_defs = (
 156     reqdate                 => { text => $::locale->text('Reqdate'),
 157                                   sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date }},
 158     description             => { text => $::locale->text('Description'),
 159                                   sub => sub { $_[0]->description },
 160                              obj_link => sub { $self->link_to($_[0]->part) }},
 161     partnumber              => { text => $::locale->text('Part Number'),
 162                                   sub => sub { $_[0]->part->partnumber },
 163                              obj_link => sub { $self->link_to($_[0]->part) }},
 164     qty                     => { text => $::locale->text('Qty'),
 165                                   sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit }},
 166     missing                 => { text => $::locale->text('Missing qty'),
 167                                   sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit }},
 168     shipped_qty             => { text => $::locale->text('shipped'),
 169                                   sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit }},
 170     ordnumber               => { text => $::locale->text('Order'),
 171                                   sub => sub { $_[0]->order->ordnumber },
 172                              obj_link => sub { $self->link_to($_[0]->order) }},
 173     customer                => { text => $::locale->text('Customer'),
 174                                   sub => sub { $_[0]->order->customer->name },
 175                              obj_link => sub { $self->link_to($_[0]->order->customer) }},
 176   );
 177
 178
 179   for my $col (@sortable) {
 180     $column_defs{$col}{link} = $self->get_callback(
 181       sort_by  => $col,
 182       sort_dir => ($self->{sort_by} eq $col ? 1 - $self->{sort_dir} : $self->{sort_dir}),
 183     );
 184   }
 185
 186   map { $column_defs{$_}->{visible} = 1 } @visible;
 187
 188   $report->set_columns(%column_defs);
 189   $report->set_column_order(@columns);
 190   $report->set_options(allow_pdf_export => 1, allow_csv_export => 1);
 191   $report->set_sort_indicator(%params);
 192   $report->set_export_options(@{ $params{report_generator_export_options} || [] });
 193   $report->set_options(
 194     %{ $params{report_generator_options} || {} },
 195     output_format        => 'HTML',
 196     top_info_text        => $::locale->text('Delivery Plan for currently outstanding sales orders'),
 197     title                => $::locale->text('Delivery Plan'),
 198   );
 199   $report->set_options_from_form;
 200
 201   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 202
 203   $self->{report_data} = {
 204     column_defs => \%column_defs,
 205     columns     => \@columns,
 206     visible     => \@visible,
 207     sortable    => \@sortable,
 208   };
 209 }
 210
 211 sub list_objects {
 212   my ($self) = @_;
 213   my $column_defs = $self->{report_data}{column_defs};
 214   for my $obj (@{ $self->{orderitems} || [] }) {
 215     $self->{report}->add_data({
 216       map {
 217         $_ => {
 218           data => $column_defs->{$_}{sub} ? $column_defs->{$_}{sub}->($obj)
 219                 : $obj->can($_)           ? $obj->$_
 220                 :                           $obj->{$_},
 221           link => $column_defs->{$_}{obj_link} ? $column_defs->{$_}{obj_link}->($obj) : '',
 222         },
 223       } @{ $self->{report_data}{columns} || {} }
 224     });
 225   }
 226
 227   return $self->{report}->generate_with_headers;
 228 }
 229
 230 sub make_filter_summary {
 231   my ($self) = @_;
 232
 233   my $filter = $::form->{filter} || {};
 234   my @filter_strings;
 235
 236   my @filters = (
 237     [ $filter->{order}{"ordnumber:substr::ilike"}, $::locale->text('Number') ],
 238     [ $filter->{part}{"partnumber:substr::ilike"}, $::locale->text('Part Number') ],
 239     [ $filter->{"description:substr::ilike"}, $::locale->text('Part Description') ],
 240     [ $filter->{"reqdate:date::ge"}, $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 241     [ $filter->{"reqdate:date::le"}, $::locale->text('Delivery Date') . " " . $::locale->text('To Date') ],
 242     [ $filter->{"qty:number"}, $::locale->text('Quantity') ],
 243     [ $filter->{order}{customer}{"name:substr::ilike"}, $::locale->text('Customer') ],
 244     [ $filter->{order}{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number') ],
 245   );
 246
 247   my @flags = (
 248     [ $filter->{part}{type}{part}, $::locale->text('Parts') ],
 249     [ $filter->{part}{type}{service}, $::locale->text('Services') ],
 250     [ $filter->{part}{type}{assembly}, $::locale->text('Assemblies') ],
 251   );
 252
 253   for (@flags) {
 254     push @filter_strings, "$_->[1]" if $_->[0];
 255   }
 256   for (@filters) {
 257     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 258   }
 259
 260   $self->{filter_summary} = join ', ', @filter_strings;
 261 }
 262
 263 sub link_to {
 264   my ($self, $object, %params) = @_;
 265
 266   return unless $object;
 267   my $action = $params{action} || 'edit';
 268
 269   if ($object->isa('SL::DB::Order')) {
 270     my $type   = $object->type;
 271     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 272     my $id     = $object->id;
 273
 274     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 275   }
 276   if ($object->isa('SL::DB::Part')) {
 277     my $id     = $object->id;
 278     return "ic.pl?action=$action&id=$id";
 279   }
 280   if ($object->isa('SL::DB::Customer')) {
 281     my $id     = $object->id;
 282     return "ct.pl?action=$action&id=$id&db=customer";
 283   }
 284 }
 285
 286 # unfortunately ParseFilter can't handle compount filters.
 287 # so we clone the original filter (still need that for serializing)
 288 # rip out the options we know an replace them with the compound options.
 289 # ParseFilter will take care of the prefixing then.
 290 sub _pre_parse_filter {
 291   my ($self, $orig_filter, $launder_to) = @_;
 292
 293   return undef unless $orig_filter;
 294
 295   my $filter = clone($orig_filter);
 296   if ($filter->{part} && $filter->{part}{type}) {
 297     $launder_to->{part}{type} = delete $filter->{part}{type};
 298     my @part_filters = grep $_, map {
 299       $launder_to->{part}{type}{$_} ? SL::DB::Manager::Part->type_filter($_) : ()
 300     } qw(part service assembly);
 301
 302     push @{ $filter->{and} }, or => [ @part_filters ] if @part_filters;
 303   }
 304
 305   for my $op (qw(le ge)) {
 306     if ($filter->{"reqdate:date::$op"}) {
 307       $launder_to->{"reqdate_date__$op"} = delete $filter->{"reqdate:date::$op"};
 308       my $parsed_date = DateTime->from_lxoffice($launder_to->{"reqdate_date__$op"});
 309       push @{ $filter->{and} }, or => [
 310         'reqdate' => { $op => $parsed_date },
 311         and => [
 312           'reqdate' => undef,
 313           'order.reqdate' => { $op => $parsed_date },
 314         ]
 315       ] if $parsed_date;
 316     }
 317   }
 318
 319   if (my $style = delete $filter->{searchstyle}) {
 320     $self->{searchstyle}       = $style;
 321     $launder_to->{searchstyle} = $style;
 322   }
 323
 324   return $filter;
 325 }
 326
 327 1;