SL/Controller/Draft.pm

   1 package SL::Controller::Draft;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use SL::Helper::Flash qw(flash);
   8 use SL::Locale::String qw(t8);
   9 use SL::Request;
  10 use SL::DB::Draft;
  11 use SL::DBUtils qw(selectall_hashref_query);
  12 use YAML;
  13 use List::Util qw(max);
  14
  15 use Rose::Object::MakeMethods::Generic (
  16  scalar => [ qw() ],
  17  'scalar --get_set_init' => [ qw(module submodule draft) ],
  18 );
  19
  20 __PACKAGE__->run_before('check_auth');
  21
  22 my %allowed_modules = map { $_ => "bin/mozilla/$_.pl" } qw(is ir ar ap gl);
  23
  24 #
  25 # actions
  26 #
  27
  28 sub action_draft_dialog {
  29   my ($self) = @_;
  30   $self->js
  31     ->dialog->open({
  32       html   => $self->dialog_html,
  33       id     => 'save_draft',
  34       dialog => {
  35         title => t8('Drafts'),
  36       },
  37     })
  38     ->render;
  39 }
  40
  41 sub action_save {
  42   my ($self) = @_;
  43
  44   my $id          = $::form->{id};
  45   my $description = $::form->{description} or die 'need description';
  46   my $form        = $self->_build_form;
  47
  48   my $draft = SL::DB::Manager::Draft->find_by_or_create(id => $id);
  49
  50   $draft->id($self->module . '-' . $self->submodule . '-' . Common::unique_id()) unless $draft->id;
  51
  52   $draft->assign_attributes(
  53     module      => $self->module,
  54     submodule   => $self->submodule,
  55     description => $description,
  56     form        => YAML::Dump($form),
  57     employee_id => SL::DB::Manager::Employee->current->id,
  58   );
  59
  60   $self->draft($draft);
  61
  62   if (!$draft->save) {
  63     flash('error', t8('There was an error saving the draft'));
  64     $self->js
  65       ->html('#save_draft', $self->dialog_html)
  66       ->render;
  67   } else {
  68     $self->js
  69       ->flash('info', t8("Draft saved."))
  70       ->dialog->close('#save_draft')
  71       ->render;
  72   }
  73 }
  74
  75 sub action_load {
  76   my ($self) = @_;
  77
  78   if (!$allowed_modules{ $self->draft->module }) {
  79     $::form->error(t8('Unknown module: #1', $self->draft->module));
  80   } else {
  81     package main;
  82     require $allowed_modules{ $self->draft->module };
  83   }
  84   my $params = delete $::form->{form};
  85   my $new_form = YAML::Load($self->draft->form);
  86   $::form->{$_} = $new_form->{$_} for keys %$new_form;
  87   $::form->{"draft_$_"} = $self->draft->$_ for qw(id description);
  88
  89   if ($params && 'HASH' eq ref $params) {
  90     $::form->{$_} = $params->{$_} for keys %$params;
  91   }
  92   $::form->{script} = $self->draft->module . '.pl';
  93   ::show_draft();
  94 }
  95
  96 sub action_delete {
  97   my ($self) = @_;
  98
  99   $self->module($self->draft->module);
 100   $self->submodule($self->draft->submodule);
 101
 102   if (!$self->draft->delete) {
 103     flash('error', t8('There was an error deleting the draft'));
 104     $self->js
 105       ->html('#save_draft', $self->dialog_html)
 106       ->render;
 107   } else {
 108     flash('info', t8('Draft deleted'));
 109
 110     $self->js
 111       ->html('#save_draft', $self->dialog_html)
 112       ->render;
 113   }
 114 }
 115
 116 #
 117 # helpers
 118 #
 119
 120 sub _build_form {
 121   my $last_index = max map { /form\[(\d+)\]/ ? $1 : 0 } keys %$::form;
 122   my $new_form = {};
 123
 124   for my $i (0..$last_index) {
 125     SL::Request::_store_value($new_form, $::form->{"form[$i][name]"}, $::form->{"form[$i][value]"});
 126   }
 127
 128   return $new_form;
 129 }
 130
 131 sub draft_list {
 132   my ($self) = @_;
 133
 134   my $result = selectall_hashref_query($::form, $::form->get_standard_dbh, <<SQL, $self->module, $self->submodule);
 135     SELECT d.*, date(d.itime) AS date, e.name AS employee_name
 136     FROM drafts d
 137     LEFT JOIN employee e ON d.employee_id = e.id
 138     WHERE (d.module = ?) AND (d.submodule = ?)
 139     ORDER BY d.itime
 140 SQL
 141 }
 142
 143 sub dialog_html {
 144   my ($self) = @_;
 145
 146   $self->render('drafts/form', { layout => 0, output => 0 },
 147     drafts_list => $self->draft_list
 148   )
 149 }
 150
 151 sub init_module {
 152   $::form->{module}      or die 'need module';
 153 }
 154
 155 sub init_submodule {
 156   $::form->{submodule}   or die 'need submodule';
 157 }
 158
 159 sub init_draft {
 160   SL::DB::Manager::Draft->find_by(id => $::form->{id}) or die t8('Could not load this draft');
 161 }
 162
 163 sub check_auth {
 164   $::auth->assert('vendor_invoice_edit | invoice_edit | ap_transactions | ar_transactions');
 165 }
 166
 167 1;
 168
 169 __END__
 170
 171 =encoding utf-8
 172
 173 =head1 NAME
 174
 175 SL::Controller::Draft
 176
 177 =head1 DESCRIPTION
 178
 179 Encapsulates the old draft mechanism. Use and improvement are discuraged as
 180 long as the storage is not upgrade safe.
 181
 182 =head1 TODO
 183
 184   - optional popup on entry
 185
 186 =head1 AUTHOR
 187
 188 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 189
 190 =cut