SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Price;
  22
  23 use SL::Helper::DateTime;
  24 use SL::Helper::CreatePDF qw(:all);
  25
  26 use List::Util qw(max first);
  27 use List::MoreUtils qw(none pairwise first_index);
  28 use English qw(-no_match_vars);
  29 use File::Spec;
  30
  31 use Rose::Object::MakeMethods::Generic
  32 (
  33  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  34 );
  35
  36
  37 # safety
  38 __PACKAGE__->run_before('_check_auth');
  39
  40 __PACKAGE__->run_before('_recalc',
  41                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  42
  43 __PACKAGE__->run_before('_get_unalterable_data',
  44                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  45
  46 #
  47 # actions
  48 #
  49
  50 sub action_add {
  51   my ($self) = @_;
  52
  53   $self->order->transdate(DateTime->now_local());
  54
  55   $self->_pre_render();
  56   $self->render(
  57     'order/form',
  58     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  59            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  60            : '',
  61     %{$self->{template_args}}
  62   );
  63 }
  64
  65 sub action_edit {
  66   my ($self) = @_;
  67
  68   $self->_pre_render();
  69   $self->render(
  70     'order/form',
  71     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  72            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  73            : '',
  74     %{$self->{template_args}}
  75   );
  76 }
  77
  78 sub action_update {
  79   my ($self) = @_;
  80
  81   $self->_pre_render();
  82   $self->render(
  83     'order/form',
  84     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  85            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  86            : '',
  87     %{$self->{template_args}}
  88   );
  89 }
  90
  91 sub action_save {
  92   my ($self) = @_;
  93
  94   my $errors = $self->_save();
  95
  96   if (scalar @{ $errors }) {
  97     $self->js->flash('error', $_) foreach @{ $errors };
  98     return $self->js->render();
  99   }
 100
 101   flash_later('info', $::locale->text('The order has been saved'));
 102   my @redirect_params = (
 103     action => 'edit',
 104     type   => $self->type,
 105     id     => $self->order->id,
 106   );
 107
 108   $self->redirect_to(@redirect_params);
 109 }
 110
 111 sub action_create_pdf {
 112   my ($self) = @_;
 113
 114   my $pdf;
 115   my @errors = _create_pdf($self->order, \$pdf);
 116   if (scalar @errors) {
 117     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 118   }
 119
 120   my $sfile = SL::SessionFile::Random->new(mode => "w");
 121   $sfile->fh->print($pdf);
 122   $sfile->fh->close;
 123
 124   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 125   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 126
 127   $::form->{formname}  = $self->type;
 128   $::form->{language} = 'de';
 129   my $pdf_filename =  $::form->get_formname_translation . '_' . $self->order->ordnumber . '.pdf';
 130
 131   $self->js
 132     ->run('download_pdf', $pdf_filename, $key)
 133     ->flash('info', t8('The PDF has been created'))->render($self);
 134 }
 135
 136 sub action_download_pdf {
 137   my ($self) = @_;
 138
 139   my $key = $::form->{key};
 140   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 141   return $self->send_file(
 142     $tmp_filename,
 143     type => 'application/pdf',
 144     name => $::form->{pdf_filename},
 145   );
 146 }
 147
 148 sub action_show_email_dialog {
 149   my ($self) = @_;
 150
 151   my $cv_method = $self->cv;
 152
 153   if (!$self->order->$cv_method) {
 154     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 155                     ->render($self);
 156   }
 157
 158   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 159   $self->{email}->{to} ||= $self->order->$cv_method->email;
 160   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 161   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 162   # Todo: get addresses from shipto, if any
 163
 164   my $form = Form->new;
 165   $form->{ordnumber} = $self->order->ordnumber;
 166   $form->{formname}  = $self->type;
 167   $form->{type}      = $self->type;
 168   $form->{language} = 'de';
 169   $form->{format}   = 'pdf';
 170
 171   $self->{email}->{subject}             = $form->generate_email_subject();
 172   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 173   $self->{email}->{message}             = $form->create_email_signature();
 174
 175   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 176   $self->js
 177       ->run('show_email_dialog', $dialog_html)
 178       ->reinit_widgets
 179       ->render($self);
 180 }
 181
 182 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 183 sub action_send_email {
 184   my ($self) = @_;
 185
 186   my $mail      = Mailer->new;
 187   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 188   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 189
 190   my $pdf;
 191   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 192   if (scalar @errors) {
 193     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 194   }
 195
 196   $mail->{attachments} = [{ "content" => $pdf,
 197                             "name"    => $::form->{email}->{attachment_filename} }];
 198
 199   if (my $err = $mail->send) {
 200     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 201                     ->render($self);
 202   }
 203
 204   # internal notes
 205   my $intnotes = $self->order->intnotes;
 206   $intnotes   .= "\n\n" if $self->order->intnotes;
 207   $intnotes   .= t8('[email]')                                                                                        . "\n";
 208   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 209   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 210   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 211   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 212   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 213   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 214
 215   $self->js
 216       ->val('#order_intnotes', $intnotes)
 217       ->run('close_email_dialog')
 218       ->render($self);
 219 }
 220
 221 sub action_save_and_delivery_order {
 222   my ($self) = @_;
 223
 224   my $errors = $self->_save();
 225
 226   if (scalar @{ $errors }) {
 227     $self->js->flash('error', $_) foreach @{ $errors };
 228     return $self->js->render();
 229   }
 230
 231   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 232
 233   flash_later('info', $::locale->text('The order has been saved'));
 234   my @redirect_params = (
 235     controller => 'do.pl',
 236     action     => 'edit',
 237     type       => $delivery_order->type,
 238     id         => $delivery_order->id,
 239     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 240   );
 241
 242   $self->redirect_to(@redirect_params);
 243 }
 244
 245 sub action_customer_vendor_changed {
 246   my ($self) = @_;
 247
 248   my $cv_method = $self->cv;
 249
 250   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 251     $self->js->show('#cp_row');
 252   } else {
 253     $self->js->hide('#cp_row');
 254   }
 255
 256   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 257     $self->js->show('#shipto_row');
 258   } else {
 259     $self->js->hide('#shipto_row');
 260   }
 261
 262   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 263
 264   if ($self->order->is_sales) {
 265     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 266                               ? $self->order->$cv_method->taxincluded_checked
 267                               : $::myconfig{taxincluded_checked});
 268   }
 269
 270   $self->_recalc();
 271
 272   $self->js
 273     ->replaceWith('#order_cp_id',       $self->build_contact_select)
 274     ->replaceWith('#order_shipto_id',   $self->build_shipto_select)
 275     ->val(        '#order_taxzone_id',  $self->order->taxzone_id)
 276     ->val(        '#order_taxincluded', $self->order->taxincluded)
 277     ->focus(      '#order_' . $self->cv . '_id');
 278
 279   $self->_js_redisplay_amounts_and_taxes;
 280   $self->js->render();
 281 }
 282
 283 sub action_add_item {
 284   my ($self) = @_;
 285
 286   my $form_attr = $::form->{add_item};
 287
 288   return unless $form_attr->{parts_id};
 289
 290   my $item = SL::DB::OrderItem->new;
 291   $item->assign_attributes(%$form_attr);
 292
 293   my $part         = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 294
 295   my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 296
 297   my $price_src;
 298   if ($item->sellprice) {
 299     $price_src = $price_source->price_from_source("");
 300     $price_src->price($item->sellprice);
 301   } else {
 302     $price_src = $price_source->best_price
 303            ? $price_source->best_price
 304            : $price_source->price_from_source("");
 305     $price_src->price(0) if !$price_source->best_price;
 306   }
 307
 308   my $discount_src;
 309   if ($item->discount) {
 310     $discount_src = $price_source->discount_from_source("");
 311     $discount_src->discount($item->discount);
 312   } else {
 313     $discount_src = $price_source->best_discount
 314                   ? $price_source->best_discount
 315                   : $price_source->discount_from_source("");
 316     $discount_src->discount(0) if !$price_source->best_discount;
 317   }
 318
 319   my %new_attr;
 320   $new_attr{part}                   = $part;
 321   $new_attr{description}            = $part->description if ! $item->description;
 322   $new_attr{qty}                    = 1.0                if ! $item->qty;
 323   $new_attr{sellprice}              = $price_src->price;
 324   $new_attr{discount}               = $discount_src->discount;
 325   $new_attr{active_price_source}    = $price_src;
 326   $new_attr{active_discount_source} = $discount_src;
 327
 328   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 329   # they cannot be retrieved via custom_variables until the order/orderitem is
 330   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 331   $new_attr{custom_variables} = [];
 332
 333   $item->assign_attributes(%new_attr);
 334
 335   $self->order->add_items($item);
 336
 337   $self->_recalc();
 338
 339   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 340   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 341
 342   $self->js
 343     ->append('#row_table_id', $row_as_html)
 344     ->val('#add_item_parts_id', '')
 345     ->val('#add_item_parts_id_name', '')
 346     ->val('#add_item_description', '')
 347     ->val('#add_item_qty_as_number', '')
 348     ->val('#add_item_sellprice_as_number', '')
 349     ->val('#add_item_discount_as_percent', '')
 350     ->run('row_table_scroll_down')
 351     ->run('row_set_keyboard_events_by_id', $item_id)
 352     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 353     ->focus('#add_item_parts_id_name');
 354
 355   $self->_js_redisplay_amounts_and_taxes;
 356   $self->js->render();
 357 }
 358
 359 sub action_recalc_amounts_and_taxes {
 360   my ($self) = @_;
 361
 362   $self->_recalc();
 363
 364   $self->_js_redisplay_linetotals;
 365   $self->_js_redisplay_amounts_and_taxes;
 366   $self->js->render();
 367 }
 368
 369 sub action_price_popup {
 370   my ($self) = @_;
 371
 372   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 373   my $item = $self->order->items->[$idx];
 374
 375   $self->render_price_dialog($item);
 376 }
 377
 378 sub _js_redisplay_linetotals {
 379   my ($self) = @_;
 380
 381   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 382   $self->js
 383     ->run('redisplay_linetotals', \@data);
 384 }
 385
 386 sub _js_redisplay_amounts_and_taxes {
 387   my ($self) = @_;
 388
 389   if (scalar @{ $self->{taxes} }) {
 390     $self->js->show('#taxincluded_row_id');
 391   } else {
 392     $self->js->hide('#taxincluded_row_id');
 393   }
 394
 395   if ($self->order->taxincluded) {
 396     $self->js->hide('#subtotal_row_id');
 397   } else {
 398     $self->js->show('#subtotal_row_id');
 399   }
 400
 401   $self->js
 402     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 403     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 404     ->remove('.tax_row')
 405     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 406 }
 407
 408 #
 409 # helpers
 410 #
 411
 412 sub init_valid_types {
 413   [ _sales_order_type(), _purchase_order_type() ];
 414 }
 415
 416 sub init_type {
 417   my ($self) = @_;
 418
 419   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 420     die "Not a valid type for order";
 421   }
 422
 423   $self->type($::form->{type});
 424 }
 425
 426 sub init_cv {
 427   my ($self) = @_;
 428
 429   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 430          : $self->type eq _purchase_order_type() ? 'vendor'
 431          : die "Not a valid type for order";
 432
 433   return $cv;
 434 }
 435
 436 sub init_p {
 437   SL::Presenter->get;
 438 }
 439
 440 sub init_order {
 441   _make_order();
 442 }
 443
 444 sub _check_auth {
 445   my ($self) = @_;
 446
 447   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 448
 449   my $right   = $right_for->{ $self->type };
 450   $right    ||= 'DOES_NOT_EXIST';
 451
 452   $::auth->assert($right);
 453 }
 454
 455 sub build_contact_select {
 456   my ($self) = @_;
 457
 458   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 459                        value_key  => 'cp_id',
 460                        title_key  => 'full_name_dep',
 461                        default    => $self->order->cp_id,
 462                        with_empty => 1,
 463                        style      => 'width: 300px',
 464   );
 465 }
 466
 467 sub build_shipto_select {
 468   my ($self) = @_;
 469
 470   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 471                        value_key  => 'shipto_id',
 472                        title_key  => 'displayable_id',
 473                        default    => $self->order->shipto_id,
 474                        with_empty => 1,
 475                        style      => 'width: 300px',
 476   );
 477 }
 478
 479 sub build_tax_rows {
 480   my ($self) = @_;
 481
 482   my $rows_as_html;
 483   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 484     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 485   }
 486   return $rows_as_html;
 487 }
 488
 489
 490 sub render_price_dialog {
 491   my ($self, $record_item) = @_;
 492
 493   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 494
 495   $self->js
 496     ->run(
 497       'kivi.io.price_chooser_dialog',
 498       t8('Available Prices'),
 499       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 500     )
 501     ->reinit_widgets;
 502
 503 #   if (@errors) {
 504 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 505 #     $self->js->show('#dialog_flash_error');
 506 #   }
 507
 508   $self->js->render;
 509 }
 510
 511 sub _make_order {
 512   my ($self) = @_;
 513
 514   # add_items adds items to an order with no items for saving, but they cannot
 515   # be retrieved via items until the order is saved. Adding empty items to new
 516   # order here solves this problem.
 517   my $order;
 518   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 519   $order ||= SL::DB::Order->new(orderitems => []);
 520
 521   $order->assign_attributes(%{$::form->{order}});
 522
 523   return $order;
 524 }
 525
 526 sub _recalc {
 527   my ($self) = @_;
 528
 529   # bb: todo: currency later
 530   $self->order->currency_id($::instance_conf->get_currency_id());
 531
 532   my %pat = $self->order->calculate_prices_and_taxes();
 533   $self->{taxes} = [];
 534   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 535     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 536
 537     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 538     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 539                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 540                                 tax       => $tax });
 541   }
 542
 543   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 544 }
 545
 546
 547 sub _get_unalterable_data {
 548   my ($self) = @_;
 549
 550   foreach my $item (@{ $self->order->items }) {
 551     if ($item->id) {
 552       # load data from orderitems (db)
 553       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 554       $item->$_($db_item->$_) for qw(longdescription);
 555     } else {
 556       # set data from part (or other sources)
 557       $item->longdescription($item->part->notes);
 558     }
 559
 560     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 561     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 562     foreach my $var (@{ $item->cvars_by_config }) {
 563       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 564     }
 565     $item->parse_custom_variable_values;
 566   }
 567 }
 568
 569
 570 sub _save {
 571   my ($self) = @_;
 572
 573   my $errors = [];
 574   my $db = $self->order->db;
 575
 576   $db->do_transaction(
 577     sub {
 578       $self->order->save();
 579   }) || push(@{$errors}, $db->error);
 580
 581   return $errors;
 582 }
 583
 584
 585 sub _pre_render {
 586   my ($self) = @_;
 587
 588   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 589   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 590                                                                                        deleted => 0 ] ],
 591                                                                     sort_by => 'name');
 592   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 593                                                                                        deleted => 0 ] ],
 594                                                                     sort_by => 'name');
 595   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 596                                                                                       active => 1 ] ],
 597                                                                    sort_by => 'projectnumber');
 598   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 599   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 600
 601   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 602
 603   foreach  my $item (@{$self->order->items}) {
 604     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 605     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 606     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 607
 608   }
 609
 610   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 611 }
 612
 613 sub _create_pdf {
 614   my ($order, $pdf_ref, $params) = @_;
 615
 616   my $print_form = Form->new('');
 617   $print_form->{type}     = $order->type;
 618   $print_form->{formname} = $order->type;
 619   $print_form->{format}   = $params->{format} || 'pdf',
 620   $print_form->{media}    = $params->{media}  || 'file';
 621
 622   $order->flatten_to_form($print_form, format_amounts => 1);
 623   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 624   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 625
 626   my @errors = ();
 627   $print_form->throw_on_error(sub {
 628     eval {
 629       $print_form->prepare_for_printing;
 630
 631       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 632         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 633         variables => $print_form,
 634         variable_content_types => {
 635           longdescription => 'html',
 636           partnotes       => 'html',
 637           notes           => 'html',
 638         },
 639       );
 640       1;
 641     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 642   });
 643
 644   return @errors;
 645 }
 646
 647 sub _sales_order_type {
 648   'sales_order';
 649 }
 650
 651 sub _purchase_order_type {
 652   'purchase_order';
 653 }
 654
 655 1;
 656
 657 __END__
 658
 659 =encoding utf-8
 660
 661 =head1 NAME
 662
 663 SL::Controller::Order - controller for orders
 664
 665 =head1 TODO
 666
 667 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 668
 669 =head1 AUTHOR
 670
 671 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 672
 673 =cut
 674