SL/Controller/Letter.pm

   1 package SL::Controller::Letter;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Carp;
   7 use File::Basename;
   8 use POSIX qw(strftime);
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::CT;
  12 use SL::DB::Employee;
  13 use SL::DB::Language;
  14 use SL::DB::Letter;
  15 use SL::DB::LetterDraft;
  16 use SL::DB::Printer;
  17 use SL::File;
  18 use SL::Helper::Flash qw(flash flash_later);
  19 use SL::Helper::CreatePDF;
  20 use SL::Helper::PrintOptions;
  21 use SL::Locale::String qw(t8);
  22 use SL::Mailer;
  23 use SL::IS;
  24 use SL::Presenter::Tag qw(select_tag);
  25 use SL::ReportGenerator;
  26 use SL::Webdav;
  27 use SL::Webdav::File;
  28
  29 use Rose::Object::MakeMethods::Generic (
  30   'scalar --get_set_init' => [ qw(letter all_employees models webdav_objects is_sales) ],
  31 );
  32
  33 __PACKAGE__->run_before('check_auth_edit');
  34 __PACKAGE__->run_before('check_auth_report', only => [ qw(list) ]);
  35
  36 use constant TEXT_CREATED_FOR_VALUES => (qw(presskit fax letter));
  37 use constant PAGE_CREATED_FOR_VALUES => (qw(sketch 1 2));
  38
  39 my %sort_columns = (
  40   date                  => t8('Date'),
  41   subject               => t8('Subject'),
  42   letternumber          => t8('Letternumber'),
  43   customer_id           => t8('Customer'),
  44   vendor_id             => t8('Vendor'),
  45   contact               => t8('Contact'),
  46 );
  47
  48 ### actions
  49
  50 sub action_add {
  51   my ($self, %params) = @_;
  52
  53   return if $self->load_letter_draft(%params);
  54
  55   $self->letter->employee_id(SL::DB::Manager::Employee->current->id);
  56   $self->letter->salesman_id(SL::DB::Manager::Employee->current->id);
  57
  58   $self->_display(
  59     title       => t8('Add Letter'),
  60     language_id => $params{language_id},
  61   );
  62 }
  63
  64 sub action_edit {
  65   my ($self, %params) = @_;
  66
  67   return $self->action_add
  68     unless $::form->{letter} || $::form->{draft};
  69
  70   if ($::form->{draft}) {
  71     $self->letter(SL::DB::Letter->new_from_draft($::form->{draft}{id}));
  72     $self->is_sales($self->letter->is_sales);
  73   }
  74
  75   $self->_display(
  76     title  => t8('Edit Letter'),
  77   );
  78 }
  79
  80 sub action_save {
  81   my ($self, %params) = @_;
  82
  83   my $letter = $self->_update;
  84
  85   if (!$self->check_letter($letter)) {
  86     return $self->_display;
  87   }
  88
  89   $self->check_number;
  90
  91   if (!$letter->save) {
  92     flash('error', t8('There was an error saving the letter'));
  93     return $self->_display;
  94   }
  95
  96   flash('info', t8('Letter saved!'));
  97
  98   $self->_display;
  99 }
 100
 101 sub action_update_contacts {
 102   my ($self) = @_;
 103
 104   my $letter = $self->letter;
 105
 106   if (!$self->letter->has_customer_vendor) {
 107     return $self->js
 108       ->replaceWith(
 109         '#letter_cp_id',
 110         select_tag('letter.cp_id', [], value_key => 'cp_id', title_key => 'full_name')
 111       )
 112       ->render;
 113   }
 114
 115   my $contacts = $letter->customer_vendor->contacts;
 116
 117   my $default;
 118   if (   $letter->contact
 119       && $letter->contact->cp_cv_id
 120       && $letter->contact->cp_cv_id == $letter->customer_vendor_id) {
 121     $default = $letter->contact->cp_id;
 122   } else {
 123     $default = '';
 124   }
 125
 126   $self->js
 127     ->replaceWith(
 128       '#letter_cp_id',
 129       select_tag('letter.cp_id', $contacts, default => $default, value_key => 'cp_id', title_key => 'full_name')
 130     )
 131     ->render;
 132 }
 133
 134 sub action_save_letter_draft {
 135   my ($self, %params) = @_;
 136
 137   $self->check_letter;
 138
 139   my $letter_draft = SL::DB::LetterDraft->new_from_letter($self->_update);
 140
 141   if (!$letter_draft->save) {
 142     flash('error', t8('There was an error saving the letter draft'));
 143     return $self->_display;
 144   }
 145
 146   flash('info', t8('Draft for this Letter saved!'));
 147
 148   $self->_display;
 149 }
 150
 151 sub action_delete {
 152   my ($self, %params) = @_;
 153
 154   if (!$self->letter->delete) {
 155     flash('error', t8('An error occurred. Letter could not be deleted.'));
 156     return $self->action_update;
 157   }
 158
 159   flash_later('info', t8('Letter deleted'));
 160   $self->redirect_to(action => 'list');
 161 }
 162
 163 sub action_delete_letter_drafts {
 164   my ($self, %params) = @_;
 165
 166   my @ids =  grep { /^checked_(.*)/ && $::form->{$_} } keys %$::form;
 167
 168   SL::DB::Manager::LetterDraft->delete_all(query => [ ids => \@ids ]) if @ids;
 169
 170   $self->redirect_to(action => 'add');
 171 }
 172
 173 sub action_list {
 174   my ($self, %params) = @_;
 175
 176   $self->setup_list_action_bar;
 177   $self->make_filter_summary;
 178   $self->prepare_report;
 179
 180   my $letters = $self->models->get;
 181   $self->report_generator_list_objects(report => $self->{report}, objects => $letters);
 182
 183 }
 184
 185 sub action_print_letter {
 186   my ($self, %params) = @_;
 187
 188   my $letter = $self->_update;
 189
 190   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
 191     name        => 'letter',
 192     printer_id  => $::form->{printer_id},
 193     language_id => $::form->{language_id},
 194     formname    => 'letter',
 195     format      => 'pdf',
 196   );
 197
 198   if (!defined $template_file) {
 199     $::form->error($::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files));
 200   }
 201
 202   my %result;
 203   eval {
 204     %result = SL::Template::LaTeX->parse_and_create_pdf(
 205       $template_file,
 206       SELF          => $self,
 207       FORM          => $::form,
 208       letter        => $letter,
 209       template_meta => {
 210         formname  => 'letter',
 211         language  => SL::DB::Manager::Language->find_by_or_create(id => $::form->{language_id}*1),
 212         extension => 'pdf',
 213         format    => $::form->{format},
 214         media     => $::form->{media},
 215         printer   => SL::DB::Manager::Printer->find_by_or_create(id => $::form->{printer_id} || undef),
 216         today     => DateTime->today,
 217       },
 218     );
 219
 220     die $result{error} if $result{error};
 221
 222     $::form->{type}         = 'letter';
 223     $::form->{formname}     = 'letter';
 224     $::form->{letternumber} = $letter->letternumber;
 225     my $attachment_name     = $::form->generate_attachment_filename;
 226
 227     if ($::instance_conf->get_webdav_documents) {
 228       my $webdav_file = SL::Webdav::File->new(
 229         filename => $attachment_name,
 230         webdav   => SL::Webdav->new(
 231           type   => 'letter',
 232           number => $letter->letternumber,
 233         ),
 234       );
 235
 236       $webdav_file->store(file => $result{file_name});
 237     }
 238
 239     if ($::instance_conf->get_doc_storage) {
 240       my %save_params = (object_id    => $letter->id,
 241                          object_type  => 'letter',
 242                          mime_type    => 'application/pdf',
 243                          source       => 'created',
 244                          file_type    => 'document',
 245                          file_name    => $attachment_name,
 246                          file_path    => $result{file_name});
 247       SL::File->save(%save_params);
 248     }
 249
 250     # set some form defaults for printing webdav copy variables
 251     if ( $::form->{media} eq 'email') {
 252       my $mail             = Mailer->new;
 253       my $signature        = $::myconfig{signature};
 254       $mail->{$_}          = $params{email}->{$_} for qw(to cc subject message bcc);
 255       $mail->{from}        = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 256       $mail->{attachments} = [{ path => $result{file_name},
 257                                 name => $params{email}->{attachment_filename} }];
 258       $mail->{message}    .=  "\n-- \n$signature";
 259       $mail->{message}     =~ s/\r//g;
 260       $mail->{record_id}   =  $letter->id;
 261       $mail->send;
 262       unlink $result{file_name};
 263
 264       flash_later('info', t8('The email has been sent.'));
 265       $self->redirect_to(action => 'edit', 'letter.id' => $letter->id);
 266
 267       return 1;
 268     }
 269
 270     if (!$::form->{printer_id} || $::form->{media} eq 'screen') {
 271       $self->send_file($result{file_name}, name => $attachment_name);
 272       unlink $result{file_name};
 273
 274       return 1;
 275     }
 276
 277     my $printer = SL::DB::Printer->new(id => $::form->{printer_id})->load;
 278     $printer->print_document(
 279       copies    => $::form->{copies},
 280       file_name => $result{file_name},
 281     );
 282
 283     unlink $result{file_name};
 284
 285     flash_later('info', t8('The documents have been sent to the printer \'#1\'.', $printer->printer_description));
 286     $self->redirect_to(action => 'edit', 'letter.id' => $letter->id, media => 'printer', printer_id => $::form->{printer_id});
 287     1;
 288   } or do {
 289     unlink $result{file_name} if $result{file_name};
 290     $::form->error(t8("Creating the PDF failed:") . " " . $@);
 291   };
 292 }
 293
 294 sub action_update {
 295   my ($self, $name_selected) = @_;
 296
 297   $self->_display(
 298     letter => $self->_update,
 299   );
 300 }
 301
 302 sub action_skip_draft {
 303   my ($self) = @_;
 304   $self->action_add(skip_drafts => 1);
 305 }
 306
 307 sub action_delete_drafts {
 308   my ($self) = @_;
 309
 310   my @ids = @{ $::form->{ids} || [] };
 311   SL::DB::Manager::LetterDraft->delete_all(where => [ id => \@ids ]) if @ids;
 312
 313   $self->action_add(skip_drafts => 1);
 314 }
 315
 316 sub action_send_email {
 317   my ($self) = @_;
 318
 319   $::form->{media} = 'email';
 320   $self->action_print_letter(email => $::form->{email_form});
 321 }
 322
 323 ### internal methods
 324
 325 sub _display {
 326   my ($self, %params) = @_;
 327
 328   $::request->{layout}->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery kivi.Letter kivi.SalesPurchase kivi.File);
 329
 330   my $letter = $self->letter;
 331
 332  $params{title} ||= t8('Edit Letter');
 333
 334   $::form->{type}             = 'letter';   # needed for print_options
 335   $::form->{vc}               = $letter->is_sales ? 'customer' : 'vendor'; # needs to be for _get_contacts...
 336
 337   $::form->{language_id} ||= $params{language_id};
 338   $::form->{languages}   ||= SL::DB::Manager::Language->get_all_sorted;
 339   $::form->{printers}      = SL::DB::Manager::Printer->get_all_sorted;
 340
 341   $self->setup_display_action_bar;
 342   $self->render('letter/edit',
 343     %params,
 344     TCF           => [ map { key => $_, value => t8(ucfirst $_) }, TEXT_CREATED_FOR_VALUES() ],
 345     PCF           => [ map { key => $_, value => t8(ucfirst $_) }, PAGE_CREATED_FOR_VALUES() ],
 346     letter        => $letter,
 347     employees     => $self->all_employees,
 348     print_options => SL::Helper::PrintOptions->get_print_options (
 349       options => { no_postscript   => 1,
 350                    no_opendocument => 1,
 351                    no_html         => 1,
 352                    no_queue        => 1,
 353                    show_headers    => 1,
 354                  }),
 355
 356   );
 357 }
 358
 359 sub _update {
 360   my ($self, %params) = @_;
 361
 362   my $letter = $self->letter;
 363
 364   $self->check_date;
 365   $self->set_greetings;
 366
 367   return $letter;
 368 }
 369
 370 sub prepare_report {
 371   my ($self) = @_;
 372
 373   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 374   $self->{report} = $report;
 375
 376   my @columns  = qw(date subject letternumber customer_id vendor_id contact date);
 377   my @sortable = qw(date subject letternumber customer_id vendor_id contact date);
 378
 379   my %column_defs = (
 380     date                  => { text => t8('Date'),         sub => sub { $_[0]->date_as_date } },
 381     subject               => { text => t8('Subject'),      sub => sub { $_[0]->subject },
 382                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 383     letternumber          => { text => t8('Letternumber'), sub => sub { $_[0]->letternumber },
 384                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 385     customer_id           => { text => t8('Customer'),      sub => sub { SL::DB::Manager::Customer->find_by_or_create(id => $_[0]->customer_id)->displayable_name }, visible => $self->is_sales },
 386     vendor_id             => { text => t8('Vendor'),        sub => sub { SL::DB::Manager::Vendor->find_by_or_create(id => $_[0]->vendor_id)->displayable_name }, visible => !$self->is_sales},
 387     contact               => { text => t8('Contact'),       sub => sub { $_[0]->contact ? $_[0]->contact->full_name : '' } },
 388   );
 389
 390   $column_defs{$_}{text} = $sort_columns{$_} for keys %column_defs;
 391
 392   $report->set_options(
 393     std_column_visibility => 1,
 394     controller_class      => 'Letter',
 395     output_format         => 'HTML',
 396     title                 => t8('Letters'),
 397     allow_pdf_export      => 1,
 398     allow_csv_export      => 1,
 399   );
 400
 401   $report->set_columns(%column_defs);
 402   $report->set_column_order(@columns);
 403   $report->set_export_options(qw(list filter is_sales));
 404   $report->set_options_from_form;
 405
 406   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 407   $self->models->add_additional_url_params(is_sales => $self->is_sales);
 408   $self->models->finalize;
 409   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 410
 411   $report->set_options(
 412     raw_top_info_text    => $self->render('letter/report_top',    { output => 0 }),
 413     raw_bottom_info_text => $self->render('letter/report_bottom', { output => 0 }, models => $self->models),
 414     attachment_basename  => t8('letters_list') . strftime('_%Y%m%d', localtime time),
 415   );
 416 }
 417
 418 sub make_filter_summary {
 419   my ($self) = @_;
 420
 421   my $filter = $::form->{filter} || {};
 422   my @filter_strings;
 423
 424   my $employee = $filter->{employee_id} ? SL::DB::Employee->new(id => $filter->{employee_id})->load->name : '';
 425   my $salesman = $filter->{salesman_id} ? SL::DB::Employee->new(id => $filter->{salesman_id})->load->name : '';
 426
 427   my @filters = (
 428     [ $filter->{"letternumber:substr::ilike"},  t8('Number')     ],
 429     [ $filter->{"subject:substr::ilike"},       t8('Subject')    ],
 430     [ $filter->{"body:substr::ilike"},          t8('Body')       ],
 431     [ $filter->{"date:date::ge"},               t8('From Date')  ],
 432     [ $filter->{"date:date::le"},               t8('To Date')    ],
 433     [ $employee,                                t8('Employee')   ],
 434     [ $salesman,                                t8('Salesman')   ],
 435   );
 436
 437   my %flags = (
 438   );
 439   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 440
 441   for (@flags) {
 442     push @filter_strings, $_ if $_;
 443   }
 444   for (@filters) {
 445     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 446   }
 447
 448   $self->{filter_summary} = join ', ', @filter_strings;
 449 }
 450
 451 sub load_letter_draft {
 452   my ($self, %params) = @_;
 453
 454   return 0 if $params{skip_drafts};
 455
 456   my $letter_drafts = SL::DB::Manager::LetterDraft->get_all(
 457     query => [
 458       SL::DB::Manager::Letter->is_sales_filter($self->is_sales),
 459     ]
 460   );
 461
 462   return unless @$letter_drafts;
 463
 464   $self->setup_load_letter_draft_action_bar;
 465   $self->render('letter/load_drafts',
 466     title         => t8('Letter Draft'),
 467     LETTER_DRAFTS => $letter_drafts,
 468   );
 469
 470   return 1;
 471 }
 472
 473 sub check_date {
 474   my ($self) = @_;
 475   my $letter = $self->letter;
 476
 477   return unless $letter;
 478   return if $letter->date;
 479
 480   $letter->date(DateTime->today)
 481 }
 482
 483 sub check_letter {
 484   my ($self, $letter) = @_;
 485
 486   $letter ||= $self->letter;
 487
 488   my $error;
 489
 490   if (!$letter->subject) {
 491     flash('error', t8('The subject is missing.'));
 492     $error = 1;
 493   }
 494   if (!$letter->body) {
 495     flash('error', t8('The body is missing.'));
 496     $error = 1;
 497   }
 498   if (!$letter->employee_id) {
 499     flash('error', t8('The employee is missing.'));
 500     $error = 1;
 501   }
 502
 503   return !$error;
 504 }
 505
 506 sub check_number {
 507   my ($self, $letter) = @_;
 508
 509   $letter ||= $self->letter;
 510
 511   return if $letter->letternumber;
 512
 513   $letter->letternumber(SL::TransNumber->new(type => 'letter', id => $self->{id}, number => $self->{letternumber})->create_unique);
 514 }
 515
 516 sub set_greetings {
 517   my ($self) = @_;
 518   my $letter = $self->letter;
 519
 520   return unless $letter;
 521   return if $letter->greeting;
 522
 523   $letter->greeting(t8('Dear Sir or Madam,'));
 524 }
 525
 526 sub init_letter {
 527   my ($self) = @_;
 528
 529   my $letter      = SL::DB::Manager::Letter->find_by_or_create(id => $::form->{letter}{id} || 0)
 530                                            ->assign_attributes(%{ $::form->{letter} });
 531
 532   if ($letter->cp_id) {
 533 #     $letter->customer_vendor_id($letter->contact->cp_cv_id);
 534       # contacts don't have language_id yet
 535 #     $letter->greeting(GenericTranslations->get(
 536 #       translation_type => 'greetings::' . ($letter->contact->cp_gender eq 'f' ? 'female' : 'male'),
 537 #       language_id      => $letter->contact->language_id,
 538 #       allow_fallback   => 1
 539 #     ));
 540   }
 541
 542   $self->is_sales($letter->is_sales) if $letter->id;
 543
 544   $letter;
 545 }
 546
 547 sub init_models {
 548   my ($self) = @_;
 549
 550   SL::Controller::Helper::GetModels->new(
 551     controller   => $self,
 552     model        => 'Letter',
 553     query        => [
 554       SL::DB::Manager::Letter->is_sales_filter($self->is_sales),
 555     ],
 556     sorted       => \%sort_columns,
 557     with_objects => [ 'contact', 'salesman', 'employee' ],
 558   );
 559 }
 560
 561 sub init_all_employees {
 562   SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 563 }
 564
 565 sub init_webdav_objects {
 566   my ($self) = @_;
 567
 568   return [] if !$self->letter || !$self->letter->letternumber || !$::instance_conf->get_webdav;
 569
 570   my $webdav = SL::Webdav->new(
 571     type     => 'letter',
 572     number   => $self->letter->letternumber,
 573   );
 574
 575   my @all_objects = $webdav->get_all_objects;
 576
 577   return [ map {
 578     +{ name => $_->filename,
 579        type => t8('File'),
 580        link => File::Spec->catfile($_->full_filedescriptor),
 581      }
 582   } @all_objects ];
 583 }
 584
 585 sub init_is_sales {
 586   die 'is_sales must be set' unless defined $::form->{is_sales};
 587   $::form->{is_sales};
 588 }
 589
 590 sub check_auth_edit {
 591   $::form->{is_sales} ? $::auth->assert('sales_letter_edit')
 592                       : $::auth->assert('purchase_letter_edit');
 593 }
 594
 595 sub check_auth_report {
 596   $::form->{is_sales} ? $::auth->assert('sales_letter_report')
 597                       : $::auth->assert('purchase_letter_report');
 598 }
 599
 600 sub setup_load_letter_draft_action_bar {
 601   my ($self, %params) = @_;
 602
 603   for my $bar ($::request->layout->get('actionbar')) {
 604     $bar->add(
 605       link => [
 606         t8('Skip'),
 607         link      => $self->url_for(action => 'skip_draft', is_sales => $self->is_sales),
 608         accesskey => 'enter',
 609       ],
 610       action => [
 611         t8('Delete'),
 612         submit  => [ '#form', { action => 'delete_drafts' } ],
 613         checks  => [ [ 'kivi.check_if_entries_selected', '[name="ids[+]"]' ] ],
 614         confirm => t8('Do you really want to delete this draft?'),
 615       ],
 616     );
 617   }
 618 }
 619
 620 sub setup_display_action_bar {
 621   my ($self, %params) = @_;
 622
 623   for my $bar ($::request->layout->get('actionbar')) {
 624     $bar->add(
 625       action => [
 626         t8('Update'),
 627         submit    => [ '#form', { action => 'Letter/update' } ],
 628         accesskey => 'enter',
 629       ],
 630
 631       combobox => [
 632         action => [
 633           t8('Save'),
 634           submit => [ '#form', { action => 'Letter/save' } ],
 635         ],
 636         action => [
 637           t8('Save Draft'),
 638           submit => [ '#form', { action => 'Letter/save_letter_draft' } ],
 639         ],
 640       ], # end of combobox "Save"
 641
 642       action => [
 643         t8('Delete'),
 644         submit   => [ '#form', { action => 'Letter/delete' } ],
 645         confirm  => t8('Are you sure you want to delete this letter?'),
 646         disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 647       ],
 648
 649       combobox => [
 650         action => [ t8('Export') ],
 651         action => [
 652           t8('Print'),
 653           call     => [ 'kivi.SalesPurchase.show_print_dialog', 'Letter/print_letter' ],
 654           disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 655         ],
 656         action => [
 657           t8('E-mail'),
 658           call     => [ 'kivi.SalesPurchase.show_email_dialog', 'Letter/send_email' ],
 659           disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 660         ],
 661       ],
 662     );
 663   }
 664 }
 665
 666 sub setup_list_action_bar {
 667   my ($self, %params) = @_;
 668
 669   for my $bar ($::request->layout->get('actionbar')) {
 670     $bar->add(
 671       action => [
 672         t8('Update'),
 673         submit    => [ '#search_form', { action => 'Letter/list' } ],
 674         accesskey => 'enter',
 675       ],
 676     );
 677   }
 678 }
 679
 680 1;
 681
 682 __END__
 683
 684 =encoding utf-8
 685
 686 =head1 NAME
 687
 688 SL::Controller::Letter - Letters CRUD and printing
 689
 690 =head1 DESCRIPTION
 691
 692 Simple letter CRUD controller with drafting capabilities.
 693
 694 copy to webdav is crap
 695
 696 =head1 AUTHOR
 697
 698 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 699
 700 =cut