SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Price;
  22
  23 use SL::Helper::DateTime;
  24 use SL::Helper::CreatePDF qw(:all);
  25
  26 use List::Util qw(max first);
  27 use List::MoreUtils qw(none pairwise);
  28 use English qw(-no_match_vars);
  29 use File::Spec;
  30
  31 use Rose::Object::MakeMethods::Generic
  32 (
  33  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  34 );
  35
  36
  37 # safety
  38 __PACKAGE__->run_before('_check_auth');
  39
  40 __PACKAGE__->run_before('_recalc',
  41                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  42
  43 __PACKAGE__->run_before('_get_unalterable_data',
  44                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  45
  46 #
  47 # actions
  48 #
  49
  50 sub action_add {
  51   my ($self) = @_;
  52
  53   $self->order->transdate(DateTime->now_local());
  54
  55   $self->_pre_render();
  56   $self->render(
  57     'order/form',
  58     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  59            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  60            : '',
  61     %{$self->{template_args}}
  62   );
  63 }
  64
  65 sub action_edit {
  66   my ($self) = @_;
  67
  68   $self->_pre_render();
  69   $self->render(
  70     'order/form',
  71     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  72            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  73            : '',
  74     %{$self->{template_args}}
  75   );
  76 }
  77
  78 sub action_update {
  79   my ($self) = @_;
  80
  81   $self->_pre_render();
  82   $self->render(
  83     'order/form',
  84     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  85            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  86            : '',
  87     %{$self->{template_args}}
  88   );
  89 }
  90
  91 sub action_save {
  92   my ($self) = @_;
  93
  94   my $errors = $self->_save();
  95
  96   if (scalar @{ $errors }) {
  97     $self->js->flash('error', $_) foreach @{ $errors };
  98     return $self->js->render();
  99   }
 100
 101   flash_later('info', $::locale->text('The order has been saved'));
 102   my @redirect_params = (
 103     action => 'edit',
 104     type   => $self->type,
 105     id     => $self->order->id,
 106   );
 107
 108   $self->redirect_to(@redirect_params);
 109 }
 110
 111 sub action_create_pdf {
 112   my ($self) = @_;
 113
 114   my $pdf;
 115   my @errors = _create_pdf($self->order, \$pdf);
 116   if (scalar @errors) {
 117     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 118   }
 119
 120   my $sfile = SL::SessionFile::Random->new(mode => "w");
 121   $sfile->fh->print($pdf);
 122   $sfile->fh->close;
 123
 124   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 125   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 126
 127   $::form->{formname}  = $self->type;
 128   $::form->{language} = 'de';
 129   my $pdf_filename =  $::form->get_formname_translation . '_' . $self->order->ordnumber . '.pdf';
 130
 131   $self->js
 132     ->run('download_pdf', $pdf_filename, $key)
 133     ->flash('info', t8('The PDF has been created'))->render($self);
 134 }
 135
 136 sub action_download_pdf {
 137   my ($self) = @_;
 138
 139   my $key = $::form->{key};
 140   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 141   return $self->send_file(
 142     $tmp_filename,
 143     type => 'application/pdf',
 144     name => $::form->{pdf_filename},
 145   );
 146 }
 147
 148 sub action_show_email_dialog {
 149   my ($self) = @_;
 150
 151   my $cv_method = $self->cv;
 152
 153   if (!$self->order->$cv_method) {
 154     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 155                     ->render($self);
 156   }
 157
 158   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 159   $self->{email}->{to} ||= $self->order->$cv_method->email;
 160   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 161   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 162   # Todo: get addresses from shipto, if any
 163
 164   my $form = Form->new;
 165   $form->{ordnumber} = $self->order->ordnumber;
 166   $form->{formname}  = $self->type;
 167   $form->{type}      = $self->type;
 168   $form->{language} = 'de';
 169   $form->{format}   = 'pdf';
 170
 171   $self->{email}->{subject}             = $form->generate_email_subject();
 172   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 173   $self->{email}->{message}             = $form->create_email_signature();
 174
 175   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 176   $self->js
 177       ->run('show_email_dialog', $dialog_html)
 178       ->reinit_widgets
 179       ->render($self);
 180 }
 181
 182 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 183 sub action_send_email {
 184   my ($self) = @_;
 185
 186   my $mail      = Mailer->new;
 187   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 188   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 189
 190   my $pdf;
 191   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 192   if (scalar @errors) {
 193     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 194   }
 195
 196   $mail->{attachments} = [{ "content" => $pdf,
 197                             "name"    => $::form->{email}->{attachment_filename} }];
 198
 199   if (my $err = $mail->send) {
 200     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 201                     ->render($self);
 202   }
 203
 204   # internal notes
 205   my $intnotes = $self->order->intnotes;
 206   $intnotes   .= "\n\n" if $self->order->intnotes;
 207   $intnotes   .= t8('[email]')                                                                                        . "\n";
 208   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 209   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 210   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 211   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 212   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 213   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 214
 215   $self->js
 216       ->val('#order_intnotes', $intnotes)
 217       ->run('close_email_dialog')
 218       ->render($self);
 219 }
 220
 221 sub action_save_and_delivery_order {
 222   my ($self) = @_;
 223
 224   my $errors = $self->_save();
 225
 226   if (scalar @{ $errors }) {
 227     $self->js->flash('error', $_) foreach @{ $errors };
 228     return $self->js->render();
 229   }
 230
 231   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 232
 233   flash_later('info', $::locale->text('The order has been saved'));
 234   my @redirect_params = (
 235     controller => 'do.pl',
 236     action     => 'edit',
 237     type       => $delivery_order->type,
 238     id         => $delivery_order->id,
 239     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 240   );
 241
 242   $self->redirect_to(@redirect_params);
 243 }
 244
 245 sub action_customer_vendor_changed {
 246   my ($self) = @_;
 247
 248   my $cv_method = $self->cv;
 249
 250   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 251     $self->js->show('#cp_row');
 252   } else {
 253     $self->js->hide('#cp_row');
 254   }
 255
 256   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 257     $self->js->show('#shipto_row');
 258   } else {
 259     $self->js->hide('#shipto_row');
 260   }
 261
 262   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 263
 264   if ($self->order->is_sales) {
 265     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 266                               ? $self->order->$cv_method->taxincluded_checked
 267                               : $::myconfig{taxincluded_checked});
 268   }
 269
 270   $self->_recalc();
 271
 272   $self->js
 273     ->replaceWith('#order_cp_id',       $self->build_contact_select)
 274     ->replaceWith('#order_shipto_id',   $self->build_shipto_select)
 275     ->val(        '#order_taxzone_id',  $self->order->taxzone_id)
 276     ->val(        '#order_taxincluded', $self->order->taxincluded)
 277     ->focus(      '#order_' . $self->cv . '_id');
 278
 279   $self->_js_redisplay_amounts_and_taxes;
 280   $self->js->render();
 281 }
 282
 283 sub action_add_item {
 284   my ($self) = @_;
 285
 286   my $form_attr = $::form->{add_item};
 287
 288   return unless $form_attr->{parts_id};
 289
 290   my $item = SL::DB::OrderItem->new;
 291   $item->assign_attributes(%$form_attr);
 292
 293   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 294   my $cv_method   = $self->cv;
 295   my $cv_discount = $self->order->$cv_method? $self->order->$cv_method->discount : 0.0;
 296
 297   my $price = $item->sellprice;
 298   $price  ||= ($self->order->$cv_method && $self->order->$cv_method->klass)
 299             ? (SL::DB::Manager::Price->find_by(parts_id => $part->id, pricegroup_id => $self->order->$cv_method->klass)->price || $part->sellprice)
 300             : $part->sellprice;
 301
 302   my %new_attr;
 303   $new_attr{part}        = $part;
 304   $new_attr{description} = $part->description if ! $item->description;
 305   $new_attr{qty}         = 1.0                if ! $item->qty;
 306   $new_attr{unit}        = $part->unit;
 307   $new_attr{sellprice}   = $price;
 308   $new_attr{discount}    = $cv_discount       if ! $item->discount;
 309
 310   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 311   # they cannot be retrieved via custom_variables until the order/orderitem is
 312   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 313   $new_attr{custom_variables} = [];
 314
 315   $item->assign_attributes(%new_attr);
 316
 317   $self->order->add_items($item);
 318
 319   $self->_recalc();
 320
 321   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 322   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 323
 324   $self->js
 325     ->append('#row_table_id', $row_as_html)
 326     ->val('#add_item_parts_id', '')
 327     ->val('#add_item_parts_id_name', '')
 328     ->val('#add_item_description', '')
 329     ->val('#add_item_qty_as_number', '')
 330     ->val('#add_item_sellprice_as_number', '')
 331     ->val('#add_item_discount_as_percent', '')
 332     ->run('row_table_scroll_down')
 333     ->run('row_set_keyboard_events_by_id', $item_id)
 334     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 335     ->focus('#add_item_parts_id_name');
 336
 337   $self->_js_redisplay_amounts_and_taxes;
 338   $self->js->render();
 339 }
 340
 341 sub action_recalc_amounts_and_taxes {
 342   my ($self) = @_;
 343
 344   $self->_recalc();
 345
 346   $self->_js_redisplay_linetotals;
 347   $self->_js_redisplay_amounts_and_taxes;
 348   $self->js->render();
 349 }
 350
 351 sub _js_redisplay_linetotals {
 352   my ($self) = @_;
 353
 354   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 355   $self->js
 356     ->run('redisplay_linetotals', \@data);
 357 }
 358
 359 sub _js_redisplay_amounts_and_taxes {
 360   my ($self) = @_;
 361
 362   if (scalar @{ $self->{taxes} }) {
 363     $self->js->show('#taxincluded_row_id');
 364   } else {
 365     $self->js->hide('#taxincluded_row_id');
 366   }
 367
 368   if ($self->order->taxincluded) {
 369     $self->js->hide('#subtotal_row_id');
 370   } else {
 371     $self->js->show('#subtotal_row_id');
 372   }
 373
 374   $self->js
 375     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 376     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 377     ->remove('.tax_row')
 378     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 379 }
 380
 381 #
 382 # helpers
 383 #
 384
 385 sub init_valid_types {
 386   [ _sales_order_type(), _purchase_order_type() ];
 387 }
 388
 389 sub init_type {
 390   my ($self) = @_;
 391
 392   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 393     die "Not a valid type for order";
 394   }
 395
 396   $self->type($::form->{type});
 397 }
 398
 399 sub init_cv {
 400   my ($self) = @_;
 401
 402   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 403          : $self->type eq _purchase_order_type() ? 'vendor'
 404          : die "Not a valid type for order";
 405
 406   return $cv;
 407 }
 408
 409 sub init_p {
 410   SL::Presenter->get;
 411 }
 412
 413 sub init_order {
 414   _make_order();
 415 }
 416
 417 sub _check_auth {
 418   my ($self) = @_;
 419
 420   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 421
 422   my $right   = $right_for->{ $self->type };
 423   $right    ||= 'DOES_NOT_EXIST';
 424
 425   $::auth->assert($right);
 426 }
 427
 428 sub build_contact_select {
 429   my ($self) = @_;
 430
 431   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 432                        value_key  => 'cp_id',
 433                        title_key  => 'full_name_dep',
 434                        default    => $self->order->cp_id,
 435                        with_empty => 1,
 436                        style      => 'width: 300px',
 437   );
 438 }
 439
 440 sub build_shipto_select {
 441   my ($self) = @_;
 442
 443   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 444                        value_key  => 'shipto_id',
 445                        title_key  => 'displayable_id',
 446                        default    => $self->order->shipto_id,
 447                        with_empty => 1,
 448                        style      => 'width: 300px',
 449   );
 450 }
 451
 452 sub build_tax_rows {
 453   my ($self) = @_;
 454
 455   my $rows_as_html;
 456   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 457     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 458   }
 459   return $rows_as_html;
 460 }
 461
 462
 463 sub _make_order {
 464   my ($self) = @_;
 465
 466   # add_items adds items to an order with no items for saving, but they cannot
 467   # be retrieved via items until the order is saved. Adding empty items to new
 468   # order here solves this problem.
 469   my $order;
 470   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 471   $order ||= SL::DB::Order->new(orderitems => []);
 472
 473   $order->assign_attributes(%{$::form->{order}});
 474
 475   return $order;
 476 }
 477
 478
 479 sub _recalc {
 480   my ($self) = @_;
 481
 482   # bb: todo: currency later
 483   $self->order->currency_id($::instance_conf->get_currency_id());
 484
 485   my %pat = $self->order->calculate_prices_and_taxes();
 486   $self->{taxes} = [];
 487   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 488     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 489
 490     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 491     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 492                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 493                                 tax       => $tax });
 494   }
 495
 496   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 497 }
 498
 499
 500 sub _get_unalterable_data {
 501   my ($self) = @_;
 502
 503   foreach my $item (@{ $self->order->items }) {
 504     if ($item->id) {
 505       # load data from orderitems (db)
 506       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 507       $item->$_($db_item->$_) for qw(active_discount_source active_price_source longdescription);
 508     } else {
 509       # set data from part (or other sources)
 510       $item->longdescription($item->part->notes);
 511       #$item->active_price_source('');
 512       #$item->active_discount_source('');
 513     }
 514
 515     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 516     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 517     foreach my $var (@{ $item->cvars_by_config }) {
 518       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 519     }
 520     $item->parse_custom_variable_values;
 521   }
 522 }
 523
 524
 525 sub _save {
 526   my ($self) = @_;
 527
 528   my $errors = [];
 529   my $db = $self->order->db;
 530
 531   $db->do_transaction(
 532     sub {
 533       $self->order->save();
 534   }) || push(@{$errors}, $db->error);
 535
 536   return $errors;
 537 }
 538
 539
 540 sub _pre_render {
 541   my ($self) = @_;
 542
 543   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 544   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 545                                                                                        deleted => 0 ] ],
 546                                                                     sort_by => 'name');
 547   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 548                                                                                        deleted => 0 ] ],
 549                                                                     sort_by => 'name');
 550   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 551                                                                                       active => 1 ] ],
 552                                                                    sort_by => 'projectnumber');
 553   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 554   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 555
 556   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 557
 558   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 559 }
 560
 561 sub _create_pdf {
 562   my ($order, $pdf_ref, $params) = @_;
 563
 564   my $print_form = Form->new('');
 565   $print_form->{type}     = $order->type;
 566   $print_form->{formname} = $order->type;
 567   $print_form->{format}   = $params->{format} || 'pdf',
 568   $print_form->{media}    = $params->{media}  || 'file';
 569
 570   $order->flatten_to_form($print_form, format_amounts => 1);
 571   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 572   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 573
 574   my @errors = ();
 575   $print_form->throw_on_error(sub {
 576     eval {
 577       $print_form->prepare_for_printing;
 578
 579       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 580         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 581         variables => $print_form,
 582         variable_content_types => {
 583           longdescription => 'html',
 584           partnotes       => 'html',
 585           notes           => 'html',
 586         },
 587       );
 588       1;
 589     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 590   });
 591
 592   return @errors;
 593 }
 594
 595 sub _sales_order_type {
 596   'sales_order';
 597 }
 598
 599 sub _purchase_order_type {
 600   'purchase_order';
 601 }
 602
 603 1;
 604
 605 __END__
 606
 607 =encoding utf-8
 608
 609 =head1 NAME
 610
 611 SL::Controller::Order - controller for orders
 612
 613 =head1 TODO
 614
 615 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 616
 617 =head1 AUTHOR
 618
 619 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 620
 621 =cut
 622