SL/Controller/Inventory.pm

   1 package SL::Controller::Inventory;
   2
   3 use strict;
   4 use warnings;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::DB::Inventory;
   9 use SL::DB::Part;
  10 use SL::DB::Warehouse;
  11 use SL::DB::Unit;
  12 use SL::WH;
  13 use SL::Locale::String qw(t8);
  14 use SL::ClientJS;
  15 use SL::Presenter;
  16 use SL::DBUtils;
  17 use SL::Helper::Flash;
  18
  19 use Rose::Object::MakeMethods::Generic (
  20   'scalar --get_set_init' => [ qw(warehouses units js p) ],
  21   'scalar'                => [ qw(warehouse bin unit part) ],
  22 );
  23
  24 __PACKAGE__->run_before('_check_auth');
  25 __PACKAGE__->run_before('_check_warehouses');
  26 __PACKAGE__->run_before('load_part_from_form',   only => [ qw(stock_in part_changed mini_stock stock) ]);
  27 __PACKAGE__->run_before('load_unit_from_form',   only => [ qw(stock_in part_changed mini_stock stock) ]);
  28 __PACKAGE__->run_before('load_wh_from_form',     only => [ qw(stock_in warehouse_changed stock) ]);
  29 __PACKAGE__->run_before('load_bin_from_form',    only => [ qw(stock_in stock) ]);
  30 __PACKAGE__->run_before('set_target_from_part',  only => [ qw(part_changed) ]);
  31 __PACKAGE__->run_before('mini_stock',            only => [ qw(stock_in mini_stock) ]);
  32 __PACKAGE__->run_before('sanitize_target',       only => [ qw(stock_in warehouse_changed part_changed) ]);
  33 __PACKAGE__->run_before('set_layout');
  34
  35 sub action_stock_in {
  36   my ($self) = @_;
  37
  38   $::form->{title}   = t8('Stock');
  39
  40   $::request->layout->focus('#part_id_name');
  41   $_[0]->render('inventory/warehouse_selection_stock', title => $::form->{title});
  42 }
  43
  44 sub action_stock {
  45   my ($self) = @_;
  46
  47   my $qty = $::form->parse_amount(\%::myconfig, $::form->{qty});
  48
  49   if ($qty < 0) {
  50     flash_later('error', t8('Cannot stock negative amounts'));
  51   } else {
  52     # do stock
  53     WH->transfer({
  54       parts         => $self->part,
  55       dst_bin       => $self->bin,
  56       dst_wh        => $self->warehouse,
  57       qty           => $qty,
  58       unit          => $self->unit,
  59       transfer_type => 'stock',
  60       chargenumber  => $::form->{chargenumber},
  61       ean           => $::form->{ean},
  62       comment       => $::form->{comment},
  63     });
  64
  65     if ($::form->{write_default_bin}) {
  66       $self->part->load;   # onhand is calculated in between. don't mess that up
  67       $self->part->bin($self->bin);
  68       $self->part->warehouse($self->warehouse);
  69       $self->part->save;
  70     }
  71
  72     flash_later('info', t8('Transfer successful'));
  73   }
  74
  75   # redirect
  76   $self->redirect_to(
  77     action       => 'stock_in',
  78     part_id      => $self->part->id,
  79     bin_id       => $self->bin->id,
  80     warehouse_id => $self->warehouse->id,
  81     unit_id      => $self->unit->id,
  82   );
  83 }
  84
  85 sub action_part_changed {
  86   my ($self) = @_;
  87
  88   # no standard? ask user if he wants to write it
  89   if ($self->part->id && !$self->part->bin_id && !$self->part->warehouse_id) {
  90     $self->js->show('#write_default_bin_span');
  91   } else {
  92     $self->js->hide('#write_default_bin_span')
  93              ->removeAttr('#write_default_bin', 'checked');
  94   }
  95
  96   $self->js
  97     ->replaceWith('#warehouse_id', $self->build_warehouse_select)
  98     ->replaceWith('#bin_id', $self->build_bin_select)
  99     ->replaceWith('#unit_id', $self->build_unit_select)
 100     ->focus('#warehouse_id')
 101     ->render($self);
 102 }
 103
 104 sub action_warehouse_changed {
 105   my ($self) = @_;
 106
 107   $self->js
 108     ->replaceWith('#bin_id', $self->build_bin_select)
 109     ->focus('#bin_id')
 110     ->render($self);
 111 }
 112
 113 sub action_mini_stock {
 114   my ($self) = @_;
 115
 116   $self->js
 117     ->html('#stock', $self->render('inventory/_stock', { output => 0 }))
 118     ->render($self);
 119 }
 120
 121 #================================================================
 122
 123 sub _check_auth {
 124   $main::auth->assert('warehouse_management');
 125 }
 126
 127 sub _check_warehouses {
 128   $_[0]->show_no_warehouses_error if !@{ $_[0]->warehouses };
 129 }
 130
 131 sub init_warehouses {
 132   SL::DB::Manager::Warehouse->get_all(query => [ or => [ invalid => 0, invalid => undef ]]);
 133 }
 134
 135 sub init_units {
 136   SL::DB::Manager::Unit->get_all;
 137 }
 138
 139 sub init_js {
 140   SL::ClientJS->new;
 141 }
 142
 143 sub init_p {
 144   SL::Presenter->get;
 145 }
 146
 147 sub set_target_from_part {
 148   my ($self) = @_;
 149
 150   return if !$self->part;
 151
 152   $self->warehouse($self->part->warehouse) if $self->part->warehouse;
 153   $self->bin(      $self->part->bin)       if $self->part->bin;
 154 }
 155
 156 sub sanitize_target {
 157   my ($self) = @_;
 158
 159   $self->warehouse($self->warehouses->[0])       if !$self->warehouse || !$self->warehouse->id;
 160   $self->bin      ($self->warehouse->bins->[0])  if !$self->bin       || !$self->bin->id;
 161 }
 162
 163 sub load_part_from_form {
 164   $_[0]->part(SL::DB::Manager::Part->find_by_or_create(id => $::form->{part_id}));
 165 }
 166
 167 sub load_unit_from_form {
 168   $_[0]->unit(SL::DB::Manager::Unit->find_by_or_create(id => $::form->{unit_id}));
 169 }
 170
 171 sub load_wh_from_form {
 172   $_[0]->warehouse(SL::DB::Manager::Warehouse->find_by_or_create(id => $::form->{warehouse_id}));
 173 }
 174
 175 sub load_bin_from_form {
 176   $_[0]->bin(SL::DB::Manager::Bin->find_by_or_create(id => $::form->{bin_id}));
 177 }
 178
 179 sub set_layout {
 180   $::request->layout->add_javascripts('client_js.js');
 181 }
 182
 183 sub build_warehouse_select {
 184  $_[0]->p->select_tag('warehouse_id', $_[0]->warehouses,
 185    title_key => 'description',
 186    default   => $_[0]->warehouse->id,
 187    onchange  => 'reload_bin_selection()',
 188   )
 189 }
 190
 191 sub build_bin_select {
 192   $_[0]->p->select_tag('bin_id', [ $_[0]->warehouse->bins ],
 193     title_key => 'description',
 194     default   => $_[0]->bin->id,
 195   );
 196 }
 197
 198 sub build_unit_select {
 199   $_[0]->part->id
 200     ? $_[0]->p->select_tag('unit_id', $_[0]->part->available_units,
 201         title_key => 'name',
 202         default   => $_[0]->part->unit_obj->id,
 203       )
 204     : $_[0]->p->select_tag('unit_id', $_[0]->units,
 205         title_key => 'name',
 206       )
 207 }
 208
 209 sub mini_journal {
 210   my ($self) = @_;
 211
 212   # get last 10 transaction ids
 213   my $query = 'SELECT trans_id, max(itime) FROM inventory GROUP BY trans_id ORDER BY max(itime) DESC LIMIT 10';
 214   my @ids = selectall_array_query($::form, $::form->get_standard_dbh, $query);
 215
 216   my $objs;
 217   $objs = SL::DB::Manager::Inventory->get_all(query => [ trans_id => \@ids ]) if @ids;
 218
 219   # at most 2 of them belong to a transaction and the qty determins in or out.
 220   # sort them for display
 221   my %transactions;
 222   for (@$objs) {
 223     $transactions{ $_->trans_id }{ $_->qty > 0 ? 'in' : 'out' } = $_;
 224     $transactions{ $_->trans_id }{base} = $_;
 225   }
 226   # and get them into order again
 227   my @sorted = map { $transactions{$_} } @ids;
 228
 229   return \@sorted;
 230 }
 231
 232 sub mini_stock {
 233   my ($self) = @_;
 234
 235   my $stock             = $self->part->get_simple_stock;
 236   $self->{stock_by_bin} = { map { $_->{bin_id} => $_ } @$stock };
 237   $self->{stock_empty}  = ! grep { $_->{sum} * 1 } @$stock;
 238 }
 239
 240 sub show_no_warehouses_error {
 241   my ($self) = @_;
 242
 243   my $msg = t8('No warehouse has been created yet or the quantity of the bins is not configured yet.') . ' ';
 244
 245   if ($::auth->check_right($::form->{login}, 'config')) { # TODO wut?
 246     $msg .= t8('You can create warehouses and bins via the menu "System -> Warehouses".');
 247   } else {
 248     $msg .= t8('Please ask your administrator to create warehouses and bins.');
 249   }
 250   $::form->show_generic_error($msg);
 251 }
 252
 253 1;