SL/Controller/FinancialControllingReport.pm

   1 package SL::Controller::FinancialControllingReport;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use List::Util qw(sum);
   7
   8 use SL::DB::Order;
   9 use SL::DB::ProjectType;
  10 use SL::Controller::Helper::GetModels;
  11 use SL::Controller::Helper::Paginated;
  12 use SL::Controller::Helper::Sorted;
  13 use SL::Controller::Helper::ParseFilter;
  14 use SL::Controller::Helper::ReportGenerator;
  15 use SL::Locale::String;
  16
  17 use Rose::Object::MakeMethods::Generic (
  18   scalar => [ qw(db_args flat_filter project_types) ],
  19 );
  20
  21 __PACKAGE__->run_before(sub { $::auth->assert('sales_order_edit'); });
  22
  23 __PACKAGE__->get_models_url_params('flat_filter');
  24 __PACKAGE__->make_paginated(
  25   MODEL         => 'Order',
  26   PAGINATE_ARGS => 'db_args',
  27   ONLY          => [ qw(list) ],
  28 );
  29
  30 __PACKAGE__->make_sorted(
  31   MODEL                   => 'Order',
  32   ONLY                    => [ qw(list) ],
  33
  34   DEFAULT_BY              => 'globalprojectnumber',
  35   DEFAULT_DIR             => 1,
  36
  37   ordnumber               => t8('Order'),
  38   customer                => t8('Customer'),
  39   transaction_description => t8('Transaction description'),
  40   globalprojectnumber     => t8('Project'),
  41   globalproject_type      => t8('Project Type'),
  42   netamount               => t8('Order amount'),
  43 );
  44
  45 sub action_list {
  46   my ($self) = @_;
  47
  48   $self->project_types(SL::DB::Manager::ProjectType->get_all_sorted);
  49
  50   $self->db_args($self->setup_db_args_for_list(filter => $::form->{filter}));
  51   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  52   $self->make_filter_summary;
  53
  54   $self->prepare_report;
  55
  56   $self->{orders} = $self->get_models(%{ $self->db_args });
  57
  58   $self->calculate_data;
  59
  60   $self->list_objects;
  61 }
  62
  63 # private functions
  64
  65 sub setup_db_args_for_list {
  66   my ($self) = @_;
  67
  68   $self->{filter} = {};
  69   my %args     = ( parse_filter($::form->{filter}, with_objects => [ 'customer', 'globalproject', 'globalproject.project_type' ], launder_to => $self->{filter}));
  70   $args{query} = [
  71     @{ $args{query} || [] },
  72     SL::DB::Manager::Order->type_filter('sales_order'),
  73     or => [
  74       globalproject_id => undef,
  75       and              => [
  76         'globalproject.active' => 1,
  77         'globalproject.valid'  => 1,
  78       ]],
  79   ];
  80
  81   return \%args;
  82 }
  83
  84 sub prepare_report {
  85   my ($self)      = @_;
  86
  87   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  88   $self->{report} = $report;
  89
  90   my @columns     = qw(customer globalprojectnumber globalproject_type ordnumber netamount delivered_amount delivered_amount_p billed_amount billed_amount_p paid_amount paid_amount_p
  91                        billable_amount billable_amount_p other_amount);
  92   my @sortable    = qw(ordnumber transdate customer netamount globalprojectnumber globalproject_type);
  93   $self->{number_columns} = [ qw(netamount billed_amount billed_amount_p delivered_amount delivered_amount_p paid_amount paid_amount_p other_amount billable_amount billable_amount_p) ];
  94
  95   my %column_defs           = (
  96     netamount               => {                                                                                         },
  97     billed_amount           => { text     => $::locale->text('Billed amount')                                            },
  98     billed_amount_p         => { text     => $::locale->text('%')                                                        },
  99     delivered_amount        => { text     => $::locale->text('Delivered amount')                                         },
 100     delivered_amount_p      => { text     => $::locale->text('%')                                                        },
 101     paid_amount             => { text     => $::locale->text('Paid amount')                                              },
 102     paid_amount_p           => { text     => $::locale->text('%')                                                        },
 103     billable_amount         => { text     => $::locale->text('Billable amount')                                          },
 104     billable_amount_p       => { text     => $::locale->text('%')                                                        },
 105     other_amount            => { text     => $::locale->text('Billed extra expenses')                                    },
 106     ordnumber               => { obj_link => sub { $self->link_to($_[0])                                              }  },
 107     customer                => {      sub => sub { $_[0]->customer->name                                              },
 108                                  obj_link => sub { $self->link_to($_[0]->customer)                                    }  },
 109     globalprojectnumber     => {      sub => sub { $_[0]->globalproject_id ? $_[0]->globalproject->projectnumber : '' },
 110                                  obj_link => sub { $self->link_to($_[0]->globalproject)                               }  },
 111     globalproject_type      => { text     => $::locale->text('Project type'),
 112                                  sub      => sub { $_[0]->globalproject_id ? $_[0]->globalproject->project_type->description : '' }  },
 113   );
 114
 115   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 116   map { $column_defs{$_}->{align} = 'right' } @{ $self->{number_columns} };
 117
 118   $report->set_options(
 119     std_column_visibility => 1,
 120     controller_class      => 'FinancialControllingReport',
 121     output_format         => 'HTML',
 122     top_info_text         => $::locale->text('Financial controlling report for open sales orders'),
 123     raw_top_info_text     => $self->render('financial_controlling_report/report_top',    { output => 0 }),
 124     raw_bottom_info_text  => $self->render('financial_controlling_report/report_bottom', { output => 0 }),
 125     title                 => $::locale->text('Financial Controlling Report'),
 126     allow_pdf_export      => 1,
 127     allow_csv_export      => 1,
 128   );
 129   $report->set_columns(%column_defs);
 130   $report->set_column_order(@columns);
 131   $report->set_export_options(qw(list filter));
 132   $report->set_options_from_form;
 133   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 134
 135   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 136 }
 137
 138 sub calculate_data {
 139   my ($self) = @_;
 140
 141   foreach my $order (@{ $self->{orders} }) {
 142     my @delivery_orders = @{ $order->linked_records(direction => 'to', to => 'DeliveryOrder', via => 'Order', query => [ '!customer_id' => undef ]) };
 143     my @invoices        = @{ $order->linked_records(direction => 'to', to => 'Invoice',       via => [ 'Order', 'DeliveryOrder' ])                  };
 144
 145     @invoices = (
 146       grep({ !$_->storno_id } @invoices),
 147       map({ @{ $_->storno_invoices } } grep { $_->storno && !$_->storno_id } @invoices),
 148     );
 149
 150     $order->{delivered_amount}  = sum map { $self->sum_relevant_items(order => $order, other => $_, by_order => 1)    } @delivery_orders;
 151     $order->{billed_amount}     = sum map { $self->sum_relevant_items(order => $order, other => $_)                   } @invoices;
 152     $order->{paid_amount}       = sum map { $_->paid * $_->netamount / (($_->amount * 1) || ($_->netamount * 1) || 1) } @invoices;
 153     my $billed_amount           = sum map { $_->netamount                                                             } @invoices;
 154     $order->{other_amount}      = $billed_amount             - $order->{billed_amount};
 155     $order->{billable_amount}   = $order->{delivered_amount} - $order->{billed_amount};
 156
 157     foreach (qw(delivered billed paid billable)) {
 158       $order->{"${_}_amount_p"} = $order->netamount * 1 ? $order->{"${_}_amount"} * 100 / $order->netamount : undef;
 159     }
 160   }
 161 }
 162
 163 sub sum_items {
 164   my ($self, %params) = @_;
 165
 166   my %vals;
 167
 168   foreach my $item (@{ $params{obj}->items }) {
 169     $vals{$item->parts_id}            ||= { parts_id => $item->parts_id, amount => 0, base_qty => 0 };
 170     $vals{$item->parts_id}->{amount}   += $item->qty * $item->sellprice * (1 - $item->discount) / (($item->price_factor * 1) || 1);
 171     $vals{$item->parts_id}->{base_qty} += $item->qty * $item->unit_obj->base_factor;
 172   }
 173
 174   return \%vals;
 175 }
 176
 177 sub sum_relevant_items {
 178   my ($self, %params) = @_;
 179
 180   $params{order}->{amounts_by_parts_id} ||= $self->sum_items(obj => $params{order});
 181   my $sums                                = $self->sum_items(obj => $params{other});
 182   my $total                               = 0;
 183
 184   foreach my $item (grep { $params{order}->{amounts_by_parts_id}->{ $_->{parts_id} } } values %{ $sums }) {
 185     my $order_item = $params{order}->{amounts_by_parts_id}->{ $item->{parts_id} };
 186     if ($params{by_order} && $order_item->{base_qty}) {
 187       $total += $order_item->{amount} * $item->{base_qty} / $order_item->{base_qty};
 188     } else {
 189       $total += $item->{amount};
 190     }
 191   }
 192
 193   return $total;
 194 }
 195
 196 sub list_objects {
 197   my ($self)      = @_;
 198   my $modify_data = sub {
 199     my ($data) = @_;
 200     map { $data->{$_}->{data} = defined $data->{$_}->{data} ? int($data->{$_}->{data}) : ''  } grep {  m/_p$/ } @{ $self->{number_columns} };
 201     map { $data->{$_}->{data} = $::form->format_amount(\%::myconfig, $data->{$_}->{data}, 2) } grep { !m/_p$/ } @{ $self->{number_columns} };
 202   };
 203
 204   return $self->report_generator_list_objects(report => $self->{report}, objects => $self->{orders}, data_callback => $modify_data);
 205 }
 206
 207 sub make_filter_summary {
 208   my ($self) = @_;
 209
 210   my $filter = $::form->{filter} || {};
 211   my @filter_strings;
 212
 213   my @filters = (
 214     [ $filter->{"ordnumber:substr::ilike"},                $::locale->text('Number')                                          ],
 215     [ $filter->{"transdate:date::ge"},                     $::locale->text('Order Date') . " " . $::locale->text('From Date') ],
 216     [ $filter->{"transdate:date::le"},                     $::locale->text('Order Date') . " " . $::locale->text('To Date')   ],
 217     [ $filter->{customer}{"name:substr::ilike"},           $::locale->text('Customer')                                        ],
 218     [ $filter->{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number')                                 ],
 219   );
 220
 221   $self->{filter_summary} = join ', ', @filter_strings;
 222 }
 223
 224 sub link_to {
 225   my ($self, $object, %params) = @_;
 226
 227   return unless $object;
 228   my $action = $params{action} || 'edit';
 229
 230   if ($object->isa('SL::DB::Order')) {
 231     my $type = $object->type;
 232     my $id   = $object->id;
 233
 234     return "oe.pl?action=$action&type=$type&vc=customer&id=$id";
 235   }
 236   if ($object->isa('SL::DB::Customer')) {
 237     my $id     = $object->id;
 238     return "ct.pl?action=$action&id=$id&db=customer";
 239   }
 240   if ($object->isa('SL::DB::Project')) {
 241     my $id     = $object->id;
 242     return "controller.pl?action=Project/$action&id=$id";
 243   }
 244 }
 245
 246 1;