SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::Paginated;
  10 use SL::Controller::Helper::Sorted;
  11 use SL::Controller::Helper::ParseFilter;
  12 use SL::Controller::Helper::ReportGenerator;
  13
  14 use Rose::Object::MakeMethods::Generic (
  15   scalar => [ qw(db_args flat_filter) ],
  16 );
  17
  18 __PACKAGE__->run_before(sub { $::auth->assert('sales_order_edit'); });
  19
  20 __PACKAGE__->get_models_url_params('flat_filter');
  21 __PACKAGE__->make_paginated(
  22   MODEL         => 'OrderItem',
  23   PAGINATE_ARGS => 'db_args',
  24   ONLY          => [ qw(list) ],
  25 );
  26
  27 __PACKAGE__->make_sorted(
  28   MODEL       => 'OrderItem',
  29   ONLY        => [ qw(list) ],
  30
  31   DEFAULT_BY  => 'reqdate',
  32   DEFAULT_DIR => 1,
  33
  34   reqdate     => 'Reqdate',
  35   description => 'Description',
  36   partnumber  => 'Part Number',
  37   qty         => 'Qty',
  38   shipped_qty => 'shipped',
  39   ordnumber   => 'Order',
  40   customer    => 'Customer',
  41 );
  42
  43 sub action_list {
  44   my ($self) = @_;
  45
  46   $self->db_args($self->setup_for_list(filter => $::form->{filter}));
  47   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  48   $self->make_filter_summary;
  49
  50   $self->prepare_report;
  51
  52   $self->{orderitems} = $self->get_models(%{ $self->db_args });
  53
  54   $self->list_objects;
  55 }
  56
  57 # private functions
  58
  59 sub setup_for_list {
  60   my ($self, %params) = @_;
  61   $self->{filter} = {};
  62   my %args = (
  63     parse_filter(
  64       $self->_pre_parse_filter($::form->{filter}, $self->{filter}),
  65       with_objects => [ 'order', 'order.customer', 'part' ],
  66       launder_to => $self->{filter},
  67     ),
  68   );
  69
  70   $args{query} = [ @{ $args{query} || [] },
  71     (
  72       'order.customer_id' => { gt => 0 },
  73       'order.closed' => 0,
  74       or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
  75
  76       # filter by shipped_qty < qty, read from innermost to outermost
  77       'id' => [ \"
  78         -- 3. resolve the desired information about those
  79         SELECT oi.id FROM (
  80           -- 2. slice only part, orderitem and both quantities from it
  81           SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
  82             -- 1. join orderitems and deliverorder items via record_links.
  83             --    also add customer data to filter for sales_orders
  84             SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
  85             FROM orderitems oi, oe, record_links rl, delivery_order_items doi
  86             WHERE
  87               oe.id = oi.trans_id AND
  88               oe.customer_id IS NOT NULL AND
  89               (oe.quotation = 'f' OR oe.quotation IS NULL) AND
  90               NOT oe.closed AND
  91               rl.from_id = oe.id AND
  92               rl.from_id = oi.trans_id AND
  93               oe.id = oi.trans_id AND
  94               rl.from_table = 'oe' AND
  95               rl.to_table = 'delivery_orders' AND
  96               rl.to_id = doi.delivery_order_id AND
  97               oi.parts_id = doi.parts_id
  98           ) tuples GROUP BY parts_id, trans_id, qty
  99         ) partials
 100         LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 101         WHERE oi.qty > doi_qty
 102
 103         UNION ALL
 104
 105         -- 4. since the join over record_links fails for sales_orders wihtout any delivery order
 106         --    retrieve those without record_links at all
 107         SELECT oi.id FROM orderitems oi, oe
 108         WHERE
 109           oe.id = oi.trans_id AND
 110           oe.customer_id IS NOT NULL AND
 111           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 112           NOT oe.closed AND
 113           oi.trans_id NOT IN (
 114             SELECT from_id
 115             FROM record_links rl
 116             WHERE
 117               rl.from_table ='oe' AND
 118               rl.to_table = 'delivery_orders'
 119           )
 120       " ],
 121     )
 122   ];
 123
 124   return \%args;
 125 }
 126
 127 sub prepare_report {
 128   my ($self)      = @_;
 129
 130   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 131   $self->{report} = $report;
 132
 133   my @columns     = qw(reqdate customer ordnumber partnumber description qty shipped_qty);
 134   my @sortable    = qw(reqdate customer ordnumber partnumber description                );
 135
 136   my %column_defs = (
 137     reqdate       => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
 138     description   => {      sub => sub { $_[0]->description                                                              },
 139                        obj_link => sub { $self->link_to($_[0]->part)                                                     } },
 140     partnumber    => {      sub => sub { $_[0]->part->partnumber                                                         },
 141                        obj_link => sub { $self->link_to($_[0]->part)                                                     } },
 142     qty           => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit                                        } },
 143     shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit } },
 144     ordnumber     => {      sub => sub { $_[0]->order->ordnumber                                                         },
 145                        obj_link => sub { $self->link_to($_[0]->order)                                                    } },
 146     customer      => {      sub => sub { $_[0]->order->customer->name                                                    },
 147                        obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
 148   );
 149
 150   map { $column_defs{$_}->{text} = $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 151
 152   $report->set_options(
 153     std_column_visibility => 1,
 154     controller_class      => 'DeliveryPlan',
 155     output_format         => 'HTML',
 156     top_info_text         => $::locale->text('Delivery Plan for currently outstanding sales orders'),
 157     raw_top_info_text     => $self->render('delivery_plan/report_top',    { no_output => 1, partial => 1 }),
 158     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { no_output => 1, partial => 1 }),
 159     title                 => $::locale->text('Delivery Plan'),
 160     allow_pdf_export      => 1,
 161     allow_csv_export      => 1,
 162   );
 163   $report->set_columns(%column_defs);
 164   $report->set_column_order(@columns);
 165   $report->set_export_options(qw(list filter));
 166   $report->set_options_from_form;
 167   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 168
 169   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 170
 171   $self->{report_data} = {
 172     column_defs        => \%column_defs,
 173     columns            => \@columns,
 174   };
 175 }
 176
 177 sub list_objects {
 178   my ($self) = @_;
 179   my $column_defs = $self->{report_data}{column_defs};
 180   for my $obj (@{ $self->{orderitems} || [] }) {
 181     $self->{report}->add_data({
 182       map {
 183         $_ => {
 184           data => $column_defs->{$_}{sub} ? $column_defs->{$_}{sub}->($obj)
 185                 : $obj->can($_)           ? $obj->$_
 186                 :                           $obj->{$_},
 187           link => $column_defs->{$_}{obj_link} ? $column_defs->{$_}{obj_link}->($obj) : '',
 188         },
 189       } @{ $self->{report_data}{columns} || {} }
 190     });
 191   }
 192
 193   return $self->{report}->generate_with_headers;
 194 }
 195
 196 sub make_filter_summary {
 197   my ($self) = @_;
 198
 199   my $filter = $::form->{filter} || {};
 200   my @filter_strings;
 201
 202   my @filters = (
 203     [ $filter->{order}{"ordnumber:substr::ilike"},                $::locale->text('Number')                                             ],
 204     [ $filter->{part}{"partnumber:substr::ilike"},                $::locale->text('Part Number')                                        ],
 205     [ $filter->{"description:substr::ilike"},                     $::locale->text('Part Description')                                   ],
 206     [ $filter->{"reqdate:date::ge"},                              $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 207     [ $filter->{"reqdate:date::le"},                              $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 208     [ $filter->{"qty:number"},                                    $::locale->text('Quantity')                                           ],
 209     [ $filter->{order}{customer}{"name:substr::ilike"},           $::locale->text('Customer')                                           ],
 210     [ $filter->{order}{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number')                                    ],
 211   );
 212
 213   my @flags = (
 214     [ $filter->{part}{type}{part},     $::locale->text('Parts')      ],
 215     [ $filter->{part}{type}{service},  $::locale->text('Services')   ],
 216     [ $filter->{part}{type}{assembly}, $::locale->text('Assemblies') ],
 217   );
 218
 219   for (@flags) {
 220     push @filter_strings, "$_->[1]" if $_->[0];
 221   }
 222   for (@filters) {
 223     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 224   }
 225
 226   $self->{filter_summary} = join ', ', @filter_strings;
 227 }
 228
 229 sub link_to {
 230   my ($self, $object, %params) = @_;
 231
 232   return unless $object;
 233   my $action = $params{action} || 'edit';
 234
 235   if ($object->isa('SL::DB::Order')) {
 236     my $type   = $object->type;
 237     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 238     my $id     = $object->id;
 239
 240     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 241   }
 242   if ($object->isa('SL::DB::Part')) {
 243     my $id     = $object->id;
 244     return "ic.pl?action=$action&id=$id";
 245   }
 246   if ($object->isa('SL::DB::Customer')) {
 247     my $id     = $object->id;
 248     return "ct.pl?action=$action&id=$id&db=customer";
 249   }
 250 }
 251
 252 # unfortunately ParseFilter can't handle compount filters.
 253 # so we clone the original filter (still need that for serializing)
 254 # rip out the options we know an replace them with the compound options.
 255 # ParseFilter will take care of the prefixing then.
 256 sub _pre_parse_filter {
 257   my ($self, $orig_filter, $launder_to) = @_;
 258
 259   return undef unless $orig_filter;
 260
 261   my $filter = clone($orig_filter);
 262   if ($filter->{part} && $filter->{part}{type}) {
 263     $launder_to->{part}{type} = delete $filter->{part}{type};
 264     my @part_filters = grep $_, map {
 265       $launder_to->{part}{type}{$_} ? SL::DB::Manager::Part->type_filter($_) : ()
 266     } qw(part service assembly);
 267
 268     push @{ $filter->{and} }, or => [ @part_filters ] if @part_filters;
 269   }
 270
 271   for my $op (qw(le ge)) {
 272     if ($filter->{"reqdate:date::$op"}) {
 273       $launder_to->{"reqdate_date__$op"} = delete $filter->{"reqdate:date::$op"};
 274       my $parsed_date = DateTime->from_lxoffice($launder_to->{"reqdate_date__$op"});
 275       push @{ $filter->{and} }, or => [
 276         'reqdate' => { $op => $parsed_date },
 277         and => [
 278           'reqdate' => undef,
 279           'order.reqdate' => { $op => $parsed_date },
 280         ]
 281       ] if $parsed_date;
 282     }
 283   }
 284
 285   if (my $style = delete $filter->{searchstyle}) {
 286     $self->{searchstyle}       = $style;
 287     $launder_to->{searchstyle} = $style;
 288   }
 289
 290   return $filter;
 291 }
 292
 293 1;