SL/Controller/FinancialControllingReport.pm

   1 package SL::Controller::FinancialControllingReport;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use List::Util qw(sum);
   7
   8 use SL::DB::Order;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::Paginated;
  11 use SL::Controller::Helper::Sorted;
  12 use SL::Controller::Helper::ParseFilter;
  13 use SL::Controller::Helper::ReportGenerator;
  14 use SL::Locale::String;
  15
  16 use Rose::Object::MakeMethods::Generic (
  17   scalar => [ qw(db_args flat_filter) ],
  18 );
  19
  20 __PACKAGE__->run_before(sub { $::auth->assert('sales_order_edit'); });
  21
  22 __PACKAGE__->get_models_url_params('flat_filter');
  23 __PACKAGE__->make_paginated(
  24   MODEL         => 'Order',
  25   PAGINATE_ARGS => 'db_args',
  26   ONLY          => [ qw(list) ],
  27 );
  28
  29 __PACKAGE__->make_sorted(
  30   MODEL                   => 'Order',
  31   ONLY                    => [ qw(list) ],
  32
  33   DEFAULT_BY              => 'globalprojectnumber',
  34   DEFAULT_DIR             => 1,
  35
  36   ordnumber               => t8('Order'),
  37   customer                => t8('Customer'),
  38   transaction_description => t8('Transaction description'),
  39   globalprojectnumber     => t8('Project'),
  40   netamount               => t8('Order amount'),
  41 );
  42
  43 sub action_list {
  44   my ($self) = @_;
  45
  46   $self->db_args($self->setup_db_args_for_list(filter => $::form->{filter}));
  47   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  48   $self->make_filter_summary;
  49
  50   $self->prepare_report;
  51
  52   $self->{orders} = $self->get_models(%{ $self->db_args });
  53
  54   $self->calculate_data;
  55
  56   $self->list_objects;
  57 }
  58
  59 # private functions
  60
  61 sub setup_db_args_for_list {
  62   my ($self) = @_;
  63
  64   $self->{filter} = {};
  65   my %args     = ( parse_filter($::form->{filter}, with_objects => [ 'customer', 'globalproject' ], launder_to => $self->{filter}));
  66   $args{query} = [
  67     @{ $args{query} || [] },
  68     SL::DB::Manager::Order->type_filter('sales_order'),
  69   ];
  70
  71   return \%args;
  72 }
  73
  74 sub prepare_report {
  75   my ($self)      = @_;
  76
  77   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  78   $self->{report} = $report;
  79
  80   my @columns     = qw(customer globalprojectnumber ordnumber netamount delivered_amount delivered_amount_p billed_amount billed_amount_p paid_amount paid_amount_p
  81                        billable_amount billable_amount_p other_amount);
  82   my @sortable    = qw(ordnumber transdate customer netamount globalprojectnumber);
  83   $self->{number_columns} = [ qw(netamount billed_amount billed_amount_p delivered_amount delivered_amount_p paid_amount paid_amount_p other_amount billable_amount billable_amount_p) ];
  84
  85   my %column_defs           = (
  86     netamount               => {                                                                                         },
  87     billed_amount           => { text     => $::locale->text('Billed amount')                                            },
  88     billed_amount_p         => { text     => $::locale->text('%')                                                        },
  89     delivered_amount        => { text     => $::locale->text('Delivered amount')                                         },
  90     delivered_amount_p      => { text     => $::locale->text('%')                                                        },
  91     paid_amount             => { text     => $::locale->text('Paid amount')                                              },
  92     paid_amount_p           => { text     => $::locale->text('%')                                                        },
  93     billable_amount         => { text     => $::locale->text('Billable amount')                                          },
  94     billable_amount_p       => { text     => $::locale->text('%')                                                        },
  95     other_amount            => { text     => $::locale->text('Billed extra expenses')                                    },
  96     ordnumber               => { obj_link => sub { $self->link_to($_[0])                                              }  },
  97     customer                => {      sub => sub { $_[0]->customer->name                                              },
  98                                  obj_link => sub { $self->link_to($_[0]->customer)                                    }  },
  99     globalprojectnumber     => {      sub => sub { $_[0]->globalproject_id ? $_[0]->globalproject->projectnumber : '' }  },
 100   );
 101
 102   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 103   map { $column_defs{$_}->{align} = 'right' } @{ $self->{number_columns} };
 104
 105   $report->set_options(
 106     std_column_visibility => 1,
 107     controller_class      => 'FinancialControllingReport',
 108     output_format         => 'HTML',
 109     top_info_text         => $::locale->text('Financial controlling report for open sales orders'),
 110     raw_top_info_text     => $self->render('financial_controlling_report/report_top',    { no_output => 1, partial => 1 }),
 111     raw_bottom_info_text  => $self->render('financial_controlling_report/report_bottom', { no_output => 1, partial => 1 }),
 112     title                 => $::locale->text('Financial Controlling Report'),
 113     allow_pdf_export      => 1,
 114     allow_csv_export      => 1,
 115   );
 116   $report->set_columns(%column_defs);
 117   $report->set_column_order(@columns);
 118   $report->set_export_options(qw(list filter));
 119   $report->set_options_from_form;
 120   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 121
 122   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 123
 124   $self->{report_data} = {
 125     column_defs        => \%column_defs,
 126     columns            => \@columns,
 127   };
 128 }
 129
 130 sub calculate_data {
 131   my ($self) = @_;
 132
 133   foreach my $order (@{ $self->{orders} }) {
 134     my $delivery_orders = $order->linked_records(direction => 'to', to => 'DeliveryOrder', via => 'Order', query => [ '!customer_id' => undef ]);
 135     my $invoices        = $order->linked_records(direction => 'to', to => 'Invoice',       via => [ 'Order', 'DeliveryOrder' ]);
 136
 137     $order->{delivered_amount}  = sum map { $self->sum_relevant_items(order => $order, other => $_, by_order => 1) } @{ $delivery_orders };
 138     $order->{billed_amount}     = sum map { $self->sum_relevant_items(order => $order, other => $_)                } @{ $invoices        };
 139     $order->{paid_amount}       = sum map { $_->paid                                                               } @{ $invoices        };
 140     my $billed_amount           = sum map { $_->netamount                                                          } @{ $invoices        };
 141     $order->{other_amount}      = $billed_amount             - $order->{billed_amount};
 142     $order->{billable_amount}   = $order->{delivered_amount} - $order->{billed_amount};
 143
 144     foreach (qw(delivered billed paid billable)) {
 145       $order->{"${_}_amount_p"} = $order->netamount * 1 ? $order->{"${_}_amount"} * 100 / $order->netamount : undef;
 146     }
 147   }
 148 }
 149
 150 sub sum_items {
 151   my ($self, %params) = @_;
 152
 153   my %vals;
 154
 155   foreach my $item (@{ $params{obj}->items }) {
 156     $vals{$item->parts_id}            ||= { parts_id => $item->parts_id, amount => 0, base_qty => 0 };
 157     $vals{$item->parts_id}->{amount}   += $item->qty * $item->sellprice * (1 - $item->discount) / (($item->price_factor * 1) || 1);
 158     $vals{$item->parts_id}->{base_qty} += $item->qty * $item->unit_obj->base_factor;
 159   }
 160
 161   return \%vals;
 162 }
 163
 164 sub sum_relevant_items {
 165   my ($self, %params) = @_;
 166
 167   $params{order}->{amounts_by_parts_id} ||= $self->sum_items(obj => $params{order});
 168   my $sums                                = $self->sum_items(obj => $params{other});
 169   my $total                               = 0;
 170
 171   foreach my $item (grep { $params{order}->{amounts_by_parts_id}->{ $_->{parts_id} } } values %{ $sums }) {
 172     my $order_item = $params{order}->{amounts_by_parts_id}->{ $item->{parts_id} };
 173     if ($params{by_order} && $order_item->{base_qty}) {
 174       $total += $order_item->{amount} * $item->{base_qty} / $order_item->{base_qty};
 175     } else {
 176       $total += $item->{amount};
 177     }
 178   }
 179
 180   return $total;
 181 }
 182
 183 sub list_objects {
 184   my ($self)      = @_;
 185   my $column_defs = $self->{report_data}->{column_defs};
 186
 187   for my $obj (@{ $self->{orders} || [] }) {
 188     my %data = map {
 189       $_ => {
 190         data => $column_defs->{$_}{sub} ? $column_defs->{$_}{sub}->($obj)
 191               : $obj->can($_)           ? $obj->$_
 192               :                           $obj->{$_},
 193         link => $column_defs->{$_}{obj_link} ? $column_defs->{$_}{obj_link}->($obj) : '',
 194       },
 195     } @{ $self->{report_data}{columns} || {} };
 196
 197     map { $data{$_}->{data} = defined $data{$_}->{data} ? int($data{$_}->{data}) : ''    } grep {  m/_p$/ } @{ $self->{number_columns} };
 198     map { $data{$_}->{data} = $::form->format_amount(\%::myconfig, $data{$_}->{data}, 2) } grep { !m/_p$/ } @{ $self->{number_columns} };
 199
 200     $self->{report}->add_data(\%data);
 201   }
 202
 203   return $self->{report}->generate_with_headers;
 204 }
 205
 206 sub make_filter_summary {
 207   my ($self) = @_;
 208
 209   my $filter = $::form->{filter} || {};
 210   my @filter_strings;
 211
 212   my @filters = (
 213     [ $filter->{"ordnumber:substr::ilike"},                $::locale->text('Number')                                          ],
 214     [ $filter->{"transdate:date::ge"},                     $::locale->text('Order Date') . " " . $::locale->text('From Date') ],
 215     [ $filter->{"transdate:date::le"},                     $::locale->text('Order Date') . " " . $::locale->text('To Date')   ],
 216     [ $filter->{customer}{"name:substr::ilike"},           $::locale->text('Customer')                                        ],
 217     [ $filter->{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number')                                 ],
 218   );
 219
 220   $self->{filter_summary} = join ', ', @filter_strings;
 221 }
 222
 223 sub link_to {
 224   my ($self, $object, %params) = @_;
 225
 226   return unless $object;
 227   my $action = $params{action} || 'edit';
 228
 229   if ($object->isa('SL::DB::Order')) {
 230     my $type = $object->type;
 231     my $id   = $object->id;
 232
 233     return "oe.pl?action=$action&type=$type&vc=customer&id=$id";
 234   }
 235   if ($object->isa('SL::DB::Customer')) {
 236     my $id     = $object->id;
 237     return "ct.pl?action=$action&id=$id&db=customer";
 238   }
 239 }
 240
 241 1;