SL/Controller/Draft.pm

   1 package SL::Controller::Draft;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use SL::Helper::Flash qw(flash);
   8 use SL::Locale::String qw(t8);
   9 use SL::Request;
  10 use SL::DB::Draft;
  11 use SL::DBUtils qw(selectall_hashref_query);
  12 use YAML;
  13 use List::Util qw(max);
  14
  15 use Rose::Object::MakeMethods::Generic (
  16  scalar => [ qw() ],
  17  'scalar --get_set_init' => [ qw(module submodule draft) ],
  18 );
  19
  20 __PACKAGE__->run_before('check_auth');
  21
  22 my %allowed_modules = map { $_ => "bin/mozilla/$_.pl" } qw(is ir ar ap gl);
  23
  24 #
  25 # actions
  26 #
  27
  28 sub action_draft_dialog {
  29   my ($self) = @_;
  30   $self->js
  31     ->dialog->open({
  32       html   => $self->dialog_html,
  33       id     => 'save_draft',
  34       dialog => {
  35         title => t8('Drafts'),
  36       },
  37     })
  38     ->render;
  39 }
  40
  41 sub action_save {
  42   my ($self) = @_;
  43
  44   my $id          = $::form->{id};
  45   my $description = $::form->{description} or die 'need description';
  46   my $form        = $self->_build_form;
  47
  48   my $draft = SL::DB::Manager::Draft->find_by_or_create(id => $id);
  49
  50   $draft->id($self->module . '-' . $self->submodule . '-' . Common::unique_id()) unless $draft->id;
  51
  52   $draft->assign_attributes(
  53     module      => $self->module,
  54     submodule   => $self->submodule,
  55     description => $description,
  56     form        => YAML::Dump($form),
  57     employee_id => SL::DB::Manager::Employee->current->id,
  58   );
  59
  60   $self->draft($draft);
  61
  62   if (!$draft->save) {
  63     flash('error', t8('There was an error saving the draft'));
  64     $self->js
  65       ->html('#save_draft', $self->dialog_html)
  66       ->render;
  67   } else {
  68     $self->js
  69       ->flash('info', t8("Draft saved."))
  70       ->dialog->close('#save_draft')
  71       ->render;
  72   }
  73 }
  74
  75 sub action_load {
  76   my ($self) = @_;
  77
  78   if (!$allowed_modules{ $self->draft->module }) {
  79     $::form->error(t8('Unknown module: #1', $self->draft->module));
  80   } else {
  81     package main;
  82     require $allowed_modules{ $self->draft->module };
  83   }
  84
  85
  86   my $params = delete $::form->{form};
  87   my $new_form = YAML::Load($self->draft->form);
  88   $::form->{$_} = $new_form->{$_} for keys %$new_form;
  89   $::form->{"draft_$_"} = $self->draft->$_ for qw(id description);
  90
  91   if ($params && 'HASH' eq ref $params) {
  92     $::form->{$_} = $params->{$_} for keys %$params;
  93   }
  94
  95   $::form->{script} = $self->draft->module . '.pl';
  96   ::update();
  97 }
  98
  99 sub action_delete {
 100   my ($self) = @_;
 101
 102   $self->module($self->draft->module);
 103   $self->submodule($self->draft->submodule);
 104
 105   if (!$self->draft->delete) {
 106     flash('error', t8('There was an error deleting the draft'));
 107     $self->js
 108       ->html('#save_draft', $self->dialog_html)
 109       ->render;
 110   } else {
 111     flash('info', t8('Draft deleted'));
 112
 113     $self->js
 114       ->html('#save_draft', $self->dialog_html)
 115       ->render;
 116   }
 117 }
 118
 119 #
 120 # helpers
 121 #
 122
 123 sub _build_form {
 124   my $last_index = max map { /form\[(\d+)\]/ ? $1 : 0 } keys %$::form;
 125   my $new_form = {};
 126
 127   for my $i (0..$last_index) {
 128     SL::Request::_store_value($new_form, $::form->{"form[$i][name]"}, $::form->{"form[$i][value]"});
 129   }
 130
 131   return $new_form;
 132 }
 133
 134 sub draft_list {
 135   my ($self) = @_;
 136
 137   my $result = selectall_hashref_query($::form, $::form->get_standard_dbh, <<SQL, $self->module, $self->submodule);
 138     SELECT d.*, date(d.itime) AS date, e.name AS employee_name
 139     FROM drafts d
 140     LEFT JOIN employee e ON d.employee_id = e.id
 141     WHERE (d.module = ?) AND (d.submodule = ?)
 142     ORDER BY d.itime
 143 SQL
 144 }
 145
 146 sub dialog_html {
 147   my ($self) = @_;
 148
 149   $self->render('drafts/form', { layout => 0, output => 0 },
 150     drafts_list => $self->draft_list
 151   )
 152 }
 153
 154 sub init_module {
 155   $::form->{module}      or die 'need module';
 156 }
 157
 158 sub init_submodule {
 159   $::form->{submodule}   or die 'need submodule';
 160 }
 161
 162 sub init_draft {
 163   SL::DB::Manager::Draft->find_by(id => $::form->{id}) or die t8('Could not load this draft');
 164 }
 165
 166 sub check_auth {
 167   $::auth->assert('vendor_invoice_edit | invoice_edit | ap_transactions | ar_transactions');
 168 }
 169
 170 1;
 171
 172 __END__
 173
 174 =encoding utf-8
 175
 176 =head1 NAME
 177
 178 SL::Controller::Draft
 179
 180 =head1 DESCRIPTION
 181
 182 Encapsulates the old draft mechanism. Use and improvement are discuraged as
 183 long as the storage is not upgrade safe.
 184
 185 =head1 TODO
 186
 187   - optional popup on entry
 188
 189 =head1 AUTHOR
 190
 191 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 192
 193 =cut