SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13
  14 use SL::DB::Order;
  15 use SL::DB::Customer;
  16 use SL::DB::Vendor;
  17 use SL::DB::TaxZone;
  18 use SL::DB::Employee;
  19 use SL::DB::Project;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22 use SL::DB::Price;
  23 use SL::DB::Part;
  24
  25 use SL::Helper::DateTime;
  26 use SL::Helper::CreatePDF qw(:all);
  27
  28 use SL::Controller::Helper::GetModels;
  29
  30 use List::Util qw(max first);
  31 use List::MoreUtils qw(none pairwise first_index);
  32 use English qw(-no_match_vars);
  33 use File::Spec;
  34
  35 use Rose::Object::MakeMethods::Generic
  36 (
  37  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models) ],
  38 );
  39
  40
  41 # safety
  42 __PACKAGE__->run_before('_check_auth');
  43
  44 __PACKAGE__->run_before('_recalc',
  45                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  46
  47 __PACKAGE__->run_before('_get_unalterable_data',
  48                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  49
  50 #
  51 # actions
  52 #
  53
  54 sub action_add {
  55   my ($self) = @_;
  56
  57   $self->order->transdate(DateTime->now_local());
  58   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  59
  60   $self->_pre_render();
  61   $self->render(
  62     'order/form',
  63     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  64            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  65            : '',
  66     %{$self->{template_args}}
  67   );
  68 }
  69
  70 sub action_edit {
  71   my ($self) = @_;
  72
  73   $self->_pre_render();
  74   $self->render(
  75     'order/form',
  76     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  77            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  78            : '',
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 sub action_update {
  84   my ($self) = @_;
  85
  86   $self->_pre_render();
  87   $self->render(
  88     'order/form',
  89     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  90            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  91            : '',
  92     %{$self->{template_args}}
  93   );
  94 }
  95
  96 sub action_save {
  97   my ($self) = @_;
  98
  99   my $errors = $self->_save();
 100
 101   if (scalar @{ $errors }) {
 102     $self->js->flash('error', $_) foreach @{ $errors };
 103     return $self->js->render();
 104   }
 105
 106   flash_later('info', $::locale->text('The order has been saved'));
 107   my @redirect_params = (
 108     action => 'edit',
 109     type   => $self->type,
 110     id     => $self->order->id,
 111   );
 112
 113   $self->redirect_to(@redirect_params);
 114 }
 115
 116 sub action_create_pdf {
 117   my ($self) = @_;
 118
 119   my $pdf;
 120   my @errors = _create_pdf($self->order, \$pdf);
 121   if (scalar @errors) {
 122     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 123   }
 124
 125   my $sfile = SL::SessionFile::Random->new(mode => "w");
 126   $sfile->fh->print($pdf);
 127   $sfile->fh->close;
 128
 129   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 130   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 131
 132   my $form = Form->new;
 133   $form->{ordnumber} = $self->order->ordnumber;
 134   $form->{formname}  = $self->type;
 135   $form->{type}      = $self->type;
 136   $form->{language}  = 'de';
 137   $form->{format}    = 'pdf';
 138
 139   my $pdf_filename = $form->generate_attachment_filename();
 140
 141   # copy file to webdav folder
 142   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 143     my $webdav = SL::Webdav->new(
 144       type     => $self->type,
 145       number   => $self->order->ordnumber,
 146     );
 147     my $webdav_file = SL::Webdav::File->new(
 148       webdav   => $webdav,
 149       filename => $pdf_filename,
 150     );
 151     eval {
 152       $webdav_file->store(data => \$pdf);
 153       1;
 154     } or do {
 155       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 156     }
 157   }
 158
 159   $self->js
 160     ->run('download_pdf', $pdf_filename, $key)
 161     ->flash('info', t8('The PDF has been created'))->render($self);
 162 }
 163
 164 sub action_download_pdf {
 165   my ($self) = @_;
 166
 167   my $key = $::form->{key};
 168   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 169   return $self->send_file(
 170     $tmp_filename,
 171     type => 'application/pdf',
 172     name => $::form->{pdf_filename},
 173   );
 174 }
 175
 176 sub action_show_email_dialog {
 177   my ($self) = @_;
 178
 179   my $cv_method = $self->cv;
 180
 181   if (!$self->order->$cv_method) {
 182     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 183                     ->render($self);
 184   }
 185
 186   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 187   $self->{email}->{to} ||= $self->order->$cv_method->email;
 188   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 189   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 190   # Todo: get addresses from shipto, if any
 191
 192   my $form = Form->new;
 193   $form->{ordnumber} = $self->order->ordnumber;
 194   $form->{formname}  = $self->type;
 195   $form->{type}      = $self->type;
 196   $form->{language} = 'de';
 197   $form->{format}   = 'pdf';
 198
 199   $self->{email}->{subject}             = $form->generate_email_subject();
 200   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 201   $self->{email}->{message}             = $form->create_email_signature();
 202
 203   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 204   $self->js
 205       ->run('show_email_dialog', $dialog_html)
 206       ->reinit_widgets
 207       ->render($self);
 208 }
 209
 210 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 211 sub action_send_email {
 212   my ($self) = @_;
 213
 214   my $mail      = Mailer->new;
 215   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 216   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 217
 218   my $pdf;
 219   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 220   if (scalar @errors) {
 221     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 222   }
 223
 224   $mail->{attachments} = [{ "content" => $pdf,
 225                             "name"    => $::form->{email}->{attachment_filename} }];
 226
 227   if (my $err = $mail->send) {
 228     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 229                     ->render($self);
 230   }
 231
 232   # internal notes
 233   my $intnotes = $self->order->intnotes;
 234   $intnotes   .= "\n\n" if $self->order->intnotes;
 235   $intnotes   .= t8('[email]')                                                                                        . "\n";
 236   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 237   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 238   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 239   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 240   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 241   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 242
 243   $self->js
 244       ->val('#order_intnotes', $intnotes)
 245       ->run('close_email_dialog')
 246       ->render($self);
 247 }
 248
 249 sub action_save_and_delivery_order {
 250   my ($self) = @_;
 251
 252   my $errors = $self->_save();
 253
 254   if (scalar @{ $errors }) {
 255     $self->js->flash('error', $_) foreach @{ $errors };
 256     return $self->js->render();
 257   }
 258
 259   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 260
 261   flash_later('info', $::locale->text('The order has been saved'));
 262   my @redirect_params = (
 263     controller => 'do.pl',
 264     action     => 'edit',
 265     type       => $delivery_order->type,
 266     id         => $delivery_order->id,
 267     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 268   );
 269
 270   $self->redirect_to(@redirect_params);
 271 }
 272
 273 sub action_customer_vendor_changed {
 274   my ($self) = @_;
 275
 276   my $cv_method = $self->cv;
 277
 278   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 279     $self->js->show('#cp_row');
 280   } else {
 281     $self->js->hide('#cp_row');
 282   }
 283
 284   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 285     $self->js->show('#shipto_row');
 286   } else {
 287     $self->js->hide('#shipto_row');
 288   }
 289
 290   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 291
 292   if ($self->order->is_sales) {
 293     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 294                               ? $self->order->$cv_method->taxincluded_checked
 295                               : $::myconfig{taxincluded_checked});
 296   }
 297
 298   $self->order->payment_id($self->order->$cv_method->payment_id);
 299   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 300
 301   $self->_recalc();
 302
 303   $self->js
 304     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 305     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 306     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 307     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 308     ->val(        '#order_payment_id',       $self->order->payment_id)
 309     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 310     ->focus(      '#order_' . $self->cv . '_id');
 311
 312   $self->_js_redisplay_amounts_and_taxes;
 313   $self->js->render();
 314 }
 315
 316 sub action_add_item {
 317   my ($self) = @_;
 318
 319   my $form_attr = $::form->{add_item};
 320
 321   return unless $form_attr->{parts_id};
 322
 323   my $item = _make_item($self->order, $form_attr);
 324   $self->order->add_items($item);
 325
 326   $self->_recalc();
 327
 328   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 329   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 330
 331   $self->js
 332     ->append('#row_table_id', $row_as_html)
 333     ->val('#add_item_parts_id', '')
 334     ->val('#add_item_parts_id_name', '')
 335     ->val('#add_item_description', '')
 336     ->val('#add_item_qty_as_number', '')
 337     ->val('#add_item_sellprice_as_number', '')
 338     ->val('#add_item_discount_as_percent', '')
 339     ->run('row_table_scroll_down')
 340     ->run('row_set_keyboard_events_by_id', $item_id)
 341     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 342     ->on('.reformat_number', 'change', 'reformat_number')
 343     ->focus('#add_item_parts_id_name');
 344
 345   $self->_js_redisplay_amounts_and_taxes;
 346   $self->js->render();
 347 }
 348
 349 sub action_show_multi_items_dialog {
 350   require SL::DB::PartsGroup;
 351   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 352                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 353 }
 354
 355 sub action_multi_items_update_result {
 356   my $multi_items = $_[0]->multi_items_models->get;
 357   if (scalar @{$multi_items}) {
 358     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 359                   multi_items => $multi_items);
 360   } else {
 361     $_[0]->render(\'', { layout => 0 }); # ') make emacs happy
 362   }
 363 }
 364
 365 sub action_add_multi_items {
 366   my ($self) = @_;
 367
 368   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 369   return $self->js->render() unless scalar @form_attr;
 370
 371   my @items;
 372   foreach my $attr (@form_attr) {
 373     push @items, _make_item($self->order, $attr);
 374   }
 375   $self->order->add_items(@items);
 376
 377   $self->_recalc();
 378
 379   foreach my $item (@items) {
 380     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 381     my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 382
 383     $self->js
 384         ->append('#row_table_id', $row_as_html)
 385         ->run('row_set_keyboard_events_by_id', $item_id);
 386   }
 387
 388   $self->js
 389     ->run('close_multi_items_dialog')
 390     ->run('row_table_scroll_down')
 391     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 392     ->on('.reformat_number', 'change', 'reformat_number')
 393     ->focus('#add_item_parts_id_name');
 394
 395   $self->_js_redisplay_amounts_and_taxes;
 396   $self->js->render();
 397 }
 398
 399 sub action_recalc_amounts_and_taxes {
 400   my ($self) = @_;
 401
 402   $self->_recalc();
 403
 404   $self->_js_redisplay_linetotals;
 405   $self->_js_redisplay_amounts_and_taxes;
 406   $self->js->render();
 407 }
 408
 409 sub action_price_popup {
 410   my ($self) = @_;
 411
 412   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 413   my $item = $self->order->items->[$idx];
 414
 415   $self->render_price_dialog($item);
 416 }
 417
 418 sub _js_redisplay_linetotals {
 419   my ($self) = @_;
 420
 421   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 422   $self->js
 423     ->run('redisplay_linetotals', \@data);
 424 }
 425
 426 sub _js_redisplay_amounts_and_taxes {
 427   my ($self) = @_;
 428
 429   if (scalar @{ $self->{taxes} }) {
 430     $self->js->show('#taxincluded_row_id');
 431   } else {
 432     $self->js->hide('#taxincluded_row_id');
 433   }
 434
 435   if ($self->order->taxincluded) {
 436     $self->js->hide('#subtotal_row_id');
 437   } else {
 438     $self->js->show('#subtotal_row_id');
 439   }
 440
 441   $self->js
 442     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 443     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 444     ->remove('.tax_row')
 445     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 446 }
 447
 448 #
 449 # helpers
 450 #
 451
 452 sub init_valid_types {
 453   [ _sales_order_type(), _purchase_order_type() ];
 454 }
 455
 456 sub init_type {
 457   my ($self) = @_;
 458
 459   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 460     die "Not a valid type for order";
 461   }
 462
 463   $self->type($::form->{type});
 464 }
 465
 466 sub init_cv {
 467   my ($self) = @_;
 468
 469   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 470          : $self->type eq _purchase_order_type() ? 'vendor'
 471          : die "Not a valid type for order";
 472
 473   return $cv;
 474 }
 475
 476 sub init_p {
 477   SL::Presenter->get;
 478 }
 479
 480 sub init_order {
 481   _make_order();
 482 }
 483
 484 sub init_multi_items_models {
 485   SL::Controller::Helper::GetModels->new(
 486     controller     => $_[0],
 487     model          => 'Part',
 488     with_objects   => [ qw(unit_obj) ],
 489     disable_plugin => 'paginated',
 490     source         => $::form->{multi_items},
 491     sorted         => {
 492       _default    => {
 493         by  => 'partnumber',
 494         dir => 1,
 495       },
 496       partnumber  => t8('Partnumber'),
 497       description => t8('Description')}
 498   );
 499 }
 500
 501 sub _check_auth {
 502   my ($self) = @_;
 503
 504   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 505
 506   my $right   = $right_for->{ $self->type };
 507   $right    ||= 'DOES_NOT_EXIST';
 508
 509   $::auth->assert($right);
 510 }
 511
 512 sub build_contact_select {
 513   my ($self) = @_;
 514
 515   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 516                        value_key  => 'cp_id',
 517                        title_key  => 'full_name_dep',
 518                        default    => $self->order->cp_id,
 519                        with_empty => 1,
 520                        style      => 'width: 300px',
 521   );
 522 }
 523
 524 sub build_shipto_select {
 525   my ($self) = @_;
 526
 527   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 528                        value_key  => 'shipto_id',
 529                        title_key  => 'displayable_id',
 530                        default    => $self->order->shipto_id,
 531                        with_empty => 1,
 532                        style      => 'width: 300px',
 533   );
 534 }
 535
 536 sub build_tax_rows {
 537   my ($self) = @_;
 538
 539   my $rows_as_html;
 540   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 541     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 542   }
 543   return $rows_as_html;
 544 }
 545
 546
 547 sub render_price_dialog {
 548   my ($self, $record_item) = @_;
 549
 550   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 551
 552   $self->js
 553     ->run(
 554       'kivi.io.price_chooser_dialog',
 555       t8('Available Prices'),
 556       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 557     )
 558     ->reinit_widgets;
 559
 560 #   if (@errors) {
 561 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 562 #     $self->js->show('#dialog_flash_error');
 563 #   }
 564
 565   $self->js->render;
 566 }
 567
 568 sub _make_order {
 569   my ($self) = @_;
 570
 571   # add_items adds items to an order with no items for saving, but they cannot
 572   # be retrieved via items until the order is saved. Adding empty items to new
 573   # order here solves this problem.
 574   my $order;
 575   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 576   $order ||= SL::DB::Order->new(orderitems => []);
 577
 578   $order->assign_attributes(%{$::form->{order}});
 579
 580   return $order;
 581 }
 582
 583 sub _make_item {
 584   my ($record, $attr) = @_;
 585
 586   my $item = SL::DB::OrderItem->new;
 587   $item->assign_attributes(%$attr);
 588
 589   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 590   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 591
 592   $item->unit($part->unit) if !$item->unit;
 593
 594   my $price_src;
 595   if ($item->sellprice) {
 596     $price_src = $price_source->price_from_source("");
 597     $price_src->price($item->sellprice);
 598   } else {
 599     $price_src = $price_source->best_price
 600            ? $price_source->best_price
 601            : $price_source->price_from_source("");
 602     $price_src->price(0) if !$price_source->best_price;
 603   }
 604
 605   my $discount_src;
 606   if ($item->discount) {
 607     $discount_src = $price_source->discount_from_source("");
 608     $discount_src->discount($item->discount);
 609   } else {
 610     $discount_src = $price_source->best_discount
 611                   ? $price_source->best_discount
 612                   : $price_source->discount_from_source("");
 613     $discount_src->discount(0) if !$price_source->best_discount;
 614   }
 615
 616   my %new_attr;
 617   $new_attr{part}                   = $part;
 618   $new_attr{description}            = $part->description if ! $item->description;
 619   $new_attr{qty}                    = 1.0                if ! $item->qty;
 620   $new_attr{sellprice}              = $price_src->price;
 621   $new_attr{discount}               = $discount_src->discount;
 622   $new_attr{active_price_source}    = $price_src;
 623   $new_attr{active_discount_source} = $discount_src;
 624
 625   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 626   # they cannot be retrieved via custom_variables until the order/orderitem is
 627   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 628   $new_attr{custom_variables} = [];
 629
 630   $item->assign_attributes(%new_attr);
 631
 632   return $item;
 633 }
 634
 635 sub _recalc {
 636   my ($self) = @_;
 637
 638   # bb: todo: currency later
 639   $self->order->currency_id($::instance_conf->get_currency_id());
 640
 641   my %pat = $self->order->calculate_prices_and_taxes();
 642   $self->{taxes} = [];
 643   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 644     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 645
 646     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 647     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 648                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 649                                 tax       => $tax });
 650   }
 651
 652   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 653 }
 654
 655
 656 sub _get_unalterable_data {
 657   my ($self) = @_;
 658
 659   foreach my $item (@{ $self->order->items }) {
 660     if ($item->id) {
 661       # load data from orderitems (db)
 662       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 663       $item->$_($db_item->$_) for qw(longdescription);
 664     } else {
 665       # set data from part (or other sources)
 666       $item->longdescription($item->part->notes);
 667     }
 668
 669     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 670     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 671     foreach my $var (@{ $item->cvars_by_config }) {
 672       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 673     }
 674     $item->parse_custom_variable_values;
 675   }
 676 }
 677
 678
 679 sub _save {
 680   my ($self) = @_;
 681
 682   my $errors = [];
 683   my $db = $self->order->db;
 684
 685   $db->do_transaction(
 686     sub {
 687       $self->order->save();
 688   }) || push(@{$errors}, $db->error);
 689
 690   return $errors;
 691 }
 692
 693
 694 sub _pre_render {
 695   my ($self) = @_;
 696
 697   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 698   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 699   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 700                                                                                        deleted => 0 ] ],
 701                                                                     sort_by => 'name');
 702   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 703                                                                                        deleted => 0 ] ],
 704                                                                     sort_by => 'name');
 705   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 706                                                                                       active => 1 ] ],
 707                                                                    sort_by => 'projectnumber');
 708   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 709   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 710
 711   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 712
 713   foreach  my $item (@{$self->order->items}) {
 714     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 715     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 716     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 717
 718   }
 719
 720   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 721     my $webdav = SL::Webdav->new(
 722       type     => $self->type,
 723       number   => $self->order->ordnumber,
 724     );
 725     my $webdav_path = $webdav->webdav_path;
 726     my @all_objects = $webdav->get_all_objects;
 727     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 728                                                     type => t8('File'),
 729                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 730                                                 } } @all_objects;
 731   }
 732
 733   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 734 }
 735
 736 sub _create_pdf {
 737   my ($order, $pdf_ref, $params) = @_;
 738
 739   my $print_form = Form->new('');
 740   $print_form->{type}     = $order->type;
 741   $print_form->{formname} = $order->type;
 742   $print_form->{format}   = $params->{format} || 'pdf',
 743   $print_form->{media}    = $params->{media}  || 'file';
 744
 745   $order->flatten_to_form($print_form, format_amounts => 1);
 746   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 747   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 748
 749   my @errors = ();
 750   $print_form->throw_on_error(sub {
 751     eval {
 752       $print_form->prepare_for_printing;
 753
 754       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 755         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 756         variables => $print_form,
 757         variable_content_types => {
 758           longdescription => 'html',
 759           partnotes       => 'html',
 760           notes           => 'html',
 761         },
 762       );
 763       1;
 764     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 765   });
 766
 767   return @errors;
 768 }
 769
 770 sub _sales_order_type {
 771   'sales_order';
 772 }
 773
 774 sub _purchase_order_type {
 775   'purchase_order';
 776 }
 777
 778 1;
 779
 780 __END__
 781
 782 =encoding utf-8
 783
 784 =head1 NAME
 785
 786 SL::Controller::Order - controller for orders
 787
 788 =head1 TODO
 789
 790 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 791
 792 =head1 AUTHOR
 793
 794 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 795
 796 =cut
 797