SL/Controller/Letter.pm

   1 package SL::Controller::Letter;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Carp;
   7 use File::Basename;
   8 use POSIX qw(strftime);
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::CT;
  12 use SL::DB::Employee;
  13 use SL::DB::Language;
  14 use SL::DB::Letter;
  15 use SL::DB::LetterDraft;
  16 use SL::DB::Printer;
  17 use SL::Helper::Flash qw(flash flash_later);
  18 use SL::Helper::CreatePDF;
  19 use SL::Helper::PrintOptions;
  20 use SL::Locale::String qw(t8);
  21 use SL::Mailer;
  22 use SL::IS;
  23 use SL::Presenter::Tag qw(select_tag);
  24 use SL::ReportGenerator;
  25 use SL::Webdav;
  26 use SL::Webdav::File;
  27
  28 use Rose::Object::MakeMethods::Generic (
  29   'scalar --get_set_init' => [ qw(letter all_employees models webdav_objects is_sales) ],
  30 );
  31
  32 __PACKAGE__->run_before('check_auth_edit');
  33 __PACKAGE__->run_before('check_auth_report', only => [ qw(list) ]);
  34
  35 use constant TEXT_CREATED_FOR_VALUES => (qw(presskit fax letter));
  36 use constant PAGE_CREATED_FOR_VALUES => (qw(sketch 1 2));
  37
  38 my %sort_columns = (
  39   date                  => t8('Date'),
  40   subject               => t8('Subject'),
  41   letternumber          => t8('Letternumber'),
  42   customer_id           => t8('Customer'),
  43   vendor_id             => t8('Vendor'),
  44   contact               => t8('Contact'),
  45 );
  46
  47 ### actions
  48
  49 sub action_add {
  50   my ($self, %params) = @_;
  51
  52   return if $self->load_letter_draft(%params);
  53
  54   $self->letter->employee_id(SL::DB::Manager::Employee->current->id);
  55   $self->letter->salesman_id(SL::DB::Manager::Employee->current->id);
  56
  57   $self->_display(
  58     title       => t8('Add Letter'),
  59     language_id => $params{language_id},
  60   );
  61 }
  62
  63 sub action_edit {
  64   my ($self, %params) = @_;
  65
  66   return $self->action_add
  67     unless $::form->{letter} || $::form->{draft};
  68
  69   if ($::form->{draft}) {
  70     $self->letter(SL::DB::Letter->new_from_draft($::form->{draft}{id}));
  71     $self->is_sales($self->letter->is_sales);
  72   }
  73
  74   $self->_display(
  75     title  => t8('Edit Letter'),
  76   );
  77 }
  78
  79 sub action_save {
  80   my ($self, %params) = @_;
  81
  82   my $letter = $self->_update;
  83
  84   if (!$self->check_letter($letter)) {
  85     return $self->_display;
  86   }
  87
  88   $self->check_number;
  89
  90   if (!$letter->save) {
  91     flash('error', t8('There was an error saving the letter'));
  92     return $self->_display;
  93   }
  94
  95   flash('info', t8('Letter saved!'));
  96
  97   $self->_display;
  98 }
  99
 100 sub action_update_contacts {
 101   my ($self) = @_;
 102
 103   my $letter = $self->letter;
 104
 105   if (!$self->letter->has_customer_vendor) {
 106     return $self->js
 107       ->replaceWith(
 108         '#letter_cp_id',
 109         select_tag('letter.cp_id', [], value_key => 'cp_id', title_key => 'full_name')
 110       )
 111       ->render;
 112   }
 113
 114   my $contacts = $letter->customer_vendor->contacts;
 115
 116   my $default;
 117   if (   $letter->contact
 118       && $letter->contact->cp_cv_id
 119       && $letter->contact->cp_cv_id == $letter->customer_vendor_id) {
 120     $default = $letter->contact->cp_id;
 121   } else {
 122     $default = '';
 123   }
 124
 125   $self->js
 126     ->replaceWith(
 127       '#letter_cp_id',
 128       select_tag('letter.cp_id', $contacts, default => $default, value_key => 'cp_id', title_key => 'full_name')
 129     )
 130     ->render;
 131 }
 132
 133 sub action_save_letter_draft {
 134   my ($self, %params) = @_;
 135
 136   $self->check_letter;
 137
 138   my $letter_draft = SL::DB::LetterDraft->new_from_letter($self->_update);
 139
 140   if (!$letter_draft->save) {
 141     flash('error', t8('There was an error saving the letter draft'));
 142     return $self->_display;
 143   }
 144
 145   flash('info', t8('Draft for this Letter saved!'));
 146
 147   $self->_display;
 148 }
 149
 150 sub action_delete {
 151   my ($self, %params) = @_;
 152
 153   if (!$self->letter->delete) {
 154     flash('error', t8('An error occurred. Letter could not be deleted.'));
 155     return $self->action_update;
 156   }
 157
 158   flash_later('info', t8('Letter deleted'));
 159   $self->redirect_to(action => 'list');
 160 }
 161
 162 sub action_delete_letter_drafts {
 163   my ($self, %params) = @_;
 164
 165   my @ids =  grep { /^checked_(.*)/ && $::form->{$_} } keys %$::form;
 166
 167   SL::DB::Manager::LetterDraft->delete_all(query => [ ids => \@ids ]) if @ids;
 168
 169   $self->redirect_to(action => 'add');
 170 }
 171
 172 sub action_list {
 173   my ($self, %params) = @_;
 174
 175   $self->setup_list_action_bar;
 176   $self->make_filter_summary;
 177   $self->prepare_report;
 178
 179   my $letters = $self->models->get;
 180   $self->report_generator_list_objects(report => $self->{report}, objects => $letters);
 181
 182 }
 183
 184 sub action_print_letter {
 185   my ($self, %params) = @_;
 186
 187   my $display_form = $::form->{display_form} || "display_form";
 188   my $letter       = $self->_update;
 189
 190   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
 191     name        => 'letter',
 192     printer_id  => $::form->{printer_id},
 193     language_id => $::form->{language_id},
 194     formname    => 'letter',
 195     format      => 'pdf',
 196   );
 197
 198   if (!defined $template_file) {
 199     $::form->error($::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files));
 200   }
 201
 202   my %result;
 203   eval {
 204     %result = SL::Template::LaTeX->parse_and_create_pdf(
 205       $template_file,
 206       SELF          => $self,
 207       FORM          => $::form,
 208       letter        => $letter,
 209       template_meta => {
 210         formname  => 'letter',
 211         language  => SL::DB::Language->new,
 212         extension => 'pdf',
 213         format    => $::form->{format},
 214         media     => $::form->{media},
 215         printer   => SL::DB::Manager::Printer->find_by_or_create(id => $::form->{printer_id} || undef),
 216         today     => DateTime->today,
 217       },
 218     );
 219
 220     die $result{error} if $result{error};
 221
 222     $::form->{type}         = 'letter';
 223     $::form->{formname}     = 'letter';
 224     $::form->{letternumber} = $letter->letternumber;
 225     my $attachment_name     = $::form->generate_attachment_filename;
 226
 227     if ($::instance_conf->get_webdav_documents) {
 228       my $webdav_file = SL::Webdav::File->new(
 229         filename => $attachment_name,
 230         webdav   => SL::Webdav->new(
 231           type   => 'letter',
 232           number => $letter->letternumber,
 233         ),
 234       );
 235
 236       $webdav_file->store(file => $result{file_name});
 237     }
 238
 239     # set some form defaults for printing webdav copy variables
 240     if ( $::form->{media} eq 'email') {
 241       my $mail             = Mailer->new;
 242       my $signature        = $::myconfig{signature};
 243       $mail->{$_}          = $params{email}->{$_} for qw(to cc subject message bcc);
 244       $mail->{from}        = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 245       $mail->{attachments} = [{ path => $result{file_name},
 246                                 name => $params{email}->{attachment_filename} }];
 247       $mail->{message}    .=  "\n-- \n$signature";
 248       $mail->{message}     =~ s/\r//g;
 249       $mail->{record_id}   =  $letter->id;
 250       $mail->send;
 251       unlink $result{file_name};
 252
 253       flash_later('info', t8('The email has been sent.'));
 254       $self->redirect_to(action => 'edit', 'letter.id' => $letter->id);
 255
 256       return 1;
 257     }
 258
 259     if (!$::form->{printer_id} || $::form->{media} eq 'screen') {
 260       $self->send_file($result{file_name}, name => $attachment_name);
 261       unlink $result{file_name};
 262
 263       return 1;
 264     }
 265
 266     my $printer = SL::DB::Printer->new(id => $::form->{printer_id})->load;
 267     $printer->print_document(
 268       copies    => $::form->{copies},
 269       file_name => $result{file_name},
 270     );
 271
 272     unlink $result{file_name};
 273
 274     flash_later('info', t8('The documents have been sent to the printer \'#1\'.', $printer->printer_description));
 275     $self->redirect_to(action => 'edit', 'letter.id' => $letter->id, media => 'printer', printer_id => $::form->{printer_id});
 276     1;
 277   } or do {
 278     unlink $result{file_name} if $result{file_name};
 279     $::form->error(t8("Creating the PDF failed:") . " " . $@);
 280   };
 281 }
 282
 283 sub action_update {
 284   my ($self, $name_selected) = @_;
 285
 286   $self->_display(
 287     letter => $self->_update,
 288   );
 289 }
 290
 291 sub action_skip_draft {
 292   my ($self) = @_;
 293   $self->action_add(skip_drafts => 1);
 294 }
 295
 296 sub action_delete_drafts {
 297   my ($self) = @_;
 298
 299   my @ids = @{ $::form->{ids} || [] };
 300   SL::DB::Manager::LetterDraft->delete_all(where => [ id => \@ids ]) if @ids;
 301
 302   $self->action_add(skip_drafts => 1);
 303 }
 304
 305 sub action_send_email {
 306   my ($self) = @_;
 307
 308   $::form->{media} = 'email';
 309   $self->action_print_letter(email => $::form->{email_form});
 310 }
 311
 312 ### internal methods
 313
 314 sub _display {
 315   my ($self, %params) = @_;
 316
 317   $::request->{layout}->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery kivi.Letter);
 318
 319   my $letter = $self->letter;
 320
 321  $params{title} ||= t8('Edit Letter');
 322
 323   $::form->{type}             = 'letter';   # needed for print_options
 324   $::form->{vc}               = $letter->is_sales ? 'customer' : 'vendor'; # needs to be for _get_contacts...
 325
 326   $::form->{language_id} ||= $params{language_id};
 327   $::form->{languages}   ||= SL::DB::Manager::Language->get_all_sorted;
 328   $::form->{printers}      = SL::DB::Manager::Printer->get_all_sorted;
 329
 330   $self->setup_display_action_bar;
 331   $self->render('letter/edit',
 332     %params,
 333     TCF           => [ map { key => $_, value => t8(ucfirst $_) }, TEXT_CREATED_FOR_VALUES() ],
 334     PCF           => [ map { key => $_, value => t8(ucfirst $_) }, PAGE_CREATED_FOR_VALUES() ],
 335     letter        => $letter,
 336     employees     => $self->all_employees,
 337     print_options => SL::Helper::PrintOptions->get_print_options (
 338       options => { no_postscript   => 1,
 339                    no_opendocument => 1,
 340                    no_html         => 1,
 341                    no_queue        => 1,
 342                    show_headers    => 1,
 343                  }),
 344
 345   );
 346 }
 347
 348 sub _update {
 349   my ($self, %params) = @_;
 350
 351   my $letter = $self->letter;
 352
 353   $self->check_date;
 354   $self->set_greetings;
 355
 356   return $letter;
 357 }
 358
 359 sub prepare_report {
 360   my ($self) = @_;
 361
 362   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 363   $self->{report} = $report;
 364
 365   my @columns  = qw(date subject letternumber customer_id vendor_id contact date);
 366   my @sortable = qw(date subject letternumber customer_id vendor_id contact date);
 367
 368   my %column_defs = (
 369     date                  => { text => t8('Date'),         sub => sub { $_[0]->date_as_date } },
 370     subject               => { text => t8('Subject'),      sub => sub { $_[0]->subject },
 371                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 372     letternumber          => { text => t8('Letternumber'), sub => sub { $_[0]->letternumber },
 373                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 374     customer_id           => { text => t8('Customer'),      sub => sub { SL::DB::Manager::Customer->find_by_or_create(id => $_[0]->customer_id)->displayable_name }, visible => $self->is_sales },
 375     vendor_id             => { text => t8('Vendor'),        sub => sub { SL::DB::Manager::Vendor->find_by_or_create(id => $_[0]->vendor_id)->displayable_name }, visible => !$self->is_sales},
 376     contact               => { text => t8('Contact'),       sub => sub { $_[0]->contact ? $_[0]->contact->full_name : '' } },
 377   );
 378
 379   $column_defs{$_}{text} = $sort_columns{$_} for keys %column_defs;
 380
 381   $report->set_options(
 382     std_column_visibility => 1,
 383     controller_class      => 'Letter',
 384     output_format         => 'HTML',
 385     title                 => t8('Letters'),
 386     allow_pdf_export      => 1,
 387     allow_csv_export      => 1,
 388   );
 389
 390   $report->set_columns(%column_defs);
 391   $report->set_column_order(@columns);
 392   $report->set_export_options(qw(list filter is_sales));
 393   $report->set_options_from_form;
 394
 395   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 396   $self->models->add_additional_url_params(is_sales => $self->is_sales);
 397   $self->models->finalize;
 398   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 399
 400   $report->set_options(
 401     raw_top_info_text    => $self->render('letter/report_top',    { output => 0 }),
 402     raw_bottom_info_text => $self->render('letter/report_bottom', { output => 0 }, models => $self->models),
 403     attachment_basename  => t8('letters_list') . strftime('_%Y%m%d', localtime time),
 404   );
 405 }
 406
 407 sub make_filter_summary {
 408   my ($self) = @_;
 409
 410   my $filter = $::form->{filter} || {};
 411   my @filter_strings;
 412
 413   my $employee = $filter->{employee_id} ? SL::DB::Employee->new(id => $filter->{employee_id})->load->name : '';
 414   my $salesman = $filter->{salesman_id} ? SL::DB::Employee->new(id => $filter->{salesman_id})->load->name : '';
 415
 416   my @filters = (
 417     [ $filter->{"letternumber:substr::ilike"},  t8('Number')     ],
 418     [ $filter->{"subject:substr::ilike"},       t8('Subject')    ],
 419     [ $filter->{"body:substr::ilike"},          t8('Body')       ],
 420     [ $filter->{"date:date::ge"},               t8('From Date')  ],
 421     [ $filter->{"date:date::le"},               t8('To Date')    ],
 422     [ $employee,                                t8('Employee')   ],
 423     [ $salesman,                                t8('Salesman')   ],
 424   );
 425
 426   my %flags = (
 427   );
 428   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 429
 430   for (@flags) {
 431     push @filter_strings, $_ if $_;
 432   }
 433   for (@filters) {
 434     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 435   }
 436
 437   $self->{filter_summary} = join ', ', @filter_strings;
 438 }
 439
 440 sub load_letter_draft {
 441   my ($self, %params) = @_;
 442
 443   return 0 if $params{skip_drafts};
 444
 445   my $letter_drafts = SL::DB::Manager::LetterDraft->get_all(
 446     query => [
 447       SL::DB::Manager::Letter->is_sales_filter($self->is_sales),
 448     ]
 449   );
 450
 451   return unless @$letter_drafts;
 452
 453   $self->setup_load_letter_draft_action_bar;
 454   $self->render('letter/load_drafts',
 455     title         => t8('Letter Draft'),
 456     LETTER_DRAFTS => $letter_drafts,
 457   );
 458
 459   return 1;
 460 }
 461
 462 sub check_date {
 463   my ($self) = @_;
 464   my $letter = $self->letter;
 465
 466   return unless $letter;
 467   return if $letter->date;
 468
 469   $letter->date(DateTime->today)
 470 }
 471
 472 sub check_letter {
 473   my ($self, $letter) = @_;
 474
 475   $letter ||= $self->letter;
 476
 477   my $error;
 478
 479   if (!$letter->subject) {
 480     flash('error', t8('The subject is missing.'));
 481     $error = 1;
 482   }
 483   if (!$letter->body) {
 484     flash('error', t8('The body is missing.'));
 485     $error = 1;
 486   }
 487   if (!$letter->employee_id) {
 488     flash('error', t8('The employee is missing.'));
 489     $error = 1;
 490   }
 491
 492   return !$error;
 493 }
 494
 495 sub check_number {
 496   my ($self, $letter) = @_;
 497
 498   $letter ||= $self->letter;
 499
 500   return if $letter->letternumber;
 501
 502   $letter->letternumber(SL::TransNumber->new(type => 'letter', id => $self->{id}, number => $self->{letternumber})->create_unique);
 503 }
 504
 505 sub set_greetings {
 506   my ($self) = @_;
 507   my $letter = $self->letter;
 508
 509   return unless $letter;
 510   return if $letter->greeting;
 511
 512   $letter->greeting(t8('Dear Sir or Madam,'));
 513 }
 514
 515 sub export_letter_to_form {
 516   my ($self, $letter) = @_;
 517   # nope, not pretty.
 518
 519   $letter ||= $self->letter;
 520
 521   for ($letter->meta->columns) {
 522     if ((ref $_) =~ /Date/i) {
 523       $::form->{$_->name} = $letter->$_->to_kivitendo;
 524     } else {
 525       $::form->{$_->name} = $letter->$_;
 526     }
 527   }
 528 }
 529
 530 sub init_letter {
 531   my ($self) = @_;
 532
 533   my $letter      = SL::DB::Manager::Letter->find_by_or_create(id => $::form->{letter}{id} || 0)
 534                                            ->assign_attributes(%{ $::form->{letter} });
 535
 536   if ($letter->cp_id) {
 537 #     $letter->customer_vendor_id($letter->contact->cp_cv_id);
 538       # contacts don't have language_id yet
 539 #     $letter->greeting(GenericTranslations->get(
 540 #       translation_type => 'greetings::' . ($letter->contact->cp_gender eq 'f' ? 'female' : 'male'),
 541 #       language_id      => $letter->contact->language_id,
 542 #       allow_fallback   => 1
 543 #     ));
 544   }
 545
 546   $self->is_sales($letter->is_sales) if $letter->id;
 547
 548   $letter;
 549 }
 550
 551 sub init_models {
 552   my ($self) = @_;
 553
 554   SL::Controller::Helper::GetModels->new(
 555     controller   => $self,
 556     model        => 'Letter',
 557     query        => [
 558       SL::DB::Manager::Letter->is_sales_filter($self->is_sales),
 559     ],
 560     sorted       => \%sort_columns,
 561     with_objects => [ 'contact', 'salesman', 'employee' ],
 562   );
 563 }
 564
 565 sub init_all_employees {
 566   SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 567 }
 568
 569 sub init_webdav_objects {
 570   my ($self) = @_;
 571
 572   return [] if !$self->letter || !$self->letter->letternumber || !$::instance_conf->get_webdav;
 573
 574   my $webdav = SL::Webdav->new(
 575     type     => 'letter',
 576     number   => $self->letter->letternumber,
 577   );
 578
 579   my @all_objects = $webdav->get_all_objects;
 580
 581   return [ map {
 582     +{ name => $_->filename,
 583        type => t8('File'),
 584        link => File::Spec->catfile($_->full_filedescriptor),
 585      }
 586   } @all_objects ];
 587 }
 588
 589 sub init_is_sales {
 590   die 'is_sales must be set' unless defined $::form->{is_sales};
 591   $::form->{is_sales};
 592 }
 593
 594 sub check_auth_edit {
 595   $::form->{is_sales} ? $::auth->assert('sales_letter_edit')
 596                       : $::auth->assert('purchase_letter_edit');
 597 }
 598
 599 sub check_auth_report {
 600   $::form->{is_sales} ? $::auth->assert('sales_letter_report')
 601                       : $::auth->assert('purchase_letter_report');
 602 }
 603
 604 sub setup_load_letter_draft_action_bar {
 605   my ($self, %params) = @_;
 606
 607   for my $bar ($::request->layout->get('actionbar')) {
 608     $bar->add(
 609       link => [
 610         t8('Skip'),
 611         link      => $self->url_for(action => 'skip_draft', is_sales => $self->is_sales),
 612         accesskey => 'enter',
 613       ],
 614       action => [
 615         t8('Delete'),
 616         submit  => [ '#form', { action => 'delete_drafts' } ],
 617         checks  => [ [ 'kivi.check_if_entries_selected', '[name="ids[+]"]' ] ],
 618         confirm => t8('Do you really want to delete this draft?'),
 619       ],
 620     );
 621   }
 622 }
 623
 624 sub setup_display_action_bar {
 625   my ($self, %params) = @_;
 626
 627   for my $bar ($::request->layout->get('actionbar')) {
 628     $bar->add(
 629       action => [
 630         t8('Update'),
 631         submit    => [ '#form', { action => 'Letter/update' } ],
 632         accesskey => 'enter',
 633       ],
 634
 635       combobox => [
 636         action => [
 637           t8('Save'),
 638           submit => [ '#form', { action => 'Letter/save' } ],
 639         ],
 640         action => [
 641           t8('Save Draft'),
 642           submit => [ '#form', { action => 'Letter/save_letter_draft' } ],
 643         ],
 644       ], # end of combobox "Save"
 645
 646       action => [
 647         t8('Delete'),
 648         submit   => [ '#form', { action => 'Letter/delete' } ],
 649         confirm  => t8('Are you sure you want to delete this letter?'),
 650         disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 651       ],
 652
 653       combobox => [
 654         action => [ t8('Export') ],
 655         action => [
 656           t8('Print'),
 657           call     => [ 'kivi.SalesPurchase.show_print_dialog', 'Letter/print_letter' ],
 658           disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 659         ],
 660         action => [
 661           t8('E-mail'),
 662           call     => [ 'kivi.SalesPurchase.show_email_dialog', 'Letter/send_email' ],
 663           disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 664         ],
 665       ],
 666     );
 667   }
 668 }
 669
 670 sub setup_list_action_bar {
 671   my ($self, %params) = @_;
 672
 673   for my $bar ($::request->layout->get('actionbar')) {
 674     $bar->add(
 675       action => [
 676         t8('Update'),
 677         submit    => [ '#search_form', { action => 'Letter/list' } ],
 678         accesskey => 'enter',
 679       ],
 680     );
 681   }
 682 }
 683
 684 1;
 685
 686 __END__
 687
 688 =encoding utf-8
 689
 690 =head1 NAME
 691
 692 SL::Controller::Letter - Letters CRUD and printing
 693
 694 =head1 DESCRIPTION
 695
 696 Simple letter CRUD controller with drafting capabilities.
 697
 698 copy to webdav is crap
 699
 700 =head1 AUTHOR
 701
 702 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 703
 704 =cut