SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13
  14 use SL::DB::Order;
  15 use SL::DB::Customer;
  16 use SL::DB::Vendor;
  17 use SL::DB::TaxZone;
  18 use SL::DB::Employee;
  19 use SL::DB::Project;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22 use SL::DB::Price;
  23 use SL::DB::Part;
  24
  25 use SL::Helper::DateTime;
  26 use SL::Helper::CreatePDF qw(:all);
  27
  28 use SL::Controller::Helper::GetModels;
  29
  30 use List::Util qw(max first);
  31 use List::MoreUtils qw(none pairwise first_index);
  32 use English qw(-no_match_vars);
  33 use File::Spec;
  34
  35 use Rose::Object::MakeMethods::Generic
  36 (
  37  scalar => [ qw(item_ids_to_delete) ],
  38  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models) ],
  39 );
  40
  41
  42 # safety
  43 __PACKAGE__->run_before('_check_auth');
  44
  45 __PACKAGE__->run_before('_recalc',
  46                         only => [ qw(update save save_and_delivery_order create_pdf send_email) ]);
  47
  48 __PACKAGE__->run_before('_get_unalterable_data',
  49                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  50
  51 #
  52 # actions
  53 #
  54
  55 sub action_add {
  56   my ($self) = @_;
  57
  58   $self->order->transdate(DateTime->now_local());
  59   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  60
  61   $self->_pre_render();
  62   $self->render(
  63     'order/form',
  64     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  65            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  66            : '',
  67     %{$self->{template_args}}
  68   );
  69 }
  70
  71 sub action_edit {
  72   my ($self) = @_;
  73
  74   $self->_load_order;
  75   $self->_recalc();
  76   $self->_pre_render();
  77   $self->render(
  78     'order/form',
  79     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  80            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  81            : '',
  82     %{$self->{template_args}}
  83   );
  84 }
  85
  86 sub action_update {
  87   my ($self) = @_;
  88
  89   $self->_pre_render();
  90   $self->render(
  91     'order/form',
  92     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  93            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  94            : '',
  95     %{$self->{template_args}}
  96   );
  97 }
  98
  99 sub action_delete {
 100   my ($self) = @_;
 101
 102   my $errors = $self->_delete();
 103
 104   if (scalar @{ $errors }) {
 105     $self->js->flash('error', $_) foreach @{ $errors };
 106     return $self->js->render();
 107   }
 108
 109   flash_later('info', $::locale->text('The order has been deleted'));
 110   my @redirect_params = (
 111     action => 'edit',
 112     type   => $self->type,
 113   );
 114
 115   $self->redirect_to(@redirect_params);
 116 }
 117
 118 sub action_save {
 119   my ($self) = @_;
 120
 121   my $errors = $self->_save();
 122
 123   if (scalar @{ $errors }) {
 124     $self->js->flash('error', $_) foreach @{ $errors };
 125     return $self->js->render();
 126   }
 127
 128   flash_later('info', $::locale->text('The order has been saved'));
 129   my @redirect_params = (
 130     action => 'edit',
 131     type   => $self->type,
 132     id     => $self->order->id,
 133   );
 134
 135   $self->redirect_to(@redirect_params);
 136 }
 137
 138 sub action_create_pdf {
 139   my ($self) = @_;
 140
 141   my $pdf;
 142   my @errors = _create_pdf($self->order, \$pdf);
 143   if (scalar @errors) {
 144     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 145   }
 146
 147   my $sfile = SL::SessionFile::Random->new(mode => "w");
 148   $sfile->fh->print($pdf);
 149   $sfile->fh->close;
 150
 151   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 152   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 153
 154   my $form = Form->new;
 155   $form->{ordnumber} = $self->order->ordnumber;
 156   $form->{formname}  = $self->type;
 157   $form->{type}      = $self->type;
 158   $form->{language}  = 'de';
 159   $form->{format}    = 'pdf';
 160
 161   my $pdf_filename = $form->generate_attachment_filename();
 162
 163   # copy file to webdav folder
 164   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 165     my $webdav = SL::Webdav->new(
 166       type     => $self->type,
 167       number   => $self->order->ordnumber,
 168     );
 169     my $webdav_file = SL::Webdav::File->new(
 170       webdav   => $webdav,
 171       filename => $pdf_filename,
 172     );
 173     eval {
 174       $webdav_file->store(data => \$pdf);
 175       1;
 176     } or do {
 177       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 178     }
 179   }
 180
 181   $self->js
 182     ->run('download_pdf', $pdf_filename, $key)
 183     ->flash('info', t8('The PDF has been created'))->render($self);
 184 }
 185
 186 sub action_download_pdf {
 187   my ($self) = @_;
 188
 189   my $key = $::form->{key};
 190   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 191   return $self->send_file(
 192     $tmp_filename,
 193     type => 'application/pdf',
 194     name => $::form->{pdf_filename},
 195   );
 196 }
 197
 198 sub action_show_email_dialog {
 199   my ($self) = @_;
 200
 201   my $cv_method = $self->cv;
 202
 203   if (!$self->order->$cv_method) {
 204     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 205                     ->render($self);
 206   }
 207
 208   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 209   $self->{email}->{to} ||= $self->order->$cv_method->email;
 210   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 211   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 212   # Todo: get addresses from shipto, if any
 213
 214   my $form = Form->new;
 215   $form->{ordnumber} = $self->order->ordnumber;
 216   $form->{formname}  = $self->type;
 217   $form->{type}      = $self->type;
 218   $form->{language} = 'de';
 219   $form->{format}   = 'pdf';
 220
 221   $self->{email}->{subject}             = $form->generate_email_subject();
 222   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 223   $self->{email}->{message}             = $form->create_email_signature();
 224
 225   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 226   $self->js
 227       ->run('show_email_dialog', $dialog_html)
 228       ->reinit_widgets
 229       ->render($self);
 230 }
 231
 232 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 233 sub action_send_email {
 234   my ($self) = @_;
 235
 236   my $mail      = Mailer->new;
 237   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 238   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 239
 240   my $pdf;
 241   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 242   if (scalar @errors) {
 243     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 244   }
 245
 246   $mail->{attachments} = [{ "content" => $pdf,
 247                             "name"    => $::form->{email}->{attachment_filename} }];
 248
 249   if (my $err = $mail->send) {
 250     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 251                     ->render($self);
 252   }
 253
 254   # internal notes
 255   my $intnotes = $self->order->intnotes;
 256   $intnotes   .= "\n\n" if $self->order->intnotes;
 257   $intnotes   .= t8('[email]')                                                                                        . "\n";
 258   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 259   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 260   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 261   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 262   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 263   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 264
 265   $self->js
 266       ->val('#order_intnotes', $intnotes)
 267       ->run('close_email_dialog')
 268       ->render($self);
 269 }
 270
 271 sub action_save_and_delivery_order {
 272   my ($self) = @_;
 273
 274   my $errors = $self->_save();
 275
 276   if (scalar @{ $errors }) {
 277     $self->js->flash('error', $_) foreach @{ $errors };
 278     return $self->js->render();
 279   }
 280   flash_later('info', $::locale->text('The order has been saved'));
 281
 282   my @redirect_params = (
 283     controller => 'oe.pl',
 284     action     => 'oe_delivery_order_from_order',
 285     id         => $self->order->id,
 286   );
 287
 288   $self->redirect_to(@redirect_params);
 289 }
 290
 291 sub action_customer_vendor_changed {
 292   my ($self) = @_;
 293
 294   my $cv_method = $self->cv;
 295
 296   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 297     $self->js->show('#cp_row');
 298   } else {
 299     $self->js->hide('#cp_row');
 300   }
 301
 302   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 303     $self->js->show('#shipto_row');
 304   } else {
 305     $self->js->hide('#shipto_row');
 306   }
 307
 308   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 309
 310   if ($self->order->is_sales) {
 311     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 312                               ? $self->order->$cv_method->taxincluded_checked
 313                               : $::myconfig{taxincluded_checked});
 314   }
 315
 316   $self->order->payment_id($self->order->$cv_method->payment_id);
 317   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 318
 319   $self->_recalc();
 320
 321   $self->js
 322     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 323     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 324     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 325     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 326     ->val(        '#order_payment_id',       $self->order->payment_id)
 327     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 328     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 329     ->focus(      '#order_' . $self->cv . '_id');
 330
 331   $self->_js_redisplay_amounts_and_taxes;
 332   $self->js->render();
 333 }
 334
 335 sub action_unit_changed {
 336   my ($self) = @_;
 337
 338   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 339   my $item = $self->order->items_sorted->[$idx];
 340
 341   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 342   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 343
 344   $self->_recalc();
 345
 346   $self->js
 347     ->run('update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 348   $self->_js_redisplay_linetotals;
 349   $self->_js_redisplay_amounts_and_taxes;
 350   $self->js->render();
 351 }
 352
 353 sub action_add_item {
 354   my ($self) = @_;
 355
 356   my $form_attr = $::form->{add_item};
 357
 358   return unless $form_attr->{parts_id};
 359
 360   my $item = _new_item($self->order, $form_attr);
 361   $self->order->add_items($item);
 362
 363   $self->_recalc();
 364
 365   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 366   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 367
 368   $self->js
 369     ->append('#row_table_id', $row_as_html)
 370     ->val('.add_item_input', '')
 371     ->run('row_table_scroll_down')
 372     ->run('row_set_keyboard_events_by_id', $item_id)
 373     ->run('set_unit_change_with_oldval_by_id', $item_id)
 374     ->run('renumber_positions')
 375     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 376     ->on('.reformat_number', 'change', 'reformat_number')
 377     ->focus('#add_item_parts_id_name');
 378
 379   $self->_js_redisplay_amounts_and_taxes;
 380   $self->js->render();
 381 }
 382
 383 sub action_show_multi_items_dialog {
 384   require SL::DB::PartsGroup;
 385   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 386                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 387 }
 388
 389 sub action_multi_items_update_result {
 390   my $max_count = 100;
 391   my $count = $_[0]->multi_items_models->count;
 392
 393   if ($count == 0) {
 394     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 395     $_[0]->render($text, { layout => 0 });
 396   } elsif ($count > $max_count) {
 397     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 398     $_[0]->render($text, { layout => 0 });
 399   } else {
 400     my $multi_items = $_[0]->multi_items_models->get;
 401     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 402                   multi_items => $multi_items);
 403   }
 404 }
 405
 406 sub action_add_multi_items {
 407   my ($self) = @_;
 408
 409   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 410   return $self->js->render() unless scalar @form_attr;
 411
 412   my @items;
 413   foreach my $attr (@form_attr) {
 414     push @items, _new_item($self->order, $attr);
 415   }
 416   $self->order->add_items(@items);
 417
 418   $self->_recalc();
 419
 420   foreach my $item (@items) {
 421     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 422     my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 423
 424     $self->js
 425         ->append('#row_table_id', $row_as_html)
 426         ->run('row_set_keyboard_events_by_id', $item_id)
 427         ->run('set_unit_change_with_oldval_by_id', $item_id);
 428   }
 429
 430   $self->js
 431     ->run('close_multi_items_dialog')
 432     ->run('row_table_scroll_down')
 433     ->run('renumber_positions')
 434     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 435     ->on('.reformat_number', 'change', 'reformat_number')
 436     ->focus('#add_item_parts_id_name');
 437
 438   $self->_js_redisplay_amounts_and_taxes;
 439   $self->js->render();
 440 }
 441
 442 sub action_recalc_amounts_and_taxes {
 443   my ($self) = @_;
 444
 445   $self->_recalc();
 446
 447   $self->_js_redisplay_linetotals;
 448   $self->_js_redisplay_amounts_and_taxes;
 449   $self->js->render();
 450 }
 451
 452 sub action_price_popup {
 453   my ($self) = @_;
 454
 455   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 456   my $item = $self->order->items_sorted->[$idx];
 457
 458   $self->render_price_dialog($item);
 459 }
 460
 461 sub _js_redisplay_linetotals {
 462   my ($self) = @_;
 463
 464   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items_sorted };
 465   $self->js
 466     ->run('redisplay_linetotals', \@data);
 467 }
 468
 469 sub _js_redisplay_amounts_and_taxes {
 470   my ($self) = @_;
 471
 472   if (scalar @{ $self->{taxes} }) {
 473     $self->js->show('#taxincluded_row_id');
 474   } else {
 475     $self->js->hide('#taxincluded_row_id');
 476   }
 477
 478   if ($self->order->taxincluded) {
 479     $self->js->hide('#subtotal_row_id');
 480   } else {
 481     $self->js->show('#subtotal_row_id');
 482   }
 483
 484   $self->js
 485     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 486     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 487     ->remove('.tax_row')
 488     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 489 }
 490
 491 #
 492 # helpers
 493 #
 494
 495 sub init_valid_types {
 496   [ _sales_order_type(), _purchase_order_type() ];
 497 }
 498
 499 sub init_type {
 500   my ($self) = @_;
 501
 502   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 503     die "Not a valid type for order";
 504   }
 505
 506   $self->type($::form->{type});
 507 }
 508
 509 sub init_cv {
 510   my ($self) = @_;
 511
 512   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 513          : $self->type eq _purchase_order_type() ? 'vendor'
 514          : die "Not a valid type for order";
 515
 516   return $cv;
 517 }
 518
 519 sub init_p {
 520   SL::Presenter->get;
 521 }
 522
 523 sub init_order {
 524   $_[0]->_make_order;
 525 }
 526
 527 sub init_multi_items_models {
 528   SL::Controller::Helper::GetModels->new(
 529     controller     => $_[0],
 530     model          => 'Part',
 531     with_objects   => [ qw(unit_obj) ],
 532     disable_plugin => 'paginated',
 533     source         => $::form->{multi_items},
 534     sorted         => {
 535       _default    => {
 536         by  => 'partnumber',
 537         dir => 1,
 538       },
 539       partnumber  => t8('Partnumber'),
 540       description => t8('Description')}
 541   );
 542 }
 543
 544 sub _check_auth {
 545   my ($self) = @_;
 546
 547   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 548
 549   my $right   = $right_for->{ $self->type };
 550   $right    ||= 'DOES_NOT_EXIST';
 551
 552   $::auth->assert($right);
 553 }
 554
 555 sub build_contact_select {
 556   my ($self) = @_;
 557
 558   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 559                        value_key  => 'cp_id',
 560                        title_key  => 'full_name_dep',
 561                        default    => $self->order->cp_id,
 562                        with_empty => 1,
 563                        style      => 'width: 300px',
 564   );
 565 }
 566
 567 sub build_shipto_select {
 568   my ($self) = @_;
 569
 570   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 571                        value_key  => 'shipto_id',
 572                        title_key  => 'displayable_id',
 573                        default    => $self->order->shipto_id,
 574                        with_empty => 1,
 575                        style      => 'width: 300px',
 576   );
 577 }
 578
 579 sub build_tax_rows {
 580   my ($self) = @_;
 581
 582   my $rows_as_html;
 583   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 584     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 585   }
 586   return $rows_as_html;
 587 }
 588
 589
 590 sub render_price_dialog {
 591   my ($self, $record_item) = @_;
 592
 593   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 594
 595   $self->js
 596     ->run(
 597       'kivi.io.price_chooser_dialog',
 598       t8('Available Prices'),
 599       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 600     )
 601     ->reinit_widgets;
 602
 603 #   if (@errors) {
 604 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 605 #     $self->js->show('#dialog_flash_error');
 606 #   }
 607
 608   $self->js->render;
 609 }
 610
 611 sub _load_order {
 612   my ($self) = @_;
 613
 614   return if !$::form->{id};
 615
 616   $self->order(SL::DB::Manager::Order->find_by(id => $::form->{id}));
 617 }
 618
 619 sub _make_order {
 620   my ($self) = @_;
 621
 622   # add_items adds items to an order with no items for saving, but they cannot
 623   # be retrieved via items until the order is saved. Adding empty items to new
 624   # order here solves this problem.
 625   my $order;
 626   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 627   $order ||= SL::DB::Order->new(orderitems => []);
 628
 629   my $form_orderitems = delete $::form->{order}->{orderitems};
 630   $order->assign_attributes(%{$::form->{order}});
 631
 632   # remove deleted items
 633   $self->item_ids_to_delete([]);
 634   foreach my $idx (reverse 0..$#{$order->orderitems}) {
 635     my $item = $order->orderitems->[$idx];
 636     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
 637       splice @{$order->orderitems}, $idx, 1;
 638       push @{$self->item_ids_to_delete}, $item->id;
 639     }
 640   }
 641
 642   my @items;
 643   my $pos = 1;
 644   foreach my $form_attr (@{$form_orderitems}) {
 645     my $item = _make_item($order, $form_attr);
 646     $item->position($pos);
 647     push @items, $item;
 648     $pos++;
 649   }
 650   $order->add_items(grep {!$_->id} @items);
 651
 652   return $order;
 653 }
 654
 655
 656 # Make item objects from form values. For items already existing read from db.
 657 # Create a new item else. And assign attributes.
 658 sub _make_item {
 659   my ($record, $attr) = @_;
 660
 661   my $item;
 662   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
 663
 664   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 665   # they cannot be retrieved via custom_variables until the order/orderitem is
 666   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 667   $item ||= SL::DB::OrderItem->new(custom_variables => []);
 668   $item->assign_attributes(%$attr);
 669
 670   return $item;
 671 }
 672
 673 sub _new_item {
 674   my ($record, $attr) = @_;
 675
 676   my $item = SL::DB::OrderItem->new;
 677   $item->assign_attributes(%$attr);
 678
 679   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 680   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 681
 682   $item->unit($part->unit) if !$item->unit;
 683
 684   my $price_src;
 685   if ($item->sellprice) {
 686     $price_src = $price_source->price_from_source("");
 687     $price_src->price($item->sellprice);
 688   } else {
 689     $price_src = $price_source->best_price
 690            ? $price_source->best_price
 691            : $price_source->price_from_source("");
 692     $price_src->price(0) if !$price_source->best_price;
 693   }
 694
 695   my $discount_src;
 696   if ($item->discount) {
 697     $discount_src = $price_source->discount_from_source("");
 698     $discount_src->discount($item->discount);
 699   } else {
 700     $discount_src = $price_source->best_discount
 701                   ? $price_source->best_discount
 702                   : $price_source->discount_from_source("");
 703     $discount_src->discount(0) if !$price_source->best_discount;
 704   }
 705
 706   my %new_attr;
 707   $new_attr{part}                   = $part;
 708   $new_attr{description}            = $part->description if ! $item->description;
 709   $new_attr{qty}                    = 1.0                if ! $item->qty;
 710   $new_attr{sellprice}              = $price_src->price;
 711   $new_attr{discount}               = $discount_src->discount;
 712   $new_attr{active_price_source}    = $price_src;
 713   $new_attr{active_discount_source} = $discount_src;
 714
 715   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 716   # they cannot be retrieved via custom_variables until the order/orderitem is
 717   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 718   $new_attr{custom_variables} = [];
 719
 720   $item->assign_attributes(%new_attr);
 721
 722   return $item;
 723 }
 724
 725 sub _recalc {
 726   my ($self) = @_;
 727
 728   # bb: todo: currency later
 729   $self->order->currency_id($::instance_conf->get_currency_id());
 730
 731   my %pat = $self->order->calculate_prices_and_taxes();
 732   $self->{taxes} = [];
 733   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 734     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 735
 736     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 737     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 738                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 739                                 tax       => $tax });
 740   }
 741
 742   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 743 }
 744
 745
 746 sub _get_unalterable_data {
 747   my ($self) = @_;
 748
 749   foreach my $item (@{ $self->order->items }) {
 750     if ($item->id) {
 751       # load data from orderitems (db)
 752       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 753       $item->$_($db_item->$_) for qw(longdescription);
 754     } else {
 755       # set data from part (or other sources)
 756       $item->longdescription($item->part->notes);
 757     }
 758
 759     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 760     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 761     foreach my $var (@{ $item->cvars_by_config }) {
 762       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 763     }
 764     $item->parse_custom_variable_values;
 765   }
 766 }
 767
 768
 769 sub _delete {
 770   my ($self) = @_;
 771
 772   my $errors = [];
 773   my $db = $self->order->db;
 774
 775   $db->do_transaction(
 776     sub {
 777       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 778       $self->order->delete;
 779       my $spool = $::lx_office_conf{paths}->{spool};
 780       unlink map { "$spool/$_" } @spoolfiles if $spool;
 781
 782       1;
 783   }) || push(@{$errors}, $db->error);
 784
 785   return $errors;
 786 }
 787
 788
 789 sub _save {
 790   my ($self) = @_;
 791
 792   my $errors = [];
 793   my $db = $self->order->db;
 794
 795   $db->do_transaction(
 796     sub {
 797       SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete};
 798       $self->order->save(cascade => 1);
 799   }) || push(@{$errors}, $db->error);
 800
 801   return $errors;
 802 }
 803
 804
 805 sub _pre_render {
 806   my ($self) = @_;
 807
 808   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 809   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 810   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 811                                                                                        deleted => 0 ] ],
 812                                                                     sort_by => 'name');
 813   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 814                                                                                        deleted => 0 ] ],
 815                                                                     sort_by => 'name');
 816   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 817                                                                                       active => 1 ] ],
 818                                                                    sort_by => 'projectnumber');
 819   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 820   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 821
 822   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 823
 824   foreach my $item (@{$self->order->orderitems}) {
 825     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 826     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 827     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 828   }
 829
 830   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 831     my $webdav = SL::Webdav->new(
 832       type     => $self->type,
 833       number   => $self->order->ordnumber,
 834     );
 835     my $webdav_path = $webdav->webdav_path;
 836     my @all_objects = $webdav->get_all_objects;
 837     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 838                                                     type => t8('File'),
 839                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 840                                                 } } @all_objects;
 841   }
 842
 843   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 844 }
 845
 846 sub _create_pdf {
 847   my ($order, $pdf_ref, $params) = @_;
 848
 849   my $print_form = Form->new('');
 850   $print_form->{type}     = $order->type;
 851   $print_form->{formname} = $order->type;
 852   $print_form->{format}   = $params->{format} || 'pdf',
 853   $print_form->{media}    = $params->{media}  || 'file';
 854
 855   $order->flatten_to_form($print_form, format_amounts => 1);
 856   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 857   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 858
 859   my @errors = ();
 860   $print_form->throw_on_error(sub {
 861     eval {
 862       $print_form->prepare_for_printing;
 863
 864       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 865         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 866         variables => $print_form,
 867         variable_content_types => {
 868           longdescription => 'html',
 869           partnotes       => 'html',
 870           notes           => 'html',
 871         },
 872       );
 873       1;
 874     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 875   });
 876
 877   return @errors;
 878 }
 879
 880 sub _sales_order_type {
 881   'sales_order';
 882 }
 883
 884 sub _purchase_order_type {
 885   'purchase_order';
 886 }
 887
 888 1;