SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::AdditionalBillingAddress;
  17 use SL::DB::AuthUser;
  18 use SL::DB::History;
  19 use SL::DB::Order;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22 use SL::DB::Part;
  23 use SL::DB::PartClassification;
  24 use SL::DB::PartsGroup;
  25 use SL::DB::Printer;
  26 use SL::DB::Language;
  27 use SL::DB::RecordLink;
  28 use SL::DB::RequirementSpec;
  29 use SL::DB::Shipto;
  30 use SL::DB::Translation;
  31
  32 use SL::Helper::CreatePDF qw(:all);
  33 use SL::Helper::PrintOptions;
  34 use SL::Helper::ShippedQty;
  35 use SL::Helper::UserPreferences::PositionsScrollbar;
  36 use SL::Helper::UserPreferences::UpdatePositions;
  37
  38 use SL::Controller::Helper::GetModels;
  39
  40 use List::Util qw(first sum0);
  41 use List::UtilsBy qw(sort_by uniq_by);
  42 use List::MoreUtils qw(any none pairwise first_index);
  43 use English qw(-no_match_vars);
  44 use File::Spec;
  45 use Cwd;
  46 use Sort::Naturally;
  47
  48 use Rose::Object::MakeMethods::Generic
  49 (
  50  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  51  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  52 );
  53
  54
  55 # safety
  56 __PACKAGE__->run_before('check_auth');
  57
  58 __PACKAGE__->run_before('recalc',
  59                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  60                                      print send_email) ]);
  61
  62 __PACKAGE__->run_before('get_unalterable_data',
  63                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  64                                      print send_email) ]);
  65
  66 #
  67 # actions
  68 #
  69
  70 # add a new order
  71 sub action_add {
  72   my ($self) = @_;
  73
  74   $self->order->transdate(DateTime->now_local());
  75   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  76                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  77
  78   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  79       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  80       && (!$self->order->reqdate)) {
  81     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  82   }
  83
  84
  85   $self->pre_render();
  86   $self->render(
  87     'order/form',
  88     title => $self->get_title_for('add'),
  89     %{$self->{template_args}}
  90   );
  91 }
  92
  93 # edit an existing order
  94 sub action_edit {
  95   my ($self) = @_;
  96
  97   if ($::form->{id}) {
  98     $self->load_order;
  99
 100   } else {
 101     # this is to edit an order from an unsaved order object
 102
 103     # set item ids to new fake id, to identify them as new items
 104     foreach my $item (@{$self->order->items_sorted}) {
 105       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 106     }
 107     # trigger rendering values for second row as hidden, because they
 108     # are loaded only on demand. So we need to keep the values from
 109     # the source.
 110     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 111   }
 112
 113   $self->recalc();
 114   $self->pre_render();
 115   $self->render(
 116     'order/form',
 117     title => $self->get_title_for('edit'),
 118     %{$self->{template_args}}
 119   );
 120 }
 121
 122 # edit a collective order (consisting of one or more existing orders)
 123 sub action_edit_collective {
 124   my ($self) = @_;
 125
 126   # collect order ids
 127   my @multi_ids = map {
 128     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 129   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 130
 131   # fall back to add if no ids are given
 132   if (scalar @multi_ids == 0) {
 133     $self->action_add();
 134     return;
 135   }
 136
 137   # fall back to save as new if only one id is given
 138   if (scalar @multi_ids == 1) {
 139     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 140     $self->action_save_as_new();
 141     return;
 142   }
 143
 144   # make new order from given orders
 145   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 146   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 147   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 148
 149   $self->action_edit();
 150 }
 151
 152 # delete the order
 153 sub action_delete {
 154   my ($self) = @_;
 155
 156   my $errors = $self->delete();
 157
 158   if (scalar @{ $errors }) {
 159     $self->js->flash('error', $_) foreach @{ $errors };
 160     return $self->js->render();
 161   }
 162
 163   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 164            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 165            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 166            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 167            : '';
 168   flash_later('info', $text);
 169
 170   my @redirect_params = (
 171     action => 'add',
 172     type   => $self->type,
 173   );
 174
 175   $self->redirect_to(@redirect_params);
 176 }
 177
 178 # save the order
 179 sub action_save {
 180   my ($self) = @_;
 181
 182   my $errors = $self->save();
 183
 184   if (scalar @{ $errors }) {
 185     $self->js->flash('error', $_) foreach @{ $errors };
 186     return $self->js->render();
 187   }
 188
 189   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 190            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 191            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 192            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 193            : '';
 194   flash_later('info', $text);
 195
 196   my @redirect_params = (
 197     action => 'edit',
 198     type   => $self->type,
 199     id     => $self->order->id,
 200   );
 201
 202   $self->redirect_to(@redirect_params);
 203 }
 204
 205 # save the order as new document an open it for edit
 206 sub action_save_as_new {
 207   my ($self) = @_;
 208
 209   my $order = $self->order;
 210
 211   if (!$order->id) {
 212     $self->js->flash('error', t8('This object has not been saved yet.'));
 213     return $self->js->render();
 214   }
 215
 216   # load order from db to check if values changed
 217   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 218
 219   my %new_attrs;
 220   # Lets assign a new number if the user hasn't changed the previous one.
 221   # If it has been changed manually then use it as-is.
 222   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 223                         ? ''
 224                         : trim($order->number);
 225
 226   # Clear transdate unless changed
 227   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 228                         ? DateTime->today_local
 229                         : $order->transdate;
 230
 231   # Set new reqdate unless changed if it is enabled in client config
 232   if ($order->reqdate == $saved_order->reqdate) {
 233     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 234                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 235
 236     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 237         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 238       $new_attrs{reqdate} = '';
 239     } else {
 240       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 241     }
 242   } else {
 243     $new_attrs{reqdate} = $order->reqdate;
 244   }
 245
 246   # Update employee
 247   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 248
 249   # Create new record from current one
 250   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 251
 252   # no linked records on save as new
 253   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 254
 255   # save
 256   $self->action_save();
 257 }
 258
 259 # print the order
 260 #
 261 # This is called if "print" is pressed in the print dialog.
 262 # If PDF creation was requested and succeeded, the pdf is offered for download
 263 # via send_file (which uses ajax in this case).
 264 sub action_print {
 265   my ($self) = @_;
 266
 267   my $errors = $self->save();
 268
 269   if (scalar @{ $errors }) {
 270     $self->js->flash('error', $_) foreach @{ $errors };
 271     return $self->js->render();
 272   }
 273
 274   $self->js_reset_order_and_item_ids_after_save;
 275
 276   my $format      = $::form->{print_options}->{format};
 277   my $media       = $::form->{print_options}->{media};
 278   my $formname    = $::form->{print_options}->{formname};
 279   my $copies      = $::form->{print_options}->{copies};
 280   my $groupitems  = $::form->{print_options}->{groupitems};
 281   my $printer_id  = $::form->{print_options}->{printer_id};
 282
 283   # only PDF, OpenDocument & HTML for now
 284   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf html)) {
 285     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 286   }
 287
 288   # only screen or printer by now
 289   if (none { $media eq $_ } qw(screen printer)) {
 290     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 291   }
 292
 293   # create a form for generate_attachment_filename
 294   my $form   = Form->new;
 295   $form->{$self->nr_key()}  = $self->order->number;
 296   $form->{type}             = $self->type;
 297   $form->{format}           = $format;
 298   $form->{formname}         = $formname;
 299   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 300   my $doc_filename          = $form->generate_attachment_filename();
 301
 302   my $doc;
 303   my @errors = $self->generate_doc(\$doc, { format     => $format,
 304                                             formname   => $formname,
 305                                             language   => $self->order->language,
 306                                             printer_id => $printer_id,
 307                                             groupitems => $groupitems });
 308   if (scalar @errors) {
 309     return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render;
 310   }
 311
 312   if ($media eq 'screen') {
 313     # screen/download
 314     $self->js->flash('info', t8('The document has been created.'));
 315     $self->send_file(
 316       \$doc,
 317       type         => SL::MIME->mime_type_from_ext($doc_filename),
 318       name         => $doc_filename,
 319       js_no_render => 1,
 320     );
 321
 322   } elsif ($media eq 'printer') {
 323     # printer
 324     my $printer_id = $::form->{print_options}->{printer_id};
 325     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 326       copies  => $copies,
 327       content => $doc,
 328     );
 329
 330     $self->js->flash('info', t8('The document has been printed.'));
 331   }
 332
 333   my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $doc_filename, $formname);
 334   if (scalar @warnings) {
 335     $self->js->flash('warning', $_) for @warnings;
 336   }
 337
 338   $self->save_history('PRINTED');
 339
 340   $self->js
 341     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 342     ->render;
 343 }
 344 sub action_preview_pdf {
 345   my ($self) = @_;
 346
 347   my $errors = $self->save();
 348   if (scalar @{ $errors }) {
 349     $self->js->flash('error', $_) foreach @{ $errors };
 350     return $self->js->render();
 351   }
 352
 353   $self->js_reset_order_and_item_ids_after_save;
 354
 355   my $format      = 'pdf';
 356   my $media       = 'screen';
 357   my $formname    = $self->type;
 358
 359   # only pdf
 360   # create a form for generate_attachment_filename
 361   my $form   = Form->new;
 362   $form->{$self->nr_key()}  = $self->order->number;
 363   $form->{type}             = $self->type;
 364   $form->{format}           = $format;
 365   $form->{formname}         = $formname;
 366   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 367   my $pdf_filename          = $form->generate_attachment_filename();
 368
 369   my $pdf;
 370   my @errors = $self->generate_doc(\$pdf, { format     => $format,
 371                                             formname   => $formname,
 372                                             language   => $self->order->language,
 373                                           });
 374   if (scalar @errors) {
 375     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 376   }
 377   $self->save_history('PREVIEWED');
 378   $self->js->flash('info', t8('The PDF has been previewed'));
 379   # screen/download
 380   $self->send_file(
 381     \$pdf,
 382     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 383     name         => $pdf_filename,
 384     js_no_render => 0,
 385   );
 386 }
 387
 388 # open the email dialog
 389 sub action_save_and_show_email_dialog {
 390   my ($self) = @_;
 391
 392   my $errors = $self->save();
 393
 394   if (scalar @{ $errors }) {
 395     $self->js->flash('error', $_) foreach @{ $errors };
 396     return $self->js->render();
 397   }
 398
 399   my $cv_method = $self->cv;
 400
 401   if (!$self->order->$cv_method) {
 402     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 403                     ->render($self);
 404   }
 405
 406   my $email_form;
 407   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 408   $email_form->{to} ||= $self->order->$cv_method->email;
 409   $email_form->{cc}   = $self->order->$cv_method->cc;
 410   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 411   # Todo: get addresses from shipto, if any
 412
 413   my $form = Form->new;
 414   $form->{$self->nr_key()}  = $self->order->number;
 415   $form->{cusordnumber}     = $self->order->cusordnumber;
 416   $form->{formname}         = $self->type;
 417   $form->{type}             = $self->type;
 418   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 419   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 420   $form->{format}           = 'pdf';
 421   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 422
 423   $email_form->{subject}             = $form->generate_email_subject();
 424   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 425   $email_form->{message}             = $form->generate_email_body();
 426   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 427
 428   my %files = $self->get_files_for_email_dialog();
 429
 430   my @employees_with_email = grep {
 431     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 432     $user && !!trim($user->get_config_value('email'));
 433   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 434
 435   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 436                                   email_form    => $email_form,
 437                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 438                                   FILES         => \%files,
 439                                   is_customer   => $self->cv eq 'customer',
 440                                   ALL_EMPLOYEES => \@employees_with_email,
 441   );
 442
 443   $self->js
 444       ->run('kivi.Order.show_email_dialog', $dialog_html)
 445       ->reinit_widgets
 446       ->render($self);
 447 }
 448
 449 # send email
 450 #
 451 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 452 sub action_send_email {
 453   my ($self) = @_;
 454
 455   my $errors = $self->save();
 456
 457   if (scalar @{ $errors }) {
 458     $self->js->run('kivi.Order.close_email_dialog');
 459     $self->js->flash('error', $_) foreach @{ $errors };
 460     return $self->js->render();
 461   }
 462
 463   $self->js_reset_order_and_item_ids_after_save;
 464
 465   my $email_form  = delete $::form->{email_form};
 466   my %field_names = (to => 'email');
 467
 468   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 469
 470   # for Form::cleanup which may be called in Form::send_email
 471   $::form->{cwd}    = getcwd();
 472   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 473
 474   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 475   $::form->{media}  = 'email';
 476
 477   $::form->{attachment_policy} //= '';
 478
 479   # Is an old file version available?
 480   my $attfile;
 481   if ($::form->{attachment_policy} eq 'old_file') {
 482     $attfile = SL::File->get_all(object_id     => $self->order->id,
 483                                  object_type   => $self->type,
 484                                  file_type     => 'document',
 485                                  print_variant => $::form->{formname});
 486   }
 487
 488   if ($::form->{attachment_policy} ne 'no_file' && !($::form->{attachment_policy} eq 'old_file' && $attfile)) {
 489     my $doc;
 490     my @errors = $self->generate_doc(\$doc, {media      => $::form->{media},
 491                                              format     => $::form->{print_options}->{format},
 492                                              formname   => $::form->{print_options}->{formname},
 493                                              language   => $self->order->language,
 494                                              printer_id => $::form->{print_options}->{printer_id},
 495                                              groupitems => $::form->{print_options}->{groupitems}});
 496     if (scalar @errors) {
 497       return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render($self);
 498     }
 499
 500     my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $::form->{attachment_filename}, $::form->{formname});
 501     if (scalar @warnings) {
 502       flash_later('warning', $_) for @warnings;
 503     }
 504
 505     my $sfile = SL::SessionFile::Random->new(mode => "w");
 506     $sfile->fh->print($doc);
 507     $sfile->fh->close;
 508
 509     $::form->{tmpfile} = $sfile->file_name;
 510     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 511   }
 512
 513   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 514   $::form->send_email(\%::myconfig, $::form->{print_options}->{format});
 515
 516   # internal notes
 517   my $intnotes = $self->order->intnotes;
 518   $intnotes   .= "\n\n" if $self->order->intnotes;
 519   $intnotes   .= t8('[email]')                                                                                        . "\n";
 520   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 521   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 522   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 523   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 524   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 525   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 526
 527   $self->order->update_attributes(intnotes => $intnotes);
 528
 529   $self->save_history('MAILED');
 530
 531   flash_later('info', t8('The email has been sent.'));
 532
 533   my @redirect_params = (
 534     action => 'edit',
 535     type   => $self->type,
 536     id     => $self->order->id,
 537   );
 538
 539   $self->redirect_to(@redirect_params);
 540 }
 541
 542 # open the periodic invoices config dialog
 543 #
 544 # If there are values in the form (i.e. dialog was opened before),
 545 # then use this values. Create new ones, else.
 546 sub action_show_periodic_invoices_config_dialog {
 547   my ($self) = @_;
 548
 549   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 550   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 551   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 552                                                    order_value_periodicity => 'p', # = same as periodicity
 553                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 554                                                    extend_automatically_by => 12,
 555                                                    active                  => 1,
 556                                                    email_subject           => GenericTranslations->get(
 557                                                                                 language_id      => $::form->{language_id},
 558                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 559                                                    email_body              => GenericTranslations->get(
 560                                                                                 language_id      => $::form->{language_id},
 561                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 562   );
 563   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 564   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 565
 566   $::form->get_lists(printers => "ALL_PRINTERS",
 567                      charts   => { key       => 'ALL_CHARTS',
 568                                    transdate => 'current_date' });
 569
 570   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 571
 572   if ($::form->{customer_id}) {
 573     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 574     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 575     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 576     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 577     $config->send_email(0) if $::form->{postal_invoice};
 578   }
 579
 580   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 581                 popup_dialog             => 1,
 582                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 583                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 584                 config                   => $config,
 585                 %$::form);
 586 }
 587
 588 # assign the values of the periodic invoices config dialog
 589 # as yaml in the hidden tag and set the status.
 590 sub action_assign_periodic_invoices_config {
 591   my ($self) = @_;
 592
 593   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 594
 595   my $config = { active                     => $::form->{active}       ? 1 : 0,
 596                  terminated                 => $::form->{terminated}   ? 1 : 0,
 597                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 598                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 599                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 600                  start_date_as_date         => $::form->{start_date_as_date},
 601                  end_date_as_date           => $::form->{end_date_as_date},
 602                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 603                  print                      => $::form->{print}      ? 1                         : 0,
 604                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 605                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 606                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 607                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 608                  send_email                 => $::form->{send_email} ? 1 : 0,
 609                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 610                  email_recipient_address    => $::form->{email_recipient_address},
 611                  email_sender               => $::form->{email_sender},
 612                  email_subject              => $::form->{email_subject},
 613                  email_body                 => $::form->{email_body},
 614                };
 615
 616   my $periodic_invoices_config = SL::YAML::Dump($config);
 617
 618   my $status = $self->get_periodic_invoices_status($config);
 619
 620   $self->js
 621     ->remove('#order_periodic_invoices_config')
 622     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 623     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 624     ->html('#periodic_invoices_status', $status)
 625     ->flash('info', t8('The periodic invoices config has been assigned.'))
 626     ->render($self);
 627 }
 628
 629 sub action_get_has_active_periodic_invoices {
 630   my ($self) = @_;
 631
 632   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 633   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 634
 635   my $has_active_periodic_invoices =
 636        $self->type eq sales_order_type()
 637     && $config
 638     && $config->active
 639     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 640     && $config->get_previous_billed_period_start_date;
 641
 642   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 643 }
 644
 645 # save the order and redirect to the frontend subroutine for a new
 646 # delivery order
 647 sub action_save_and_delivery_order {
 648   my ($self) = @_;
 649
 650   $self->save_and_redirect_to(
 651     controller => 'oe.pl',
 652     action     => 'oe_delivery_order_from_order',
 653   );
 654 }
 655
 656 # save the order and redirect to the frontend subroutine for a new
 657 # invoice
 658 sub action_save_and_invoice {
 659   my ($self) = @_;
 660
 661   $self->save_and_redirect_to(
 662     controller => 'oe.pl',
 663     action     => 'oe_invoice_from_order',
 664   );
 665 }
 666
 667 # workflow from sales order to sales quotation
 668 sub action_sales_quotation {
 669   $_[0]->workflow_sales_or_request_for_quotation();
 670 }
 671
 672 # workflow from sales order to sales quotation
 673 sub action_request_for_quotation {
 674   $_[0]->workflow_sales_or_request_for_quotation();
 675 }
 676
 677 # workflow from sales quotation to sales order
 678 sub action_sales_order {
 679   $_[0]->workflow_sales_or_purchase_order();
 680 }
 681
 682 # workflow from rfq to purchase order
 683 sub action_purchase_order {
 684   $_[0]->workflow_sales_or_purchase_order();
 685 }
 686
 687 # workflow from purchase order to ap transaction
 688 sub action_save_and_ap_transaction {
 689   my ($self) = @_;
 690
 691   $self->save_and_redirect_to(
 692     controller => 'ap.pl',
 693     action     => 'add_from_purchase_order',
 694   );
 695 }
 696
 697 # set form elements in respect to a changed customer or vendor
 698 #
 699 # This action is called on an change of the customer/vendor picker.
 700 sub action_customer_vendor_changed {
 701   my ($self) = @_;
 702
 703   setup_order_from_cv($self->order);
 704   $self->recalc();
 705
 706   my $cv_method = $self->cv;
 707
 708   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 709     $self->js->show('#cp_row');
 710   } else {
 711     $self->js->hide('#cp_row');
 712   }
 713
 714   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 715     $self->js->show('#shipto_selection');
 716   } else {
 717     $self->js->hide('#shipto_selection');
 718   }
 719
 720   if ($cv_method eq 'customer') {
 721     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 722     $self->js->$show_hide('#billing_address_row');
 723   }
 724
 725   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 726
 727   $self->js
 728     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 729     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 730     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 731     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 732     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 733     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 734     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 735     ->val(        '#order_currency_id',        $self->order->currency_id)
 736     ->val(        '#order_payment_id',         $self->order->payment_id)
 737     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 738     ->val(        '#order_intnotes',           $self->order->intnotes)
 739     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 740     ->focus(      '#order_' . $self->cv . '_id')
 741     ->run('kivi.Order.update_exchangerate');
 742
 743   $self->js_redisplay_amounts_and_taxes;
 744   $self->js_redisplay_cvpartnumbers;
 745   $self->js->render();
 746 }
 747
 748 # open the dialog for customer/vendor details
 749 sub action_show_customer_vendor_details_dialog {
 750   my ($self) = @_;
 751
 752   my $is_customer = 'customer' eq $::form->{vc};
 753   my $cv;
 754   if ($is_customer) {
 755     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 756   } else {
 757     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 758   }
 759
 760   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 761   $details{discount_as_percent} = $cv->discount_as_percent;
 762   $details{creditlimt}          = $cv->creditlimit_as_number;
 763   $details{business}            = $cv->business->description      if $cv->business;
 764   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 765   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 766   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 767   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 768
 769   if ($is_customer) {
 770     foreach my $entry (@{ $cv->additional_billing_addresses }) {
 771       push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 772     }
 773   }
 774   foreach my $entry (@{ $cv->shipto }) {
 775     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 776   }
 777   foreach my $entry (@{ $cv->contacts }) {
 778     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 779   }
 780
 781   $_[0]->render('common/show_vc_details', { layout => 0 },
 782                 is_customer => $is_customer,
 783                 %details);
 784
 785 }
 786
 787 # called if a unit in an existing item row is changed
 788 sub action_unit_changed {
 789   my ($self) = @_;
 790
 791   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 792   my $item = $self->order->items_sorted->[$idx];
 793
 794   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 795   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 796
 797   $self->recalc();
 798
 799   $self->js
 800     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 801   $self->js_redisplay_line_values;
 802   $self->js_redisplay_amounts_and_taxes;
 803   $self->js->render();
 804 }
 805
 806 # add an item row for a new item entered in the input row
 807 sub action_add_item {
 808   my ($self) = @_;
 809
 810   delete $::form->{add_item}->{create_part_type};
 811
 812   my $form_attr = $::form->{add_item};
 813
 814   return unless $form_attr->{parts_id};
 815
 816   my $item = new_item($self->order, $form_attr);
 817
 818   $self->order->add_items($item);
 819
 820   $self->recalc();
 821
 822   $self->get_item_cvpartnumber($item);
 823
 824   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 825   my $row_as_html = $self->p->render('order/tabs/_row',
 826                                      ITEM => $item,
 827                                      ID   => $item_id,
 828                                      SELF => $self,
 829   );
 830
 831   if ($::form->{insert_before_item_id}) {
 832     $self->js
 833       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 834   } else {
 835     $self->js
 836       ->append('#row_table_id', $row_as_html);
 837   }
 838
 839   if ( $item->part->is_assortment ) {
 840     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 841     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 842       my $attr = { parts_id => $assortment_item->parts_id,
 843                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 844                    unit     => $assortment_item->unit,
 845                    description => $assortment_item->part->description,
 846                  };
 847       my $item = new_item($self->order, $attr);
 848
 849       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 850       $item->discount(1) unless $assortment_item->charge;
 851
 852       $self->order->add_items( $item );
 853       $self->recalc();
 854       $self->get_item_cvpartnumber($item);
 855       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 856       my $row_as_html = $self->p->render('order/tabs/_row',
 857                                          ITEM => $item,
 858                                          ID   => $item_id,
 859                                          SELF => $self,
 860       );
 861       if ($::form->{insert_before_item_id}) {
 862         $self->js
 863           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 864       } else {
 865         $self->js
 866           ->append('#row_table_id', $row_as_html);
 867       }
 868     };
 869   };
 870
 871   $self->js
 872     ->val('.add_item_input', '')
 873     ->run('kivi.Order.init_row_handlers')
 874     ->run('kivi.Order.renumber_positions')
 875     ->focus('#add_item_parts_id_name');
 876
 877   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 878
 879   $self->js_redisplay_amounts_and_taxes;
 880   $self->js->render();
 881 }
 882
 883 # add item rows for multiple items at once
 884 sub action_add_multi_items {
 885   my ($self) = @_;
 886
 887   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 888   return $self->js->render() unless scalar @form_attr;
 889
 890   my @items;
 891   foreach my $attr (@form_attr) {
 892     my $item = new_item($self->order, $attr);
 893     push @items, $item;
 894     if ( $item->part->is_assortment ) {
 895       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 896         my $attr = { parts_id => $assortment_item->parts_id,
 897                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 898                      unit     => $assortment_item->unit,
 899                      description => $assortment_item->part->description,
 900                    };
 901         my $item = new_item($self->order, $attr);
 902
 903         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 904         $item->discount(1) unless $assortment_item->charge;
 905         push @items, $item;
 906       }
 907     }
 908   }
 909   $self->order->add_items(@items);
 910
 911   $self->recalc();
 912
 913   foreach my $item (@items) {
 914     $self->get_item_cvpartnumber($item);
 915     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 916     my $row_as_html = $self->p->render('order/tabs/_row',
 917                                        ITEM => $item,
 918                                        ID   => $item_id,
 919                                        SELF => $self,
 920     );
 921
 922     if ($::form->{insert_before_item_id}) {
 923       $self->js
 924         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 925     } else {
 926       $self->js
 927         ->append('#row_table_id', $row_as_html);
 928     }
 929   }
 930
 931   $self->js
 932     ->run('kivi.Part.close_picker_dialogs')
 933     ->run('kivi.Order.init_row_handlers')
 934     ->run('kivi.Order.renumber_positions')
 935     ->focus('#add_item_parts_id_name');
 936
 937   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 938
 939   $self->js_redisplay_amounts_and_taxes;
 940   $self->js->render();
 941 }
 942
 943 # recalculate all linetotals, amounts and taxes and redisplay them
 944 sub action_recalc_amounts_and_taxes {
 945   my ($self) = @_;
 946
 947   $self->recalc();
 948
 949   $self->js_redisplay_line_values;
 950   $self->js_redisplay_amounts_and_taxes;
 951   $self->js->render();
 952 }
 953
 954 sub action_update_exchangerate {
 955   my ($self) = @_;
 956
 957   my $data = {
 958     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 959     currency_name => $self->order->currency->name,
 960     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 961   };
 962
 963   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 964 }
 965
 966 # redisplay item rows if they are sorted by an attribute
 967 sub action_reorder_items {
 968   my ($self) = @_;
 969
 970   my %sort_keys = (
 971     partnumber   => sub { $_[0]->part->partnumber },
 972     description  => sub { $_[0]->description },
 973     qty          => sub { $_[0]->qty },
 974     sellprice    => sub { $_[0]->sellprice },
 975     discount     => sub { $_[0]->discount },
 976     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 977   );
 978
 979   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 980
 981   my $method = $sort_keys{$::form->{order_by}};
 982   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 983   if ($::form->{sort_dir}) {
 984     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 985       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 986     } else {
 987       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 988     }
 989   } else {
 990     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 991       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 992     } else {
 993       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 994     }
 995   }
 996   $self->js
 997     ->run('kivi.Order.redisplay_items', \@to_sort)
 998     ->render;
 999 }
1000
1001 # show the popup to choose a price/discount source
1002 sub action_price_popup {
1003   my ($self) = @_;
1004
1005   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
1006   my $item = $self->order->items_sorted->[$idx];
1007
1008   $self->render_price_dialog($item);
1009 }
1010
1011 # save the order in a session variable and redirect to the part controller
1012 sub action_create_part {
1013   my ($self) = @_;
1014
1015   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1016
1017   my $callback     = $self->url_for(
1018     action       => 'return_from_create_part',
1019     type         => $self->type, # type is needed for check_auth on return
1020     previousform => $previousform,
1021   );
1022
1023   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1024
1025   my @redirect_params = (
1026     controller => 'Part',
1027     action     => 'add',
1028     part_type  => $::form->{add_item}->{create_part_type},
1029     callback   => $callback,
1030     show_abort => 1,
1031   );
1032
1033   $self->redirect_to(@redirect_params);
1034 }
1035
1036 sub action_return_from_create_part {
1037   my ($self) = @_;
1038
1039   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1040
1041   $::auth->restore_form_from_session(delete $::form->{previousform});
1042
1043   # set item ids to new fake id, to identify them as new items
1044   foreach my $item (@{$self->order->items_sorted}) {
1045     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1046   }
1047
1048   $self->recalc();
1049   $self->get_unalterable_data();
1050   $self->pre_render();
1051
1052   # trigger rendering values for second row/longdescription as hidden,
1053   # because they are loaded only on demand. So we need to keep the values
1054   # from the source.
1055   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1056   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1057
1058   $self->render(
1059     'order/form',
1060     title => $self->get_title_for('edit'),
1061     %{$self->{template_args}}
1062   );
1063
1064 }
1065
1066 # load the second row for one or more items
1067 #
1068 # This action gets the html code for all items second rows by rendering a template for
1069 # the second row and sets the html code via client js.
1070 sub action_load_second_rows {
1071   my ($self) = @_;
1072
1073   $self->recalc() if $self->order->is_sales; # for margin calculation
1074
1075   foreach my $item_id (@{ $::form->{item_ids} }) {
1076     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1077     my $item = $self->order->items_sorted->[$idx];
1078
1079     $self->js_load_second_row($item, $item_id, 0);
1080   }
1081
1082   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1083
1084   $self->js->render();
1085 }
1086
1087 # update description, notes and sellprice from master data
1088 sub action_update_row_from_master_data {
1089   my ($self) = @_;
1090
1091   foreach my $item_id (@{ $::form->{item_ids} }) {
1092     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1093     my $item  = $self->order->items_sorted->[$idx];
1094     my $texts = get_part_texts($item->part, $self->order->language_id);
1095
1096     $item->description($texts->{description});
1097     $item->longdescription($texts->{longdescription});
1098
1099     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1100
1101     my $price_src;
1102     if ($item->part->is_assortment) {
1103     # add assortment items with price 0, as the components carry the price
1104       $price_src = $price_source->price_from_source("");
1105       $price_src->price(0);
1106     } else {
1107       $price_src = $price_source->best_price
1108                  ? $price_source->best_price
1109                  : $price_source->price_from_source("");
1110       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1111       $price_src->price(0) if !$price_source->best_price;
1112     }
1113
1114
1115     $item->sellprice($price_src->price);
1116     $item->active_price_source($price_src);
1117
1118     $self->js
1119       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1120       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1121       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1122       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1123
1124     if ($self->search_cvpartnumber) {
1125       $self->get_item_cvpartnumber($item);
1126       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1127     }
1128   }
1129
1130   $self->recalc();
1131   $self->js_redisplay_line_values;
1132   $self->js_redisplay_amounts_and_taxes;
1133
1134   $self->js->render();
1135 }
1136
1137 sub js_load_second_row {
1138   my ($self, $item, $item_id, $do_parse) = @_;
1139
1140   if ($do_parse) {
1141     # Parse values from form (they are formated while rendering (template)).
1142     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1143     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1144     foreach my $var (@{ $item->cvars_by_config }) {
1145       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1146     }
1147     $item->parse_custom_variable_values;
1148   }
1149
1150   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1151
1152   $self->js
1153     ->html('#second_row_' . $item_id, $row_as_html)
1154     ->data('#second_row_' . $item_id, 'loaded', 1);
1155 }
1156
1157 sub js_redisplay_line_values {
1158   my ($self) = @_;
1159
1160   my $is_sales = $self->order->is_sales;
1161
1162   # sales orders with margins
1163   my @data;
1164   if ($is_sales) {
1165     @data = map {
1166       [
1167        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1168        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1169        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1170       ]} @{ $self->order->items_sorted };
1171   } else {
1172     @data = map {
1173       [
1174        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1175       ]} @{ $self->order->items_sorted };
1176   }
1177
1178   $self->js
1179     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1180 }
1181
1182 sub js_redisplay_amounts_and_taxes {
1183   my ($self) = @_;
1184
1185   if (scalar @{ $self->{taxes} }) {
1186     $self->js->show('#taxincluded_row_id');
1187   } else {
1188     $self->js->hide('#taxincluded_row_id');
1189   }
1190
1191   if ($self->order->taxincluded) {
1192     $self->js->hide('#subtotal_row_id');
1193   } else {
1194     $self->js->show('#subtotal_row_id');
1195   }
1196
1197   if ($self->order->is_sales) {
1198     my $is_neg = $self->order->marge_total < 0;
1199     $self->js
1200       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1201       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1202       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1203       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1204       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1205       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1206       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1207       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1208   }
1209
1210   $self->js
1211     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1212     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1213     ->remove('.tax_row')
1214     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1215 }
1216
1217 sub js_redisplay_cvpartnumbers {
1218   my ($self) = @_;
1219
1220   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1221
1222   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1223
1224   $self->js
1225     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1226 }
1227
1228 sub js_reset_order_and_item_ids_after_save {
1229   my ($self) = @_;
1230
1231   $self->js
1232     ->val('#id', $self->order->id)
1233     ->val('#converted_from_oe_id', '')
1234     ->val('#order_' . $self->nr_key(), $self->order->number);
1235
1236   my $idx = 0;
1237   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1238     next if !$self->order->items_sorted->[$idx]->id;
1239     next if $form_item_id !~ m{^new};
1240     $self->js
1241       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1242       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1243       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1244   } continue {
1245     $idx++;
1246   }
1247   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1248 }
1249
1250 #
1251 # helpers
1252 #
1253
1254 sub init_valid_types {
1255   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1256 }
1257
1258 sub init_type {
1259   my ($self) = @_;
1260
1261   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1262     die "Not a valid type for order";
1263   }
1264
1265   $self->type($::form->{type});
1266 }
1267
1268 sub init_cv {
1269   my ($self) = @_;
1270
1271   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1272          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1273          : die "Not a valid type for order";
1274
1275   return $cv;
1276 }
1277
1278 sub init_search_cvpartnumber {
1279   my ($self) = @_;
1280
1281   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1282   my $search_cvpartnumber;
1283   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1284   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1285
1286   return $search_cvpartnumber;
1287 }
1288
1289 sub init_show_update_button {
1290   my ($self) = @_;
1291
1292   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1293 }
1294
1295 sub init_p {
1296   SL::Presenter->get;
1297 }
1298
1299 sub init_order {
1300   $_[0]->make_order;
1301 }
1302
1303 sub init_all_price_factors {
1304   SL::DB::Manager::PriceFactor->get_all;
1305 }
1306
1307 sub init_part_picker_classification_ids {
1308   my ($self)    = @_;
1309   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1310
1311   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1312 }
1313
1314 sub check_auth {
1315   my ($self) = @_;
1316
1317   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1318
1319   my $right   = $right_for->{ $self->type };
1320   $right    ||= 'DOES_NOT_EXIST';
1321
1322   $::auth->assert($right);
1323 }
1324
1325 # build the selection box for contacts
1326 #
1327 # Needed, if customer/vendor changed.
1328 sub build_contact_select {
1329   my ($self) = @_;
1330
1331   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1332     value_key  => 'cp_id',
1333     title_key  => 'full_name_dep',
1334     default    => $self->order->cp_id,
1335     with_empty => 1,
1336     style      => 'width: 300px',
1337   );
1338 }
1339
1340 # build the selection box for the additional billing address
1341 #
1342 # Needed, if customer/vendor changed.
1343 sub build_billing_address_select {
1344   my ($self) = @_;
1345
1346   return '' if $self->cv ne 'customer';
1347
1348   select_tag('order.billing_address_id',
1349              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1350              value_key  => 'id',
1351              title_key  => 'displayable_id',
1352              default    => $self->order->billing_address_id,
1353              with_empty => 0,
1354              style      => 'width: 300px',
1355   );
1356 }
1357
1358 # build the selection box for shiptos
1359 #
1360 # Needed, if customer/vendor changed.
1361 sub build_shipto_select {
1362   my ($self) = @_;
1363
1364   select_tag('order.shipto_id',
1365              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1366              value_key  => 'shipto_id',
1367              title_key  => 'displayable_id',
1368              default    => $self->order->shipto_id,
1369              with_empty => 0,
1370              style      => 'width: 300px',
1371   );
1372 }
1373
1374 # build the inputs for the cusom shipto dialog
1375 #
1376 # Needed, if customer/vendor changed.
1377 sub build_shipto_inputs {
1378   my ($self) = @_;
1379
1380   my $content = $self->p->render('common/_ship_to_dialog',
1381                                  vc_obj      => $self->order->customervendor,
1382                                  cs_obj      => $self->order->custom_shipto,
1383                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1384                                  id_selector => '#order_shipto_id');
1385
1386   div_tag($content, id => 'shipto_inputs');
1387 }
1388
1389 # render the info line for business
1390 #
1391 # Needed, if customer/vendor changed.
1392 sub build_business_info_row
1393 {
1394   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1395 }
1396
1397 # build the rows for displaying taxes
1398 #
1399 # Called if amounts where recalculated and redisplayed.
1400 sub build_tax_rows {
1401   my ($self) = @_;
1402
1403   my $rows_as_html;
1404   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1405     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1406   }
1407   return $rows_as_html;
1408 }
1409
1410
1411 sub render_price_dialog {
1412   my ($self, $record_item) = @_;
1413
1414   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1415
1416   $self->js
1417     ->run(
1418       'kivi.io.price_chooser_dialog',
1419       t8('Available Prices'),
1420       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1421     )
1422     ->reinit_widgets;
1423
1424 #   if (@errors) {
1425 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1426 #     $self->js->show('#dialog_flash_error');
1427 #   }
1428
1429   $self->js->render;
1430 }
1431
1432 sub load_order {
1433   my ($self) = @_;
1434
1435   return if !$::form->{id};
1436
1437   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1438
1439   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1440   # You need a custom shipto object to call cvars_by_config to get the cvars.
1441   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1442
1443   return $self->order;
1444 }
1445
1446 # load or create a new order object
1447 #
1448 # And assign changes from the form to this object.
1449 # If the order is loaded from db, check if items are deleted in the form,
1450 # remove them form the object and collect them for removing from db on saving.
1451 # Then create/update items from form (via make_item) and add them.
1452 sub make_order {
1453   my ($self) = @_;
1454
1455   # add_items adds items to an order with no items for saving, but they cannot
1456   # be retrieved via items until the order is saved. Adding empty items to new
1457   # order here solves this problem.
1458   my $order;
1459   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1460   $order ||= SL::DB::Order->new(orderitems  => [],
1461                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1462                                 currency_id => $::instance_conf->get_currency_id(),);
1463
1464   my $cv_id_method = $self->cv . '_id';
1465   if (!$::form->{id} && $::form->{$cv_id_method}) {
1466     $order->$cv_id_method($::form->{$cv_id_method});
1467     setup_order_from_cv($order);
1468   }
1469
1470   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1471   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1472
1473   $order->assign_attributes(%{$::form->{order}});
1474
1475   $self->setup_custom_shipto_from_form($order, $::form);
1476
1477   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1478     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1479     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1480   }
1481
1482   # remove deleted items
1483   $self->item_ids_to_delete([]);
1484   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1485     my $item = $order->orderitems->[$idx];
1486     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1487       splice @{$order->orderitems}, $idx, 1;
1488       push @{$self->item_ids_to_delete}, $item->id;
1489     }
1490   }
1491
1492   my @items;
1493   my $pos = 1;
1494   foreach my $form_attr (@{$form_orderitems}) {
1495     my $item = make_item($order, $form_attr);
1496     $item->position($pos);
1497     push @items, $item;
1498     $pos++;
1499   }
1500   $order->add_items(grep {!$_->id} @items);
1501
1502   return $order;
1503 }
1504
1505 # create or update items from form
1506 #
1507 # Make item objects from form values. For items already existing read from db.
1508 # Create a new item else. And assign attributes.
1509 sub make_item {
1510   my ($record, $attr) = @_;
1511
1512   my $item;
1513   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1514
1515   my $is_new = !$item;
1516
1517   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1518   # they cannot be retrieved via custom_variables until the order/orderitem is
1519   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1520   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1521
1522   $item->assign_attributes(%$attr);
1523
1524   if ($is_new) {
1525     my $texts = get_part_texts($item->part, $record->language_id);
1526     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1527     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1528     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1529   }
1530
1531   return $item;
1532 }
1533
1534 # create a new item
1535 #
1536 # This is used to add one item
1537 sub new_item {
1538   my ($record, $attr) = @_;
1539
1540   my $item = SL::DB::OrderItem->new;
1541
1542   # Remove attributes where the user left or set the inputs empty.
1543   # So these attributes will be undefined and we can distinguish them
1544   # from zero later on.
1545   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1546     delete $attr->{$_} if $attr->{$_} eq '';
1547   }
1548
1549   $item->assign_attributes(%$attr);
1550
1551   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1552   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1553
1554   $item->unit($part->unit) if !$item->unit;
1555
1556   my $price_src;
1557   if ( $part->is_assortment ) {
1558     # add assortment items with price 0, as the components carry the price
1559     $price_src = $price_source->price_from_source("");
1560     $price_src->price(0);
1561   } elsif (defined $item->sellprice) {
1562     $price_src = $price_source->price_from_source("");
1563     $price_src->price($item->sellprice);
1564   } else {
1565     $price_src = $price_source->best_price
1566                ? $price_source->best_price
1567                : $price_source->price_from_source("");
1568     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1569     $price_src->price(0) if !$price_source->best_price;
1570   }
1571
1572   my $discount_src;
1573   if (defined $item->discount) {
1574     $discount_src = $price_source->discount_from_source("");
1575     $discount_src->discount($item->discount);
1576   } else {
1577     $discount_src = $price_source->best_discount
1578                   ? $price_source->best_discount
1579                   : $price_source->discount_from_source("");
1580     $discount_src->discount(0) if !$price_source->best_discount;
1581   }
1582
1583   my %new_attr;
1584   $new_attr{part}                   = $part;
1585   $new_attr{description}            = $part->description     if ! $item->description;
1586   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1587   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1588   $new_attr{sellprice}              = $price_src->price;
1589   $new_attr{discount}               = $discount_src->discount;
1590   $new_attr{active_price_source}    = $price_src;
1591   $new_attr{active_discount_source} = $discount_src;
1592   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1593   $new_attr{project_id}             = $record->globalproject_id;
1594   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1595
1596   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1597   # they cannot be retrieved via custom_variables until the order/orderitem is
1598   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1599   $new_attr{custom_variables} = [];
1600
1601   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1602
1603   $item->assign_attributes(%new_attr, %{ $texts });
1604
1605   return $item;
1606 }
1607
1608 sub setup_order_from_cv {
1609   my ($order) = @_;
1610
1611   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1612
1613   $order->intnotes($order->customervendor->notes);
1614
1615   return if !$order->is_sales;
1616
1617   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1618   $order->taxincluded(defined($order->customer->taxincluded_checked)
1619                       ? $order->customer->taxincluded_checked
1620                       : $::myconfig{taxincluded_checked});
1621
1622   my $address = $order->customer->default_billing_address;;
1623   $order->billing_address_id($address ? $address->id : undef);
1624 }
1625
1626 # setup custom shipto from form
1627 #
1628 # The dialog returns form variables starting with 'shipto' and cvars starting
1629 # with 'shiptocvar_'.
1630 # Mark it to be deleted if a shipto from master data is selected
1631 # (i.e. order has a shipto).
1632 # Else, update or create a new custom shipto. If the fields are empty, it
1633 # will not be saved on save.
1634 sub setup_custom_shipto_from_form {
1635   my ($self, $order, $form) = @_;
1636
1637   if ($order->shipto) {
1638     $self->is_custom_shipto_to_delete(1);
1639   } else {
1640     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1641
1642     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1643     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1644
1645     $custom_shipto->assign_attributes(%$shipto_attrs);
1646     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1647   }
1648 }
1649
1650 # recalculate prices and taxes
1651 #
1652 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1653 sub recalc {
1654   my ($self) = @_;
1655
1656   my %pat = $self->order->calculate_prices_and_taxes();
1657
1658   $self->{taxes} = [];
1659   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1660     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1661
1662     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1663                                 netamount => $netamount,
1664                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1665   }
1666   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1667 }
1668
1669 # get data for saving, printing, ..., that is not changed in the form
1670 #
1671 # Only cvars for now.
1672 sub get_unalterable_data {
1673   my ($self) = @_;
1674
1675   foreach my $item (@{ $self->order->items }) {
1676     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1677     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1678     foreach my $var (@{ $item->cvars_by_config }) {
1679       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1680     }
1681     $item->parse_custom_variable_values;
1682   }
1683 }
1684
1685 # delete the order
1686 #
1687 # And remove related files in the spool directory
1688 sub delete {
1689   my ($self) = @_;
1690
1691   my $errors = [];
1692   my $db     = $self->order->db;
1693
1694   $db->with_transaction(
1695     sub {
1696       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1697       $self->order->delete;
1698       my $spool = $::lx_office_conf{paths}->{spool};
1699       unlink map { "$spool/$_" } @spoolfiles if $spool;
1700
1701       $self->save_history('DELETED');
1702
1703       1;
1704   }) || push(@{$errors}, $db->error);
1705
1706   return $errors;
1707 }
1708
1709 # save the order
1710 #
1711 # And delete items that are deleted in the form.
1712 sub save {
1713   my ($self) = @_;
1714
1715   my $errors = [];
1716   my $db     = $self->order->db;
1717
1718   $db->with_transaction(sub {
1719     # delete custom shipto if it is to be deleted or if it is empty
1720     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1721       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1722       $self->order->custom_shipto(undef);
1723     }
1724
1725     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1726     $self->order->save(cascade => 1);
1727
1728     # link records
1729     if ($::form->{converted_from_oe_id}) {
1730       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1731
1732       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1733         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1734         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1735         $src->link_to_record($self->order);
1736       }
1737       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1738         my $idx = 0;
1739         foreach (@{ $self->order->items_sorted }) {
1740           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1741           next if !$from_id;
1742           SL::DB::RecordLink->new(from_table => 'orderitems',
1743                                   from_id    => $from_id,
1744                                   to_table   => 'orderitems',
1745                                   to_id      => $_->id
1746           )->save;
1747           $idx++;
1748         }
1749       }
1750
1751       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1752     }
1753
1754     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1755
1756     $self->save_history('SAVED');
1757
1758     1;
1759   }) || push(@{$errors}, $db->error);
1760
1761   return $errors;
1762 }
1763
1764 sub workflow_sales_or_request_for_quotation {
1765   my ($self) = @_;
1766
1767   # always save
1768   my $errors = $self->save();
1769
1770   if (scalar @{ $errors }) {
1771     $self->js->flash('error', $_) for @{ $errors };
1772     return $self->js->render();
1773   }
1774
1775   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1776
1777   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1778   $self->{converted_from_oe_id} = delete $::form->{id};
1779
1780   # set item ids to new fake id, to identify them as new items
1781   foreach my $item (@{$self->order->items_sorted}) {
1782     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1783   }
1784
1785   # change form type
1786   $::form->{type} = $destination_type;
1787   $self->type($self->init_type);
1788   $self->cv  ($self->init_cv);
1789   $self->check_auth;
1790
1791   $self->recalc();
1792   $self->get_unalterable_data();
1793   $self->pre_render();
1794
1795   # trigger rendering values for second row as hidden, because they
1796   # are loaded only on demand. So we need to keep the values from the
1797   # source.
1798   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1799
1800   $self->render(
1801     'order/form',
1802     title => $self->get_title_for('edit'),
1803     %{$self->{template_args}}
1804   );
1805 }
1806
1807 sub workflow_sales_or_purchase_order {
1808   my ($self) = @_;
1809
1810   # always save
1811   my $errors = $self->save();
1812
1813   if (scalar @{ $errors }) {
1814     $self->js->flash('error', $_) foreach @{ $errors };
1815     return $self->js->render();
1816   }
1817
1818   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1819                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1820                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1821                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1822                        : '';
1823
1824   # check for direct delivery
1825   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1826   my $custom_shipto;
1827   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1828       && $::form->{use_shipto} && $self->order->shipto) {
1829     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1830   }
1831
1832   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1833   $self->{converted_from_oe_id} = delete $::form->{id};
1834
1835   # set item ids to new fake id, to identify them as new items
1836   foreach my $item (@{$self->order->items_sorted}) {
1837     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1838   }
1839
1840   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1841     if ($::form->{use_shipto}) {
1842       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1843     } else {
1844       # remove any custom shipto if not wanted
1845       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1846     }
1847   }
1848
1849   # change form type
1850   $::form->{type} = $destination_type;
1851   $self->type($self->init_type);
1852   $self->cv  ($self->init_cv);
1853   $self->check_auth;
1854
1855   $self->recalc();
1856   $self->get_unalterable_data();
1857   $self->pre_render();
1858
1859   # trigger rendering values for second row as hidden, because they
1860   # are loaded only on demand. So we need to keep the values from the
1861   # source.
1862   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1863
1864   $self->render(
1865     'order/form',
1866     title => $self->get_title_for('edit'),
1867     %{$self->{template_args}}
1868   );
1869 }
1870
1871
1872 sub pre_render {
1873   my ($self) = @_;
1874
1875   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1876   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1877   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1878   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1879   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1880                                                                                               deleted => 0 ] ],
1881                                                                            sort_by => 'name');
1882   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1883                                                                                               deleted => 0 ] ],
1884                                                                            sort_by => 'name');
1885   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1886                                                                                                         obsolete => 0 ] ]);
1887   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1888   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1889   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1890   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1891   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1892
1893   my $print_form = Form->new('');
1894   $print_form->{type}        = $self->type;
1895   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1896   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1897     form => $print_form,
1898     options => {dialog_name_prefix => 'print_options.',
1899                 show_headers       => 1,
1900                 no_queue           => 1,
1901                 no_postscript      => 1,
1902                 no_opendocument    => 0,
1903                 no_html            => 0},
1904   );
1905
1906   foreach my $item (@{$self->order->orderitems}) {
1907     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1908     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1909     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1910   }
1911
1912   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1913     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1914     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1915     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1916     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1917   }
1918
1919   if ($self->order->number && $::instance_conf->get_webdav) {
1920     my $webdav = SL::Webdav->new(
1921       type     => $self->type,
1922       number   => $self->order->number,
1923     );
1924     my @all_objects = $webdav->get_all_objects;
1925     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1926                                                     type => t8('File'),
1927                                                     link => File::Spec->catfile($_->full_filedescriptor),
1928                                                 } } @all_objects;
1929   }
1930
1931   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
1932       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
1933     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
1934   }
1935
1936   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1937
1938   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1939                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
1940   $self->setup_edit_action_bar;
1941 }
1942
1943 sub setup_edit_action_bar {
1944   my ($self, %params) = @_;
1945
1946   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1947                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1948                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1949
1950   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
1951   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
1952
1953   for my $bar ($::request->layout->get('actionbar')) {
1954     $bar->add(
1955       combobox => [
1956         action => [
1957           t8('Save'),
1958           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1959                                                     $::instance_conf->get_order_warn_no_deliverydate,
1960           ],
1961           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
1962                          @req_trans_cost_art, @req_cusordnumber,
1963           ],
1964         ],
1965         action => [
1966           t8('Save as new'),
1967           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1968           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1969                          @req_trans_cost_art, @req_cusordnumber,
1970           ],
1971           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1972         ],
1973       ], # end of combobox "Save"
1974
1975       combobox => [
1976         action => [
1977           t8('Workflow'),
1978         ],
1979         action => [
1980           t8('Save and Quotation'),
1981           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1982           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
1983           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1984         ],
1985         action => [
1986           t8('Save and RFQ'),
1987           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1988           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1989         ],
1990         action => [
1991           t8('Save and Sales Order'),
1992           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1993           checks   => [ @req_trans_cost_art ],
1994           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1995         ],
1996         action => [
1997           t8('Save and Purchase Order'),
1998           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1999           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
2000           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
2001         ],
2002         action => [
2003           t8('Save and Delivery Order'),
2004           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2005                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2006                                                                                                                         ],
2007           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2008                          @req_trans_cost_art, @req_cusordnumber,
2009           ],
2010           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
2011         ],
2012         action => [
2013           t8('Save and Invoice'),
2014           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2015           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2016                          @req_trans_cost_art, @req_cusordnumber,
2017           ],
2018         ],
2019         action => [
2020           t8('Save and AP Transaction'),
2021           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2022           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
2023         ],
2024
2025       ], # end of combobox "Workflow"
2026
2027       combobox => [
2028         action => [
2029           t8('Export'),
2030         ],
2031         action => [
2032           t8('Save and preview PDF'),
2033           call   => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2034                                                         $::instance_conf->get_order_warn_no_deliverydate,
2035                     ],
2036           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2037         ],
2038         action => [
2039           t8('Save and print'),
2040           call   => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2041                                                        $::instance_conf->get_order_warn_no_deliverydate,
2042                     ],
2043           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2044         ],
2045         action => [
2046           t8('Save and E-mail'),
2047           id   => 'save_and_email_action',
2048           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2049                                                                      $::instance_conf->get_order_warn_no_deliverydate,
2050                   ],
2051           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2052         ],
2053         action => [
2054           t8('Download attachments of all parts'),
2055           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2056           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2057           only_if  => $::instance_conf->get_doc_storage,
2058         ],
2059       ], # end of combobox "Export"
2060
2061       action => [
2062         t8('Delete'),
2063         call     => [ 'kivi.Order.delete_order' ],
2064         confirm  => $::locale->text('Do you really want to delete this object?'),
2065         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2066         only_if  => $deletion_allowed,
2067       ],
2068
2069       combobox => [
2070         action => [
2071           t8('more')
2072         ],
2073         action => [
2074           t8('History'),
2075           call     => [ 'set_history_window', $self->order->id, 'id' ],
2076           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2077         ],
2078         action => [
2079           t8('Follow-Up'),
2080           call     => [ 'kivi.Order.follow_up_window' ],
2081           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2082           only_if  => $::auth->assert('productivity', 1),
2083         ],
2084       ], # end of combobox "more"
2085     );
2086   }
2087 }
2088
2089 sub generate_doc {
2090   my ($self, $doc_ref, $params) = @_;
2091
2092   my $order  = $self->order;
2093   my @errors = ();
2094
2095   my $print_form = Form->new('');
2096   $print_form->{type}        = $order->type;
2097   $print_form->{formname}    = $params->{formname} || $order->type;
2098   $print_form->{format}      = $params->{format}   || 'pdf';
2099   $print_form->{media}       = $params->{media}    || 'file';
2100   $print_form->{groupitems}  = $params->{groupitems};
2101   $print_form->{printer_id}  = $params->{printer_id};
2102   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2103
2104   $order->language($params->{language});
2105   $order->flatten_to_form($print_form, format_amounts => 1);
2106
2107   my $template_ext;
2108   my $template_type;
2109   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2110     $template_ext  = 'odt';
2111     $template_type = 'OpenDocument';
2112   } elsif ($print_form->{format} =~ m{html}i) {
2113     $template_ext  = 'html';
2114     $template_type = 'HTML';
2115   }
2116
2117   # search for the template
2118   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2119     name        => $print_form->{formname},
2120     extension   => $template_ext,
2121     email       => $print_form->{media} eq 'email',
2122     language    => $params->{language},
2123     printer_id  => $print_form->{printer_id},
2124   );
2125
2126   if (!defined $template_file) {
2127     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2128   }
2129
2130   return @errors if scalar @errors;
2131
2132   $print_form->throw_on_error(sub {
2133     eval {
2134       $print_form->prepare_for_printing;
2135
2136       $$doc_ref = SL::Helper::CreatePDF->create_pdf(
2137         format        => $print_form->{format},
2138         template_type => $template_type,
2139         template      => $template_file,
2140         variables     => $print_form,
2141         variable_content_types => {
2142           longdescription => 'html',
2143           partnotes       => 'html',
2144           notes           => 'html',
2145           $::form->get_variable_content_types_for_cvars,
2146         },
2147       );
2148       1;
2149     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2150   });
2151
2152   return @errors;
2153 }
2154
2155 sub get_files_for_email_dialog {
2156   my ($self) = @_;
2157
2158   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2159
2160   return %files if !$::instance_conf->get_doc_storage;
2161
2162   if ($self->order->id) {
2163     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2164     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2165     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2166     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2167   }
2168
2169   my @parts =
2170     uniq_by { $_->{id} }
2171     map {
2172       +{ id         => $_->part->id,
2173          partnumber => $_->part->partnumber }
2174     } @{$self->order->items_sorted};
2175
2176   foreach my $part (@parts) {
2177     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2178     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2179   }
2180
2181   foreach my $key (keys %files) {
2182     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2183   }
2184
2185   return %files;
2186 }
2187
2188 sub make_periodic_invoices_config_from_yaml {
2189   my ($yaml_config) = @_;
2190
2191   return if !$yaml_config;
2192   my $attr = SL::YAML::Load($yaml_config);
2193   return if 'HASH' ne ref $attr;
2194   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2195 }
2196
2197
2198 sub get_periodic_invoices_status {
2199   my ($self, $config) = @_;
2200
2201   return                      if $self->type ne sales_order_type();
2202   return t8('not configured') if !$config;
2203
2204   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2205              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2206              :                                                     die "Cannot get status of periodic invoices config";
2207
2208   return $active ? t8('active') : t8('inactive');
2209 }
2210
2211 sub get_title_for {
2212   my ($self, $action) = @_;
2213
2214   return '' if none { lc($action)} qw(add edit);
2215
2216   # for locales:
2217   # $::locale->text("Add Sales Order");
2218   # $::locale->text("Add Purchase Order");
2219   # $::locale->text("Add Quotation");
2220   # $::locale->text("Add Request for Quotation");
2221   # $::locale->text("Edit Sales Order");
2222   # $::locale->text("Edit Purchase Order");
2223   # $::locale->text("Edit Quotation");
2224   # $::locale->text("Edit Request for Quotation");
2225
2226   $action = ucfirst(lc($action));
2227   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2228        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2229        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2230        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2231        : '';
2232 }
2233
2234 sub get_item_cvpartnumber {
2235   my ($self, $item) = @_;
2236
2237   return if !$self->search_cvpartnumber;
2238   return if !$self->order->customervendor;
2239
2240   if ($self->cv eq 'vendor') {
2241     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2242     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2243   } elsif ($self->cv eq 'customer') {
2244     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2245     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2246   }
2247 }
2248
2249 sub get_part_texts {
2250   my ($part_or_id, $language_or_id, %defaults) = @_;
2251
2252   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2253   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2254   my $texts       = {
2255     description     => $defaults{description}     // $part->description,
2256     longdescription => $defaults{longdescription} // $part->notes,
2257   };
2258
2259   return $texts unless $language_id;
2260
2261   my $translation = SL::DB::Manager::Translation->get_first(
2262     where => [
2263       parts_id    => $part->id,
2264       language_id => $language_id,
2265     ]);
2266
2267   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2268   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2269
2270   return $texts;
2271 }
2272
2273 sub sales_order_type {
2274   'sales_order';
2275 }
2276
2277 sub purchase_order_type {
2278   'purchase_order';
2279 }
2280
2281 sub sales_quotation_type {
2282   'sales_quotation';
2283 }
2284
2285 sub request_quotation_type {
2286   'request_quotation';
2287 }
2288
2289 sub nr_key {
2290   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2291        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2292        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2293        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2294        : '';
2295 }
2296
2297 sub save_and_redirect_to {
2298   my ($self, %params) = @_;
2299
2300   my $errors = $self->save();
2301
2302   if (scalar @{ $errors }) {
2303     $self->js->flash('error', $_) foreach @{ $errors };
2304     return $self->js->render();
2305   }
2306
2307   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2308            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2309            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2310            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2311            : '';
2312   flash_later('info', $text);
2313
2314   $self->redirect_to(%params, id => $self->order->id);
2315 }
2316
2317 sub save_history {
2318   my ($self, $addition) = @_;
2319
2320   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2321   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2322
2323   SL::DB::History->new(
2324     trans_id    => $self->order->id,
2325     employee_id => SL::DB::Manager::Employee->current->id,
2326     what_done   => $self->order->type,
2327     snumbers    => $snumbers,
2328     addition    => $addition,
2329   )->save;
2330 }
2331
2332 sub store_doc_to_webdav_and_filemanagement {
2333   my ($self, $content, $filename, $variant) = @_;
2334
2335   my $order = $self->order;
2336   my @errors;
2337
2338   # copy file to webdav folder
2339   if ($order->number && $::instance_conf->get_webdav_documents) {
2340     my $webdav = SL::Webdav->new(
2341       type     => $order->type,
2342       number   => $order->number,
2343     );
2344     my $webdav_file = SL::Webdav::File->new(
2345       webdav   => $webdav,
2346       filename => $filename,
2347     );
2348     eval {
2349       $webdav_file->store(data => \$content);
2350       1;
2351     } or do {
2352       push @errors, t8('Storing the document to the WebDAV folder failed: #1', $@);
2353     };
2354   }
2355   if ($order->id && $::instance_conf->get_doc_storage) {
2356     eval {
2357       SL::File->save(object_id     => $order->id,
2358                      object_type   => $order->type,
2359                      mime_type     => SL::MIME->mime_type_from_ext($filename),
2360                      source        => 'created',
2361                      file_type     => 'document',
2362                      file_name     => $filename,
2363                      file_contents => $content,
2364                      print_variant => $variant);
2365       1;
2366     } or do {
2367       push @errors, t8('Storing the document in the storage backend failed: #1', $@);
2368     };
2369   }
2370
2371   return @errors;
2372 }
2373
2374 sub link_requirement_specs_linking_to_created_from_objects {
2375   my ($self, @converted_from_oe_ids) = @_;
2376
2377   return unless @converted_from_oe_ids;
2378
2379   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2380   foreach my $rs_order (@{ $rs_orders }) {
2381     SL::DB::RequirementSpecOrder->new(
2382       order_id            => $self->order->id,
2383       requirement_spec_id => $rs_order->requirement_spec_id,
2384       version_id          => $rs_order->version_id,
2385     )->save;
2386   }
2387 }
2388
2389 sub set_project_in_linked_requirement_specs {
2390   my ($self) = @_;
2391
2392   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2393   foreach my $rs_order (@{ $rs_orders }) {
2394     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2395
2396     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2397   }
2398 }
2399
2400 1;
2401
2402 __END__
2403
2404 =encoding utf-8
2405
2406 =head1 NAME
2407
2408 SL::Controller::Order - controller for orders
2409
2410 =head1 SYNOPSIS
2411
2412 This is a new form to enter orders, completely rewritten with the use
2413 of controller and java script techniques.
2414
2415 The aim is to provide the user a better experience and a faster workflow. Also
2416 the code should be more readable, more reliable and better to maintain.
2417
2418 =head2 Key Features
2419
2420 =over 4
2421
2422 =item *
2423
2424 One input row, so that input happens every time at the same place.
2425
2426 =item *
2427
2428 Use of pickers where possible.
2429
2430 =item *
2431
2432 Possibility to enter more than one item at once.
2433
2434 =item *
2435
2436 Item list in a scrollable area, so that the workflow buttons stay at
2437 the bottom.
2438
2439 =item *
2440
2441 Reordering item rows with drag and drop is possible. Sorting item rows is
2442 possible (by partnumber, description, qty, sellprice and discount for now).
2443
2444 =item *
2445
2446 No C<update> is necessary. All entries and calculations are managed
2447 with ajax-calls and the page only reloads on C<save>.
2448
2449 =item *
2450
2451 User can see changes immediately, because of the use of java script
2452 and ajax.
2453
2454 =back
2455
2456 =head1 CODE
2457
2458 =head2 Layout
2459
2460 =over 4
2461
2462 =item * C<SL/Controller/Order.pm>
2463
2464 the controller
2465
2466 =item * C<template/webpages/order/form.html>
2467
2468 main form
2469
2470 =item * C<template/webpages/order/tabs/basic_data.html>
2471
2472 Main tab for basic_data.
2473
2474 This is the only tab here for now. "linked records" and "webdav" tabs are
2475 reused from generic code.
2476
2477 =over 4
2478
2479 =item * C<template/webpages/order/tabs/_business_info_row.html>
2480
2481 For displaying information on business type
2482
2483 =item * C<template/webpages/order/tabs/_item_input.html>
2484
2485 The input line for items
2486
2487 =item * C<template/webpages/order/tabs/_row.html>
2488
2489 One row for already entered items
2490
2491 =item * C<template/webpages/order/tabs/_tax_row.html>
2492
2493 Displaying tax information
2494
2495 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2496
2497 Dialog for selecting price and discount sources
2498
2499 =back
2500
2501 =item * C<js/kivi.Order.js>
2502
2503 java script functions
2504
2505 =back
2506
2507 =head1 TODO
2508
2509 =over 4
2510
2511 =item * testing
2512
2513 =item * price sources: little symbols showing better price / better discount
2514
2515 =item * select units in input row?
2516
2517 =item * check for direct delivery (workflow sales order -> purchase order)
2518
2519 =item * access rights
2520
2521 =item * display weights
2522
2523 =item * mtime check
2524
2525 =item * optional client/user behaviour
2526
2527 (transactions has to be set - department has to be set -
2528  force project if enabled in client config)
2529
2530 =back
2531
2532 =head1 KNOWN BUGS AND CAVEATS
2533
2534 =over 4
2535
2536 =item *
2537
2538 Customer discount is not displayed as a valid discount in price source popup
2539 (this might be a bug in price sources)
2540
2541 (I cannot reproduce this (Bernd))
2542
2543 =item *
2544
2545 No indication that <shift>-up/down expands/collapses second row.
2546
2547 =item *
2548
2549 Inline creation of parts is not currently supported
2550
2551 =item *
2552
2553 Table header is not sticky in the scrolling area.
2554
2555 =item *
2556
2557 Sorting does not include C<position>, neither does reordering.
2558
2559 This behavior was implemented intentionally. But we can discuss, which behavior
2560 should be implemented.
2561
2562 =back
2563
2564 =head1 To discuss / Nice to have
2565
2566 =over 4
2567
2568 =item *
2569
2570 How to expand/collapse second row. Now it can be done clicking the icon or
2571 <shift>-up/down.
2572
2573 =item *
2574
2575 Possibility to select PriceSources in input row?
2576
2577 =item *
2578
2579 This controller uses a (changed) copy of the template for the PriceSource
2580 dialog. Maybe there could be used one code source.
2581
2582 =item *
2583
2584 Rounding-differences between this controller (PriceTaxCalculator) and the old
2585 form. This is not only a problem here, but also in all parts using the PTC.
2586 There exists a ticket and a patch. This patch should be testet.
2587
2588 =item *
2589
2590 An indicator, if the actual inputs are saved (like in an
2591 editor or on text processing application).
2592
2593 =item *
2594
2595 A warning when leaving the page without saveing unchanged inputs.
2596
2597
2598 =back
2599
2600 =head1 AUTHOR
2601
2602 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2603
2604 =cut