SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21
  22 use SL::Helper::DateTime;
  23 use SL::Helper::CreatePDF qw(:all);
  24
  25 use List::Util qw(max first);
  26 use List::MoreUtils qw(none pairwise);
  27 use English qw(-no_match_vars);
  28
  29 use Rose::Object::MakeMethods::Generic
  30 (
  31  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  32 );
  33
  34
  35 # safety
  36 __PACKAGE__->run_before('_check_auth');
  37
  38 __PACKAGE__->run_before('_recalc',
  39                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  40
  41 __PACKAGE__->run_before('_get_unalterable_data',
  42                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  43
  44 #
  45 # actions
  46 #
  47
  48 sub action_add {
  49   my ($self) = @_;
  50
  51   $self->order->transdate(DateTime->now_local());
  52
  53   $self->_pre_render();
  54   $self->render(
  55     'order/form',
  56     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  57            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  58            : '',
  59     %{$self->{template_args}}
  60   );
  61 }
  62
  63 sub action_edit {
  64   my ($self) = @_;
  65
  66   $self->_pre_render();
  67   $self->render(
  68     'order/form',
  69     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  70            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  71            : '',
  72     %{$self->{template_args}}
  73   );
  74 }
  75
  76 sub action_update {
  77   my ($self) = @_;
  78
  79   $self->_pre_render();
  80   $self->render(
  81     'order/form',
  82     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  83            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  84            : '',
  85     %{$self->{template_args}}
  86   );
  87 }
  88
  89 sub action_save {
  90   my ($self) = @_;
  91
  92   my $errors = $self->_save();
  93
  94   if (scalar @{ $errors }) {
  95     $self->js->flash('error', $_) foreach @{ $errors };
  96     return $self->js->render();
  97   }
  98
  99   flash_later('info', $::locale->text('The order has been saved'));
 100   my @redirect_params = (
 101     action => 'edit',
 102     type   => $self->type,
 103     id     => $self->order->id,
 104   );
 105
 106   $self->redirect_to(@redirect_params);
 107 }
 108
 109 sub action_create_pdf {
 110   my ($self) = @_;
 111
 112   my $pdf;
 113   my @errors = _create_pdf($self->order, \$pdf);
 114   if (scalar @errors) {
 115     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 116   }
 117
 118   my $sfile = SL::SessionFile::Random->new(mode => "w");
 119   $sfile->fh->print($pdf);
 120   $sfile->fh->close;
 121
 122   my $tmp_filename = $sfile->file_name;
 123   my $pdf_filename = t8('Sales Order') . '_' . $self->order->ordnumber . '.pdf';
 124
 125   $self->js
 126     ->run('download_pdf', $tmp_filename, $pdf_filename)
 127     ->flash('info', t8('The PDF has been created'))->render($self);
 128 }
 129
 130 sub action_download_pdf {
 131   my ($self) = @_;
 132
 133   return $self->send_file(
 134     $::form->{tmp_filename},
 135     type => 'application/pdf',
 136     name => $::form->{pdf_filename},
 137   );
 138 }
 139
 140 sub action_show_email_dialog {
 141   my ($self) = @_;
 142
 143   my $cv_method = $self->cv;
 144
 145   if (!$self->order->$cv_method) {
 146     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 147                     ->render($self);
 148   }
 149
 150   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 151   $self->{email}->{to} ||= $self->order->$cv_method->email;
 152   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 153   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 154   # Todo: get addresses from shipto, if any
 155
 156   my $form = Form->new;
 157   $form->{ordnumber} = $self->order->ordnumber;
 158   $form->{formname}  = $self->type;
 159   $form->{type}      = $self->type;
 160   $form->{language} = 'de';
 161   $form->{format}   = 'pdf';
 162
 163   $self->{email}->{subject}             = $form->generate_email_subject();
 164   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 165   $self->{email}->{message}             = $form->create_email_signature();
 166
 167   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 168   $self->js
 169       ->run('show_email_dialog', $dialog_html)
 170       ->reinit_widgets
 171       ->render($self);
 172 }
 173
 174 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 175 sub action_send_email {
 176   my ($self) = @_;
 177
 178   my $mail      = Mailer->new;
 179   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 180   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 181
 182   my $pdf;
 183   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 184   if (scalar @errors) {
 185     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 186   }
 187
 188   $mail->{attachments} = [{ "content" => $pdf,
 189                             "name"    => $::form->{email}->{attachment_filename} }];
 190
 191   if (my $err = $mail->send) {
 192     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 193                     ->render($self);
 194   }
 195
 196   # internal notes
 197   my $intnotes = $self->order->intnotes;
 198   $intnotes   .= "\n\n" if $self->order->intnotes;
 199   $intnotes   .= t8('[email]')                                                                                        . "\n";
 200   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 201   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 202   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 203   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 204   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 205   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 206
 207   $self->js
 208       ->val('#order_intnotes', $intnotes)
 209       ->run('close_email_dialog')
 210       ->render($self);
 211 }
 212
 213 sub action_save_and_delivery_order {
 214   my ($self) = @_;
 215
 216   my $errors = $self->_save();
 217
 218   if (scalar @{ $errors }) {
 219     $self->js->flash('error', $_) foreach @{ $errors };
 220     return $self->js->render();
 221   }
 222
 223   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 224
 225   flash_later('info', $::locale->text('The order has been saved'));
 226   my @redirect_params = (
 227     controller => 'do.pl',
 228     action     => 'edit',
 229     type       => $delivery_order->type,
 230     id         => $delivery_order->id,
 231     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 232   );
 233
 234   $self->redirect_to(@redirect_params);
 235 }
 236
 237 sub action_customer_vendor_changed {
 238   my ($self) = @_;
 239
 240   if ($self->cv eq 'customer') {
 241     $self->order->customer(SL::DB::Manager::Customer->find_by_or_create(id => $::form->{cv_id}));
 242
 243   } elsif ($self->cv eq 'vendor') {
 244     $self->order->vendor(SL::DB::Manager::Vendor->find_by_or_create(id => $::form->{cv_id}));
 245   }
 246
 247   if ($self->order->{$self->cv}->contacts && scalar @{ $self->order->{$self->cv}->contacts } > 0) {
 248     $self->js->show('#cp_row');
 249   } else {
 250     $self->js->hide('#cp_row');
 251   }
 252
 253   if ($self->order->{$self->cv}->shipto && scalar @{ $self->order->{$self->cv}->shipto } > 0) {
 254     $self->js->show('#shipto_row');
 255   } else {
 256     $self->js->hide('#shipto_row');
 257   }
 258
 259   $self->js
 260     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 261     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 262     ->val('#order_taxzone_id', $self->order->{$self->cv}->taxzone_id)
 263     ->focus('#order_' . $self->cv . '_id')
 264     ->render($self);
 265 }
 266
 267 sub action_add_item {
 268   my ($self) = @_;
 269
 270   my $form_attr = $::form->{add_item};
 271
 272   return unless $form_attr->{parts_id};
 273
 274   my $item = SL::DB::OrderItem->new;
 275   $item->assign_attributes(%$form_attr);
 276
 277   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 278   my $cv_method   = $self->cv;
 279   my $cv_discount = $self->order->$cv_method? $self->order->$cv_method->discount : 0.0;
 280
 281   my %new_attr;
 282   $new_attr{part}        = $part;
 283   $new_attr{description} = $part->description if ! $item->description;
 284   $new_attr{qty}         = 1.0                if ! $item->qty;
 285   $new_attr{unit}        = $part->unit;
 286   $new_attr{sellprice}   = $part->sellprice   if ! $item->sellprice;
 287   $new_attr{discount}    = $cv_discount       if ! $item->discount;
 288
 289   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 290   # they cannot be retrieved via custom_variables until the order/orderitem is
 291   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 292   $new_attr{custom_variables} = [];
 293
 294   $item->assign_attributes(%new_attr);
 295
 296   $self->order->add_items($item);
 297
 298   $self->_recalc();
 299
 300   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 301   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 302
 303   $self->js
 304     ->append('#row_table_id', $row_as_html)
 305     ->val('#add_item_parts_id', '')
 306     ->val('#add_item_parts_id_name', '')
 307     ->val('#add_item_description', '')
 308     ->val('#add_item_qty_as_number', '')
 309     ->val('#add_item_sellprice_as_number', '')
 310     ->val('#add_item_discount_as_percent', '')
 311     ->run('row_table_scroll_down')
 312     ->run('row_set_keyboard_events_by_id', $item_id)
 313     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 314     ->focus('#add_item_parts_id_name');
 315
 316   $self->_js_redisplay_amounts_and_taxes;
 317   $self->js->render();
 318 }
 319
 320 sub action_recalc_amounts_and_taxes {
 321   my ($self) = @_;
 322
 323   $self->_recalc();
 324
 325   $self->_js_redisplay_linetotals;
 326   $self->_js_redisplay_amounts_and_taxes;
 327   $self->js->render();
 328 }
 329
 330 sub _js_redisplay_linetotals {
 331   my ($self) = @_;
 332
 333   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 334   $self->js
 335     ->run('redisplay_linetotals', \@data);
 336 }
 337
 338 sub _js_redisplay_amounts_and_taxes {
 339   my ($self) = @_;
 340
 341   if (scalar @{ $self->{taxes} }) {
 342     $self->js->show('#taxincluded_row_id');
 343   } else {
 344     $self->js->hide('#taxincluded_row_id');
 345   }
 346
 347   if ($self->order->taxincluded) {
 348     $self->js->hide('#subtotal_row_id');
 349   } else {
 350     $self->js->show('#subtotal_row_id');
 351   }
 352
 353   $self->js
 354     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 355     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 356     ->remove('.tax_row')
 357     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 358 }
 359
 360 #
 361 # helpers
 362 #
 363
 364 sub init_valid_types {
 365   [ _sales_order_type(), _purchase_order_type() ];
 366 }
 367
 368 sub init_type {
 369   my ($self) = @_;
 370
 371   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 372     die "Not a valid type for order";
 373   }
 374
 375   $self->type($::form->{type});
 376 }
 377
 378 sub init_cv {
 379   my ($self) = @_;
 380
 381   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 382          : $self->type eq _purchase_order_type() ? 'vendor'
 383          : die "Not a valid type for order";
 384
 385   return $cv;
 386 }
 387
 388 sub init_p {
 389   SL::Presenter->get;
 390 }
 391
 392 sub init_order {
 393   _make_order();
 394 }
 395
 396 sub _check_auth {
 397   my ($self) = @_;
 398
 399   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 400
 401   my $right   = $right_for->{ $self->type };
 402   $right    ||= 'DOES_NOT_EXIST';
 403
 404   $::auth->assert($right);
 405 }
 406
 407 sub build_contact_select {
 408   my ($self) = @_;
 409
 410   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 411                        value_key  => 'cp_id',
 412                        title_key  => 'full_name_dep',
 413                        default    => $self->order->cp_id,
 414                        with_empty => 1,
 415                        style      => 'width: 300px',
 416   );
 417 }
 418
 419 sub build_shipto_select {
 420   my ($self) = @_;
 421
 422   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 423                        value_key  => 'shipto_id',
 424                        title_key  => 'displayable_id',
 425                        default    => $self->order->shipto_id,
 426                        with_empty => 1,
 427                        style      => 'width: 300px',
 428   );
 429 }
 430
 431 sub build_tax_rows {
 432   my ($self) = @_;
 433
 434   my $rows_as_html;
 435   foreach my $tax (@{ $self->{taxes} }) {
 436     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 437   }
 438   return $rows_as_html;
 439 }
 440
 441
 442 sub _make_order {
 443   my ($self) = @_;
 444
 445   # add_items adds items to an order with no items for saving, but they cannot
 446   # be retrieved via items until the order is saved. Adding empty items to new
 447   # order here solves this problem.
 448   my $order;
 449   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 450   $order ||= SL::DB::Order->new(orderitems => []);
 451
 452   $order->assign_attributes(%{$::form->{order}});
 453
 454   return $order;
 455 }
 456
 457
 458 sub _recalc {
 459   my ($self) = @_;
 460
 461   # bb: todo: currency later
 462   $self->order->currency_id($::instance_conf->get_currency_id());
 463
 464   my %pat = $self->order->calculate_prices_and_taxes();
 465   $self->{taxes} = [];
 466   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 467     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 468
 469     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 470     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 471                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 472                                 tax       => $tax });
 473   }
 474
 475   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 476 }
 477
 478
 479 sub _get_unalterable_data {
 480   my ($self) = @_;
 481
 482   foreach my $item (@{ $self->order->items }) {
 483     if ($item->id) {
 484       # load data from orderitems (db)
 485       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 486       $item->$_($db_item->$_) for qw(active_discount_source active_price_source longdescription);
 487     } else {
 488       # set data from part (or other sources)
 489       $item->longdescription($item->part->notes);
 490       #$item->active_price_source('');
 491       #$item->active_discount_source('');
 492     }
 493
 494     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 495     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 496     foreach my $var (@{ $item->cvars_by_config }) {
 497       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 498     }
 499     $item->parse_custom_variable_values;
 500   }
 501 }
 502
 503
 504 sub _save {
 505   my ($self) = @_;
 506
 507   my $errors = [];
 508   my $db = $self->order->db;
 509
 510   $db->do_transaction(
 511     sub {
 512       $self->order->save();
 513   }) || push(@{$errors}, $db->error);
 514
 515   return $errors;
 516 }
 517
 518
 519 sub _pre_render {
 520   my ($self) = @_;
 521
 522   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 523   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 524                                                                                        deleted => 0 ] ],
 525                                                                     sort_by => 'name');
 526   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 527                                                                                        deleted => 0 ] ],
 528                                                                     sort_by => 'name');
 529   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 530                                                                                       active => 1 ] ],
 531                                                                    sort_by => 'projectnumber');
 532   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 533   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 534
 535   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 536
 537   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 538 }
 539
 540 sub _create_pdf {
 541   my ($order, $pdf_ref, $params) = @_;
 542
 543   my $print_form = Form->new('');
 544   $print_form->{type}     = 'sales_order';
 545   $print_form->{formname} = 'sales_order',
 546   $print_form->{format}   = $params->{format} || 'pdf',
 547   $print_form->{media}    = $params->{media}  || 'file';
 548
 549   $order->flatten_to_form($print_form, format_amounts => 1);
 550   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 551   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 552
 553   my @errors = ();
 554   $print_form->throw_on_error(sub {
 555     eval {
 556       $print_form->prepare_for_printing;
 557
 558       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 559         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 560         variables => $print_form,
 561         variable_content_types => {
 562           longdescription => 'html',
 563           partnotes       => 'html',
 564           notes           => 'html',
 565         },
 566       );
 567       1;
 568     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 569   });
 570
 571   return @errors;
 572 }
 573
 574 sub _sales_order_type {
 575   'sales_order';
 576 }
 577
 578 sub _purchase_order_type {
 579   'purchase_order';
 580 }
 581
 582 1;
 583
 584 __END__
 585
 586 =encoding utf-8
 587
 588 =head1 NAME
 589
 590 SL::Controller::Order - controller for orders
 591
 592 =head1 TODO
 593
 594 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 595
 596 =head1 AUTHOR
 597
 598 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 599
 600 =cut
 601