SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::PriceSource;
   9
  10 use SL::DB::Order;
  11 use SL::DB::Customer;
  12 use SL::DB::Vendor;
  13 use SL::DB::TaxZone;
  14 use SL::DB::Employee;
  15 use SL::DB::Project;
  16 use SL::DB::Default;
  17 use SL::DB::Unit;
  18
  19 use SL::Helper::DateTime;
  20
  21 use List::Util qw(max first);
  22 use List::MoreUtils qw(none pairwise);
  23
  24 use Rose::Object::MakeMethods::Generic
  25 (
  26  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  27 );
  28
  29
  30 # safety
  31 __PACKAGE__->run_before('_check_auth');
  32
  33 __PACKAGE__->run_before('_recalc',
  34                         only => [ qw(edit update save) ]);
  35
  36 __PACKAGE__->run_before('_get_unalterable_data',
  37                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  38
  39 #
  40 # actions
  41 #
  42
  43 sub action_add {
  44   my ($self) = @_;
  45
  46   $self->order->transdate(DateTime->now_local());
  47
  48   $self->_pre_render();
  49   $self->render(
  50     'order/form',
  51     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  52            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  53            : '',
  54     %{$self->{template_args}}
  55   );
  56 }
  57
  58 sub action_edit {
  59   my ($self) = @_;
  60
  61   $self->_pre_render();
  62   $self->render(
  63     'order/form',
  64     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  65            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  66            : '',
  67     %{$self->{template_args}}
  68   );
  69 }
  70
  71 sub action_update {
  72   my ($self) = @_;
  73
  74   $self->_pre_render();
  75   $self->render(
  76     'order/form',
  77     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  78            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  79            : '',
  80     %{$self->{template_args}}
  81   );
  82 }
  83
  84 sub action_delete {
  85   my ($self) = @_;
  86
  87   my $errors = $self->_delete();
  88
  89   if (scalar @{ $errors }) {
  90     $self->js->flash('error', $_) foreach @{ $errors };
  91     return $self->js->render();
  92   }
  93
  94   flash_later('info', $::locale->text('The order has been deleted'));
  95   my @redirect_params = (
  96     action => 'edit',
  97     type   => $self->type,
  98   );
  99
 100   $self->redirect_to(@redirect_params);
 101 }
 102
 103 sub action_save {
 104   my ($self) = @_;
 105
 106   my $errors = $self->_save();
 107
 108   if (scalar @{ $errors }) {
 109     $self->js->flash('error', $_) foreach @{ $errors };
 110     return $self->js->render();
 111   }
 112
 113   flash_later('info', $::locale->text('The order has been saved'));
 114   my @redirect_params = (
 115     action => 'edit',
 116     type   => $self->type,
 117     id     => $self->order->id,
 118   );
 119
 120   $self->redirect_to(@redirect_params);
 121 }
 122
 123 sub action_customer_vendor_changed {
 124   my ($self) = @_;
 125
 126   my $cv_method = $self->cv;
 127
 128   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 129     $self->js->show('#cp_row');
 130   } else {
 131     $self->js->hide('#cp_row');
 132   }
 133
 134   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 135     $self->js->show('#shipto_row');
 136   } else {
 137     $self->js->hide('#shipto_row');
 138   }
 139
 140   $self->order->payment_id($self->order->$cv_method->payment_id);
 141   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 142
 143   $self->js
 144     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 145     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 146     ->val('#order_taxzone_id', $self->order->taxzone_id)
 147     ->val('#order_payment_id',       $self->order->payment_id)
 148     ->val('#order_delivery_term_id', $self->order->delivery_term_id)
 149     ->val('#order_intnotes',         $self->order->$cv_method->notes)
 150     ->focus('#order_' . $self->cv . '_id')
 151     ->render($self);
 152 }
 153
 154 sub action_add_item {
 155   my ($self) = @_;
 156
 157   my $form_attr = $::form->{add_item};
 158
 159   return unless $form_attr->{parts_id};
 160
 161   my $item = SL::DB::OrderItem->new;
 162   $item->assign_attributes(%$form_attr);
 163
 164   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 165   my $cv_method   = $self->cv;
 166   my $cv_discount = $self->order->$cv_method? $self->order->$cv_method->discount : 0.0;
 167
 168   my %new_attr;
 169   $new_attr{part}        = $part;
 170   $new_attr{description} = $part->description if ! $item->description;
 171   $new_attr{qty}         = 1.0                if ! $item->qty;
 172   $new_attr{unit}        = $part->unit;
 173   $new_attr{sellprice}   = $part->sellprice   if ! $item->sellprice;
 174   $new_attr{discount}    = $cv_discount       if ! $item->discount;
 175
 176   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 177   # they cannot be retrieved via custom_variables until the order/orderitem is
 178   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 179   $new_attr{custom_variables} = [];
 180
 181   $item->assign_attributes(%new_attr);
 182
 183   $self->order->add_items($item);
 184
 185   $self->_recalc();
 186
 187   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 188   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 189
 190   $self->js
 191     ->append('#row_table_id', $row_as_html)
 192     ->val('.add_item_input', '')
 193     ->run('row_table_scroll_down')
 194     ->run('row_set_keyboard_events_by_id', $item_id)
 195     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 196     ->focus('#add_item_parts_id_name');
 197
 198   $self->_js_redisplay_amounts_and_taxes;
 199   $self->js->render();
 200 }
 201
 202 sub action_recalc_amounts_and_taxes {
 203   my ($self) = @_;
 204
 205   $self->_recalc();
 206
 207   $self->_js_redisplay_linetotals;
 208   $self->_js_redisplay_amounts_and_taxes;
 209   $self->js->render();
 210 }
 211
 212 sub _js_redisplay_linetotals {
 213   my ($self) = @_;
 214
 215   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 216   $self->js
 217     ->run('redisplay_linetotals', \@data);
 218 }
 219
 220 sub _js_redisplay_amounts_and_taxes {
 221   my ($self) = @_;
 222
 223   $self->js
 224     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 225     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 226     ->remove('.tax_row')
 227     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 228 }
 229
 230 #
 231 # helpers
 232 #
 233
 234 sub init_valid_types {
 235   [ _sales_order_type(), _purchase_order_type() ];
 236 }
 237
 238 sub init_type {
 239   my ($self) = @_;
 240
 241   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 242     die "Not a valid type for order";
 243   }
 244
 245   $self->type($::form->{type});
 246 }
 247
 248 sub init_cv {
 249   my ($self) = @_;
 250
 251   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 252          : $self->type eq _purchase_order_type() ? 'vendor'
 253          : die "Not a valid type for order";
 254
 255   return $cv;
 256 }
 257
 258 sub init_p {
 259   SL::Presenter->get;
 260 }
 261
 262 sub init_order {
 263   _make_order();
 264 }
 265
 266 sub _check_auth {
 267   my ($self) = @_;
 268
 269   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 270
 271   my $right   = $right_for->{ $self->type };
 272   $right    ||= 'DOES_NOT_EXIST';
 273
 274   $::auth->assert($right);
 275 }
 276
 277 sub build_contact_select {
 278   my ($self) = @_;
 279
 280   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 281                        value_key  => 'cp_id',
 282                        title_key  => 'full_name_dep',
 283                        default    => $self->order->cp_id,
 284                        with_empty => 1,
 285                        style      => 'width: 300px',
 286   );
 287 }
 288
 289 sub build_shipto_select {
 290   my ($self) = @_;
 291
 292   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 293                        value_key  => 'shipto_id',
 294                        title_key  => 'displayable_id',
 295                        default    => $self->order->shipto_id,
 296                        with_empty => 1,
 297                        style      => 'width: 300px',
 298   );
 299 }
 300
 301 sub build_tax_rows {
 302   my ($self) = @_;
 303
 304   my $rows_as_html;
 305   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 306     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax);
 307   }
 308   return $rows_as_html;
 309 }
 310
 311
 312 sub _make_order {
 313   my ($self) = @_;
 314
 315   # add_items adds items to an order with no items for saving, but they cannot
 316   # be retrieved via items until the order is saved. Adding empty items to new
 317   # order here solves this problem.
 318   my $order;
 319   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 320   $order ||= SL::DB::Order->new(orderitems => []);
 321
 322   $order->assign_attributes(%{$::form->{order}});
 323
 324   return $order;
 325 }
 326
 327
 328 sub _recalc {
 329   my ($self) = @_;
 330
 331   # bb: todo: currency later
 332   $self->order->currency_id($::instance_conf->get_currency_id());
 333
 334   my %pat = $self->order->calculate_prices_and_taxes();
 335   $self->{taxes} = [];
 336   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 337     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 338     push(@{ $self->{taxes} }, { amount => $pat{taxes}->{$tax_chart_id},
 339                                 tax    => $tax });
 340   }
 341
 342   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 343 }
 344
 345
 346 sub _get_unalterable_data {
 347   my ($self) = @_;
 348
 349   foreach my $item (@{ $self->order->items }) {
 350     if ($item->id) {
 351       # load data from orderitems (db)
 352       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 353       $item->$_($db_item->$_) for qw(active_discount_source active_price_source longdescription);
 354     } else {
 355       # set data from part (or other sources)
 356       $item->longdescription($item->part->notes);
 357       #$item->active_price_source('');
 358       #$item->active_discount_source('');
 359     }
 360
 361     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 362     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 363     foreach my $var (@{ $item->cvars_by_config }) {
 364       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 365     }
 366     $item->parse_custom_variable_values;
 367   }
 368 }
 369
 370
 371 sub _delete {
 372   my ($self) = @_;
 373
 374   my $errors = [];
 375   my $db = $self->order->db;
 376
 377   $db->do_transaction(
 378     sub {
 379       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 380       $self->order->delete;
 381       my $spool = $::lx_office_conf{paths}->{spool};
 382       unlink map { "$spool/$_" } @spoolfiles if $spool;
 383
 384       1;
 385   }) || push(@{$errors}, $db->error);
 386
 387   return $errors;
 388 }
 389
 390
 391 sub _save {
 392   my ($self) = @_;
 393
 394   my $errors = [];
 395   my $db = $self->order->db;
 396
 397   $db->do_transaction(
 398     sub {
 399       $self->order->save();
 400   }) || push(@{$errors}, $db->error);
 401
 402   return $errors;
 403 }
 404
 405
 406 sub _pre_render {
 407   my ($self) = @_;
 408
 409   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 410   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 411                                                                                        deleted => 0 ] ],
 412                                                                     sort_by => 'name');
 413   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 414                                                                                        deleted => 0 ] ],
 415                                                                     sort_by => 'name');
 416   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 417                                                                                       active => 1 ] ],
 418                                                                    sort_by => 'projectnumber');
 419   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 420   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 421
 422   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 423
 424   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 425 }
 426
 427 sub _sales_order_type {
 428   'sales_order';
 429 }
 430
 431 sub _purchase_order_type {
 432   'purchase_order';
 433 }
 434
 435 1;