SL/Controller/Helper/GetModels.pm

   1 package SL::Controller::Helper::GetModels;
   2
   3 use strict;
   4
   5 use parent 'Rose::Object';
   6 use SL::Controller::Helper::GetModels::Filtered;
   7 use SL::Controller::Helper::GetModels::Sorted;
   8 use SL::Controller::Helper::GetModels::Paginated;
   9
  10 use Scalar::Util qw(weaken);
  11
  12 use Rose::Object::MakeMethods::Generic (
  13   scalar => [ qw(controller model query with_objects filtered sorted paginated finalized final_params) ],
  14   'scalar --get_set_init' => [ qw(handlers source) ],
  15   array => [ qw(plugins) ],
  16 );
  17
  18 use constant PRIV => '__getmodelshelperpriv';
  19
  20
  21 # official interface
  22
  23 sub get {
  24   my ($self) = @_;
  25   my %params = $self->finalize;
  26
  27   return $self->manager->get_all(%params);
  28 }
  29
  30 sub disable_plugin {
  31   my ($self, $plugin) = @_;
  32   die 'cannot change internal state after finalize was called' if $self->finalized;
  33   die 'unsupported plugin' unless $self->can($plugin) && $self->$plugin && $self->$plugin->isa('SL::Controller::Helper::GetModels::Base');
  34
  35   $self->$plugin->disabled(1);
  36 }
  37
  38 sub enable_plugin {
  39   my ($self, $plugin) = @_;
  40   die 'cannot change internal state after finalize was called' if $self->finalized;
  41   die 'unsupported plugin' unless $self->can($plugin) && $self->$plugin && $self->$plugin->isa('SL::Controller::Helper::GetModels::Base');
  42   $self->$plugin->disabled(0);
  43 }
  44
  45 sub is_enabled_plugin {
  46   my ($self, $plugin) = @_;
  47   die 'unsupported plugin' unless $self->can($plugin) && $self->$plugin && $self->$plugin->isa('SL::Controller::Helper::GetModels::Base');
  48   $self->$plugin->is_enabled;
  49 }
  50
  51 # TODO: get better delegation
  52 sub set_report_generator_sort_options {
  53   my ($self, %params) = @_;
  54   $self->finalize;
  55
  56   $self->sorted->set_report_generator_sort_options(%params);
  57 }
  58
  59 sub get_paginate_args {
  60   my ($self) = @_;
  61   my %params = $self->finalize;
  62
  63   $self->paginated->get_current_paginate_params(%params);
  64 }
  65
  66 sub init {
  67   my ($self, %params) = @_;
  68
  69   # TODO: default model
  70   $self->model(delete $params{model});
  71
  72   my @plugins;
  73   for my $plugin (qw(filtered sorted paginated)) {
  74     next unless my $spec = delete $params{$plugin} // {};
  75     my $plugin_class = "SL::Controller::Helper::GetModels::" . ucfirst $plugin;
  76     push @plugins, $self->$plugin($plugin_class->new(%$spec, get_models => $self));
  77   }
  78   $self->plugins(@plugins);
  79
  80   $self->SUPER::init(%params);
  81
  82   $_->read_params for $self->plugins;
  83
  84   weaken $self->controller if $self->controller;
  85 }
  86
  87 sub finalize {
  88   my ($self, %params) = @_;
  89
  90   return %{ $self->final_params } if $self->finalized;
  91
  92   push @{ $params{query}        ||= [] }, @{ $self->query || [] };
  93   push @{ $params{with_objects} ||= [] }, @{ $self->with_objects || [] };
  94
  95   %params = $_->finalize(%params) for $self->plugins;
  96
  97   $self->finalized(1);
  98   $self->final_params(\%params);
  99
 100   return %params;
 101 }
 102
 103 sub register_handlers {
 104   my ($self, %additional_handlers) = @_;
 105
 106   my $handlers    = $self->handlers;
 107   map { push @{ $handlers->{$_} }, $additional_handlers{$_} if $additional_handlers{$_} } keys %$handlers;
 108 }
 109
 110 # TODO fix this
 111 sub get_models_url_params {
 112   my ($class, $sub_name_or_code) = @_;
 113
 114   my $code     = (ref($sub_name_or_code) || '') eq 'CODE' ? $sub_name_or_code : sub { shift->$sub_name_or_code(@_) };
 115   my $callback = sub {
 116     my ($self, %params)   = @_;
 117     my @additional_params = $code->($self);
 118     return (
 119       %params,
 120       (scalar(@additional_params) == 1) && (ref($additional_params[0]) eq 'HASH') ? %{ $additional_params[0] } : @additional_params,
 121     );
 122   };
 123
 124   push @{ _registered_handlers($class)->{callback} }, $callback;
 125 }
 126
 127 sub get_callback {
 128   my ($self, %override_params) = @_;
 129
 130   my %default_params = $self->_run_handlers('callback', action => $self->controller->action_name);
 131
 132   return $self->controller->url_for(%default_params, %override_params);
 133 }
 134
 135 sub manager {
 136   die "No 'model' to work on" unless $_[0]->model;
 137   "SL::DB::Manager::" . $_[0]->model;
 138 }
 139
 140 #
 141 # private/internal functions
 142 #
 143
 144 sub _run_handlers {
 145   my ($self, $handler_type, %params) = @_;
 146
 147   foreach my $sub (@{ $self->handlers->{$handler_type} }) {
 148     if (ref $sub eq 'CODE') {
 149       %params = $sub->($self, %params);
 150     } elsif ($self->can($sub)) {
 151       %params = $self->$sub(%params);
 152     } else {
 153       die "SL::Controller::Helper::GetModels::get_callback: Cannot call $sub on " . ref($self) . ")";
 154     }
 155   }
 156
 157   return %params;
 158 }
 159
 160 sub init_handlers {
 161   {
 162     callback => [],
 163   }
 164 }
 165
 166 sub init_source {
 167   $::form
 168 }
 169
 170 1;
 171 __END__
 172
 173 =pod
 174
 175 =encoding utf8
 176
 177 =head1 NAME
 178
 179 SL::Controller::Helper::GetModels - Base mixin for controller helpers
 180 dealing with semi-automatic handling of sorting and paginating lists
 181
 182 =head1 SYNOPSIS
 183
 184 For a proper synopsis see L<SL::Controller::Helper::Sorted>.
 185
 186 =head1 OVERVIEW
 187
 188 For a generic overview see L<SL::Controller::Helper::Sorted>.
 189
 190 This base module is the interface between a controller and specialized
 191 helper modules that handle things like sorting and paginating. The
 192 specialized helpers register themselves with this module via a call to
 193 L<register_get_models_handlers> during compilation time (e.g. in the
 194 case of C<Sorted> this happens when the controller calls
 195 L<SL::Controller::Helper::Sorted::make_sorted>).
 196
 197 A controller will later usually call the L<get_models>
 198 function. Templates will call the L<get_callback> function. Both
 199 functions run the registered handlers handing over control to the
 200 specialized helpers so that they may inject their parameters into the
 201 call chain.
 202
 203 The C<GetModels> helper hooks into the controller call to the action
 204 via a C<run_before> hook. This is done so that it can remember the
 205 action called by the user. This is used for constructing the callback
 206 in L<get_callback>.
 207
 208 =head1 PACKAGE FUNCTIONS
 209
 210 =over 4
 211
 212 =item C<get_models_url_params $class, $sub>
 213
 214 Register one of the controller's subs to be called whenever an URL has
 215 to be generated (e.g. for sort and pagination links). This is a way
 216 for the controller to add additional parameters to the URL (e.g. for
 217 filter parameters).
 218
 219 The C<$sub> parameter can be either a code reference or the name of
 220 one of the controller's functions.
 221
 222 The value returned by this C<$sub> must be either a single hash
 223 reference or a hash of key/value pairs to add to the URL.
 224
 225 =item C<register_get_models_handlers $class, %handlers>
 226
 227 This function should only be called from other controller helpers like
 228 C<Sorted> or C<Paginated>. It is not exported and must therefore be
 229 called its full name. The first parameter C<$class> must be the actual
 230 controller's class name.
 231
 232 If C<%handlers> contains a key C<ONLY> then it is passed to the hook
 233 registration in L<SL::Controller::Base::run_before>.
 234
 235 The C<%handlers> register callback functions in the specialized
 236 controller helpers that are called during invocation of
 237 L<get_callback> or L<get_models>. Possible keys are C<callback> and
 238 C<models>.
 239
 240 Each handler (the value in the hash) can be either a code reference
 241 (in which case it is called directly) or the name of an instance
 242 function callable on a controller instance. In both cases the handler
 243 receives a hash of parameters built during this very call to
 244 L<get_callback> or L<get_models> respectively. The handler's return
 245 value must be the new hash to be used in calls to further handlers and
 246 to the actual database model functions later on.
 247
 248 =back
 249
 250 =head1 INSTANCE FUNCTIONS
 251
 252 =over 4
 253
 254 =item C<get_callback [%params]>
 255
 256 Return an URL suitable for use as a callback parameter. It maps to the
 257 current controller and action. All registered handlers of type
 258 'callback' (e.g. the ones by C<Sorted> and C<Paginated>) can inject
 259 the parameters they need so that the same list view as is currently
 260 visible can be re-rendered.
 261
 262 Optional C<%params> passed to this function may override any parameter
 263 set by the registered handlers.
 264
 265 =item C<get_models [%params]>
 266
 267 Query the model manager via C<get_all> and return its result. The
 268 parameters to C<get_all> are constructed by calling all registered
 269 handlers of type 'models' (e.g. the ones by C<Sorted> and
 270 C<Paginated>).
 271
 272 Optional C<%params> passed to this function may override any parameter
 273 set by the registered handlers.
 274
 275 The return value is the an array reference of C<Rose> models.
 276
 277 =back
 278
 279 =head1 BUGS
 280
 281 Nothing here yet.
 282
 283 =head1 AUTHOR
 284
 285 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 286
 287 =cut