SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Price;
  22
  23 use SL::Helper::DateTime;
  24 use SL::Helper::CreatePDF qw(:all);
  25
  26 use List::Util qw(max first);
  27 use List::MoreUtils qw(none pairwise first_index);
  28 use English qw(-no_match_vars);
  29 use File::Spec;
  30
  31 use Rose::Object::MakeMethods::Generic
  32 (
  33  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  34 );
  35
  36
  37 # safety
  38 __PACKAGE__->run_before('_check_auth');
  39
  40 __PACKAGE__->run_before('_recalc',
  41                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  42
  43 __PACKAGE__->run_before('_get_unalterable_data',
  44                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  45
  46 #
  47 # actions
  48 #
  49
  50 sub action_add {
  51   my ($self) = @_;
  52
  53   $self->order->transdate(DateTime->now_local());
  54
  55   $self->_pre_render();
  56   $self->render(
  57     'order/form',
  58     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  59            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  60            : '',
  61     %{$self->{template_args}}
  62   );
  63 }
  64
  65 sub action_edit {
  66   my ($self) = @_;
  67
  68   $self->_pre_render();
  69   $self->render(
  70     'order/form',
  71     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  72            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  73            : '',
  74     %{$self->{template_args}}
  75   );
  76 }
  77
  78 sub action_update {
  79   my ($self) = @_;
  80
  81   $self->_pre_render();
  82   $self->render(
  83     'order/form',
  84     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  85            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  86            : '',
  87     %{$self->{template_args}}
  88   );
  89 }
  90
  91 sub action_delete {
  92   my ($self) = @_;
  93
  94   my $errors = $self->_delete();
  95
  96   if (scalar @{ $errors }) {
  97     $self->js->flash('error', $_) foreach @{ $errors };
  98     return $self->js->render();
  99   }
 100
 101   flash_later('info', $::locale->text('The order has been deleted'));
 102   my @redirect_params = (
 103     action => 'edit',
 104     type   => $self->type,
 105   );
 106
 107   $self->redirect_to(@redirect_params);
 108 }
 109
 110 sub action_save {
 111   my ($self) = @_;
 112
 113   my $errors = $self->_save();
 114
 115   if (scalar @{ $errors }) {
 116     $self->js->flash('error', $_) foreach @{ $errors };
 117     return $self->js->render();
 118   }
 119
 120   flash_later('info', $::locale->text('The order has been saved'));
 121   my @redirect_params = (
 122     action => 'edit',
 123     type   => $self->type,
 124     id     => $self->order->id,
 125   );
 126
 127   $self->redirect_to(@redirect_params);
 128 }
 129
 130 sub action_create_pdf {
 131   my ($self) = @_;
 132
 133   my $pdf;
 134   my @errors = _create_pdf($self->order, \$pdf);
 135   if (scalar @errors) {
 136     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 137   }
 138
 139   my $sfile = SL::SessionFile::Random->new(mode => "w");
 140   $sfile->fh->print($pdf);
 141   $sfile->fh->close;
 142
 143   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 144   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 145
 146   my $form = Form->new;
 147   $form->{ordnumber} = $self->order->ordnumber;
 148   $form->{formname}  = $self->type;
 149   $form->{type}      = $self->type;
 150   $form->{language}  = 'de';
 151   $form->{format}    = 'pdf';
 152
 153   my $pdf_filename = $form->generate_attachment_filename();
 154
 155   $self->js
 156     ->run('download_pdf', $pdf_filename, $key)
 157     ->flash('info', t8('The PDF has been created'))->render($self);
 158 }
 159
 160 sub action_download_pdf {
 161   my ($self) = @_;
 162
 163   my $key = $::form->{key};
 164   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 165   return $self->send_file(
 166     $tmp_filename,
 167     type => 'application/pdf',
 168     name => $::form->{pdf_filename},
 169   );
 170 }
 171
 172 sub action_show_email_dialog {
 173   my ($self) = @_;
 174
 175   my $cv_method = $self->cv;
 176
 177   if (!$self->order->$cv_method) {
 178     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 179                     ->render($self);
 180   }
 181
 182   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 183   $self->{email}->{to} ||= $self->order->$cv_method->email;
 184   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 185   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 186   # Todo: get addresses from shipto, if any
 187
 188   my $form = Form->new;
 189   $form->{ordnumber} = $self->order->ordnumber;
 190   $form->{formname}  = $self->type;
 191   $form->{type}      = $self->type;
 192   $form->{language} = 'de';
 193   $form->{format}   = 'pdf';
 194
 195   $self->{email}->{subject}             = $form->generate_email_subject();
 196   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 197   $self->{email}->{message}             = $form->create_email_signature();
 198
 199   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 200   $self->js
 201       ->run('show_email_dialog', $dialog_html)
 202       ->reinit_widgets
 203       ->render($self);
 204 }
 205
 206 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 207 sub action_send_email {
 208   my ($self) = @_;
 209
 210   my $mail      = Mailer->new;
 211   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 212   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 213
 214   my $pdf;
 215   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 216   if (scalar @errors) {
 217     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 218   }
 219
 220   $mail->{attachments} = [{ "content" => $pdf,
 221                             "name"    => $::form->{email}->{attachment_filename} }];
 222
 223   if (my $err = $mail->send) {
 224     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 225                     ->render($self);
 226   }
 227
 228   # internal notes
 229   my $intnotes = $self->order->intnotes;
 230   $intnotes   .= "\n\n" if $self->order->intnotes;
 231   $intnotes   .= t8('[email]')                                                                                        . "\n";
 232   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 233   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 234   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 235   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 236   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 237   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 238
 239   $self->js
 240       ->val('#order_intnotes', $intnotes)
 241       ->run('close_email_dialog')
 242       ->render($self);
 243 }
 244
 245 sub action_save_and_delivery_order {
 246   my ($self) = @_;
 247
 248   my $errors = $self->_save();
 249
 250   if (scalar @{ $errors }) {
 251     $self->js->flash('error', $_) foreach @{ $errors };
 252     return $self->js->render();
 253   }
 254   flash_later('info', $::locale->text('The order has been saved'));
 255
 256   my @redirect_params = (
 257     controller => 'oe.pl',
 258     action     => 'oe_delivery_order_from_order',
 259     id         => $self->order->id,
 260   );
 261
 262   $self->redirect_to(@redirect_params);
 263 }
 264
 265 sub action_customer_vendor_changed {
 266   my ($self) = @_;
 267
 268   my $cv_method = $self->cv;
 269
 270   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 271     $self->js->show('#cp_row');
 272   } else {
 273     $self->js->hide('#cp_row');
 274   }
 275
 276   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 277     $self->js->show('#shipto_row');
 278   } else {
 279     $self->js->hide('#shipto_row');
 280   }
 281
 282   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 283
 284   if ($self->order->is_sales) {
 285     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 286                               ? $self->order->$cv_method->taxincluded_checked
 287                               : $::myconfig{taxincluded_checked});
 288   }
 289
 290   $self->order->payment_id($self->order->$cv_method->payment_id);
 291   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 292
 293   $self->_recalc();
 294
 295   $self->js
 296     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 297     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 298     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 299     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 300     ->val(        '#order_payment_id',       $self->order->payment_id)
 301     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 302     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 303     ->focus(      '#order_' . $self->cv . '_id');
 304
 305   $self->_js_redisplay_amounts_and_taxes;
 306   $self->js->render();
 307 }
 308
 309 sub action_add_item {
 310   my ($self) = @_;
 311
 312   my $form_attr = $::form->{add_item};
 313
 314   return unless $form_attr->{parts_id};
 315
 316   my $item = SL::DB::OrderItem->new;
 317   $item->assign_attributes(%$form_attr);
 318
 319   my $part         = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 320
 321   my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 322
 323   my $price_src;
 324   if ($item->sellprice) {
 325     $price_src = $price_source->price_from_source("");
 326     $price_src->price($item->sellprice);
 327   } else {
 328     $price_src = $price_source->best_price
 329            ? $price_source->best_price
 330            : $price_source->price_from_source("");
 331     $price_src->price(0) if !$price_source->best_price;
 332   }
 333
 334   my $discount_src;
 335   if ($item->discount) {
 336     $discount_src = $price_source->discount_from_source("");
 337     $discount_src->discount($item->discount);
 338   } else {
 339     $discount_src = $price_source->best_discount
 340                   ? $price_source->best_discount
 341                   : $price_source->discount_from_source("");
 342     $discount_src->discount(0) if !$price_source->best_discount;
 343   }
 344
 345   my %new_attr;
 346   $new_attr{part}                   = $part;
 347   $new_attr{description}            = $part->description if ! $item->description;
 348   $new_attr{qty}                    = 1.0                if ! $item->qty;
 349   $new_attr{sellprice}              = $price_src->price;
 350   $new_attr{discount}               = $discount_src->discount;
 351   $new_attr{active_price_source}    = $price_src;
 352   $new_attr{active_discount_source} = $discount_src;
 353
 354   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 355   # they cannot be retrieved via custom_variables until the order/orderitem is
 356   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 357   $new_attr{custom_variables} = [];
 358
 359   $item->assign_attributes(%new_attr);
 360
 361   $self->order->add_items($item);
 362
 363   $self->_recalc();
 364
 365   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 366   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 367
 368   $self->js
 369     ->append('#row_table_id', $row_as_html)
 370     ->val('.add_item_input', '')
 371     ->run('row_table_scroll_down')
 372     ->run('row_set_keyboard_events_by_id', $item_id)
 373     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 374     ->on('.reformat_number', 'change', 'reformat_number')
 375     ->focus('#add_item_parts_id_name');
 376
 377   $self->_js_redisplay_amounts_and_taxes;
 378   $self->js->render();
 379 }
 380
 381 sub action_recalc_amounts_and_taxes {
 382   my ($self) = @_;
 383
 384   $self->_recalc();
 385
 386   $self->_js_redisplay_linetotals;
 387   $self->_js_redisplay_amounts_and_taxes;
 388   $self->js->render();
 389 }
 390
 391 sub action_price_popup {
 392   my ($self) = @_;
 393
 394   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 395   my $item = $self->order->items->[$idx];
 396
 397   $self->render_price_dialog($item);
 398 }
 399
 400 sub _js_redisplay_linetotals {
 401   my ($self) = @_;
 402
 403   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 404   $self->js
 405     ->run('redisplay_linetotals', \@data);
 406 }
 407
 408 sub _js_redisplay_amounts_and_taxes {
 409   my ($self) = @_;
 410
 411   if (scalar @{ $self->{taxes} }) {
 412     $self->js->show('#taxincluded_row_id');
 413   } else {
 414     $self->js->hide('#taxincluded_row_id');
 415   }
 416
 417   if ($self->order->taxincluded) {
 418     $self->js->hide('#subtotal_row_id');
 419   } else {
 420     $self->js->show('#subtotal_row_id');
 421   }
 422
 423   $self->js
 424     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 425     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 426     ->remove('.tax_row')
 427     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 428 }
 429
 430 #
 431 # helpers
 432 #
 433
 434 sub init_valid_types {
 435   [ _sales_order_type(), _purchase_order_type() ];
 436 }
 437
 438 sub init_type {
 439   my ($self) = @_;
 440
 441   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 442     die "Not a valid type for order";
 443   }
 444
 445   $self->type($::form->{type});
 446 }
 447
 448 sub init_cv {
 449   my ($self) = @_;
 450
 451   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 452          : $self->type eq _purchase_order_type() ? 'vendor'
 453          : die "Not a valid type for order";
 454
 455   return $cv;
 456 }
 457
 458 sub init_p {
 459   SL::Presenter->get;
 460 }
 461
 462 sub init_order {
 463   _make_order();
 464 }
 465
 466 sub _check_auth {
 467   my ($self) = @_;
 468
 469   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 470
 471   my $right   = $right_for->{ $self->type };
 472   $right    ||= 'DOES_NOT_EXIST';
 473
 474   $::auth->assert($right);
 475 }
 476
 477 sub build_contact_select {
 478   my ($self) = @_;
 479
 480   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 481                        value_key  => 'cp_id',
 482                        title_key  => 'full_name_dep',
 483                        default    => $self->order->cp_id,
 484                        with_empty => 1,
 485                        style      => 'width: 300px',
 486   );
 487 }
 488
 489 sub build_shipto_select {
 490   my ($self) = @_;
 491
 492   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 493                        value_key  => 'shipto_id',
 494                        title_key  => 'displayable_id',
 495                        default    => $self->order->shipto_id,
 496                        with_empty => 1,
 497                        style      => 'width: 300px',
 498   );
 499 }
 500
 501 sub build_tax_rows {
 502   my ($self) = @_;
 503
 504   my $rows_as_html;
 505   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 506     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 507   }
 508   return $rows_as_html;
 509 }
 510
 511
 512 sub render_price_dialog {
 513   my ($self, $record_item) = @_;
 514
 515   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 516
 517   $self->js
 518     ->run(
 519       'kivi.io.price_chooser_dialog',
 520       t8('Available Prices'),
 521       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 522     )
 523     ->reinit_widgets;
 524
 525 #   if (@errors) {
 526 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 527 #     $self->js->show('#dialog_flash_error');
 528 #   }
 529
 530   $self->js->render;
 531 }
 532
 533 sub _make_order {
 534   my ($self) = @_;
 535
 536   # add_items adds items to an order with no items for saving, but they cannot
 537   # be retrieved via items until the order is saved. Adding empty items to new
 538   # order here solves this problem.
 539   my $order;
 540   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 541   $order ||= SL::DB::Order->new(orderitems => []);
 542
 543   $order->assign_attributes(%{$::form->{order}});
 544
 545   return $order;
 546 }
 547
 548 sub _recalc {
 549   my ($self) = @_;
 550
 551   # bb: todo: currency later
 552   $self->order->currency_id($::instance_conf->get_currency_id());
 553
 554   my %pat = $self->order->calculate_prices_and_taxes();
 555   $self->{taxes} = [];
 556   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 557     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 558
 559     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 560     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 561                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 562                                 tax       => $tax });
 563   }
 564
 565   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 566 }
 567
 568
 569 sub _get_unalterable_data {
 570   my ($self) = @_;
 571
 572   foreach my $item (@{ $self->order->items }) {
 573     if ($item->id) {
 574       # load data from orderitems (db)
 575       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 576       $item->$_($db_item->$_) for qw(longdescription);
 577     } else {
 578       # set data from part (or other sources)
 579       $item->longdescription($item->part->notes);
 580     }
 581
 582     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 583     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 584     foreach my $var (@{ $item->cvars_by_config }) {
 585       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 586     }
 587     $item->parse_custom_variable_values;
 588   }
 589 }
 590
 591
 592 sub _delete {
 593   my ($self) = @_;
 594
 595   my $errors = [];
 596   my $db = $self->order->db;
 597
 598   $db->do_transaction(
 599     sub {
 600       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 601       $self->order->delete;
 602       my $spool = $::lx_office_conf{paths}->{spool};
 603       unlink map { "$spool/$_" } @spoolfiles if $spool;
 604
 605       1;
 606   }) || push(@{$errors}, $db->error);
 607
 608   return $errors;
 609 }
 610
 611
 612 sub _save {
 613   my ($self) = @_;
 614
 615   my $errors = [];
 616   my $db = $self->order->db;
 617
 618   $db->do_transaction(
 619     sub {
 620       $self->order->save();
 621   }) || push(@{$errors}, $db->error);
 622
 623   return $errors;
 624 }
 625
 626
 627 sub _pre_render {
 628   my ($self) = @_;
 629
 630   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 631   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 632                                                                                        deleted => 0 ] ],
 633                                                                     sort_by => 'name');
 634   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 635                                                                                        deleted => 0 ] ],
 636                                                                     sort_by => 'name');
 637   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 638                                                                                       active => 1 ] ],
 639                                                                    sort_by => 'projectnumber');
 640   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 641   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 642
 643   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 644
 645   foreach  my $item (@{$self->order->items}) {
 646     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 647     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 648     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 649
 650   }
 651
 652   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 653 }
 654
 655 sub _create_pdf {
 656   my ($order, $pdf_ref, $params) = @_;
 657
 658   my $print_form = Form->new('');
 659   $print_form->{type}     = $order->type;
 660   $print_form->{formname} = $order->type;
 661   $print_form->{format}   = $params->{format} || 'pdf',
 662   $print_form->{media}    = $params->{media}  || 'file';
 663
 664   $order->flatten_to_form($print_form, format_amounts => 1);
 665   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 666   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 667
 668   my @errors = ();
 669   $print_form->throw_on_error(sub {
 670     eval {
 671       $print_form->prepare_for_printing;
 672
 673       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 674         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 675         variables => $print_form,
 676         variable_content_types => {
 677           longdescription => 'html',
 678           partnotes       => 'html',
 679           notes           => 'html',
 680         },
 681       );
 682       1;
 683     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 684   });
 685
 686   return @errors;
 687 }
 688
 689 sub _sales_order_type {
 690   'sales_order';
 691 }
 692
 693 sub _purchase_order_type {
 694   'purchase_order';
 695 }
 696
 697 1;