SL/Controller/FinancialControllingReport.pm

   1 package SL::Controller::FinancialControllingReport;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use List::Util qw(sum);
   7
   8 use SL::DB::Order;
   9 use SL::DB::ProjectType;
  10 use SL::Controller::Helper::GetModels;
  11 use SL::Controller::Helper::Paginated;
  12 use SL::Controller::Helper::Sorted;
  13 use SL::Controller::Helper::ParseFilter;
  14 use SL::Controller::Helper::ReportGenerator;
  15 use SL::Locale::String;
  16
  17 use Rose::Object::MakeMethods::Generic (
  18   scalar => [ qw(db_args flat_filter project_types) ],
  19 );
  20
  21 __PACKAGE__->run_before(sub { $::auth->assert('sales_order_edit'); });
  22
  23 __PACKAGE__->get_models_url_params('flat_filter');
  24 __PACKAGE__->make_paginated(
  25   MODEL         => 'Order',
  26   PAGINATE_ARGS => 'db_args',
  27   ONLY          => [ qw(list) ],
  28 );
  29
  30 __PACKAGE__->make_sorted(
  31   MODEL                   => 'Order',
  32   ONLY                    => [ qw(list) ],
  33
  34   DEFAULT_BY              => 'globalprojectnumber',
  35   DEFAULT_DIR             => 1,
  36
  37   ordnumber               => t8('Order'),
  38   customer                => t8('Customer'),
  39   transaction_description => t8('Transaction description'),
  40   globalprojectnumber     => t8('Project'),
  41   globalproject_type      => t8('Project Type'),
  42   netamount               => t8('Order amount'),
  43 );
  44
  45 sub action_list {
  46   my ($self) = @_;
  47
  48   $self->project_types(SL::DB::Manager::ProjectType->get_all_sorted);
  49
  50   $self->db_args($self->setup_db_args_for_list(filter => $::form->{filter}));
  51   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  52   $self->make_filter_summary;
  53
  54   $self->prepare_report;
  55
  56   $self->{orders} = $self->get_models(%{ $self->db_args });
  57
  58   $self->calculate_data;
  59
  60   $self->list_objects;
  61 }
  62
  63 # private functions
  64
  65 sub setup_db_args_for_list {
  66   my ($self) = @_;
  67
  68   $self->{filter} = {};
  69   my %args     = ( parse_filter($::form->{filter}, with_objects => [ 'customer', 'globalproject', 'globalproject.project_type' ], launder_to => $self->{filter}));
  70   $args{query} = [
  71     @{ $args{query} || [] },
  72     SL::DB::Manager::Order->type_filter('sales_order'),
  73   ];
  74
  75   return \%args;
  76 }
  77
  78 sub prepare_report {
  79   my ($self)      = @_;
  80
  81   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  82   $self->{report} = $report;
  83
  84   my @columns     = qw(customer globalprojectnumber globalproject_type ordnumber netamount delivered_amount delivered_amount_p billed_amount billed_amount_p paid_amount paid_amount_p
  85                        billable_amount billable_amount_p other_amount);
  86   my @sortable    = qw(ordnumber transdate customer netamount globalprojectnumber globalproject_type);
  87   $self->{number_columns} = [ qw(netamount billed_amount billed_amount_p delivered_amount delivered_amount_p paid_amount paid_amount_p other_amount billable_amount billable_amount_p) ];
  88
  89   my %column_defs           = (
  90     netamount               => {                                                                                         },
  91     billed_amount           => { text     => $::locale->text('Billed amount')                                            },
  92     billed_amount_p         => { text     => $::locale->text('%')                                                        },
  93     delivered_amount        => { text     => $::locale->text('Delivered amount')                                         },
  94     delivered_amount_p      => { text     => $::locale->text('%')                                                        },
  95     paid_amount             => { text     => $::locale->text('Paid amount')                                              },
  96     paid_amount_p           => { text     => $::locale->text('%')                                                        },
  97     billable_amount         => { text     => $::locale->text('Billable amount')                                          },
  98     billable_amount_p       => { text     => $::locale->text('%')                                                        },
  99     other_amount            => { text     => $::locale->text('Billed extra expenses')                                    },
 100     ordnumber               => { obj_link => sub { $self->link_to($_[0])                                              }  },
 101     customer                => {      sub => sub { $_[0]->customer->name                                              },
 102                                  obj_link => sub { $self->link_to($_[0]->customer)                                    }  },
 103     globalprojectnumber     => {      sub => sub { $_[0]->globalproject_id ? $_[0]->globalproject->projectnumber : '' }  },
 104     globalproject_type      => { text     => $::locale->text('Project type'),
 105                                  sub      => sub { $_[0]->globalproject_id ? $_[0]->globalproject->project_type->description : '' }  },
 106   );
 107
 108   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 109   map { $column_defs{$_}->{align} = 'right' } @{ $self->{number_columns} };
 110
 111   $report->set_options(
 112     std_column_visibility => 1,
 113     controller_class      => 'FinancialControllingReport',
 114     output_format         => 'HTML',
 115     top_info_text         => $::locale->text('Financial controlling report for open sales orders'),
 116     raw_top_info_text     => $self->render('financial_controlling_report/report_top',    { no_output => 1, partial => 1 }),
 117     raw_bottom_info_text  => $self->render('financial_controlling_report/report_bottom', { no_output => 1, partial => 1 }),
 118     title                 => $::locale->text('Financial Controlling Report'),
 119     allow_pdf_export      => 1,
 120     allow_csv_export      => 1,
 121   );
 122   $report->set_columns(%column_defs);
 123   $report->set_column_order(@columns);
 124   $report->set_export_options(qw(list filter));
 125   $report->set_options_from_form;
 126   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 127
 128   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 129
 130   $self->{report_data} = {
 131     column_defs        => \%column_defs,
 132     columns            => \@columns,
 133   };
 134 }
 135
 136 sub calculate_data {
 137   my ($self) = @_;
 138
 139   foreach my $order (@{ $self->{orders} }) {
 140     my $delivery_orders = $order->linked_records(direction => 'to', to => 'DeliveryOrder', via => 'Order', query => [ '!customer_id' => undef ]);
 141     my $invoices        = $order->linked_records(direction => 'to', to => 'Invoice',       via => [ 'Order', 'DeliveryOrder' ]);
 142
 143     $order->{delivered_amount}  = sum map { $self->sum_relevant_items(order => $order, other => $_, by_order => 1) } @{ $delivery_orders };
 144     $order->{billed_amount}     = sum map { $self->sum_relevant_items(order => $order, other => $_)                } @{ $invoices        };
 145     $order->{paid_amount}       = sum map { $_->paid                                                               } @{ $invoices        };
 146     my $billed_amount           = sum map { $_->netamount                                                          } @{ $invoices        };
 147     $order->{other_amount}      = $billed_amount             - $order->{billed_amount};
 148     $order->{billable_amount}   = $order->{delivered_amount} - $order->{billed_amount};
 149
 150     foreach (qw(delivered billed paid billable)) {
 151       $order->{"${_}_amount_p"} = $order->netamount * 1 ? $order->{"${_}_amount"} * 100 / $order->netamount : undef;
 152     }
 153   }
 154 }
 155
 156 sub sum_items {
 157   my ($self, %params) = @_;
 158
 159   my %vals;
 160
 161   foreach my $item (@{ $params{obj}->items }) {
 162     $vals{$item->parts_id}            ||= { parts_id => $item->parts_id, amount => 0, base_qty => 0 };
 163     $vals{$item->parts_id}->{amount}   += $item->qty * $item->sellprice * (1 - $item->discount) / (($item->price_factor * 1) || 1);
 164     $vals{$item->parts_id}->{base_qty} += $item->qty * $item->unit_obj->base_factor;
 165   }
 166
 167   return \%vals;
 168 }
 169
 170 sub sum_relevant_items {
 171   my ($self, %params) = @_;
 172
 173   $params{order}->{amounts_by_parts_id} ||= $self->sum_items(obj => $params{order});
 174   my $sums                                = $self->sum_items(obj => $params{other});
 175   my $total                               = 0;
 176
 177   foreach my $item (grep { $params{order}->{amounts_by_parts_id}->{ $_->{parts_id} } } values %{ $sums }) {
 178     my $order_item = $params{order}->{amounts_by_parts_id}->{ $item->{parts_id} };
 179     if ($params{by_order} && $order_item->{base_qty}) {
 180       $total += $order_item->{amount} * $item->{base_qty} / $order_item->{base_qty};
 181     } else {
 182       $total += $item->{amount};
 183     }
 184   }
 185
 186   return $total;
 187 }
 188
 189 sub list_objects {
 190   my ($self)      = @_;
 191   my $column_defs = $self->{report_data}->{column_defs};
 192
 193   for my $obj (@{ $self->{orders} || [] }) {
 194     my %data = map {
 195       $_ => {
 196         data => $column_defs->{$_}{sub} ? $column_defs->{$_}{sub}->($obj)
 197               : $obj->can($_)           ? $obj->$_
 198               :                           $obj->{$_},
 199         link => $column_defs->{$_}{obj_link} ? $column_defs->{$_}{obj_link}->($obj) : '',
 200       },
 201     } @{ $self->{report_data}{columns} || {} };
 202
 203     map { $data{$_}->{data} = defined $data{$_}->{data} ? int($data{$_}->{data}) : ''    } grep {  m/_p$/ } @{ $self->{number_columns} };
 204     map { $data{$_}->{data} = $::form->format_amount(\%::myconfig, $data{$_}->{data}, 2) } grep { !m/_p$/ } @{ $self->{number_columns} };
 205
 206     $self->{report}->add_data(\%data);
 207   }
 208
 209   return $self->{report}->generate_with_headers;
 210 }
 211
 212 sub make_filter_summary {
 213   my ($self) = @_;
 214
 215   my $filter = $::form->{filter} || {};
 216   my @filter_strings;
 217
 218   my @filters = (
 219     [ $filter->{"ordnumber:substr::ilike"},                $::locale->text('Number')                                          ],
 220     [ $filter->{"transdate:date::ge"},                     $::locale->text('Order Date') . " " . $::locale->text('From Date') ],
 221     [ $filter->{"transdate:date::le"},                     $::locale->text('Order Date') . " " . $::locale->text('To Date')   ],
 222     [ $filter->{customer}{"name:substr::ilike"},           $::locale->text('Customer')                                        ],
 223     [ $filter->{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number')                                 ],
 224   );
 225
 226   $self->{filter_summary} = join ', ', @filter_strings;
 227 }
 228
 229 sub link_to {
 230   my ($self, $object, %params) = @_;
 231
 232   return unless $object;
 233   my $action = $params{action} || 'edit';
 234
 235   if ($object->isa('SL::DB::Order')) {
 236     my $type = $object->type;
 237     my $id   = $object->id;
 238
 239     return "oe.pl?action=$action&type=$type&vc=customer&id=$id";
 240   }
 241   if ($object->isa('SL::DB::Customer')) {
 242     my $id     = $object->id;
 243     return "ct.pl?action=$action&id=$id&db=customer";
 244   }
 245 }
 246
 247 1;