SL/Controller/LoginScreen.pm

   1 package SL::Controller::LoginScreen;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use List::Util qw(first);
   8
   9 use SL::Dispatcher::AuthHandler::User;
  10 use SL::DB::AuthClient;
  11 use SL::DB::AuthGroup;
  12 use SL::DB::AuthUser;
  13 use SL::DB::Employee;
  14 use SL::Locale::String qw(t8);
  15 use SL::User;
  16
  17 use Rose::Object::MakeMethods::Generic (
  18   'scalar --get_set_init' => [ qw(clients default_client_id) ],
  19 );
  20
  21 __PACKAGE__->run_before('set_layout');
  22
  23 #
  24 # actions
  25 #
  26
  27 sub action_user_login {
  28   my ($self) = @_;
  29
  30   # If the user is already logged in then redirect to the proper menu
  31   # script.
  32   return if $self->_redirect_to_main_script_if_already_logged_in;
  33
  34   # Otherwise show the login form.
  35   $self->show_login_form(error_state($::form->{error}));
  36 }
  37
  38 sub action_logout {
  39   my ($self) = @_;
  40
  41   $::auth->destroy_session;
  42   $::auth->create_or_refresh_session;
  43   $self->show_login_form(info => $::locale->text('You are logged out!'));
  44 }
  45
  46 sub action_login {
  47   my ($self) = @_;
  48
  49   my $login     = $::form->{'{AUTH}login'}     || $::auth->get_session_value('login');
  50   my $client_id = $::form->{'{AUTH}client_id'} || $::auth->get_session_value('client_id');
  51   my $error     = t8('Incorrect username or password or no access to selected client!');
  52
  53   if (!$::auth->set_client($client_id)) {
  54     $::auth->punish_wrong_login;
  55     return $self->show_login_form(error => $error);
  56   }
  57
  58   %::myconfig      = $login ? $::auth->read_user(login => $login) : ();
  59   $::locale        = Locale->new($::myconfig{countrycode}) if $::myconfig{countrycode};
  60   SL::Dispatcher::AuthHandler::User->new->handle(countrycode => $::myconfig{countrycode});
  61
  62   $::request->layout(SL::Layout::Dispatcher->new(style => $::myconfig{menustyle}));
  63
  64   # if we get an error back, bale out
  65   my $result = User->new(login => $::myconfig{login})->login($::form);
  66
  67   # Auth DB needs update? If so log the user out forcefully.
  68   if (User::LOGIN_AUTH_DBUPDATE_AVAILABLE() == $result) {
  69     $::auth->destroy_session;
  70     return $self->render('login_screen/auth_db_needs_update');
  71   }
  72
  73   # Basic client tables available? If not tell the user to create them
  74   # and log the user out forcefully.
  75   if (User::LOGIN_BASIC_TABLES_MISSING() == $result) {
  76     $::auth->destroy_session;
  77     return $self->render('login_screen/basic_tables_missing');
  78   }
  79
  80   # Database update available?
  81   ::end_of_request() if User::LOGIN_DBUPDATE_AVAILABLE() == $result;
  82
  83   # Other login errors.
  84   if (User::LOGIN_OK() != $result) {
  85     $::auth->punish_wrong_login;
  86     return $self->show_login_form(error => $error);
  87   }
  88
  89   # Everything is fine.
  90   $::auth->set_cookie_environment_variable();
  91
  92   $self->_redirect_to_main_script;
  93 }
  94
  95 #
  96 # settings
  97 #
  98 sub get_auth_level {
  99   return 'none';
 100 }
 101
 102 sub keep_auth_vars_in_form {
 103   return 1;
 104 }
 105
 106 #
 107 # private methods
 108 #
 109
 110 sub _redirect_to_main_script {
 111   my ($self) = @_;
 112
 113   return $self->redirect_to($::form->{callback}) if $::form->{callback};
 114
 115   $self->redirect_to(controller => "login.pl", action => 'company_logo');
 116 }
 117
 118 sub _redirect_to_main_script_if_already_logged_in {
 119   my ($self) = @_;
 120
 121   # Get 'login' from valid session.
 122   my $login = $::auth->get_session_value('login');
 123   return unless $login;
 124
 125   # See whether or not the user exists in the database.
 126   my %user = $::auth->read_user(login => $login);
 127   return if ($user{login} || '') ne $login;
 128
 129   # Check if there's a client set in the session -- and whether or not
 130   # the user still has access to the client.
 131   my $client_id = $::auth->get_session_value('client_id');
 132   return if !$client_id;
 133
 134   if (!$::auth->set_client($client_id)) {
 135     $::auth->punish_wrong_login;
 136     $::auth->destroy_session;
 137     $::auth->create_or_refresh_session;
 138     $self->show_login_form(error => t8('Incorrect username or password or no access to selected client!'));
 139     return 1;
 140   }
 141
 142   # Check if the session is logged in correctly.
 143   return if SL::Auth::OK() != $::auth->authenticate($login, undef);
 144
 145   $::auth->create_or_refresh_session;
 146   $::auth->delete_session_value('FLASH');
 147
 148   $self->_redirect_to_main_script(\%user);
 149
 150   return 1;
 151 }
 152
 153 sub error_state {
 154   my %states = (
 155     session  => { warning => t8('The session has expired. Please log in again.')                   },
 156     password => { error   => t8('Incorrect username or password or no access to selected client!') },
 157     action   => { warning => t8('The action is missing or invalid.')                               },
 158   );
 159
 160   return %{ $states{$_[0]} || {} };
 161 }
 162
 163 sub set_layout {
 164   $::request->{layout} = SL::Layout::Dispatcher->new(style => 'login');
 165 }
 166
 167 sub init_clients {
 168   return SL::DB::Manager::AuthClient->get_all_sorted;
 169 }
 170
 171 sub init_default_client_id {
 172   my ($self)         = @_;
 173   my $default_client = first { $_->is_default } @{ $self->clients };
 174   return $default_client ? $default_client->id : undef;
 175 }
 176
 177 sub show_login_form {
 178   my ($self, %params) = @_;
 179
 180   $self->render('login_screen/user_login', %params, version => $::form->read_version);
 181 }
 182
 183 1;