SL/Controller/Letter.pm

   1 package SL::Controller::Letter;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Carp;
   7 use File::Basename;
   8 use POSIX qw(strftime);
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::CT;
  12 use SL::DB::Employee;
  13 use SL::DB::Language;
  14 use SL::DB::Letter;
  15 use SL::DB::LetterDraft;
  16 use SL::DB::Printer;
  17 use SL::Helper::Flash qw(flash flash_later);
  18 use SL::Helper::CreatePDF;
  19 use SL::Helper::PrintOptions;
  20 use SL::Locale::String qw(t8);
  21 use SL::Mailer;
  22 use SL::IS;
  23 use SL::ReportGenerator;
  24 use SL::Webdav;
  25 use SL::Webdav::File;
  26
  27 use Rose::Object::MakeMethods::Generic (
  28   'scalar --get_set_init' => [ qw(letter all_employees models webdav_objects is_sales) ],
  29 );
  30
  31 __PACKAGE__->run_before('check_auth_edit');
  32 __PACKAGE__->run_before('check_auth_report', only => [ qw(list) ]);
  33
  34 use constant TEXT_CREATED_FOR_VALUES => (qw(presskit fax letter));
  35 use constant PAGE_CREATED_FOR_VALUES => (qw(sketch 1 2));
  36
  37 my %sort_columns = (
  38   date                  => t8('Date'),
  39   subject               => t8('Subject'),
  40   letternumber          => t8('Letternumber'),
  41   customer_id           => t8('Customer'),
  42   vendor_id             => t8('Vendor'),
  43   contact               => t8('Contact'),
  44 );
  45
  46 ### actions
  47
  48 sub action_add {
  49   my ($self, %params) = @_;
  50
  51   return if $self->load_letter_draft(%params);
  52
  53   $self->letter->employee_id(SL::DB::Manager::Employee->current->id);
  54   $self->letter->salesman_id(SL::DB::Manager::Employee->current->id);
  55
  56   $self->_display(
  57     title       => t8('Add Letter'),
  58     language_id => $params{language_id},
  59   );
  60 }
  61
  62 sub action_edit {
  63   my ($self, %params) = @_;
  64
  65   return $self->action_add
  66     unless $::form->{letter} || $::form->{draft};
  67
  68   if ($::form->{draft}) {
  69     $self->letter(SL::DB::Letter->new_from_draft($::form->{draft}{id}));
  70     $self->is_sales($self->letter->is_sales);
  71   }
  72
  73   $self->_display(
  74     title  => t8('Edit Letter'),
  75   );
  76 }
  77
  78 sub action_save {
  79   my ($self, %params) = @_;
  80
  81   my $letter = $self->_update;
  82
  83   if (!$self->check_letter($letter)) {
  84     return $self->_display;
  85   }
  86
  87   $self->check_number;
  88
  89   if (!$letter->save) {
  90     flash('error', t8('There was an error saving the letter'));
  91     return $self->_display;
  92   }
  93
  94   flash('info', t8('Letter saved!'));
  95
  96   $self->_display;
  97 }
  98
  99 sub action_update_contacts {
 100   my ($self) = @_;
 101
 102   my $letter = $self->letter;
 103
 104   if (!$self->letter->has_customer_vendor) {
 105     return $self->js
 106       ->replaceWith(
 107         '#letter_cp_id',
 108         SL::Presenter->get->select_tag('letter.cp_id', [], value_key => 'cp_id', title_key => 'full_name')
 109       )
 110       ->render;
 111   }
 112
 113   my $contacts = $letter->customer_vendor->contacts;
 114
 115   my $default;
 116   if (   $letter->contact
 117       && $letter->contact->cp_cv_id
 118       && $letter->contact->cp_cv_id == $letter->customer_vendor_id) {
 119     $default = $letter->contact->cp_id;
 120   } else {
 121     $default = '';
 122   }
 123
 124   $self->js
 125     ->replaceWith(
 126       '#letter_cp_id',
 127       SL::Presenter->get->select_tag('letter.cp_id', $contacts, default => $default, value_key => 'cp_id', title_key => 'full_name')
 128     )
 129     ->render;
 130 }
 131
 132 sub action_save_letter_draft {
 133   my ($self, %params) = @_;
 134
 135   $self->check_letter;
 136
 137   my $letter_draft = SL::DB::LetterDraft->new_from_letter($self->_update);
 138
 139   if (!$letter_draft->save) {
 140     flash('error', t8('There was an error saving the letter draft'));
 141     return $self->_display;
 142   }
 143
 144   flash('info', t8('Draft for this Letter saved!'));
 145
 146   $self->_display;
 147 }
 148
 149 sub action_delete {
 150   my ($self, %params) = @_;
 151
 152   if (!$self->letter->delete) {
 153     flash('error', t8('An error occured. Letter could not be deleted.'));
 154     return $self->action_update;
 155   }
 156
 157   flash_later('info', t8('Letter deleted'));
 158   $self->redirect_to(action => 'list');
 159 }
 160
 161 sub action_delete_letter_drafts {
 162   my ($self, %params) = @_;
 163
 164   my @ids =  grep { /^checked_(.*)/ && $::form->{$_} } keys %$::form;
 165
 166   SL::DB::Manager::LetterDraft->delete_all(query => [ ids => \@ids ]) if @ids;
 167
 168   $self->redirect_to(action => 'add');
 169 }
 170
 171 sub action_list {
 172   my ($self, %params) = @_;
 173
 174   $self->setup_list_action_bar;
 175   $self->make_filter_summary;
 176   $self->prepare_report;
 177
 178   my $letters = $self->models->get;
 179   $self->report_generator_list_objects(report => $self->{report}, objects => $letters);
 180
 181 }
 182
 183 sub action_print_letter {
 184   my ($self, %params) = @_;
 185
 186   my $display_form = $::form->{display_form} || "display_form";
 187   my $letter       = $self->_update;
 188
 189   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
 190     name        => 'letter',
 191     printer_id  => $::form->{printer_id},
 192     language_id => $::form->{language_id},
 193     formname    => 'letter',
 194     format      => 'pdf',
 195   );
 196
 197   if (!defined $template_file) {
 198     $::form->error($::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files));
 199   }
 200
 201   my %result;
 202   eval {
 203     %result = SL::Template::LaTeX->parse_and_create_pdf(
 204       $template_file,
 205       SELF          => $self,
 206       FORM          => $::form,
 207       letter        => $letter,
 208       template_meta => {
 209         formname  => 'letter',
 210         language  => SL::DB::Language->new,
 211         extension => 'pdf',
 212         format    => $::form->{format},
 213         media     => $::form->{media},
 214         printer   => SL::DB::Manager::Printer->find_by_or_create(id => $::form->{printer_id} || undef),
 215         today     => DateTime->today,
 216       },
 217     );
 218
 219     die $result{error} if $result{error};
 220
 221     $::form->{type}         = 'letter';
 222     $::form->{formname}     = 'letter';
 223     $::form->{letternumber} = $letter->letternumber;
 224     my $attachment_name     = $::form->generate_attachment_filename;
 225
 226     if ($::instance_conf->get_webdav_documents) {
 227       my $webdav_file = SL::Webdav::File->new(
 228         filename => $attachment_name,
 229         webdav   => SL::Webdav->new(
 230           type   => 'letter',
 231           number => $letter->letternumber,
 232         ),
 233       );
 234
 235       $webdav_file->store(file => $result{file_name});
 236     }
 237
 238     # set some form defaults for printing webdav copy variables
 239     if ( $::form->{media} eq 'email') {
 240       my $mail             = Mailer->new;
 241       my $signature        = $::myconfig{signature};
 242       $mail->{$_}          = $params{email}->{$_} for qw(to cc subject message bcc);
 243       $mail->{from}        = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 244       $mail->{attachments} = [{ path => $result{file_name},
 245                                 name => $params{email}->{attachment_filename} }];
 246       $mail->{message}    .=  "\n-- \n$signature";
 247       $mail->{message}     =~ s/\r//g;
 248
 249       $mail->send;
 250       unlink $result{file_name};
 251
 252       flash_later('info', t8('The email has been sent.'));
 253       $self->redirect_to(action => 'edit', 'letter.id' => $letter->id);
 254
 255       return 1;
 256     }
 257
 258     if (!$::form->{printer_id} || $::form->{media} eq 'screen') {
 259       $self->send_file($result{file_name}, name => $attachment_name);
 260       unlink $result{file_name};
 261
 262       return 1;
 263     }
 264
 265     my $printer = SL::DB::Printer->new(id => $::form->{printer_id})->load;
 266     $printer->print_document(
 267       copies    => $::form->{copies},
 268       file_name => $result{file_name},
 269     );
 270
 271     unlink $result{file_name};
 272
 273     flash_later('info', t8('The documents have been sent to the printer \'#1\'.', $printer->printer_description));
 274     $self->redirect_to(action => 'edit', 'letter.id' => $letter->id, media => 'printer', printer_id => $::form->{printer_id});
 275     1;
 276   } or do {
 277     unlink $result{file_name} if $result{file_name};
 278     $::form->error(t8("Creating the PDF failed:") . " " . $@);
 279   };
 280 }
 281
 282 sub action_update {
 283   my ($self, $name_selected) = @_;
 284
 285   $self->_display(
 286     letter => $self->_update,
 287   );
 288 }
 289
 290 sub action_skip_draft {
 291   my ($self) = @_;
 292   $self->action_add(skip_drafts => 1);
 293 }
 294
 295 sub action_delete_drafts {
 296   my ($self) = @_;
 297
 298   my @ids = @{ $::form->{ids} || [] };
 299   SL::DB::Manager::LetterDraft->delete_all(where => [ id => \@ids ]) if @ids;
 300
 301   $self->action_add(skip_drafts => 1);
 302 }
 303
 304 sub action_send_email {
 305   my ($self) = @_;
 306
 307   $::form->{media} = 'email';
 308   $self->action_print_letter(email => $::form->{email_form});
 309 }
 310
 311 ### internal methods
 312
 313 sub _display {
 314   my ($self, %params) = @_;
 315
 316   $::request->{layout}->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery kivi.Letter);
 317
 318   my $letter = $self->letter;
 319
 320  $params{title} ||= t8('Edit Letter');
 321
 322   $::form->{type}             = 'letter';   # needed for print_options
 323   $::form->{vc}               = $letter->is_sales ? 'customer' : 'vendor'; # needs to be for _get_contacts...
 324
 325   $::request->layout->add_javascripts('customer_or_vendor_selection.js');
 326   $::request->layout->add_javascripts('edit_part_window.js');
 327
 328   $::form->{language_id} ||= $params{language_id};
 329   $::form->{languages}   ||= SL::DB::Manager::Language->get_all_sorted;
 330   $::form->{printers}      = SL::DB::Manager::Printer->get_all_sorted;
 331
 332   $self->setup_display_action_bar;
 333   $self->render('letter/edit',
 334     %params,
 335     TCF           => [ map { key => $_, value => t8(ucfirst $_) }, TEXT_CREATED_FOR_VALUES() ],
 336     PCF           => [ map { key => $_, value => t8(ucfirst $_) }, PAGE_CREATED_FOR_VALUES() ],
 337     letter        => $letter,
 338     employees     => $self->all_employees,
 339     print_options => SL::Helper::PrintOptions->get_print_options (
 340       options => { no_postscript   => 1,
 341                    no_opendocument => 1,
 342                    no_html         => 1,
 343                    no_queue        => 1,
 344                    show_headers    => 1,
 345                  }),
 346
 347   );
 348 }
 349
 350 sub _update {
 351   my ($self, %params) = @_;
 352
 353   my $letter = $self->letter;
 354
 355   $self->check_date;
 356   $self->set_greetings;
 357
 358   return $letter;
 359 }
 360
 361 sub prepare_report {
 362   my ($self) = @_;
 363
 364   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 365   $self->{report} = $report;
 366
 367   my @columns  = qw(date subject letternumber customer_id vendor_id contact date);
 368   my @sortable = qw(date subject letternumber customer_id vendor_id contact date);
 369
 370   my %column_defs = (
 371     date                  => { text => t8('Date'),         sub => sub { $_[0]->date_as_date } },
 372     subject               => { text => t8('Subject'),      sub => sub { $_[0]->subject },
 373                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 374     letternumber          => { text => t8('Letternumber'), sub => sub { $_[0]->letternumber },
 375                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 376     customer_id           => { text => t8('Customer'),      sub => sub { SL::DB::Manager::Customer->find_by_or_create(id => $_[0]->customer_id)->displayable_name }, visible => $self->is_sales },
 377     vendor_id             => { text => t8('Vendor'),        sub => sub { SL::DB::Manager::Vendor->find_by_or_create(id => $_[0]->vendor_id)->displayable_name }, visible => !$self->is_sales},
 378     contact               => { text => t8('Contact'),       sub => sub { $_[0]->contact ? $_[0]->contact->full_name : '' } },
 379   );
 380
 381   $column_defs{$_}{text} = $sort_columns{$_} for keys %column_defs;
 382
 383   $report->set_options(
 384     std_column_visibility => 1,
 385     controller_class      => 'Letter',
 386     output_format         => 'HTML',
 387     title                 => t8('Letters'),
 388     allow_pdf_export      => 1,
 389     allow_csv_export      => 1,
 390   );
 391
 392   $report->set_columns(%column_defs);
 393   $report->set_column_order(@columns);
 394   $report->set_export_options(qw(list filter is_sales));
 395   $report->set_options_from_form;
 396
 397   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 398   $self->models->add_additional_url_params(is_sales => $self->is_sales);
 399   $self->models->finalize;
 400   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 401
 402   $report->set_options(
 403     raw_top_info_text    => $self->render('letter/report_top',    { output => 0 }),
 404     raw_bottom_info_text => $self->render('letter/report_bottom', { output => 0 }, models => $self->models),
 405     attachment_basename  => t8('letters_list') . strftime('_%Y%m%d', localtime time),
 406   );
 407 }
 408
 409 sub make_filter_summary {
 410   my ($self) = @_;
 411
 412   my $filter = $::form->{filter} || {};
 413   my @filter_strings;
 414
 415   my $employee = $filter->{employee_id} ? SL::DB::Employee->new(id => $filter->{employee_id})->load->name : '';
 416   my $salesman = $filter->{salesman_id} ? SL::DB::Employee->new(id => $filter->{salesman_id})->load->name : '';
 417
 418   my @filters = (
 419     [ $filter->{"letternumber:substr::ilike"},  t8('Number')     ],
 420     [ $filter->{"subject:substr::ilike"},       t8('Subject')    ],
 421     [ $filter->{"body:substr::ilike"},          t8('Body')       ],
 422     [ $filter->{"date:date::ge"},               t8('From Date')  ],
 423     [ $filter->{"date:date::le"},               t8('To Date')    ],
 424     [ $employee,                                t8('Employee')   ],
 425     [ $salesman,                                t8('Salesman')   ],
 426   );
 427
 428   my %flags = (
 429   );
 430   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 431
 432   for (@flags) {
 433     push @filter_strings, $_ if $_;
 434   }
 435   for (@filters) {
 436     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 437   }
 438
 439   $self->{filter_summary} = join ', ', @filter_strings;
 440 }
 441
 442 sub load_letter_draft {
 443   my ($self, %params) = @_;
 444
 445   return 0 if $params{skip_drafts};
 446
 447   my $letter_drafts = SL::DB::Manager::LetterDraft->get_all(
 448     query => [
 449       SL::DB::Manager::Letter->is_sales_filter($self->is_sales),
 450     ]
 451   );
 452
 453   return unless @$letter_drafts;
 454
 455   $self->setup_load_letter_draft_action_bar;
 456   $self->render('letter/load_drafts',
 457     title         => t8('Letter Draft'),
 458     LETTER_DRAFTS => $letter_drafts,
 459   );
 460
 461   return 1;
 462 }
 463
 464 sub check_date {
 465   my ($self) = @_;
 466   my $letter = $self->letter;
 467
 468   return unless $letter;
 469   return if $letter->date;
 470
 471   $letter->date(DateTime->today)
 472 }
 473
 474 sub check_letter {
 475   my ($self, $letter) = @_;
 476
 477   $letter ||= $self->letter;
 478
 479   my $error;
 480
 481   if (!$letter->subject) {
 482     flash('error', t8('The subject is missing.'));
 483     $error = 1;
 484   }
 485   if (!$letter->body) {
 486     flash('error', t8('The body is missing.'));
 487     $error = 1;
 488   }
 489   if (!$letter->employee_id) {
 490     flash('error', t8('The employee is missing.'));
 491     $error = 1;
 492   }
 493
 494   return !$error;
 495 }
 496
 497 sub check_number {
 498   my ($self, $letter) = @_;
 499
 500   $letter ||= $self->letter;
 501
 502   return if $letter->letternumber;
 503
 504   $letter->letternumber(SL::TransNumber->new(type => 'letter', id => $self->{id}, number => $self->{letternumber})->create_unique);
 505 }
 506
 507 sub set_greetings {
 508   my ($self) = @_;
 509   my $letter = $self->letter;
 510
 511   return unless $letter;
 512   return if $letter->greeting;
 513
 514   $letter->greeting(t8('Dear Sir or Madam,'));
 515 }
 516
 517 sub export_letter_to_form {
 518   my ($self, $letter) = @_;
 519   # nope, not pretty.
 520
 521   $letter ||= $self->letter;
 522
 523   for ($letter->meta->columns) {
 524     if ((ref $_) =~ /Date/i) {
 525       $::form->{$_->name} = $letter->$_->to_kivitendo;
 526     } else {
 527       $::form->{$_->name} = $letter->$_;
 528     }
 529   }
 530 }
 531
 532 sub init_letter {
 533   my ($self) = @_;
 534
 535   my $letter      = SL::DB::Manager::Letter->find_by_or_create(id => $::form->{letter}{id} || 0)
 536                                            ->assign_attributes(%{ $::form->{letter} });
 537
 538   if ($letter->cp_id) {
 539 #     $letter->customer_vendor_id($letter->contact->cp_cv_id);
 540       # contacts don't have language_id yet
 541 #     $letter->greeting(GenericTranslations->get(
 542 #       translation_type => 'greetings::' . ($letter->contact->cp_gender eq 'f' ? 'female' : 'male'),
 543 #       language_id      => $letter->contact->language_id,
 544 #       allow_fallback   => 1
 545 #     ));
 546   }
 547
 548   $self->is_sales($letter->is_sales) if $letter->id;
 549
 550   $letter;
 551 }
 552
 553 sub init_models {
 554   my ($self) = @_;
 555
 556   SL::Controller::Helper::GetModels->new(
 557     controller   => $self,
 558     model        => 'Letter',
 559     query        => [
 560       SL::DB::Manager::Letter->is_sales_filter($self->is_sales),
 561     ],
 562     sorted       => \%sort_columns,
 563     with_objects => [ 'contact', 'salesman', 'employee' ],
 564   );
 565 }
 566
 567 sub init_all_employees {
 568   SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 569 }
 570
 571 sub init_webdav_objects {
 572   my ($self) = @_;
 573
 574   return [] if !$self->letter || !$self->letter->letternumber || !$::instance_conf->get_webdav;
 575
 576   my $webdav = SL::Webdav->new(
 577     type     => 'letter',
 578     number   => $self->letter->letternumber,
 579   );
 580
 581   my @all_objects = $webdav->get_all_objects;
 582
 583   return [ map {
 584     +{ name => $_->filename,
 585        type => t8('File'),
 586        link => File::Spec->catfile($_->full_filedescriptor),
 587      }
 588   } @all_objects ];
 589 }
 590
 591 sub init_is_sales {
 592   die 'is_sales must be set' unless defined $::form->{is_sales};
 593   $::form->{is_sales};
 594 }
 595
 596 sub check_auth_edit {
 597   $::auth->assert('sales_letter_edit');
 598 }
 599
 600 sub check_auth_report {
 601   $::auth->assert('sales_letter_report');
 602 }
 603
 604 sub setup_load_letter_draft_action_bar {
 605   my ($self, %params) = @_;
 606
 607   for my $bar ($::request->layout->get('actionbar')) {
 608     $bar->add(
 609       link => [
 610         t8('Skip'),
 611         link      => $self->url_for(action => 'skip_draft', is_sales => $self->is_sales),
 612         accesskey => 'enter',
 613       ],
 614       action => [
 615         t8('Delete'),
 616         submit  => [ '#form', { action => 'delete_drafts' } ],
 617         checks  => [ [ 'kivi.check_if_entries_selected', '[name="ids[+]"]' ] ],
 618         confirm => t8('Do you really want to delete this draft?'),
 619       ],
 620     );
 621   }
 622 }
 623
 624 sub setup_display_action_bar {
 625   my ($self, %params) = @_;
 626
 627   for my $bar ($::request->layout->get('actionbar')) {
 628     $bar->add(
 629       action => [
 630         t8('Update'),
 631         submit    => [ '#form', { action => 'Letter/update' } ],
 632         accesskey => 'enter',
 633       ],
 634
 635       combobox => [
 636         action => [
 637           t8('Save'),
 638           submit => [ '#form', { action => 'Letter/save' } ],
 639         ],
 640         action => [
 641           t8('Save Draft'),
 642           submit => [ '#form', { action => 'Letter/save_letter_draft' } ],
 643         ],
 644       ], # end of combobox "Save"
 645
 646       action => [
 647         t8('Delete'),
 648         submit   => [ '#form', { action => 'Letter/delete' } ],
 649         confirm  => t8('Are you sure you want to delete this letter?'),
 650         disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 651       ],
 652
 653       combobox => [
 654         action => [ t8('Export') ],
 655         action => [
 656           t8('Print'),
 657           call     => [ 'kivi.SalesPurchase.show_print_dialog', 'Letter/print_letter' ],
 658           disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 659         ],
 660         action => [
 661           t8('E-mail'),
 662           call     => [ 'kivi.SalesPurchase.show_email_dialog', 'Letter/send_email' ],
 663           disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 664         ],
 665       ],
 666     );
 667   }
 668 }
 669
 670 sub setup_list_action_bar {
 671   my ($self, %params) = @_;
 672
 673   for my $bar ($::request->layout->get('actionbar')) {
 674     $bar->add(
 675       action => [
 676         t8('Update'),
 677         submit    => [ '#search_form', { action => 'Letter/list' } ],
 678         accesskey => 'enter',
 679       ],
 680     );
 681   }
 682 }
 683
 684 1;
 685
 686 __END__
 687
 688 =encoding utf-8
 689
 690 =head1 NAME
 691
 692 SL::Controller::Letter - Letters CRUD and printing
 693
 694 =head1 DESCRIPTION
 695
 696 Simple letter CRUD controller with drafting capabilities.
 697
 698 copy to webdav is crap
 699
 700 =head1 AUTHOR
 701
 702 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 703
 704 =cut